t/51threadtxn.t

   1 use strict;
   2 use warnings;
   3 use Test::More;
   4 use Config;
   5
   6 # README: If you set the env var to a number greater than 10,
   7 #   we will use that many children
   8
   9 BEGIN {
  10     plan skip_all => 'Your perl does not support ithreads'
  11         if !$Config{useithreads};
  12 }
  13
  14 BEGIN {
  15     plan skip_all => 'Minimum of perl 5.8.3 required for thread tests (DBD::Pg mandated)'
  16         if $] < '5.008003';
  17 }
  18
  19
  20 use threads;
  21 use lib qw(t/lib);
  22
  23 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  24 plan skip_all => 'Set $ENV{DBICTEST_PG_DSN}, _USER and _PASS to run this test'
  25       . ' (note: creates and drops a table named artist!)' unless ($dsn && $user);
  26
  27
  28 my $num_children = $ENV{DBICTEST_THREAD_STRESS};
  29 plan skip_all => 'Set $ENV{DBICTEST_THREAD_STRESS} to run this test'
  30     unless $num_children;
  31
  32 if($num_children !~ /^[0-9]+$/ || $num_children < 10) {
  33    $num_children = 10;
  34 }
  35
  36 use_ok('DBICTest::Schema');
  37
  38 diag "\n\nIt is ok if you see series of 'Attempt to free unreferenced scalar: ...' warnings during this test\n "
  39   if $] < '5.008005';
  40
  41 my $schema = DBICTest::Schema->connection($dsn, $user, $pass, { AutoCommit => 1, RaiseError => 1, PrintError => 0 });
  42
  43 my $parent_rs;
  44
  45 eval {
  46     my $dbh = $schema->storage->dbh;
  47
  48     {
  49         local $SIG{__WARN__} = sub {};
  50         eval { $dbh->do("DROP TABLE cd") };
  51         $dbh->do("CREATE TABLE cd (cdid serial PRIMARY KEY, artist INTEGER NOT NULL UNIQUE, title VARCHAR(100) NOT NULL UNIQUE, year VARCHAR(100) NOT NULL, genreid INTEGER, single_track INTEGER);");
  52     }
  53
  54     $schema->resultset('CD')->create({ title => 'vacation in antarctica', artist => 123, year => 1901 });
  55     $schema->resultset('CD')->create({ title => 'vacation in antarctica part 2', artist => 456, year => 1901 });
  56
  57     $parent_rs = $schema->resultset('CD')->search({ year => 1901 });
  58     $parent_rs->next;
  59 };
  60 ok(!$@) or diag "Creation eval failed: $@";
  61
  62 my @children;
  63 while(@children < $num_children) {
  64
  65     my $newthread = async {
  66         my $tid = threads->tid;
  67         # my $dbh = $schema->storage->dbh;
  68
  69         $schema->txn_do(sub {
  70             my $child_rs = $schema->resultset('CD')->search({ year => 1901 });
  71             my $row = $parent_rs->next;
  72             if($row && $row->get_column('artist') =~ /^(?:123|456)$/) {
  73                 $schema->resultset('CD')->create({ title => "test success $tid", artist => $tid, year => scalar(@children) });
  74             }
  75         });
  76         sleep(3);
  77     };
  78     die "Thread creation failed: $! $@" if !defined $newthread;
  79     push(@children, $newthread);
  80 }
  81
  82 ok(1, "past spawning");
  83
  84 {
  85     $_->join for(@children);
  86 }
  87
  88 ok(1, "past joining");
  89
  90 while(@children) {
  91     my $child = pop(@children);
  92     my $tid = $child->tid;
  93     my $rs = $schema->resultset('CD')->search({ title => "test success $tid", artist => $tid, year => scalar(@children) });
  94     is($rs->next->get_column('artist'), $tid, "Child $tid successful");
  95 }
  96
  97 ok(1, "Made it to the end");
  98
  99 $schema->storage->dbh->do("DROP TABLE cd");
 100
 101 done_testing;