t/52leaks.t

   1 # work around brain damage in PPerl (yes, it has to be a global)
   2 $SIG{__WARN__} = sub {
   3   warn @_ unless $_[0] =~ /\QUse of "goto" to jump into a construct is deprecated/
   4 } if ($ENV{DBICTEST_IN_PERSISTENT_ENV});
   5
   6 # the persistent environments run with this flag first to see if
   7 # we will run at all (e.g. it will fail if $^X doesn't match)
   8 exit 0 if $ENV{DBICTEST_PERSISTENT_ENV_BAIL_EARLY};
   9
  10 # Do the override as early as possible so that CORE::bless doesn't get compiled away
  11 # We will replace $bless_override only if we are in author mode
  12 my $bless_override;
  13 BEGIN {
  14   $bless_override = sub {
  15     CORE::bless( $_[0], (@_ > 1) ? $_[1] : caller() );
  16   };
  17   *CORE::GLOBAL::bless = sub { goto $bless_override };
  18 }
  19
  20 use strict;
  21 use warnings;
  22 use Test::More;
  23
  24 my $TB = Test::More->builder;
  25 if ($ENV{DBICTEST_IN_PERSISTENT_ENV}) {
  26   # without this explicit close ->reset below warns
  27   close ($TB->$_) for qw/output failure_output/;
  28
  29   # so done_testing can work
  30   $TB->reset;
  31
  32   # this simulates a subtest
  33   $TB->_indent(' ' x 4);
  34 }
  35
  36 use lib qw(t/lib);
  37 use DBICTest::RunMode;
  38 use DBIx::Class;
  39 use B 'svref_2object';
  40 BEGIN {
  41   plan skip_all => "Your perl version $] appears to leak like a sieve - skipping test"
  42     if DBIx::Class::_ENV_::PEEPEENESS;
  43 }
  44
  45 use Scalar::Util qw/refaddr reftype weaken/;
  46
  47 # this is what holds all weakened refs to be checked for leakage
  48 my $weak_registry = {};
  49
  50 # whether or to invoke IC::DT
  51 my $has_dt;
  52
  53 # Skip the heavy-duty leak tracing when just doing an install
  54 unless (DBICTest::RunMode->is_plain) {
  55
  56   # have our own little stack maker - Carp infloops due to the bless override
  57   my $trace = sub {
  58     my $depth = 1;
  59     my (@stack, @frame);
  60
  61     while (@frame = caller($depth++)) {
  62       push @stack, [@frame[3,1,2]];
  63     }
  64
  65     $stack[0][0] = '';
  66     return join "\tinvoked as ", map { sprintf ("%s at %s line %d\n", @$_ ) } @stack;
  67   };
  68
  69   # redefine the bless override so that we can catch each and every object created
  70   no warnings qw/redefine once/;
  71   no strict qw/refs/;
  72
  73   $bless_override = sub {
  74
  75     my $obj = CORE::bless(
  76       $_[0], (@_ > 1) ? $_[1] : do {
  77         my ($class, $fn, $line) = caller();
  78         fail ("bless() of $_[0] into $class without explicit class specification at $fn line $line")
  79           if $class =~ /^ (?: DBIx\:\:Class | DBICTest ) /x;
  80         $class;
  81       }
  82     );
  83
  84     my $slot = (sprintf '%s=%s(0x%x)', # so we don't trigger stringification
  85       ref $obj,
  86       reftype $obj,
  87       refaddr $obj,
  88     );
  89
  90     # weaken immediately to avoid weird side effects
  91     $weak_registry->{$slot} = { weakref => $obj, strace => $trace->() };
  92     weaken $weak_registry->{$slot}{weakref};
  93
  94     return $obj;
  95   };
  96
  97   require Try::Tiny;
  98   for my $func (qw/try catch finally/) {
  99     my $orig = \&{"Try::Tiny::$func"};
 100     *{"Try::Tiny::$func"} = sub (&;@) {
 101
 102       my $slot = sprintf ('CODE(0x%x)', refaddr $_[0]);
 103
 104       $weak_registry->{$slot} = { weakref => $_[0], strace => $trace->() };
 105       weaken $weak_registry->{$slot}{weakref};
 106
 107       goto $orig;
 108     }
 109   }
 110
 111   # Some modules are known to install singletons on-load
 112   # Load them and empty the registry
 113
 114   # this loads the DT armada
 115   $has_dt = DBIx::Class::Optional::Dependencies->req_ok_for('test_dt_sqlite');
 116
 117   require Errno;
 118   require DBI;
 119   require DBD::SQLite;
 120   require FileHandle;
 121
 122   %$weak_registry = ();
 123 }
 124
 125 my @compose_ns_classes;
 126 {
 127   use_ok ('DBICTest');
 128
 129   my $schema = DBICTest->init_schema;
 130   my $rs = $schema->resultset ('Artist');
 131   my $storage = $schema->storage;
 132
 133   @compose_ns_classes = map { "DBICTest::${_}" } keys %{$schema->source_registrations};
 134
 135   ok ($storage->connected, 'we are connected');
 136
 137   my $row_obj = $rs->search({}, { rows => 1})->next;  # so that commits/rollbacks work
 138   ok ($row_obj, 'row from db');
 139
 140   # txn_do to invoke more codepaths
 141   my ($mc_row_obj, $pager, $pager_explicit_count) = $schema->txn_do (sub {
 142
 143     my $artist = $rs->create ({
 144       name => 'foo artist',
 145       cds => [{
 146         title => 'foo cd',
 147         year => 1984,
 148       }],
 149     });
 150
 151     my $pg = $rs->search({}, { rows => 1})->page(2)->pager;
 152
 153     my $pg_wcount = $rs->page(4)->pager->total_entries (66);
 154
 155     return ($artist, $pg, $pg_wcount);
 156   });
 157
 158   is ($pager->next_page, 3, 'There is one more page available');
 159
 160   # based on 66 per 10 pages
 161   is ($pager_explicit_count->last_page, 7, 'Correct last page');
 162
 163   # do some population (invokes some extra codepaths)
 164   # also exercise the guard code and the manual txn control
 165   {
 166     my $guard = $schema->txn_scope_guard;
 167     # populate with bindvars
 168     $rs->populate([{ name => 'James Bound' }]);
 169     $guard->commit;
 170
 171     $schema->txn_begin;
 172     # populate mixed
 173     $rs->populate([{ name => 'James Rebound', rank => \ '11'  }]);
 174     $schema->txn_commit;
 175
 176     $schema->txn_begin;
 177     # and without bindvars
 178     $rs->populate([{ name => \ '"James Unbound"' }]);
 179     $schema->txn_rollback;
 180   }
 181
 182   my $base_collection = {
 183     resultset => $rs,
 184
 185     # twice so that we make sure only one H::M object spawned
 186     chained_resultset => $rs->search_rs ({}, { '+columns' => [ 'foo' ] } ),
 187     chained_resultset2 => $rs->search_rs ({}, { '+columns' => [ 'bar' ] } ),
 188
 189     row_object => $row_obj,
 190
 191     result_source => $rs->result_source,
 192
 193     result_source_handle => $rs->result_source->handle,
 194
 195     pager_explicit_count => $pager_explicit_count,
 196
 197   };
 198
 199   require Storable;
 200   %$base_collection = (
 201     %$base_collection,
 202     refrozen => Storable::dclone( $base_collection ),
 203     rerefrozen => Storable::dclone( Storable::dclone( $base_collection ) ),
 204     schema => $schema,
 205     storage => $storage,
 206     sql_maker => $storage->sql_maker,
 207     dbh => $storage->_dbh,
 208     fresh_pager => $rs->page(5)->pager,
 209     pager => $pager,
 210   );
 211
 212   if ($has_dt) {
 213     my $rs = $base_collection->{icdt_rs} = $schema->resultset('Event');
 214
 215     my $now = DateTime->now;
 216     for (1..5) {
 217       $base_collection->{"icdt_row_$_"} = $rs->create({
 218         created_on => DateTime->new(year => 2011, month => 1, day => $_, time_zone => "-0${_}00" ),
 219         starts_at => $now->clone->add(days => $_),
 220       });
 221     }
 222
 223     # re-search
 224     my @dummy = $rs->all;
 225   }
 226
 227   # dbh's are created in XS space, so pull them separately
 228   for ( grep { defined } map { @{$_->{ChildHandles}} } values %{ {DBI->installed_drivers()} } ) {
 229     $base_collection->{"DBI handle $_"} = $_;
 230   }
 231
 232   if ( DBIx::Class::Optional::Dependencies->req_ok_for ('test_leaks') ) {
 233     Test::Memory::Cycle::memory_cycle_ok ($base_collection, 'No cycles in the object collection')
 234   }
 235
 236   for (keys %$base_collection) {
 237     $weak_registry->{"basic $_"} = { weakref => $base_collection->{$_} };
 238     weaken $weak_registry->{"basic $_"}{weakref};
 239   }
 240 }
 241
 242 # check that "phantom-chaining" works - we never lose track of the original $schema
 243 # and have access to the entire tree without leaking anything
 244 {
 245   my $phantom;
 246   for (
 247     sub { DBICTest->init_schema },
 248     sub { shift->source('Artist') },
 249     sub { shift->resultset },
 250     sub { shift->result_source },
 251     sub { shift->schema },
 252     sub { shift->resultset('Artist') },
 253     sub { shift->find_or_create({ name => 'detachable' }) },
 254     sub { shift->result_source },
 255     sub { shift->schema },
 256     sub { shift->clone },
 257     sub { shift->resultset('Artist') },
 258     sub { shift->next },
 259     sub { shift->result_source },
 260     sub { shift->resultset },
 261     sub { shift->create({ name => 'detached' }) },
 262     sub { shift->update({ name => 'reattached' }) },
 263     sub { shift->discard_changes },
 264     sub { shift->delete },
 265     sub { shift->insert },
 266   ) {
 267     $phantom = $_->($phantom);
 268
 269     my $slot = (sprintf 'phantom %s=%s(0x%x)', # so we don't trigger stringification
 270       ref $phantom,
 271       reftype $phantom,
 272       refaddr $phantom,
 273     );
 274
 275     $weak_registry->{$slot} = $phantom;
 276     weaken $weak_registry->{$slot};
 277   }
 278
 279   ok( $phantom->in_storage, 'Properly deleted/reinserted' );
 280   is( $phantom->name, 'reattached', 'Still correct name' );
 281 }
 282
 283 # Naturally we have some exceptions
 284 my $cleared;
 285 for my $slot (keys %$weak_registry) {
 286   if ($slot =~ /^Test::Builder/) {
 287     # T::B 2.0 has result objects and other fancyness
 288     delete $weak_registry->{$slot};
 289   }
 290   elsif ($slot =~ /^SQL::Translator/) {
 291     # SQLT is a piece of shit, leaks all over
 292     delete $weak_registry->{$slot};
 293   }
 294   elsif ($slot =~ /^Hash::Merge/) {
 295     # only clear one object of a specific behavior - more would indicate trouble
 296     delete $weak_registry->{$slot}
 297       unless $cleared->{hash_merge_singleton}{$weak_registry->{$slot}{weakref}{behavior}}++;
 298   }
 299   elsif (DBIx::Class::_ENV_::INVISIBLE_DOLLAR_AT and $slot =~ /^__TxnScopeGuard__FIXUP__/) {
 300     delete $weak_registry->{$slot}
 301   }
 302   elsif ($slot =~ /^DateTime::TimeZone/) {
 303     # DT is going through a refactor it seems - let it leak zones for now
 304     delete $weak_registry->{$slot};
 305   }
 306 }
 307
 308 # every result class has a result source instance as classdata
 309 # make sure these are all present and distinct before ignoring
 310 # (distinct means only 1 reference)
 311 for my $rs_class (
 312   'DBICTest::BaseResult',
 313   @compose_ns_classes,
 314   map { DBICTest::Schema->class ($_) } DBICTest::Schema->sources
 315 ) {
 316   # need to store the SVref and examine it separately, to push the rsrc instance off the pad
 317   my $SV = svref_2object($rs_class->result_source_instance);
 318   is( $SV->REFCNT, 1, "Source instance of $rs_class referenced exactly once" );
 319
 320   # ignore it
 321   delete $weak_registry->{$rs_class->result_source_instance};
 322 }
 323
 324 # Schema classes also hold sources, but these are clones, since
 325 # each source contains the schema (or schema class name in this case)
 326 # Hence the clone so that the same source can be registered with
 327 # multiple schemas
 328 for my $moniker ( keys %{DBICTest::Schema->source_registrations || {}} ) {
 329
 330   my $SV = svref_2object(DBICTest::Schema->source($moniker));
 331   is( $SV->REFCNT, 1, "Source instance registered under DBICTest::Schema as $moniker referenced exactly once" );
 332
 333   delete $weak_registry->{DBICTest::Schema->source($moniker)};
 334 }
 335
 336 for my $slot (sort keys %$weak_registry) {
 337
 338   ok (! defined $weak_registry->{$slot}{weakref}, "No leaks of $slot") or do {
 339     my $diag = '';
 340
 341     $diag .= Devel::FindRef::track ($weak_registry->{$slot}{weakref}, 20) . "\n"
 342       if ( $ENV{TEST_VERBOSE} && eval { require Devel::FindRef });
 343
 344     if (my $stack = $weak_registry->{$slot}{strace}) {
 345       $diag .= "    Reference first seen$stack";
 346     }
 347
 348     diag $diag if $diag;
 349   };
 350 }
 351
 352 # we got so far without a failure - this is a good thing
 353 # now let's try to rerun this script under a "persistent" environment
 354 # this is ugly and dirty but we do not yet have a Test::Embedded or
 355 # similar
 356
 357 my @pperl_cmd = (qw/pperl --prefork=1/, __FILE__);
 358 my @pperl_term_cmd = @pperl_cmd;
 359 splice @pperl_term_cmd, 1, 0, '--kill';
 360
 361 # scgi is smart and will auto-reap after -t amount of seconds
 362 my @scgi_cmd = (qw/speedy -- -t5/, __FILE__);
 363
 364 SKIP: {
 365   skip 'Test already in a persistent loop', 1
 366     if $ENV{DBICTEST_IN_PERSISTENT_ENV};
 367
 368   skip 'Persistence test disabled on regular installs', 1
 369     if DBICTest::RunMode->is_plain;
 370
 371   skip 'Main test failed - skipping persistent env tests', 1
 372     unless $TB->is_passing;
 373
 374   # set up -I
 375   require Config;
 376   local $ENV{PERL5LIB} = join ($Config::Config{path_sep}, @INC);
 377
 378   local $ENV{DBICTEST_IN_PERSISTENT_ENV} = 1;
 379
 380   # try with pperl
 381   SKIP: {
 382     skip 'PPerl persistent environment tests require PPerl', 1
 383       unless eval { require PPerl };
 384
 385     # since PPerl is racy and sucks - just prime the "server"
 386     {
 387       local $ENV{DBICTEST_PERSISTENT_ENV_BAIL_EARLY} = 1;
 388       system(@pperl_cmd);
 389       sleep 1;
 390
 391       # see if it actually runs - if not might as well bail now
 392       skip "Something is wrong with pperl ($!)", 1
 393         if system(@pperl_cmd);
 394     }
 395
 396     for (1,2,3) {
 397       system(@pperl_cmd);
 398       ok (!$?, "Run in persistent env (PPerl pass $_): exit $?");
 399     }
 400
 401     ok (! system (@pperl_term_cmd), 'killed pperl instance');
 402   }
 403
 404   # try with speedy-cgi
 405   SKIP: {
 406     skip 'SPeedyCGI persistent environment tests require CGI::SpeedyCGI', 1
 407       unless eval { require CGI::SpeedyCGI };
 408
 409     {
 410       local $ENV{DBICTEST_PERSISTENT_ENV_BAIL_EARLY} = 1;
 411       skip "Something is wrong with speedy ($!)", 1
 412         if system(@scgi_cmd);
 413       sleep 1;
 414     }
 415
 416     for (1,2,3) {
 417       system(@scgi_cmd);
 418       ok (!$?, "Run in persistent env (SpeedyCGI pass $_): exit $?");
 419     }
 420   }
 421 }
 422
 423 done_testing;
 424
 425 # just an extra precaution in case we blew away from the SKIP - since there are no
 426 # PID files to go by (man does pperl really suck :(
 427 END {
 428   unless ($ENV{DBICTEST_IN_PERSISTENT_ENV}) {
 429     close STDOUT;
 430     close STDERR;
 431     local $?; # otherwise test will inherit $? of the system()
 432     system (@pperl_term_cmd);
 433   }
 434 }