t/70sqlt-diff_script_old.t

   1 #!/usr/bin/perl
   2 # vim: set ft=perl:
   3
   4 use strict;
   5
   6 use File::Spec::Functions qw(catfile updir tmpdir);
   7 use FindBin qw($Bin);
   8 use Test::More;
   9 use IPC::Open3;
  10 use Test::SQL::Translator qw(maybe_plan);
  11
  12 my @script = qw(script sqlt-diff-old);
  13 my @create1 = qw(data sqlite create.sql);
  14 my @create2 = qw(data sqlite create2.sql);
  15
  16 my $sqlt_diff = catfile($Bin, updir, @script);
  17 my $create1 = catfile($Bin, @create1);
  18 my $create2 = catfile($Bin, @create2);
  19
  20 BEGIN {
  21     maybe_plan(21,
  22         'SQL::Translator::Parser::SQLite',
  23         'SQL::Translator::Parser::MySQL',
  24         'SQL::Translator::Parser::Oracle',
  25         );
  26 }
  27
  28 ok(-e $sqlt_diff, 'Found sqlt-diff script');
  29 my $out = _run_cmd ($^X,  $sqlt_diff, "$create1=SQLite", "$create2=SQLite");
  30
  31 like($out, qr/-- Target database SQLite is untested/, "Detected 'untested' comment");
  32 like($out, qr/ALTER TABLE person CHANGE iq/, "Detected altered 'iq' field");
  33 like($out, qr/ALTER TABLE person ADD is_rock_star/,
  34     "Detected missing rock star field");
  35
  36 $out = _run_cmd ($^X, $sqlt_diff, "$create1=SQLite", "$create1=SQLite");
  37
  38 like($out, qr/There were no differences/, "Properly detected no differences");
  39
  40 my @mysql_create1 = qw(data mysql create.sql);
  41 my @mysql_create2 = qw(data mysql create2.sql);
  42
  43 my $mysql_create1 = (-d "t")
  44     ? catfile($Bin, @mysql_create1)
  45     : catfile($Bin, "t", @mysql_create1);
  46
  47 my $mysql_create2 = (-d "t")
  48     ? catfile($Bin, @mysql_create2)
  49     : catfile($Bin, "t", @mysql_create2);
  50
  51 # Test for differences
  52 $out = _run_cmd ($^X, $sqlt_diff, "$mysql_create1=MySQL", "$mysql_create2=MySQL");
  53
  54 unlike($out, qr/-- Target database MySQL is untested/, "Did not detect 'untested' comment");
  55 like($out, qr/ALTER TABLE person CHANGE person_id/, "Detected altered 'person_id' field");
  56 like($out, qr/ALTER TABLE person CHANGE iq/, "Detected altered 'iq' field");
  57 like($out, qr/ALTER TABLE person CHANGE name/, "Detected altered 'name' field");
  58 like($out, qr/ALTER TABLE person CHANGE age/, "Detected altered 'age' field");
  59 like($out, qr/ALTER TABLE person ADD is_rock_star/,
  60     "Detected missing rock star field");
  61 like($out, qr/ALTER TABLE person ADD UNIQUE UC_person_id/,
  62     "Detected missing unique constraint");
  63 like($out, qr/CREATE UNIQUE INDEX unique_name/,
  64     "Detected unique index with different name");
  65 like($out, qr/ALTER TABLE person ENGINE=InnoDB;/,
  66     "Detected altered table option");
  67 like($out, qr/ALTER TABLE employee DROP FOREIGN KEY FK5302D47D93FE702E/,
  68     "Detected drop foreign key");
  69 like($out, qr/ALTER TABLE employee ADD CONSTRAINT FK5302D47D93FE702E_diff/,
  70     "Detected add constraint");
  71 unlike($out, qr/ALTER TABLE employee ADD PRIMARY KEY/, "Primary key looks different when it shouldn't");
  72
  73 # Test for sameness
  74 $out = _run_cmd ($^X, $sqlt_diff, "$mysql_create1=MySQL", "$mysql_create1=MySQL");
  75
  76 like($out, qr/There were no differences/, "Properly detected no differences");
  77
  78 my @oracle_create1 = qw(data oracle create.sql);
  79 my @oracle_create2 = qw(data oracle create2.sql);
  80
  81 my $oracle_create1 = (-d "t")
  82     ? catfile($Bin, @oracle_create1)
  83     : catfile($Bin, "t", @oracle_create1);
  84
  85 my $oracle_create2 = (-d "t")
  86     ? catfile($Bin, @oracle_create2)
  87     : catfile($Bin, "t", @oracle_create2);
  88
  89 $out = _run_cmd ($^X, $sqlt_diff, "$oracle_create1=Oracle", "$oracle_create2=Oracle");
  90
  91 unlike($out, qr/-- Target database Oracle is untested/, "Did not detect 'untested' comment");
  92 like($out, qr/ALTER TABLE TABLE1 DROP FOREIGN KEY/,
  93     "Detected drop foreign key");
  94 like($out, qr/ALTER TABLE TABLE1 ADD CONSTRAINT/,
  95     "Detected add constraint");
  96
  97 sub _run_cmd {
  98   my $out;
  99   my $pid = open3( undef, $out, undef, @_ );
 100   my $res = do { local $/; <$out> };
 101   waitpid($pid, 0);
 102   $res;
 103 }