t/47bind_attribute.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use lib qw(t/lib);
   6 use DBIC::SqlMakerTest;
   7
   8 use_ok('DBICTest');
   9
  10 my $schema = DBICTest->init_schema;
  11
  12 BEGIN {
  13     eval "use DBD::SQLite";
  14     plan $@
  15         ? ( skip_all => 'needs DBD::SQLite for testing' )
  16         : ( tests => 9 );
  17 }
  18
  19 my $where_bind = {
  20     where => \'name like ?',
  21     bind  => [ 'Cat%' ],
  22 };
  23
  24 my $rs;
  25
  26 TODO: {
  27     local $TODO = 'bind args order needs fixing (semifor)';
  28
  29     # First, the simple cases...
  30     $rs = $schema->resultset('Artist')->search(
  31             { artistid => 1 },
  32             $where_bind,
  33     );
  34
  35     is ( $rs->count, 1, 'where/bind combined' );
  36
  37     $rs= $schema->resultset('Artist')->search({}, $where_bind)
  38         ->search({ artistid => 1});
  39
  40     is ( $rs->count, 1, 'where/bind first' );
  41
  42     $rs = $schema->resultset('Artist')->search({ artistid => 1})
  43         ->search({}, $where_bind);
  44
  45     is ( $rs->count, 1, 'where/bind last' );
  46 }
  47
  48 # More complex cases, based primarily on the Cookbook
  49 # "Arbitrary SQL through a custom ResultSource" technique,
  50 # which seems to be the only place the bind attribute is
  51 # documented.  Breaking this technique probably breaks existing
  52 # application code.
  53 my $source = DBICTest::Artist->result_source_instance;
  54 my $new_source = $source->new($source);
  55 $new_source->source_name('Complex');
  56
  57 $new_source->name(\<<'');
  58 ( SELECT a.*, cd.cdid AS cdid, cd.title AS title, cd.year AS year
  59   FROM artist a
  60   JOIN cd ON cd.artist = a.artistid
  61   WHERE cd.year = ?)
  62
  63 $schema->register_extra_source('Complex' => $new_source);
  64
  65 $rs = $schema->resultset('Complex')->search({}, { bind => [ 1999 ] });
  66 is ( $rs->count, 1, 'cookbook arbitrary sql example' );
  67
  68 $rs = $schema->resultset('Complex')->search({ 'artistid' => 1 }, { bind => [ 1999 ] });
  69 is ( $rs->count, 1, '...coobook + search condition' );
  70
  71 $rs = $schema->resultset('Complex')->search({}, { bind => [ 1999 ] })
  72     ->search({ 'artistid' => 1 });
  73 is ( $rs->count, 1, '...cookbook (bind first) + chained search' );
  74
  75 {
  76   $rs = $schema->resultset('Complex')->search({}, { bind => [ 1999 ] })->search({}, { where => \"title LIKE ?", bind => [ 'Spoon%' ] });
  77   my ($sql, @bind) = @${$rs->as_query};
  78   is_same_sql_bind(
  79     $sql, \@bind,
  80     "(SELECT me.artistid, me.name, me.rank, me.charfield FROM (SELECT a.*, cd.cdid AS cdid, cd.title AS title, cd.year AS year FROM artist a JOIN cd ON cd.artist = a.artistid WHERE cd.year = ?) WHERE title LIKE ?)",
  81     [
  82       [ '!!dummy' => '1999' ],
  83       [ '!!dummy' => 'Spoon%' ]
  84     ],
  85     'got correct SQL'
  86 );
  87
  88 }
  89
  90 TODO: {
  91     local $TODO = 'bind args order needs fixing (semifor)';
  92     $rs = $schema->resultset('Complex')->search({}, { bind => [ 1999 ] })
  93         ->search({ 'artistid' => 1 }, {
  94             where => \'title like ?',
  95             bind => [ 'Spoon%' ] });
  96     is ( $rs->count, 1, '...cookbook + chained search with extra bind' );
  97 }