t/66relationship.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use lib qw(t/lib);
   7 use DBICTest;
   8
   9 my $schema = DBICTest->init_schema();
  10
  11 plan tests => 70;
  12
  13 # has_a test
  14 my $cd = $schema->resultset("CD")->find(4);
  15 my ($artist) = ($INC{'DBICTest/HelperRels'}
  16                   ? $cd->artist
  17                   : $cd->search_related('artist'));
  18 is($artist->name, 'Random Boy Band', 'has_a search_related ok');
  19
  20 # has_many test with an order_by clause defined
  21 $artist = $schema->resultset("Artist")->find(1);
  22 my @cds = ($INC{'DBICTest/HelperRels'}
  23              ? $artist->cds
  24              : $artist->search_related('cds'));
  25 is( $cds[1]->title, 'Spoonful of bees', 'has_many search_related with order_by ok' );
  26
  27 # search_related with additional abstract query
  28 @cds = ($INC{'DBICTest/HelperRels'}
  29           ? $artist->cds({ title => { like => '%of%' } })
  30           : $artist->search_related('cds', { title => { like => '%of%' } } )
  31        );
  32 is( $cds[1]->title, 'Forkful of bees', 'search_related with abstract query ok' );
  33
  34 # creating a related object
  35 if ($INC{'DBICTest/HelperRels.pm'}) {
  36   $artist->add_to_cds({ title => 'Big Flop', year => 2005 });
  37 } else {
  38   $artist->create_related( 'cds', {
  39       title => 'Big Flop',
  40       year => 2005,
  41   } );
  42 }
  43
  44 my $big_flop_cd = ($artist->search_related('cds'))[3];
  45 is( $big_flop_cd->title, 'Big Flop', 'create_related ok' );
  46
  47 { # make sure we are not making pointless select queries when a FK IS NULL
  48   my $queries = 0;
  49   $schema->storage->debugcb(sub { $queries++; });
  50   $schema->storage->debug(1);
  51   $big_flop_cd->genre; #should not trigger a select query
  52   is($queries, 0, 'No SELECT made for belongs_to if key IS NULL');
  53   $big_flop_cd->genre_inefficient; #should trigger a select query
  54   is($queries, 1, 'SELECT made for belongs_to if key IS NULL when undef_on_null_fk disabled');
  55   $schema->storage->debug(0);
  56   $schema->storage->debugcb(undef);
  57 }
  58
  59 my( $rs_from_list ) = $artist->search_related_rs('cds');
  60 is( ref($rs_from_list), 'DBIx::Class::ResultSet', 'search_related_rs in list context returns rs' );
  61
  62 ( $rs_from_list ) = $artist->cds_rs();
  63 is( ref($rs_from_list), 'DBIx::Class::ResultSet', 'relation_rs in list context returns rs' );
  64
  65 # count_related
  66 is( $artist->count_related('cds'), 4, 'count_related ok' );
  67
  68 # set_from_related
  69 my $track = $schema->resultset("Track")->create( {
  70   trackid => 1,
  71   cd => 3,
  72   position => 98,
  73   title => 'Hidden Track'
  74 } );
  75 $track->set_from_related( cd => $cd );
  76
  77 is($track->disc->cdid, 4, 'set_from_related ok, including alternative accessor' );
  78
  79 $track->set_from_related( cd => undef );
  80
  81 ok( !defined($track->cd), 'set_from_related with undef ok');
  82
  83 TODO: {
  84     local $TODO = 'accessing $object->rel and set_from_related';
  85     my $track = $schema->resultset("Track")->new( {} );
  86     $track->cd;
  87     $track->set_from_related( cd => $cd );
  88     ok ($track->cd, 'set_from_related ok after using the accessor' );
  89 };
  90
  91 # update_from_related, the same as set_from_related, but it calls update afterwards
  92 $track = $schema->resultset("Track")->create( {
  93   trackid => 2,
  94   cd => 3,
  95   title => 'Hidden Track 2'
  96 } );
  97 $track->update_from_related( cd => $cd );
  98
  99 my $t_cd = ($schema->resultset("Track")->search( cd => 4, title => 'Hidden Track 2' ))[0]->cd;
 100
 101 is( $t_cd->cdid, 4, 'update_from_related ok' );
 102
 103 # find_or_create_related with an existing record
 104 $cd = $artist->find_or_create_related( 'cds', { title => 'Big Flop' } );
 105 is( $cd->year, 2005, 'find_or_create_related on existing record ok' );
 106
 107 # find_or_create_related creating a new record
 108 $cd = $artist->find_or_create_related( 'cds', {
 109   title => 'Greatest Hits',
 110   year => 2006,
 111 } );
 112 is( $cd->title, 'Greatest Hits', 'find_or_create_related new record ok' );
 113
 114 @cds = $artist->search_related('cds');
 115 is( ($artist->search_related('cds'))[4]->title, 'Greatest Hits', 'find_or_create_related new record search ok' );
 116
 117 $artist->delete_related( cds => { title => 'Greatest Hits' });
 118 cmp_ok( $schema->resultset("CD")->search( title => 'Greatest Hits' ), '==', 0, 'delete_related ok' );
 119
 120 # find_or_new_related with an existing record
 121 $cd = $artist->find_or_new_related( 'cds', { title => 'Big Flop' } );
 122 is( $cd->year, 2005, 'find_or_new_related on existing record ok' );
 123 ok( $cd->in_storage, 'find_or_new_related on existing record: is in_storage' );
 124
 125 # find_or_new_related instantiating a new record
 126 $cd = $artist->find_or_new_related( 'cds', {
 127   title => 'Greatest Hits 2: Louder Than Ever',
 128   year => 2007,
 129 } );
 130 is( $cd->title, 'Greatest Hits 2: Louder Than Ever', 'find_or_new_related new record ok' );
 131 ok( ! $cd->in_storage, 'find_or_new_related on a new record: not in_storage' );
 132
 133 $cd->artist(undef);
 134 my $newartist = $cd->find_or_new_related( 'artist', {
 135   name => 'Random Boy Band Two',
 136   artistid => 200,
 137 } );
 138 is($newartist->name, 'Random Boy Band Two', 'find_or_new_related new artist record with id');
 139 is($newartist->id, 200, 'find_or_new_related new artist id set');
 140
 141 lives_ok(
 142     sub {
 143         my $new_bookmark = $schema->resultset("Bookmark")->new_result( {} );
 144         my $new_related_link = $new_bookmark->new_related( 'link', {} );
 145     },
 146     'No back rel'
 147 );
 148
 149
 150 TODO: {
 151   local $TODO = "relationship checking needs fixing";
 152   # try to add a bogus relationship using the wrong cols
 153   eval {
 154       DBICTest::Schema::Artist->add_relationship(
 155           tracks => 'DBICTest::Schema::Track',
 156           { 'foreign.cd' => 'self.cdid' }
 157       );
 158   };
 159   like($@, qr/Unknown column/, 'failed when creating a rel with invalid key, ok');
 160 }
 161
 162 # another bogus relationship using no join condition
 163 eval {
 164     DBICTest::Schema::Artist->add_relationship( tracks => 'DBICTest::Track' );
 165 };
 166 like($@, qr/join condition/, 'failed when creating a rel without join condition, ok');
 167
 168 # many_to_many helper tests
 169 $cd = $schema->resultset("CD")->find(1);
 170 my @producers = $cd->producers();
 171 is( $producers[0]->name, 'Matt S Trout', 'many_to_many ok' );
 172 is( $cd->producers_sorted->next->name, 'Bob The Builder',
 173     'sorted many_to_many ok' );
 174 is( $cd->producers_sorted(producerid => 3)->next->name, 'Fred The Phenotype',
 175     'sorted many_to_many with search condition ok' );
 176
 177 $cd = $schema->resultset('CD')->find(2);
 178 my $prod_rs = $cd->producers();
 179 my $prod_before_count = $schema->resultset('Producer')->count;
 180 is( $prod_rs->count, 0, "CD doesn't yet have any producers" );
 181 my $prod = $schema->resultset('Producer')->find(1);
 182 $cd->add_to_producers($prod);
 183 is( $prod_rs->count(), 1, 'many_to_many add_to_$rel($obj) count ok' );
 184 is( $prod_rs->first->name, 'Matt S Trout',
 185     'many_to_many add_to_$rel($obj) ok' );
 186 $cd->remove_from_producers($prod);
 187 is( $schema->resultset('Producer')->find(1)->name, 'Matt S Trout',
 188     "producer object exists after remove of link" );
 189 is( $prod_rs->count, 0, 'many_to_many remove_from_$rel($obj) ok' );
 190 $cd->add_to_producers({ name => 'Testy McProducer' });
 191 is( $schema->resultset('Producer')->count, $prod_before_count+1,
 192     'add_to_$rel($hash) inserted a new producer' );
 193 is( $prod_rs->count(), 1, 'many_to_many add_to_$rel($hash) count ok' );
 194 is( $prod_rs->first->name, 'Testy McProducer',
 195     'many_to_many add_to_$rel($hash) ok' );
 196 $cd->add_to_producers({ name => 'Jack Black' });
 197 is( $prod_rs->count(), 2, 'many_to_many add_to_$rel($hash) count ok' );
 198 $cd->set_producers($schema->resultset('Producer')->all);
 199 is( $cd->producers->count(), $prod_before_count+2,
 200     'many_to_many set_$rel(@objs) count ok' );
 201 $cd->set_producers($schema->resultset('Producer')->find(1));
 202 is( $cd->producers->count(), 1, 'many_to_many set_$rel($obj) count ok' );
 203 $cd->set_producers([$schema->resultset('Producer')->all]);
 204 is( $cd->producers->count(), $prod_before_count+2,
 205     'many_to_many set_$rel(\@objs) count ok' );
 206 $cd->set_producers([$schema->resultset('Producer')->find(1)]);
 207 is( $cd->producers->count(), 1, 'many_to_many set_$rel([$obj]) count ok' );
 208
 209 eval { $cd->remove_from_producers({ fake => 'hash' }); };
 210 like( $@, qr/needs an object/, 'remove_from_$rel($hash) dies correctly' );
 211
 212 eval { $cd->add_to_producers(); };
 213 like( $@, qr/needs an object or hashref/,
 214       'add_to_$rel(undef) dies correctly' );
 215
 216 # many_to_many stresstest
 217 my $twokey = $schema->resultset('TwoKeys')->find(1,1);
 218 my $fourkey = $schema->resultset('FourKeys')->find(1,2,3,4);
 219
 220 is( $twokey->fourkeys->count, 0, 'twokey has no fourkeys' );
 221 $twokey->add_to_fourkeys($fourkey, { autopilot => 'engaged' });
 222 my $got_fourkey = $twokey->fourkeys({ sensors => 'online' })->first;
 223 is( $twokey->fourkeys->count, 1, 'twokey has one fourkey' );
 224 is( $got_fourkey->$_, $fourkey->$_,
 225     'fourkeys row has the correct value for column '.$_ )
 226   for (qw(foo bar hello goodbye sensors));
 227 $twokey->remove_from_fourkeys($fourkey);
 228 is( $twokey->fourkeys->count, 0, 'twokey has no fourkeys' );
 229 is( $twokey->fourkeys_to_twokeys->count, 0,
 230     'twokey has no links to fourkey' );
 231
 232 my $undef_artist_cd = $schema->resultset("CD")->new_result({ 'title' => 'badgers', 'year' => 2007 });
 233 is($undef_artist_cd->has_column_loaded('artist'), '', 'FK not loaded');
 234 is($undef_artist_cd->search_related('artist')->count, 0, '0=1 search when FK does not exist and object not yet in db');
 235 eval{
 236      $undef_artist_cd->related_resultset('artist')->new({name => 'foo'});
 237 };
 238 is( $@, '', "Object created on a resultset related to not yet inserted object");
 239 lives_ok{
 240   $schema->resultset('Artwork')->new_result({})->cd;
 241 } 'undef_on_null_fk does not choke on empty conds';
 242
 243 my $def_artist_cd = $schema->resultset("CD")->new_result({ 'title' => 'badgers', 'year' => 2007, artist => undef });
 244 is($def_artist_cd->has_column_loaded('artist'), 1, 'FK loaded');
 245 is($def_artist_cd->search_related('artist')->count, 0, 'closed search on null FK');
 246
 247 # test undirected many-to-many relationship (e.g. "related artists")
 248 my $undir_maps = $schema->resultset("Artist")->find(1)->artist_undirected_maps;
 249 is($undir_maps->count, 1, 'found 1 undirected map for artist 1');
 250
 251 $undir_maps = $schema->resultset("Artist")->find(2)->artist_undirected_maps;
 252 is($undir_maps->count, 1, 'found 1 undirected map for artist 2');
 253
 254 my $mapped_rs = $undir_maps->search_related('mapped_artists');
 255
 256 my @art = $mapped_rs->all;
 257
 258 cmp_ok(@art, '==', 2, "Both artist returned from map");
 259
 260 my $searched = $mapped_rs->search({'mapped_artists.artistid' => {'!=', undef}});
 261
 262 cmp_ok($searched->count, '==', 2, "Both artist returned from map after adding another condition");
 263
 264 # check join through cascaded has_many relationships
 265 $artist = $schema->resultset("Artist")->find(1);
 266 my $trackset = $artist->cds->search_related('tracks');
 267 # LEFT join means we also see the trackless additional album...
 268 cmp_ok($trackset->count, '==', 11, "Correct number of tracks for artist");
 269
 270 # now see about updating eveything that belongs to artist 2 to artist 3
 271 $artist = $schema->resultset("Artist")->find(2);
 272 my $nartist = $schema->resultset("Artist")->find(3);
 273 cmp_ok($artist->cds->count, '==', 1, "Correct orig #cds for artist");
 274 cmp_ok($nartist->cds->count, '==', 1, "Correct orig #cds for artist");
 275 $artist->cds->update({artist => $nartist->id});
 276 cmp_ok($artist->cds->count, '==', 0, "Correct new #cds for artist");
 277 cmp_ok($nartist->cds->count, '==', 2, "Correct new #cds for artist");
 278
 279 # check if is_foreign_key_constraint attr is set
 280 my $rs_normal = $schema->source('Track');
 281 my $relinfo = $rs_normal->relationship_info ('cd');
 282 cmp_ok($relinfo->{attrs}{is_foreign_key_constraint}, '==', 1, "is_foreign_key_constraint defined for belongs_to relationships.");
 283
 284 my $rs_overridden = $schema->source('ForceForeign');
 285 my $relinfo_with_attr = $rs_overridden->relationship_info ('cd_3');
 286 cmp_ok($relinfo_with_attr->{attrs}{is_foreign_key_constraint}, '==', 0, "is_foreign_key_constraint defined for belongs_to relationships with attr.");