t/72pg.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use Sub::Name;
   7 use DBIx::Class::Optional::Dependencies ();
   8 use lib qw(t/lib);
   9 use DBICTest;
  10
  11 plan skip_all => 'Test needs ' . DBIx::Class::Optional::Dependencies->req_missing_for ('test_rdbms_pg')
  12   unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_rdbms_pg');
  13
  14 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  15
  16 plan skip_all => <<'EOM' unless $dsn && $user;
  17 Set $ENV{DBICTEST_PG_DSN}, _USER and _PASS to run this test
  18 ( NOTE: This test drops and creates tables called 'artist', 'cd',
  19 'timestamp_primary_key_test', 'track', 'casecheck', 'array_test' and
  20 'sequence_test' as well as following sequences: 'pkid1_seq', 'pkid2_seq' and
  21 'nonpkid_seq'. as well as following schemas: 'dbic_t_schema',
  22 'dbic_t_schema_2', 'dbic_t_schema_3', 'dbic_t_schema_4', and 'dbic_t_schema_5')
  23 EOM
  24
  25 ### load any test classes that are defined further down in the file via BEGIN blocks
  26
  27 our @test_classes; #< array that will be pushed into by test classes defined in this file
  28 DBICTest::Schema->load_classes( map {s/.+:://;$_} @test_classes ) if @test_classes;
  29
  30 ###  pre-connect tests (keep each test separate as to make sure rebless() runs)
  31   {
  32     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  33
  34     ok (!$s->storage->_dbh, 'definitely not connected');
  35
  36     # Check that datetime_parser returns correctly before we explicitly connect.
  37     SKIP: {
  38         skip (
  39           "Pg parser detection test needs " . DBIx::Class::Optional::Dependencies->req_missing_for ('test_dt_pg'),
  40           2
  41         ) unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_dt_pg');
  42
  43         my $store = ref $s->storage;
  44         is($store, 'DBIx::Class::Storage::DBI', 'Started with generic storage');
  45
  46         my $parser = $s->storage->datetime_parser;
  47         is( $parser, 'DateTime::Format::Pg', 'datetime_parser is as expected');
  48     }
  49
  50     ok (!$s->storage->_dbh, 'still not connected');
  51   }
  52
  53   {
  54     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  55     # make sure sqlt_type overrides work (::Storage::DBI::Pg does this)
  56     ok (!$s->storage->_dbh, 'definitely not connected');
  57     is ($s->storage->sqlt_type, 'PostgreSQL', 'sqlt_type correct pre-connection');
  58     ok (!$s->storage->_dbh, 'still not connected');
  59   }
  60
  61 # test LIMIT support
  62 {
  63   my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
  64   drop_test_schema($schema);
  65   create_test_schema($schema);
  66   for (1..6) {
  67     $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
  68   }
  69   my $it = $schema->resultset('Artist')->search( {},
  70     { rows => 3,
  71       offset => 2,
  72       order_by => 'artistid' }
  73   );
  74   is( $it->count, 3, "LIMIT count ok" );  # ask for 3 rows out of 6 artists
  75   is( $it->next->name, "Artist 3", "iterator->next ok" );
  76   $it->next;
  77   $it->next;
  78   $it->next;
  79   is( $it->next, undef, "next past end of resultset ok" );
  80
  81   # Limit with select-lock
  82   lives_ok {
  83     $schema->txn_do (sub {
  84       isa_ok (
  85         $schema->resultset('Artist')->find({artistid => 1}, {for => 'update', rows => 1}),
  86         'DBICTest::Schema::Artist',
  87       );
  88     });
  89   } 'Limited FOR UPDATE select works';
  90 }
  91
  92 # check if we indeed do support stuff
  93 my $test_server_supports_insert_returning = do {
  94   my $v = DBICTest::Schema->connect($dsn, $user, $pass)
  95                    ->storage
  96                     ->_get_dbh
  97                      ->get_info(18);
  98   $v =~ /^(\d+)\.(\d+)/
  99     or die "Unparseable Pg server version: $v\n";
 100
 101   ( sprintf ('%d.%d', $1, $2) >= 8.2 ) ? 1 : 0;
 102 };
 103 is (
 104   DBICTest::Schema->connect($dsn, $user, $pass)->storage->_use_insert_returning,
 105   $test_server_supports_insert_returning,
 106   'insert returning capability guessed correctly'
 107 );
 108
 109 my $schema;
 110 for my $use_insert_returning ($test_server_supports_insert_returning
 111   ? (0,1)
 112   : (0)
 113 ) {
 114
 115   no warnings qw/once redefine/;
 116   my $old_connection = DBICTest::Schema->can('connection');
 117   local *DBICTest::Schema::connection = subname 'DBICTest::Schema::connection' => sub {
 118     my $s = shift->$old_connection(@_);
 119     $s->storage->_use_insert_returning ($use_insert_returning);
 120     $s;
 121   };
 122
 123 ### test capability override
 124   {
 125     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
 126
 127     ok (!$s->storage->_dbh, 'definitely not connected');
 128
 129     ok (
 130       ! ($s->storage->_use_insert_returning xor $use_insert_returning),
 131       'insert returning capability set correctly',
 132     );
 133     ok (!$s->storage->_dbh, 'still not connected (capability override works)');
 134   }
 135
 136 ### connect, create postgres-specific test schema
 137
 138   $schema = DBICTest::Schema->connect($dsn, $user, $pass);
 139   $schema->storage->ensure_connected;
 140
 141   drop_test_schema($schema);
 142   create_test_schema($schema);
 143
 144 ### begin main tests
 145
 146 # run a BIG bunch of tests for last-insert-id / Auto-PK / sequence
 147 # discovery
 148   run_apk_tests($schema); #< older set of auto-pk tests
 149   run_extended_apk_tests($schema); #< new extended set of auto-pk tests
 150
 151 ### type_info tests
 152
 153   my $test_type_info = {
 154       'artistid' => {
 155           'data_type' => 'integer',
 156           'is_nullable' => 0,
 157           'size' => 4,
 158       },
 159       'name' => {
 160           'data_type' => 'character varying',
 161           'is_nullable' => 1,
 162           'size' => 100,
 163           'default_value' => undef,
 164       },
 165       'rank' => {
 166           'data_type' => 'integer',
 167           'is_nullable' => 0,
 168           'size' => 4,
 169           'default_value' => 13,
 170
 171       },
 172       'charfield' => {
 173           'data_type' => 'character',
 174           'is_nullable' => 1,
 175           'size' => 10,
 176           'default_value' => undef,
 177       },
 178       'arrayfield' => {
 179           'data_type' => 'integer[]',
 180           'is_nullable' => 1,
 181           'size' => undef,
 182           'default_value' => undef,
 183       },
 184   };
 185
 186   my $type_info = $schema->storage->columns_info_for('dbic_t_schema.artist');
 187   my $artistid_defval = delete $type_info->{artistid}->{default_value};
 188   like($artistid_defval,
 189        qr/^nextval\('([^\.]*\.){0,1}artist_artistid_seq'::(?:text|regclass)\)/,
 190        'columns_info_for - sequence matches Pg get_autoinc_seq expectations');
 191   is_deeply($type_info, $test_type_info,
 192             'columns_info_for - column data types');
 193
 194
 195
 196
 197 ####### Array tests
 198
 199   BEGIN {
 200     package DBICTest::Schema::ArrayTest;
 201     push @main::test_classes, __PACKAGE__;
 202
 203     use strict;
 204     use warnings;
 205     use base 'DBICTest::BaseResult';
 206
 207     __PACKAGE__->table('dbic_t_schema.array_test');
 208     __PACKAGE__->add_columns(qw/id arrayfield/);
 209     __PACKAGE__->column_info_from_storage(1);
 210     __PACKAGE__->set_primary_key('id');
 211
 212   }
 213   SKIP: {
 214     skip "Need DBD::Pg 2.9.2 or newer for array tests", 4 if $DBD::Pg::VERSION < 2.009002;
 215
 216     my $arr_rs = $schema->resultset('ArrayTest');
 217
 218     lives_ok {
 219       $arr_rs->create({
 220         arrayfield => [1, 2],
 221       });
 222     } 'inserting arrayref as pg array data';
 223
 224     lives_ok {
 225       $arr_rs->update({
 226         arrayfield => [3, 4],
 227       });
 228     } 'updating arrayref as pg array data';
 229
 230     $arr_rs->create({
 231       arrayfield => [5, 6],
 232     });
 233
 234     lives_ok {
 235       $schema->populate('ArrayTest', [
 236         [ qw/arrayfield/ ],
 237         [ [0,0]          ],
 238       ]);
 239     } 'inserting arrayref using void ctx populate';
 240
 241     # Search using arrays
 242     lives_ok {
 243       is_deeply (
 244         $arr_rs->search({ arrayfield => { -value => [3,4] } })->first->arrayfield,
 245         [3,4],
 246         'Array value matches'
 247       );
 248     } 'searching by arrayref';
 249
 250     lives_ok {
 251       is_deeply (
 252         $arr_rs->search({ arrayfield => { '=' => { -value => [3,4] }} })->first->arrayfield,
 253         [3,4],,
 254         'Array value matches explicit equal'
 255       );
 256     } 'searching by arrayref (explicit equal sign)';
 257
 258     lives_ok {
 259       is_deeply (
 260         $arr_rs->search({ arrayfield => { '>' => { -value => [3,1] }} })->first->arrayfield,
 261         [3,4],
 262         'Array value matches greater than'
 263       );
 264     } 'searching by arrayref (greater than)';
 265
 266     lives_ok {
 267       is (
 268         $arr_rs->search({ arrayfield => { '>' => { -value => [3,7] }} })->count,
 269         1,
 270         'Greater than search found [5,6]',
 271       );
 272     } 'searching by arrayref (greater than)';
 273
 274     # Find using arrays
 275     lives_ok {
 276       is_deeply (
 277         $arr_rs->find({ arrayfield => { -value => [3,4] } })->arrayfield,
 278         [3,4],
 279         'Array value matches implicit equal'
 280       );
 281     } 'find by arrayref';
 282
 283     lives_ok {
 284       is_deeply (
 285         $arr_rs->find({ arrayfield => { '=' => { -value => [3,4] }} })->arrayfield,
 286         [3,4],
 287         'Array value matches explicit equal'
 288       );
 289     } 'find by arrayref (equal)';
 290
 291     # test inferred condition for creation
 292     TODO: for my $cond (
 293       { -value => [3,4] },
 294       \[ '= ?' => [arrayfield => [3, 4]] ],
 295     ) {
 296       local $TODO = 'No introspection of complex conditions :(';
 297       my $arr_rs_cond = $arr_rs->search({ arrayfield => $cond });
 298
 299       my $row = $arr_rs_cond->create({});
 300       is_deeply ($row->arrayfield, [3,4], 'Array value taken from $rs condition');
 301       $row->discard_changes;
 302       is_deeply ($row->arrayfield, [3,4], 'Array value made it to storage');
 303     }
 304   }
 305
 306 ########## Case check
 307
 308   BEGIN {
 309     package DBICTest::Schema::Casecheck;
 310     push @main::test_classes, __PACKAGE__;
 311
 312     use strict;
 313     use warnings;
 314     use base 'DBIx::Class::Core';
 315
 316     __PACKAGE__->table('dbic_t_schema.casecheck');
 317     __PACKAGE__->add_columns(qw/id name NAME uc_name/);
 318     __PACKAGE__->column_info_from_storage(1);
 319     __PACKAGE__->set_primary_key('id');
 320   }
 321
 322   my $name_info = $schema->source('Casecheck')->column_info( 'name' );
 323   is( $name_info->{size}, 1, "Case sensitive matching info for 'name'" );
 324
 325   my $NAME_info = $schema->source('Casecheck')->column_info( 'NAME' );
 326   is( $NAME_info->{size}, 2, "Case sensitive matching info for 'NAME'" );
 327
 328   my $uc_name_info = $schema->source('Casecheck')->column_info( 'uc_name' );
 329   is( $uc_name_info->{size}, 3, "Case insensitive matching info for 'uc_name'" );
 330
 331
 332 ## Test ResultSet->update
 333 my $artist = $schema->resultset('Artist')->first;
 334 my $cds = $artist->cds_unordered->search({
 335     year => { '!=' => 2010 }
 336 }, { prefetch => 'liner_notes' });
 337 lives_ok { $cds->update({ year => '2010' }) } 'Update on prefetched rs';
 338
 339 ## Test SELECT ... FOR UPDATE
 340
 341   SKIP: {
 342       if(eval { require Sys::SigAction }) {
 343           Sys::SigAction->import( 'set_sig_handler' );
 344       }
 345       else {
 346         skip "Sys::SigAction is not available", 6;
 347       }
 348
 349       my ($timed_out, $artist2);
 350
 351       for my $t (
 352         {
 353           # Make sure that an error was raised, and that the update failed
 354           update_lock => 1,
 355           test_sub => sub {
 356             ok($timed_out, "update from second schema times out");
 357             ok($artist2->is_column_changed('name'), "'name' column is still dirty from second schema");
 358           },
 359         },
 360         {
 361           # Make sure that an error was NOT raised, and that the update succeeded
 362           update_lock => 0,
 363           test_sub => sub {
 364             ok(! $timed_out, "update from second schema DOES NOT timeout");
 365             ok(! $artist2->is_column_changed('name'), "'name' column is NOT dirty from second schema");
 366           },
 367         },
 368       ) {
 369         # create a new schema
 370         my $schema2 = DBICTest::Schema->connect($dsn, $user, $pass);
 371         $schema2->source("Artist")->name("dbic_t_schema.artist");
 372
 373         $schema->txn_do( sub {
 374           my $rs = $schema->resultset('Artist')->search(
 375               {
 376                   artistid => 1
 377               },
 378               $t->{update_lock} ? { for => 'update' } : {}
 379           );
 380           ok ($rs->count, 'Count works');
 381
 382           my $artist = $rs->next;
 383           is($artist->artistid, 1, "select returns artistid = 1");
 384
 385           $timed_out = 0;
 386           eval {
 387               my $h = set_sig_handler( 'ALRM', sub { die "DBICTestTimeout" } );
 388               alarm(2);
 389               $artist2 = $schema2->resultset('Artist')->find(1);
 390               $artist2->name('fooey');
 391               $artist2->update;
 392               alarm(0);
 393           };
 394           $timed_out = $@ =~ /DBICTestTimeout/;
 395         });
 396
 397         $t->{test_sub}->();
 398       }
 399   }
 400
 401
 402 ######## other older Auto-pk tests
 403
 404   $schema->source("SequenceTest")->name("dbic_t_schema.sequence_test");
 405   for (1..5) {
 406       my $st = $schema->resultset('SequenceTest')->create({ name => 'foo' });
 407       is($st->pkid1, $_, "Auto-PK for sequence without default: First primary key");
 408       is($st->pkid2, $_ + 9, "Auto-PK for sequence without default: Second primary key");
 409       is($st->nonpkid, $_ + 19, "Auto-PK for sequence without default: Non-primary key");
 410   }
 411   my $st = $schema->resultset('SequenceTest')->create({ name => 'foo', pkid1 => 55 });
 412   is($st->pkid1, 55, "Auto-PK for sequence without default: First primary key set manually");
 413
 414
 415 ######## test non-serial auto-pk
 416
 417   if ($schema->storage->_use_insert_returning) {
 418     $schema->source('TimestampPrimaryKey')->name('dbic_t_schema.timestamp_primary_key_test');
 419     my $row = $schema->resultset('TimestampPrimaryKey')->create({});
 420     ok $row->id;
 421   }
 422
 423 ######## test with_deferred_fk_checks
 424
 425   $schema->source('CD')->name('dbic_t_schema.cd');
 426   $schema->source('Track')->name('dbic_t_schema.track');
 427   lives_ok {
 428     $schema->storage->with_deferred_fk_checks(sub {
 429       $schema->resultset('Track')->create({
 430         trackid => 999, cd => 999, position => 1, title => 'deferred FK track'
 431       });
 432       $schema->resultset('CD')->create({
 433         artist => 1, cdid => 999, year => '2003', title => 'deferred FK cd'
 434       });
 435     });
 436   } 'with_deferred_fk_checks code survived';
 437
 438   is eval { $schema->resultset('Track')->find(999)->title }, 'deferred FK track',
 439      'code in with_deferred_fk_checks worked';
 440
 441   throws_ok {
 442     $schema->resultset('Track')->create({
 443       trackid => 1, cd => 9999, position => 1, title => 'Track1'
 444     });
 445   } qr/constraint/i, 'with_deferred_fk_checks is off';
 446 }
 447
 448 done_testing;
 449
 450 END {
 451     return unless $schema;
 452     drop_test_schema($schema);
 453     eapk_drop_all($schema);
 454     undef $schema;
 455 };
 456
 457
 458 ######### SUBROUTINES
 459
 460 sub create_test_schema {
 461     my $schema = shift;
 462     $schema->storage->dbh_do(sub {
 463       my (undef,$dbh) = @_;
 464
 465       local $dbh->{Warn} = 0;
 466
 467       my $std_artist_table = <<EOS;
 468 (
 469   artistid serial PRIMARY KEY
 470   , name VARCHAR(100)
 471   , rank INTEGER NOT NULL DEFAULT '13'
 472   , charfield CHAR(10)
 473   , arrayfield INTEGER[]
 474 )
 475 EOS
 476
 477       $dbh->do("CREATE SCHEMA dbic_t_schema");
 478       $dbh->do("CREATE TABLE dbic_t_schema.artist $std_artist_table");
 479
 480       $dbh->do(<<EOS);
 481 CREATE TABLE dbic_t_schema.timestamp_primary_key_test (
 482   id timestamp default current_timestamp
 483 )
 484 EOS
 485       $dbh->do(<<EOS);
 486 CREATE TABLE dbic_t_schema.cd (
 487   cdid int PRIMARY KEY,
 488   artist int,
 489   title varchar(255),
 490   year varchar(4),
 491   genreid int,
 492   single_track int
 493 )
 494 EOS
 495       $dbh->do(<<EOS);
 496 CREATE TABLE dbic_t_schema.track (
 497   trackid int,
 498   cd int REFERENCES dbic_t_schema.cd(cdid) DEFERRABLE,
 499   position int,
 500   title varchar(255),
 501   last_updated_on date,
 502   last_updated_at date
 503 )
 504 EOS
 505
 506       $dbh->do(<<EOS);
 507 CREATE TABLE dbic_t_schema.sequence_test (
 508     pkid1 integer
 509     , pkid2 integer
 510     , nonpkid integer
 511     , name VARCHAR(100)
 512     , CONSTRAINT pk PRIMARY KEY(pkid1, pkid2)
 513 )
 514 EOS
 515       $dbh->do("CREATE SEQUENCE pkid1_seq START 1 MAXVALUE 999999 MINVALUE 0");
 516       $dbh->do("CREATE SEQUENCE pkid2_seq START 10 MAXVALUE 999999 MINVALUE 0");
 517       $dbh->do("CREATE SEQUENCE nonpkid_seq START 20 MAXVALUE 999999 MINVALUE 0");
 518       $dbh->do(<<EOS);
 519 CREATE TABLE dbic_t_schema.casecheck (
 520     id serial PRIMARY KEY
 521     , "name" VARCHAR(1)
 522     , "NAME" VARCHAR(2)
 523     , "UC_NAME" VARCHAR(3)
 524 )
 525 EOS
 526       $dbh->do(<<EOS);
 527 CREATE TABLE dbic_t_schema.array_test (
 528     id serial PRIMARY KEY
 529     , arrayfield INTEGER[]
 530 )
 531 EOS
 532       $dbh->do("CREATE SCHEMA dbic_t_schema_2");
 533       $dbh->do("CREATE TABLE dbic_t_schema_2.artist $std_artist_table");
 534       $dbh->do("CREATE SCHEMA dbic_t_schema_3");
 535       $dbh->do("CREATE TABLE dbic_t_schema_3.artist $std_artist_table");
 536       $dbh->do('set search_path=dbic_t_schema,public');
 537       $dbh->do("CREATE SCHEMA dbic_t_schema_4");
 538       $dbh->do("CREATE SCHEMA dbic_t_schema_5");
 539       $dbh->do(<<EOS);
 540  CREATE TABLE dbic_t_schema_4.artist
 541  (
 542    artistid integer not null default nextval('artist_artistid_seq'::regclass) PRIMARY KEY
 543    , name VARCHAR(100)
 544    , rank INTEGER NOT NULL DEFAULT '13'
 545    , charfield CHAR(10)
 546    , arrayfield INTEGER[]
 547  );
 548 EOS
 549       $dbh->do('set search_path=public,dbic_t_schema,dbic_t_schema_3');
 550       $dbh->do('create sequence public.artist_artistid_seq'); #< in the public schema
 551       $dbh->do(<<EOS);
 552  CREATE TABLE dbic_t_schema_5.artist
 553  (
 554    artistid integer not null default nextval('public.artist_artistid_seq'::regclass) PRIMARY KEY
 555    , name VARCHAR(100)
 556    , rank INTEGER NOT NULL DEFAULT '13'
 557    , charfield CHAR(10)
 558    , arrayfield INTEGER[]
 559  );
 560 EOS
 561       $dbh->do('set search_path=dbic_t_schema,public');
 562   });
 563 }
 564
 565
 566
 567 sub drop_test_schema {
 568     my ( $schema, $warn_exceptions ) = @_;
 569
 570     $schema->storage->dbh_do(sub {
 571         my (undef,$dbh) = @_;
 572
 573         local $dbh->{Warn} = 0;
 574
 575         for my $stat (
 576                       'DROP SCHEMA dbic_t_schema_5 CASCADE',
 577                       'DROP SEQUENCE public.artist_artistid_seq CASCADE',
 578                       'DROP SCHEMA dbic_t_schema_4 CASCADE',
 579                       'DROP SCHEMA dbic_t_schema CASCADE',
 580                       'DROP SEQUENCE pkid1_seq CASCADE',
 581                       'DROP SEQUENCE pkid2_seq CASCADE',
 582                       'DROP SEQUENCE nonpkid_seq CASCADE',
 583                       'DROP SCHEMA dbic_t_schema_2 CASCADE',
 584                       'DROP SCHEMA dbic_t_schema_3 CASCADE',
 585                      ) {
 586             eval { $dbh->do ($stat) };
 587             diag $@ if $@ && $warn_exceptions;
 588         }
 589     });
 590 }
 591
 592
 593 ###  auto-pk / last_insert_id / sequence discovery
 594 sub run_apk_tests {
 595     my $schema = shift;
 596
 597     # This is in Core now, but it's here just to test that it doesn't break
 598     $schema->class('Artist')->load_components('PK::Auto');
 599     cmp_ok( $schema->resultset('Artist')->count, '==', 0, 'this should start with an empty artist table');
 600
 601     # test that auto-pk also works with the defined search path by
 602     # un-schema-qualifying the table name
 603     apk_t_set($schema,'artist');
 604
 605     my $unq_new;
 606     lives_ok {
 607         $unq_new = $schema->resultset('Artist')->create({ name => 'baz' });
 608     } 'insert into unqualified, shadowed table succeeds';
 609
 610     is($unq_new && $unq_new->artistid, 1, "and got correct artistid");
 611
 612     my @test_schemas = ( [qw| dbic_t_schema_2    1  |],
 613                          [qw| dbic_t_schema_3    1  |],
 614                          [qw| dbic_t_schema_4    2  |],
 615                          [qw| dbic_t_schema_5    1  |],
 616                        );
 617     foreach my $t ( @test_schemas ) {
 618         my ($sch_name, $start_num) = @$t;
 619         #test with dbic_t_schema_2
 620         apk_t_set($schema,"$sch_name.artist");
 621         my $another_new;
 622         lives_ok {
 623             $another_new = $schema->resultset('Artist')->create({ name => 'Tollbooth Willy'});
 624             is( $another_new->artistid,$start_num, "got correct artistid for $sch_name")
 625                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 626         } "$sch_name liid 1 did not die"
 627             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 628         lives_ok {
 629             $another_new = $schema->resultset('Artist')->create({ name => 'Adam Sandler'});
 630             is( $another_new->artistid,$start_num+1, "got correct artistid for $sch_name")
 631                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 632         } "$sch_name liid 2 did not die"
 633             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 634
 635     }
 636
 637     lives_ok {
 638         apk_t_set($schema,'dbic_t_schema.artist');
 639         my $new = $schema->resultset('Artist')->create({ name => 'foo' });
 640         is($new->artistid, 4, "Auto-PK worked");
 641         $new = $schema->resultset('Artist')->create({ name => 'bar' });
 642         is($new->artistid, 5, "Auto-PK worked");
 643     } 'old auto-pk tests did not die either';
 644 }
 645
 646 # sets the artist table name and clears sequence name cache
 647 sub apk_t_set {
 648     my ( $s, $n ) = @_;
 649     $s->source("Artist")->name($n);
 650     $s->source('Artist')->column_info('artistid')->{sequence} = undef; #< clear sequence name cache
 651 }
 652
 653
 654 ######## EXTENDED AUTO-PK TESTS
 655
 656 my @eapk_id_columns;
 657 BEGIN {
 658   package DBICTest::Schema::ExtAPK;
 659   push @main::test_classes, __PACKAGE__;
 660
 661   use strict;
 662   use warnings;
 663   use base 'DBIx::Class::Core';
 664
 665   __PACKAGE__->table('apk');
 666
 667   @eapk_id_columns = qw( id1 id2 id3 id4 );
 668   __PACKAGE__->add_columns(
 669     map { $_ => { data_type => 'integer', is_auto_increment => 1 } }
 670        @eapk_id_columns
 671   );
 672
 673   __PACKAGE__->set_primary_key('id2'); #< note the SECOND column is
 674                                        #the primary key
 675 }
 676
 677 my @eapk_schemas;
 678 BEGIN{ @eapk_schemas = map "dbic_apk_$_", 0..5 }
 679 my %seqs; #< hash of schema.table.col => currval of its (DBIC) primary key sequence
 680
 681 sub run_extended_apk_tests {
 682   my $schema = shift;
 683
 684   #save the search path and reset it at the end
 685   my $search_path_save = eapk_get_search_path($schema);
 686
 687   eapk_drop_all($schema);
 688   %seqs = ();
 689
 690   # make the test schemas and sequences
 691   $schema->storage->dbh_do(sub {
 692     my ( undef, $dbh ) = @_;
 693
 694     $dbh->do("CREATE SCHEMA $_")
 695         for @eapk_schemas;
 696
 697     $dbh->do("CREATE SEQUENCE $eapk_schemas[5].fooseq");
 698     $dbh->do("SELECT setval('$eapk_schemas[5].fooseq',400)");
 699     $seqs{"$eapk_schemas[1].apk.id2"} = 400;
 700
 701     $dbh->do("CREATE SEQUENCE $eapk_schemas[4].fooseq");
 702     $dbh->do("SELECT setval('$eapk_schemas[4].fooseq',300)");
 703     $seqs{"$eapk_schemas[3].apk.id2"} = 300;
 704
 705     $dbh->do("CREATE SEQUENCE $eapk_schemas[3].fooseq");
 706     $dbh->do("SELECT setval('$eapk_schemas[3].fooseq',200)");
 707     $seqs{"$eapk_schemas[4].apk.id2"} = 200;
 708
 709     $dbh->do("SET search_path = ".join ',', reverse @eapk_schemas );
 710   });
 711
 712   # clear our search_path cache
 713   $schema->storage->{_pg_search_path} = undef;
 714
 715   eapk_create( $schema,
 716                with_search_path => [0,1],
 717              );
 718   eapk_create( $schema,
 719                with_search_path => [1,0,'public'],
 720                nextval => "$eapk_schemas[5].fooseq",
 721              );
 722   eapk_create( $schema,
 723                with_search_path => ['public',0,1],
 724                qualify_table => 2,
 725              );
 726   eapk_create( $schema,
 727                with_search_path => [3,1,0,'public'],
 728                nextval => "$eapk_schemas[4].fooseq",
 729              );
 730   eapk_create( $schema,
 731                with_search_path => [3,1,0,'public'],
 732                nextval => "$eapk_schemas[3].fooseq",
 733                qualify_table => 4,
 734              );
 735
 736   eapk_poke( $schema );
 737   eapk_poke( $schema, 0 );
 738   eapk_poke( $schema, 2 );
 739   eapk_poke( $schema, 4 );
 740   eapk_poke( $schema, 1 );
 741   eapk_poke( $schema, 0 );
 742   eapk_poke( $schema, 1 );
 743   eapk_poke( $schema );
 744   eapk_poke( $schema, 4 );
 745   eapk_poke( $schema, 3 );
 746   eapk_poke( $schema, 1 );
 747   eapk_poke( $schema, 2 );
 748   eapk_poke( $schema, 0 );
 749
 750   # set our search path back
 751   eapk_set_search_path( $schema, @$search_path_save );
 752 }
 753
 754 # do a DBIC create on the apk table in the given schema number (which is an
 755 # index of @eapk_schemas)
 756
 757 sub eapk_poke {
 758   my ($s, $schema_num) = @_;
 759
 760   my $schema_name = defined $schema_num
 761       ? $eapk_schemas[$schema_num]
 762       : '';
 763
 764   my $schema_name_actual = $schema_name || eapk_find_visible_schema($s);
 765
 766   $s->source('ExtAPK')->name($schema_name ? $schema_name.'.apk' : 'apk');
 767   #< clear sequence name cache
 768   $s->source('ExtAPK')->column_info($_)->{sequence} = undef
 769       for @eapk_id_columns;
 770
 771   no warnings 'uninitialized';
 772   lives_ok {
 773     my $new;
 774     for my $inc (1,2,3) {
 775       $new = $schema->resultset('ExtAPK')->create({ id1 => 1});
 776       my $proper_seqval = ++$seqs{"$schema_name_actual.apk.id2"};
 777       is( $new->id2, $proper_seqval, "$schema_name_actual.apk.id2 correct inc $inc" )
 778           or eapk_seq_diag($s,$schema_name);
 779       $new->discard_changes;
 780       is( $new->id1, 1 );
 781       for my $id ('id3','id4') {
 782         my $proper_seqval = ++$seqs{"$schema_name_actual.apk.$id"};
 783         is( $new->$id, $proper_seqval, "$schema_name_actual.apk.$id correct inc $inc" )
 784             or eapk_seq_diag($s,$schema_name);
 785       }
 786     }
 787   } "create in schema '$schema_name' lives"
 788       or eapk_seq_diag($s,$schema_name);
 789 }
 790
 791 # print diagnostic info on which sequences were found in the ExtAPK
 792 # class
 793 sub eapk_seq_diag {
 794     my $s = shift;
 795     my $schema = shift || eapk_find_visible_schema($s);
 796
 797     diag "$schema.apk sequences: ",
 798         join(', ',
 799              map "$_:".($s->source('ExtAPK')->column_info($_)->{sequence} || '<none>'),
 800              @eapk_id_columns
 801             );
 802 }
 803
 804 # get the postgres search path as an arrayref
 805 sub eapk_get_search_path {
 806     my ( $s ) = @_;
 807     # cache the search path as ['schema','schema',...] in the storage
 808     # obj
 809
 810     return $s->storage->dbh_do(sub {
 811         my (undef, $dbh) = @_;
 812         my @search_path;
 813         my ($sp_string) = $dbh->selectrow_array('SHOW search_path');
 814         while ( $sp_string =~ s/("[^"]+"|[^,]+),?// ) {
 815             unless( defined $1 and length $1 ) {
 816                 die "search path sanity check failed: '$1'";
 817             }
 818             push @search_path, $1;
 819         }
 820         \@search_path
 821     });
 822 }
 823 sub eapk_set_search_path {
 824     my ($s,@sp) = @_;
 825     my $sp = join ',',@sp;
 826     $s->storage->dbh_do( sub { $_[1]->do("SET search_path = $sp") } );
 827 }
 828
 829 # create the apk table in the given schema, can set whether the table name is qualified, what the nextval is for the second ID
 830 sub eapk_create {
 831     my ($schema, %a) = @_;
 832
 833     $schema->storage->dbh_do(sub {
 834         my (undef,$dbh) = @_;
 835
 836         my $searchpath_save;
 837         if ( $a{with_search_path} ) {
 838             ($searchpath_save) = $dbh->selectrow_array('SHOW search_path');
 839
 840             my $search_path = join ',',map {/\D/ ? $_ : $eapk_schemas[$_]} @{$a{with_search_path}};
 841
 842             $dbh->do("SET search_path = $search_path");
 843         }
 844
 845         my $table_name = $a{qualify_table}
 846             ? ($eapk_schemas[$a{qualify_table}] || die). ".apk"
 847             : 'apk';
 848         local $_[1]->{Warn} = 0;
 849
 850         my $id_def = $a{nextval}
 851             ? "integer not null default nextval('$a{nextval}'::regclass)"
 852             : 'serial';
 853         $dbh->do(<<EOS);
 854 CREATE TABLE $table_name (
 855   id1 serial
 856   , id2 $id_def
 857   , id3 serial primary key
 858   , id4 serial
 859 )
 860 EOS
 861
 862         if( $searchpath_save ) {
 863             $dbh->do("SET search_path = $searchpath_save");
 864         }
 865     });
 866 }
 867
 868 sub eapk_drop_all {
 869     my ( $schema, $warn_exceptions ) = @_;
 870
 871     $schema->storage->dbh_do(sub {
 872         my (undef,$dbh) = @_;
 873
 874         local $dbh->{Warn} = 0;
 875
 876         # drop the test schemas
 877         for (@eapk_schemas ) {
 878             eval{ $dbh->do("DROP SCHEMA $_ CASCADE") };
 879             diag $@ if $@ && $warn_exceptions;
 880         }
 881
 882
 883     });
 884 }
 885
 886 sub eapk_find_visible_schema {
 887     my ($s) = @_;
 888
 889     my ($schema) =
 890         $s->storage->dbh_do(sub {
 891             $_[1]->selectrow_array(<<EOS);
 892 SELECT n.nspname
 893 FROM pg_catalog.pg_namespace n
 894 JOIN pg_catalog.pg_class c ON c.relnamespace = n.oid
 895 WHERE c.relname = 'apk'
 896   AND pg_catalog.pg_table_is_visible(c.oid)
 897 EOS
 898         });
 899     return $schema;
 900 }