t/44_upgrade_db.t

   1 $|++;
   2 use strict;
   3 use Test::More;
   4
   5 # Add skips here
   6 BEGIN {
   7     my @failures;
   8     eval { use Pod::Usage; }; push @failures, 'Pod::Usage' if $@;
   9     eval { use IO::Scalar; }; push @failures, 'IO::Scalar' if $@;
  10     if ( @failures ) {
  11         my $missing = join ',', @failures;
  12         plan skip_all => "'$missing' must be installed to run these tests";
  13     }
  14 }
  15
  16 plan tests => 116;
  17
  18 use t::common qw( new_fh );
  19 use File::Spec;
  20 use Test::Deep;
  21
  22 my $PROG = File::Spec->catfile( qw( utils upgrade_db.pl ) );
  23
  24 my $short = get_pod( $PROG, 0 );
  25 my $long = get_pod( $PROG, 1 );
  26
  27 is( run_prog( $PROG ), "Missing required parameters.\n$long", "Failed no params" );
  28 is( run_prog( $PROG, '-input foo' ), "Missing required parameters.\n$long", "Failed only -input" );
  29 is( run_prog( $PROG, '-output foo' ), "Missing required parameters.\n$long", "Failed only -output" );
  30 is(
  31     run_prog( $PROG, '-input foo', '-output foo' ),
  32     "Cannot use the same filename for both input and output.\n$short",
  33     "Failed same name",
  34 );
  35
  36 is(
  37     run_prog( $PROG, '-input foo', '-output bar' ),
  38     "'foo' is not a file.\n$short",
  39     "Failed input does not exist",
  40 );
  41
  42 my (undef, $input_filename) = new_fh();
  43 my (undef, $output_filename) = new_fh();
  44
  45 is(
  46     run_prog( $PROG, "-input $input_filename", "-output $output_filename" ),
  47     "'$input_filename' is not a DBM::Deep file.\n$short",
  48     "Input is not a DBM::Deep file",
  49 );
  50
  51 # All files are of the form:
  52 #   $db->{foo} = [ 1 .. 3 ];
  53
  54 my @input_files = (
  55     '0-983',
  56     '0-99_04',
  57     '1-0000',
  58 );
  59
  60 my @output_versions = (
  61     '0.91', '0.92', '0.93', '0.94', '0.95', '0.96', '0.97', '0.98',
  62     '0.981', '0.982', '0.983',
  63     '0.99_01', '0.99_02', '0.99_03', '0.99_04',
  64     '1.00', '1.000', '1.0000',
  65 );
  66
  67 foreach my $input_filename (
  68     map {
  69         File::Spec->catfile( qw( t etc ), "db-$_" )
  70     } @input_files
  71 ) {
  72     # chmod it writable because old DBM::Deep versions don't handle readonly
  73     # files correctly. This is fixed in DBM::Deep 1.0000
  74     chmod 0600, $input_filename;
  75
  76     foreach my $v ( @output_versions ) {
  77         my (undef, $output_filename) = new_fh();
  78         my $output = run_prog(
  79             $PROG,
  80             "-input $input_filename",
  81             "-output $output_filename",
  82             "-version $v",
  83         );
  84
  85         if ( $input_filename =~ /_/ ) {
  86             is(
  87                 $output, "'$input_filename' is a dev release and not supported.\n$short",
  88                 "Input file is a dev release - not supported",
  89             );
  90
  91             next;
  92         }
  93
  94         if ( $v =~ /_/ ) {
  95             is(
  96                 $output, "-version '$v' is a dev release and not supported.\n$short",
  97                 "Output version is a dev release - not supported",
  98             );
  99
 100             next;
 101         }
 102
 103         # Now, read the output file with the right version.
 104         ok( !$output, "A successful run produces no output" );
 105         die "$output\n" if $output;
 106
 107         my $db;
 108         if ( $v =~ /^0/ ) {
 109             push @INC, File::Spec->catdir( 'utils', 'lib' );
 110             eval "use DBM::Deep::09830";
 111             $db = DBM::Deep::09830->new( $output_filename );
 112         }
 113         elsif ( $v =~ /^1/ ) {
 114             push @INC, 'lib';
 115             eval "use DBM::Deep";
 116             $db = DBM::Deep->new( $output_filename );
 117         }
 118         else {
 119             die "How did we get here?!\n";
 120         }
 121
 122         ok( $db, "Writing to version $v made a file" );
 123
 124         cmp_deeply(
 125             $db->export,
 126             { foo => [ 1 .. 3 ] },
 127             "We can read the output file",
 128         );
 129     }
 130 }
 131
 132 ################################################################################
 133
 134 #XXX This needs to be made OS-portable
 135 sub run_prog {
 136     open( my $fh, '-|', "$^X @_ 2>&1" )
 137       or die "Cannot launch '@_' as a piped filehandle: $!\n";
 138     return join '', <$fh>;
 139 }
 140
 141 # In 5.8, we could use in-memory filehandles and have done:
 142 #     open( my $fh, '>', \my $pod ) or die "Cannot open in-memory filehandle: $!\n";
 143 #     ...
 144 #     return $pod;
 145 # However, DBM::Deep requires 5.6, so this set of contortions will have to do.
 146 sub get_pod {
 147     my ($p,$v) = @_;
 148
 149     my ($fh, $fn) = new_fh();
 150     close $fh;
 151
 152     open $fh, '>', $fn;
 153     pod2usage({
 154         -input   => $p,
 155         -output  => $fh,
 156         -verbose => $v,
 157         -exitval => 'NOEXIT',
 158     });
 159     close $fh;
 160
 161     open $fh, '<', $fn;
 162     return join '', <$fh>;
 163 }