t/51threads.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5
   6 use Config;
   7 BEGIN {
   8     plan skip_all => 'Your perl does not support ithreads'
   9         if !$Config{useithreads};
  10 }
  11
  12 BEGIN {
  13     plan skip_all => 'Minimum of perl 5.8.3 required for thread tests (DBD::Pg mandated)'
  14         if $] < '5.008003';
  15 }
  16
  17 use threads;
  18 use Test::Exception;
  19 use lib qw(t/lib);
  20
  21 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  22 plan skip_all => 'Set $ENV{DBICTEST_PG_DSN}, _USER and _PASS to run this test'
  23       . ' (note: creates and drops a table named artist!)' unless ($dsn && $user);
  24
  25 # README: If you set the env var to a number greater than 10,
  26 #   we will use that many children
  27 my $num_children = $ENV{DBICTEST_THREAD_STRESS};
  28
  29 plan skip_all => 'Set $ENV{DBICTEST_THREAD_STRESS} to run this test'
  30     unless $num_children;
  31
  32 if($num_children !~ /^[0-9]+$/ || $num_children < 10) {
  33    $num_children = 10;
  34 }
  35
  36 use_ok('DBICTest::Schema');
  37
  38 diag "\n\nIt is ok if you see series of 'Attempt to free unreferenced scalar: ...' warnings during this test\n "
  39   if $] < '5.008005';
  40
  41 my $schema = DBICTest::Schema->connection($dsn, $user, $pass, { AutoCommit => 1, RaiseError => 1, PrintError => 0 });
  42
  43 my $parent_rs;
  44
  45 lives_ok (sub {
  46     my $dbh = $schema->storage->dbh;
  47
  48     {
  49         local $SIG{__WARN__} = sub {};
  50         eval { $dbh->do("DROP TABLE cd") };
  51         $dbh->do("CREATE TABLE cd (cdid serial PRIMARY KEY, artist INTEGER NOT NULL UNIQUE, title VARCHAR(100) NOT NULL UNIQUE, year VARCHAR(100) NOT NULL, genreid INTEGER, single_track INTEGER);");
  52     }
  53
  54     $schema->resultset('CD')->create({ title => 'vacation in antarctica', artist => 123, year => 1901 });
  55     $schema->resultset('CD')->create({ title => 'vacation in antarctica part 2', artist => 456, year => 1901 });
  56
  57     $parent_rs = $schema->resultset('CD')->search({ year => 1901 });
  58     $parent_rs->next;
  59 }, 'populate successfull');
  60
  61 my @children;
  62 while(@children < $num_children) {
  63
  64     my $newthread = async {
  65         my $tid = threads->tid;
  66
  67         my $child_rs = $schema->resultset('CD')->search({ year => 1901 });
  68         my $row = $parent_rs->next;
  69         if($row && $row->get_column('artist') =~ /^(?:123|456)$/) {
  70             $schema->resultset('CD')->create({ title => "test success $tid", artist => $tid, year => scalar(@children) });
  71         }
  72         sleep(3);
  73     };
  74     die "Thread creation failed: $! $@" if !defined $newthread;
  75     push(@children, $newthread);
  76 }
  77
  78 ok(1, "past spawning");
  79
  80 {
  81     $_->join for(@children);
  82 }
  83
  84 ok(1, "past joining");
  85
  86 while(@children) {
  87     my $child = pop(@children);
  88     my $tid = $child->tid;
  89     my $rs = $schema->resultset('CD')->search({ title => "test success $tid", artist => $tid, year => scalar(@children) });
  90     is($rs->next->get_column('artist'), $tid, "Child $tid successful");
  91 }
  92
  93 ok(1, "Made it to the end");
  94
  95 $schema->storage->dbh->do("DROP TABLE cd");
  96
  97 done_testing;