t/51threadtxn.t

   1 # README: If you set the env var to a number greater than 10,
   2 #   we will use that many children
   3
   4 use Config;
   5 BEGIN {
   6   unless ($Config{useithreads}) {
   7     print "1..0 # SKIP your perl does not support ithreads\n";
   8     exit 0;
   9   }
  10
  11   if ($INC{'Devel/Cover.pm'}) {
  12     print "1..0 # SKIP Devel::Cover does not work with threads yet\n";
  13     exit 0;
  14   }
  15 }
  16 use threads;
  17
  18 use DBIx::Class::Optional::Dependencies -skip_all_without => 'test_rdbms_pg';
  19
  20 use strict;
  21 use warnings;
  22
  23 use Test::More;
  24
  25 plan skip_all => 'DBIC does not actively support threads before perl 5.8.5'
  26   if $] < '5.008005';
  27
  28 use Scalar::Util 'weaken';
  29 use lib qw(t/lib);
  30 use DBICTest;
  31
  32 my $num_children = $ENV{DBICTEST_THREAD_STRESS} || 1;
  33 if($num_children !~ /^[0-9]+$/ || $num_children < 10) {
  34    $num_children = 10;
  35 }
  36
  37 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  38
  39 my $schema = DBICTest::Schema->connect($dsn, $user, $pass, { AutoCommit => 1, RaiseError => 1, PrintError => 0 });
  40
  41 my $parent_rs;
  42
  43 eval {
  44     my $dbh = $schema->storage->dbh;
  45
  46     {
  47         local $SIG{__WARN__} = sub {};
  48         eval { $dbh->do("DROP TABLE cd") };
  49         $dbh->do("CREATE TABLE cd (cdid serial PRIMARY KEY, artist INTEGER NOT NULL UNIQUE, title VARCHAR(100) NOT NULL UNIQUE, year VARCHAR(100) NOT NULL, genreid INTEGER, single_track INTEGER);");
  50     }
  51
  52     $schema->resultset('CD')->create({ title => 'vacation in antarctica', artist => 123, year => 1901 });
  53     $schema->resultset('CD')->create({ title => 'vacation in antarctica part 2', artist => 456, year => 1901 });
  54
  55     $parent_rs = $schema->resultset('CD')->search({ year => 1901 });
  56     is ($parent_rs->count, 2);
  57 };
  58 ok(!$@) or diag "Creation eval failed: $@";
  59
  60 my @children;
  61 while(@children < $num_children) {
  62
  63     my $newthread = async {
  64         my $tid = threads->tid;
  65         weaken(my $weak_schema = $schema);
  66         weaken(my $weak_parent_rs = $parent_rs);
  67         $schema->txn_do(sub {
  68             my $child_rs = $weak_schema->resultset('CD')->search({ year => 1901 });
  69             my $row = $weak_parent_rs->next;
  70             if($row && $row->get_column('artist') =~ /^(?:123|456)$/) {
  71                 $weak_schema->resultset('CD')->create({ title => "test success $tid", artist => $tid, year => scalar(@children) });
  72             }
  73         });
  74         sleep(1);  # tasty crashes without this
  75     };
  76     die "Thread creation failed: $! $@" if !defined $newthread;
  77     push(@children, $newthread);
  78 }
  79
  80 ok(1, "past spawning");
  81
  82 {
  83     $_->join for(@children);
  84 }
  85
  86 ok(1, "past joining");
  87
  88 while(@children) {
  89     my $child = pop(@children);
  90     my $tid = $child->tid;
  91     my $rs = $schema->resultset('CD')->search({ title => "test success $tid", artist => $tid, year => scalar(@children) });
  92     is($rs->next->get_column('artist'), $tid, "Child $tid successful");
  93 }
  94
  95 ok(1, "Made it to the end");
  96
  97 $schema->storage->dbh->do("DROP TABLE cd");
  98
  99 done_testing;