t/66relationship.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use lib qw(t/lib);
   6 use DBICTest;
   7
   8 my $schema = DBICTest->init_schema();
   9
  10 plan tests => 63;
  11
  12 # has_a test
  13 my $cd = $schema->resultset("CD")->find(4);
  14 my ($artist) = ($INC{'DBICTest/HelperRels'}
  15                   ? $cd->artist
  16                   : $cd->search_related('artist'));
  17 is($artist->name, 'Random Boy Band', 'has_a search_related ok');
  18
  19 # has_many test with an order_by clause defined
  20 $artist = $schema->resultset("Artist")->find(1);
  21 my @cds = ($INC{'DBICTest/HelperRels'}
  22              ? $artist->cds
  23              : $artist->search_related('cds'));
  24 is( $cds[1]->title, 'Spoonful of bees', 'has_many search_related with order_by ok' );
  25
  26 # search_related with additional abstract query
  27 @cds = ($INC{'DBICTest/HelperRels'}
  28           ? $artist->cds({ title => { like => '%of%' } })
  29           : $artist->search_related('cds', { title => { like => '%of%' } } )
  30        );
  31 is( $cds[1]->title, 'Forkful of bees', 'search_related with abstract query ok' );
  32
  33 # creating a related object
  34 if ($INC{'DBICTest/HelperRels.pm'}) {
  35   $artist->add_to_cds({ title => 'Big Flop', year => 2005 });
  36 } else {
  37   $artist->create_related( 'cds', {
  38       title => 'Big Flop',
  39       year => 2005,
  40   } );
  41 }
  42
  43 is( ($artist->search_related('cds'))[3]->title, 'Big Flop', 'create_related ok' );
  44
  45 my( $rs_from_list ) = $artist->search_related_rs('cds');
  46 is( ref($rs_from_list), 'DBIx::Class::ResultSet', 'search_related_rs in list context returns rs' );
  47
  48 ( $rs_from_list ) = $artist->cds_rs();
  49 is( ref($rs_from_list), 'DBIx::Class::ResultSet', 'relation_rs in list context returns rs' );
  50
  51 # count_related
  52 is( $artist->count_related('cds'), 4, 'count_related ok' );
  53
  54 # set_from_related
  55 my $track = $schema->resultset("Track")->create( {
  56   trackid => 1,
  57   cd => 3,
  58   position => 98,
  59   title => 'Hidden Track'
  60 } );
  61 $track->set_from_related( cd => $cd );
  62
  63 is($track->disc->cdid, 4, 'set_from_related ok, including alternative accessor' );
  64
  65 $track->set_from_related( cd => undef );
  66
  67 ok( !defined($track->cd), 'set_from_related with undef ok');
  68
  69 TODO: {
  70     local $TODO = 'accessing $object->rel and set_from_related';
  71     my $track = $schema->resultset("Track")->new( {} );
  72     $track->cd;
  73     $track->set_from_related( cd => $cd );
  74     ok ($track->cd, 'set_from_related ok after using the accessor' );
  75 };
  76
  77 # update_from_related, the same as set_from_related, but it calls update afterwards
  78 $track = $schema->resultset("Track")->create( {
  79   trackid => 2,
  80   cd => 3,
  81   position => 99,
  82   title => 'Hidden Track 2'
  83 } );
  84 $track->update_from_related( cd => $cd );
  85
  86 my $t_cd = ($schema->resultset("Track")->search( cd => 4, position => 99 ))[0]->cd;
  87
  88 is( $t_cd->cdid, 4, 'update_from_related ok' );
  89
  90 # find_or_create_related with an existing record
  91 $cd = $artist->find_or_create_related( 'cds', { title => 'Big Flop' } );
  92 is( $cd->year, 2005, 'find_or_create_related on existing record ok' );
  93
  94 # find_or_create_related creating a new record
  95 $cd = $artist->find_or_create_related( 'cds', {
  96   title => 'Greatest Hits',
  97   year => 2006,
  98 } );
  99 is( $cd->title, 'Greatest Hits', 'find_or_create_related new record ok' );
 100
 101 @cds = $artist->search_related('cds');
 102 is( ($artist->search_related('cds'))[4]->title, 'Greatest Hits', 'find_or_create_related new record search ok' );
 103
 104 $artist->delete_related( cds => { title => 'Greatest Hits' });
 105 cmp_ok( $schema->resultset("CD")->search( title => 'Greatest Hits' ), '==', 0, 'delete_related ok' );
 106
 107 # find_or_new_related with an existing record
 108 $cd = $artist->find_or_new_related( 'cds', { title => 'Big Flop' } );
 109 is( $cd->year, 2005, 'find_or_new_related on existing record ok' );
 110 ok( $cd->in_storage, 'find_or_new_related on existing record: is in_storage' );
 111
 112 # find_or_new_related instantiating a new record
 113 $cd = $artist->find_or_new_related( 'cds', {
 114   title => 'Greatest Hits 2: Louder Than Ever',
 115   year => 2007,
 116 } );
 117 is( $cd->title, 'Greatest Hits 2: Louder Than Ever', 'find_or_new_related new record ok' );
 118 ok( ! $cd->in_storage, 'find_or_new_related on a new record: not in_storage' );
 119
 120 # print STDERR Data::Dumper::Dumper($cd->get_columns);
 121 # $cd->result_source->schema->storage->debug(1);
 122 $cd->artist(undef);
 123 my $newartist = $cd->find_or_new_related( 'artist', {
 124   name => 'Random Boy Band Two',
 125   artistid => 200,
 126 } );
 127 # $cd->result_source->schema->storage->debug(0);
 128 is($newartist->name, 'Random Boy Band Two', 'find_or_new_related new artist record with id');
 129 is($newartist->id, 200, 'find_or_new_related new artist id set');
 130
 131 SKIP: {
 132   skip "relationship checking needs fixing", 1;
 133   # try to add a bogus relationship using the wrong cols
 134   eval {
 135       DBICTest::Schema::Artist->add_relationship(
 136           tracks => 'DBICTest::Schema::Track',
 137           { 'foreign.cd' => 'self.cdid' }
 138       );
 139   };
 140   like($@, qr/Unknown column/, 'failed when creating a rel with invalid key, ok');
 141 }
 142
 143 # another bogus relationship using no join condition
 144 eval {
 145     DBICTest::Schema::Artist->add_relationship( tracks => 'DBICTest::Track' );
 146 };
 147 like($@, qr/join condition/, 'failed when creating a rel without join condition, ok');
 148
 149 # many_to_many helper tests
 150 $cd = $schema->resultset("CD")->find(1);
 151 my @producers = $cd->producers();
 152 is( $producers[0]->name, 'Matt S Trout', 'many_to_many ok' );
 153 is( $cd->producers_sorted->next->name, 'Bob The Builder',
 154     'sorted many_to_many ok' );
 155 is( $cd->producers_sorted(producerid => 3)->next->name, 'Fred The Phenotype',
 156     'sorted many_to_many with search condition ok' );
 157
 158 $cd = $schema->resultset('CD')->find(2);
 159 my $prod_rs = $cd->producers();
 160 my $prod_before_count = $schema->resultset('Producer')->count;
 161 is( $prod_rs->count, 0, "CD doesn't yet have any producers" );
 162 my $prod = $schema->resultset('Producer')->find(1);
 163 $cd->add_to_producers($prod);
 164 is( $prod_rs->count(), 1, 'many_to_many add_to_$rel($obj) count ok' );
 165 is( $prod_rs->first->name, 'Matt S Trout',
 166     'many_to_many add_to_$rel($obj) ok' );
 167 $cd->remove_from_producers($prod);
 168 is( $schema->resultset('Producer')->find(1)->name, 'Matt S Trout',
 169     "producer object exists after remove of link" );
 170 is( $prod_rs->count, 0, 'many_to_many remove_from_$rel($obj) ok' );
 171 $cd->add_to_producers({ name => 'Testy McProducer' });
 172 is( $schema->resultset('Producer')->count, $prod_before_count+1,
 173     'add_to_$rel($hash) inserted a new producer' );
 174 is( $prod_rs->count(), 1, 'many_to_many add_to_$rel($hash) count ok' );
 175 is( $prod_rs->first->name, 'Testy McProducer',
 176     'many_to_many add_to_$rel($hash) ok' );
 177 $cd->add_to_producers({ name => 'Jack Black' });
 178 is( $prod_rs->count(), 2, 'many_to_many add_to_$rel($hash) count ok' );
 179 $cd->set_producers($schema->resultset('Producer')->all);
 180 is( $cd->producers->count(), $prod_before_count+2,
 181     'many_to_many set_$rel(@objs) count ok' );
 182 $cd->set_producers($schema->resultset('Producer')->find(1));
 183 is( $cd->producers->count(), 1, 'many_to_many set_$rel($obj) count ok' );
 184 $cd->set_producers([$schema->resultset('Producer')->all]);
 185 is( $cd->producers->count(), $prod_before_count+2,
 186     'many_to_many set_$rel(\@objs) count ok' );
 187 $cd->set_producers([$schema->resultset('Producer')->find(1)]);
 188 is( $cd->producers->count(), 1, 'many_to_many set_$rel([$obj]) count ok' );
 189
 190 eval { $cd->remove_from_producers({ fake => 'hash' }); };
 191 like( $@, qr/needs an object/, 'remove_from_$rel($hash) dies correctly' );
 192
 193 eval { $cd->add_to_producers(); };
 194 like( $@, qr/needs an object or hashref/,
 195       'add_to_$rel(undef) dies correctly' );
 196
 197 # many_to_many stresstest
 198 my $twokey = $schema->resultset('TwoKeys')->find(1,1);
 199 my $fourkey = $schema->resultset('FourKeys')->find(1,2,3,4);
 200
 201 is( $twokey->fourkeys->count, 0, 'twokey has no fourkeys' );
 202 $twokey->add_to_fourkeys($fourkey, { autopilot => 'engaged' });
 203 my $got_fourkey = $twokey->fourkeys({ sensors => 'online' })->first;
 204 is( $twokey->fourkeys->count, 1, 'twokey has one fourkey' );
 205 is( $got_fourkey->$_, $fourkey->$_,
 206     'fourkeys row has the correct value for column '.$_ )
 207   for (qw(foo bar hello goodbye sensors));
 208 $twokey->remove_from_fourkeys($fourkey);
 209 is( $twokey->fourkeys->count, 0, 'twokey has no fourkeys' );
 210 is( $twokey->fourkeys_to_twokeys->count, 0,
 211     'twokey has no links to fourkey' );
 212
 213 my $undef_artist_cd = $schema->resultset("CD")->new_result({ 'title' => 'badgers', 'year' => 2007 });
 214 is($undef_artist_cd->has_column_loaded('artist'), '', 'FK not loaded');
 215 is($undef_artist_cd->search_related('artist')->count, 0, '0=1 search when FK does not exist and object not yet in db');
 216
 217 my $def_artist_cd = $schema->resultset("CD")->new_result({ 'title' => 'badgers', 'year' => 2007, artist => undef });
 218 is($def_artist_cd->has_column_loaded('artist'), 1, 'FK loaded');
 219 is($def_artist_cd->search_related('artist')->count, 0, 'closed search on null FK');
 220
 221 # test undirected many-to-many relationship (e.g. "related artists")
 222 my $undir_maps = $schema->resultset("Artist")->find(1)->artist_undirected_maps;
 223 is($undir_maps->count, 1, 'found 1 undirected map for artist 1');
 224
 225 $undir_maps = $schema->resultset("Artist")->find(2)->artist_undirected_maps;
 226 is($undir_maps->count, 1, 'found 1 undirected map for artist 2');
 227
 228 my $mapped_rs = $undir_maps->search_related('mapped_artists');
 229
 230 my @art = $mapped_rs->all;
 231
 232 cmp_ok(@art, '==', 2, "Both artist returned from map");
 233
 234 my $searched = $mapped_rs->search({'mapped_artists.artistid' => {'!=', undef}});
 235
 236 cmp_ok($searched->count, '==', 2, "Both artist returned from map after adding another condition");
 237
 238 # check join through cascaded has_many relationships
 239 $artist = $schema->resultset("Artist")->find(1);
 240 my $trackset = $artist->cds->search_related('tracks');
 241 # LEFT join means we also see the trackless additional album...
 242 cmp_ok($trackset->count, '==', 11, "Correct number of tracks for artist");
 243
 244 # now see about updating eveything that belongs to artist 2 to artist 3
 245 $artist = $schema->resultset("Artist")->find(2);
 246 my $nartist = $schema->resultset("Artist")->find(3);
 247 cmp_ok($artist->cds->count, '==', 1, "Correct orig #cds for artist");
 248 cmp_ok($nartist->cds->count, '==', 1, "Correct orig #cds for artist");
 249 $artist->cds->update({artist => $nartist->id});
 250 cmp_ok($artist->cds->count, '==', 0, "Correct new #cds for artist");
 251 cmp_ok($nartist->cds->count, '==', 2, "Correct new #cds for artist");
 252