t/52leaks.t

   1 use strict;
   2 use warnings;
   3
   4 # Do the override as early as possible so that CORE::bless doesn't get compiled away
   5 # We will replace $bless_override only if we are in author mode
   6 my $bless_override;
   7 BEGIN {
   8   $bless_override = sub {
   9     CORE::bless( $_[0], (@_ > 1) ? $_[1] : caller() );
  10   };
  11   *CORE::GLOBAL::bless = sub { goto $bless_override };
  12 }
  13
  14 use Test::More;
  15
  16 use lib qw(t/lib);
  17 use DBICTest::RunMode;
  18 BEGIN {
  19   plan skip_all => "Your perl version $] appears to leak like a sieve - skipping test"
  20     if DBICTest::RunMode->peepeeness;
  21 }
  22
  23 use Scalar::Util qw/refaddr reftype weaken/;
  24 use Carp qw/longmess/;
  25 use Try::Tiny;
  26
  27 my $have_test_cycle;
  28 BEGIN {
  29   require DBIx::Class::Optional::Dependencies;
  30   $have_test_cycle = DBIx::Class::Optional::Dependencies->req_ok_for ('test_leaks')
  31     and import Test::Memory::Cycle;
  32 }
  33
  34 # this is what holds all weakened refs to be checked for leakage
  35 my $weak_registry = {};
  36
  37 # Skip the heavy-duty leak tracing when just doing an install
  38 unless (DBICTest::RunMode->is_plain) {
  39
  40   # Some modules are known to install singletons on-load
  41   # Load them before we swap out $bless_override
  42   require DBI;
  43   require DBD::SQLite;
  44   require Errno;
  45   require Class::Struct;
  46   require FileHandle;
  47   require Hash::Merge;
  48
  49   no warnings qw/redefine once/;
  50   no strict qw/refs/;
  51
  52   # redefine the bless override so that we can catch each and every object created
  53   $bless_override = sub {
  54
  55     my $obj = CORE::bless(
  56       $_[0], (@_ > 1) ? $_[1] : do {
  57         my ($class, $fn, $line) = caller();
  58         fail ("bless() of $_[0] into $class without explicit class specification at $fn line $line")
  59           if $class =~ /^ (?: DBIx\:\:Class | DBICTest ) /x;
  60         $class;
  61       }
  62     );
  63
  64     my $slot = (sprintf '%s=%s(0x%x)', # so we don't trigger stringification
  65       ref $obj,
  66       reftype $obj,
  67       refaddr $obj,
  68     );
  69
  70     # weaken immediately to avoid weird side effects
  71     $weak_registry->{$slot} = { weakref => $obj, strace => longmess() };
  72     weaken $weak_registry->{$slot}{weakref};
  73
  74     return $obj;
  75   };
  76
  77   for my $func (qw/try catch finally/) {
  78     my $orig = \&{"Try::Tiny::$func"};
  79     *{"Try::Tiny::$func"} = sub (&;@) {
  80
  81       my $slot = sprintf ('CODE(0x%x)', refaddr $_[0]);
  82
  83       $weak_registry->{$slot} = { weakref => $_[0], strace => longmess() };
  84       weaken $weak_registry->{$slot}{weakref};
  85
  86       goto $orig;
  87     }
  88   }
  89 }
  90
  91 {
  92   require DBICTest;
  93
  94   my $schema = DBICTest->init_schema;
  95   my $rs = $schema->resultset ('Artist');
  96   my $storage = $schema->storage;
  97
  98   ok ($storage->connected, 'we are connected');
  99
 100   my $row_obj = $rs->next;
 101   ok ($row_obj, 'row from db');
 102
 103   my ($mc_row_obj, $pager, $pager_explicit_count) = $schema->txn_do (sub {
 104
 105     my $artist = $rs->create ({
 106       name => 'foo artist',
 107       cds => [{
 108         title => 'foo cd',
 109         year => 1984,
 110       }],
 111     });
 112
 113     my $pg = $rs->search({}, { rows => 1})->page(2)->pager;
 114
 115     my $pg_wcount = $rs->page(4)->pager->total_entries (66);
 116
 117     return ($artist, $pg, $pg_wcount);
 118   });
 119
 120   is ($pager->next_page, 3, 'There is one more page available');
 121
 122   # based on 66 per 10 pages
 123   is ($pager_explicit_count->last_page, 7, 'Correct last page');
 124
 125   my $base_collection = {
 126     schema => $schema,
 127     storage => $storage,
 128
 129     resultset => $rs,
 130
 131     row_object => $row_obj,
 132
 133     result_source => $rs->result_source,
 134
 135     fresh_pager => $rs->page(5)->pager,
 136     pager => $pager,
 137     pager_explicit_count => $pager_explicit_count,
 138
 139     sql_maker => $storage->sql_maker,
 140     dbh => $storage->_dbh
 141   };
 142
 143   memory_cycle_ok ($base_collection, 'No cycles in the object collection')
 144     if $have_test_cycle;
 145
 146   for (keys %$base_collection) {
 147     $weak_registry->{"basic $_"} = { weakref => $base_collection->{$_} };
 148     weaken $weak_registry->{"basic $_"}{weakref};
 149   }
 150
 151 }
 152
 153 memory_cycle_ok($weak_registry, 'No cycles in the weakened object collection')
 154   if $have_test_cycle;
 155
 156 # Naturally we have some exceptions
 157 my $cleared;
 158 for my $slot (keys %$weak_registry) {
 159   if ($slot =~ /^\QTest::Builder/) {
 160     # T::B 2.0 has result objects and other fancyness
 161     delete $weak_registry->{$slot};
 162   }
 163   elsif ($slot =~ /^\QSQL::Translator/) {
 164     # SQLT is a piece of shit, leaks all over
 165     delete $weak_registry->{$slot};
 166   }
 167   elsif ($slot =~ /^\QHash::Merge/) {
 168     # only clear one object - more would indicate trouble
 169     delete $weak_registry->{$slot}
 170       unless $cleared->{hash_merge_singleton}{$weak_registry->{$slot}{weakref}{behavior}}++;
 171   }
 172   elsif ($slot =~ /^__TxnScopeGuard__FIXUP__/) {
 173     die 'The $@ debacle should have been fixed by now!!!' if $] >= 5.013008;
 174     delete $weak_registry->{$slot};
 175   }
 176 }
 177
 178
 179 # FIXME
 180 # For reasons I can not yet fully understand the table() god-method (located in
 181 # ::ResultSourceProxy::Table) attaches an actual source instance to each class
 182 # as virtually *immortal* class-data.
 183 # For now just blow away these instances manually but there got to be a saner way
 184 $_->result_source_instance(undef) for (
 185   'DBICTest::BaseResult',
 186   map { DBICTest::Schema->class ($_) } DBICTest::Schema->sources
 187 );
 188
 189 # FIXME
 190 # same problem goes for the schema - its classdata contains live result source
 191 # objects, which to add insult to the injury are *different* instances from the
 192 # ones we destroyed above
 193 DBICTest::Schema->source_registrations(undef);
 194
 195 my $tb = Test::More->builder;
 196 for my $slot (keys %$weak_registry) {
 197
 198   ok (! defined $weak_registry->{$slot}{weakref}, "No leaks of $slot") or do {
 199     my $diag = '';
 200
 201     $diag .= Devel::FindRef::track ($weak_registry->{$slot}{weakref}, 20) . "\n"
 202       if ( $ENV{TEST_VERBOSE} && try { require Devel::FindRef });
 203
 204     if (my $stack = $weak_registry->{$slot}{strace}) {
 205       $diag .= "    Reference first seen$stack";
 206     }
 207
 208     diag $diag if $diag;
 209   };
 210 }
 211
 212 done_testing;