t/71mysql.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use lib qw(t/lib);
   7 use DBICTest;
   8 use DBI::Const::GetInfoType;
   9 use DBIC::SqlMakerTest;
  10
  11 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_MYSQL_${_}" } qw/DSN USER PASS/};
  12
  13 #warn "$dsn $user $pass";
  14
  15 plan skip_all => 'Set $ENV{DBICTEST_MYSQL_DSN}, _USER and _PASS to run this test'
  16   unless ($dsn && $user);
  17
  18 my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
  19
  20 my $dbh = $schema->storage->dbh;
  21
  22 $dbh->do("DROP TABLE IF EXISTS artist;");
  23
  24 $dbh->do("CREATE TABLE artist (artistid INTEGER NOT NULL AUTO_INCREMENT PRIMARY KEY, name VARCHAR(100), rank INTEGER NOT NULL DEFAULT '13', charfield CHAR(10));");
  25
  26 $dbh->do("DROP TABLE IF EXISTS cd;");
  27
  28 $dbh->do("CREATE TABLE cd (cdid INTEGER NOT NULL AUTO_INCREMENT PRIMARY KEY, artist INTEGER, title TEXT, year DATE, genreid INTEGER, single_track INTEGER);");
  29
  30 $dbh->do("DROP TABLE IF EXISTS producer;");
  31
  32 $dbh->do("CREATE TABLE producer (producerid INTEGER NOT NULL AUTO_INCREMENT PRIMARY KEY, name TEXT);");
  33
  34 $dbh->do("DROP TABLE IF EXISTS cd_to_producer;");
  35
  36 $dbh->do("CREATE TABLE cd_to_producer (cd INTEGER,producer INTEGER);");
  37
  38 $dbh->do("DROP TABLE IF EXISTS owners;");
  39
  40 $dbh->do("CREATE TABLE owners (id INTEGER NOT NULL AUTO_INCREMENT PRIMARY KEY, name VARCHAR(100) NOT NULL);");
  41
  42 $dbh->do("DROP TABLE IF EXISTS books;");
  43
  44 $dbh->do("CREATE TABLE books (id INTEGER NOT NULL AUTO_INCREMENT PRIMARY KEY, source VARCHAR(100) NOT NULL, owner integer NOT NULL, title varchar(100) NOT NULL,  price integer);");
  45
  46 #'dbi:mysql:host=localhost;database=dbic_test', 'dbic_test', '');
  47
  48 # make sure sqlt_type overrides work (::Storage::DBI::mysql does this)
  49 {
  50   my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
  51
  52   ok (!$schema->storage->_dbh, 'definitely not connected');
  53   is ($schema->storage->sqlt_type, 'MySQL', 'sqlt_type correct pre-connection');
  54 }
  55
  56 # This is in Core now, but it's here just to test that it doesn't break
  57 $schema->class('Artist')->load_components('PK::Auto');
  58
  59 # test primary key handling
  60 my $new = $schema->resultset('Artist')->create({ name => 'foo' });
  61 ok($new->artistid, "Auto-PK worked");
  62
  63 # test LIMIT support
  64 for (1..6) {
  65     $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
  66 }
  67 my $it = $schema->resultset('Artist')->search( {},
  68     { rows => 3,
  69       offset => 2,
  70       order_by => 'artistid' }
  71 );
  72 is( $it->count, 3, "LIMIT count ok" );  # ask for 3 rows out of 7 artists
  73 is( $it->next->name, "Artist 2", "iterator->next ok" );
  74 $it->next;
  75 $it->next;
  76 is( $it->next, undef, "next past end of resultset ok" );
  77
  78 # Limit with select-lock
  79 lives_ok {
  80   $schema->txn_do (sub {
  81     isa_ok (
  82       $schema->resultset('Artist')->find({artistid => 1}, {for => 'update', rows => 1}),
  83       'DBICTest::Schema::Artist',
  84     );
  85   });
  86 } 'Limited FOR UPDATE select works';
  87
  88 # shared-lock
  89 lives_ok {
  90   $schema->txn_do (sub {
  91     isa_ok (
  92       $schema->resultset('Artist')->find({artistid => 1}, {for => 'shared'}),
  93       'DBICTest::Schema::Artist',
  94     );
  95   });
  96 } 'LOCK IN SHARE MODE select works';
  97
  98 my $test_type_info = {
  99     'artistid' => {
 100         'data_type' => 'INT',
 101         'is_nullable' => 0,
 102         'size' => 11,
 103         'default_value' => undef,
 104     },
 105     'name' => {
 106         'data_type' => 'VARCHAR',
 107         'is_nullable' => 1,
 108         'size' => 100,
 109         'default_value' => undef,
 110     },
 111     'rank' => {
 112         'data_type' => 'INT',
 113         'is_nullable' => 0,
 114         'size' => 11,
 115         'default_value' => 13,
 116     },
 117     'charfield' => {
 118         'data_type' => 'CHAR',
 119         'is_nullable' => 1,
 120         'size' => 10,
 121         'default_value' => undef,
 122     },
 123 };
 124
 125 $schema->populate ('Owners', [
 126   [qw/id  name  /],
 127   [qw/1   wiggle/],
 128   [qw/2   woggle/],
 129   [qw/3   boggle/],
 130 ]);
 131
 132 $schema->populate ('BooksInLibrary', [
 133   [qw/source  owner title   /],
 134   [qw/Library 1     secrets1/],
 135   [qw/Eatery  1     secrets2/],
 136   [qw/Library 2     secrets3/],
 137 ]);
 138
 139 #
 140 # try a distinct + prefetch on tables with identically named columns
 141 # (mysql doesn't seem to like subqueries with equally named columns)
 142 #
 143
 144 {
 145   # try a ->has_many direction (due to a 'multi' accessor the select/group_by group is collapsed)
 146   my $owners = $schema->resultset ('Owners')->search (
 147     { 'books.id' => { '!=', undef }},
 148     { prefetch => 'books', distinct => 1 }
 149   );
 150   my $owners2 = $schema->resultset ('Owners')->search ({ id => { -in => $owners->get_column ('me.id')->as_query }});
 151   for ($owners, $owners2) {
 152     is ($_->all, 2, 'Prefetched grouped search returns correct number of rows');
 153     is ($_->count, 2, 'Prefetched grouped search returns correct count');
 154   }
 155
 156   # try a ->belongs_to direction (no select collapse)
 157   my $books = $schema->resultset ('BooksInLibrary')->search (
 158     { 'owner.name' => 'wiggle' },
 159     { prefetch => 'owner', distinct => 1 }
 160   );
 161   my $books2 = $schema->resultset ('BooksInLibrary')->search ({ id => { -in => $books->get_column ('me.id')->as_query }});
 162   for ($books, $books2) {
 163     is ($_->all, 1, 'Prefetched grouped search returns correct number of rows');
 164     is ($_->count, 1, 'Prefetched grouped search returns correct count');
 165   }
 166 }
 167
 168 SKIP: {
 169     my $mysql_version = $dbh->get_info( $GetInfoType{SQL_DBMS_VER} );
 170     skip "Cannot determine MySQL server version", 1 if !$mysql_version;
 171
 172     my ($v1, $v2, $v3) = $mysql_version =~ /^(\d+)\.(\d+)(?:\.(\d+))?/;
 173     skip "Cannot determine MySQL server version", 1 if !$v1 || !defined($v2);
 174
 175     $v3 ||= 0;
 176
 177     if( ($v1 < 5) || ($v1 == 5 && $v2 == 0 && $v3 <= 3) ) {
 178         $test_type_info->{charfield}->{data_type} = 'VARCHAR';
 179     }
 180
 181     my $type_info = $schema->storage->columns_info_for('artist');
 182     is_deeply($type_info, $test_type_info, 'columns_info_for - column data types');
 183 }
 184
 185 my $cd = $schema->resultset ('CD')->create ({});
 186 my $producer = $schema->resultset ('Producer')->create ({});
 187 lives_ok { $cd->set_producers ([ $producer ]) } 'set_relationship doesnt die';
 188
 189 {
 190   my $artist = $schema->resultset('Artist')->next;
 191   my $cd = $schema->resultset('CD')->next;
 192   $cd->set_from_related ('artist', $artist);
 193   $cd->update;
 194
 195   my $rs = $schema->resultset('CD')->search ({}, { prefetch => 'artist' });
 196
 197   lives_ok sub {
 198     my $cd = $rs->next;
 199     is ($cd->artist->name, $artist->name, 'Prefetched artist');
 200   }, 'join does not throw (mysql 3 test)';
 201
 202   # induce a jointype override, make sure it works even if we don't have mysql3
 203   local $schema->storage->sql_maker->{_default_jointype} = 'inner';
 204   is_same_sql_bind (
 205     $rs->as_query,
 206     '(
 207       SELECT me.cdid, me.artist, me.title, me.year, me.genreid, me.single_track,
 208              artist.artistid, artist.name, artist.rank, artist.charfield
 209         FROM cd me
 210         INNER JOIN artist artist ON artist.artistid = me.artist
 211     )',
 212     [],
 213     'overriden default join type works',
 214   );
 215 }
 216
 217 {
 218   # Test support for straight joins
 219   my $cdsrc = $schema->source('CD');
 220   my $artrel_info = $cdsrc->relationship_info ('artist');
 221   $cdsrc->add_relationship(
 222     'straight_artist',
 223     $artrel_info->{class},
 224     $artrel_info->{cond},
 225     { %{$artrel_info->{attrs}}, join_type => 'straight' },
 226   );
 227   is_same_sql_bind (
 228     $cdsrc->resultset->search({}, { prefetch => 'straight_artist' })->as_query,
 229     '(
 230       SELECT me.cdid, me.artist, me.title, me.year, me.genreid, me.single_track,
 231              straight_artist.artistid, straight_artist.name, straight_artist.rank, straight_artist.charfield
 232         FROM cd me
 233         STRAIGHT_JOIN artist straight_artist ON straight_artist.artistid = me.artist
 234     )',
 235     [],
 236     'straight joins correctly supported for mysql'
 237   );
 238 }
 239
 240 ## Can we properly deal with the null search problem?
 241 ##
 242 ## Only way is to do a SET SQL_AUTO_IS_NULL = 0; on connect
 243 ## But I'm not sure if we should do this or not (Ash, 2008/06/03)
 244 #
 245 # There is now a built-in function to do this, test that everything works
 246 # with it (ribasushi, 2009/07/03)
 247
 248 NULLINSEARCH: {
 249     my $ansi_schema = DBICTest::Schema->connect ($dsn, $user, $pass, { on_connect_call => 'set_strict_mode' });
 250
 251     $ansi_schema->resultset('Artist')->create ({ name => 'last created artist' });
 252
 253     ok my $artist1_rs = $ansi_schema->resultset('Artist')->search({artistid=>6666})
 254       => 'Created an artist resultset of 6666';
 255
 256     is $artist1_rs->count, 0
 257       => 'Got no returned rows';
 258
 259     ok my $artist2_rs = $ansi_schema->resultset('Artist')->search({artistid=>undef})
 260       => 'Created an artist resultset of undef';
 261
 262     is $artist2_rs->count, 0
 263       => 'got no rows';
 264
 265     my $artist = $artist2_rs->single;
 266
 267     is $artist => undef
 268       => 'Nothing Found!';
 269 }
 270
 271 # check for proper grouped counts
 272 {
 273   my $ansi_schema = DBICTest::Schema->connect ($dsn, $user, $pass, {
 274     on_connect_call => 'set_strict_mode',
 275     quote_char => '`',
 276   });
 277   my $rs = $ansi_schema->resultset('CD');
 278
 279   my $years;
 280   $years->{$_->year|| scalar keys %$years}++ for $rs->all;  # NULL != NULL, thus the keys eval
 281
 282   lives_ok ( sub {
 283     is (
 284       $rs->search ({}, { group_by => 'year'})->count,
 285       scalar keys %$years,
 286       'grouped count correct',
 287     );
 288   }, 'Grouped count does not throw');
 289
 290   lives_ok( sub {
 291     $ansi_schema->resultset('Owners')->search({}, {
 292       join => 'books', group_by => [ 'me.id', 'books.id' ]
 293     })->count();
 294   }, 'count on grouped columns with the same name does not throw');
 295
 296
 297 }
 298
 299 ZEROINSEARCH: {
 300   my $cds_per_year = {
 301     2001 => 2,
 302     2002 => 1,
 303     2005 => 3,
 304   };
 305
 306   my $rs = $schema->resultset ('CD');
 307   $rs->delete;
 308   for my $y (keys %$cds_per_year) {
 309     for my $c (1 .. $cds_per_year->{$y} ) {
 310       $rs->create ({ title => "CD $y-$c", artist => 1, year => "$y-01-01" });
 311     }
 312   }
 313
 314   is ($rs->count, 6, 'CDs created successfully');
 315
 316   $rs = $rs->search ({}, {
 317     select => [ \ 'YEAR(year)' ], as => ['y'], distinct => 1,
 318   });
 319
 320   is_deeply (
 321     [ sort ($rs->get_column ('y')->all) ],
 322     [ sort keys %$cds_per_year ],
 323     'Years group successfully',
 324   );
 325
 326   $rs->create ({ artist => 1, year => '0-1-1', title => 'Jesus Rap' });
 327
 328   is_deeply (
 329     [ sort $rs->get_column ('y')->all ],
 330     [ 0, sort keys %$cds_per_year ],
 331     'Zero-year groups successfully',
 332   );
 333
 334   # convoluted search taken verbatim from list
 335   my $restrict_rs = $rs->search({ -and => [
 336     year => { '!=', 0 },
 337     year => { '!=', undef }
 338   ]});
 339
 340   is_deeply (
 341     [ $restrict_rs->get_column('y')->all ],
 342     [ $rs->get_column ('y')->all ],
 343     'Zero year was correctly excluded from resultset',
 344   );
 345 }
 346
 347 ## If find() is the first query after connect()
 348 ## DBI::Storage::sql_maker() will be called before
 349 ## _determine_driver() and so the ::SQLHacks class for MySQL
 350 ## will not be used
 351
 352 my $schema2 = DBICTest::Schema->connect($dsn, $user, $pass);
 353 $schema2->resultset("Artist")->find(4);
 354 isa_ok($schema2->storage->sql_maker, 'DBIx::Class::SQLMaker::MySQL');
 355
 356 done_testing;