t/33_transactions.todo

   1 use strict;
   2 use Test::More tests => 62;
   3 use Test::Deep;
   4 use t::common qw( new_fh );
   5
   6 use_ok( 'DBM::Deep' );
   7
   8 my ($fh, $filename) = new_fh();
   9 my $db1 = DBM::Deep->new(
  10     file => $filename,
  11     locking => 1,
  12     autoflush => 1,
  13 );
  14
  15 my $db2 = DBM::Deep->new(
  16     file => $filename,
  17     locking => 1,
  18     autoflush => 1,
  19 );
  20
  21 $db1->{x} = 'y';
  22 is( $db1->{x}, 'y', "Before transaction, DB1's X is Y" );
  23 is( $db2->{x}, 'y', "Before transaction, DB2's X is Y" );
  24
  25 $db1->begin_work;
  26
  27     is( $db1->{x}, 'y', "DB1 transaction started, no actions - DB1's X is Y" );
  28     is( $db2->{x}, 'y', "DB1 transaction started, no actions - DB2's X is Y" );
  29
  30     $db1->{x} = 'z';
  31     is( $db1->{x}, 'z', "Within DB1 transaction, DB1's X is Z" );
  32     is( $db2->{x}, 'y', "Within DB1 transaction, DB2's X is still Y" );
  33
  34     $db2->{other_x} = 'foo';
  35     is( $db2->{other_x}, 'foo', "DB2 set other_x within DB1's transaction, so DB2 can see it" );
  36     ok( !exists $db1->{other_x}, "Since other_x was added after the transaction began, DB1 doesn't see it." );
  37
  38     cmp_bag( [ keys %$db1 ], [qw( x )], "DB1 keys correct" );
  39     cmp_bag( [ keys %$db2 ], [qw( x other_x )], "DB2 keys correct" );
  40
  41 $db1->rollback;
  42
  43 is( $db1->{x}, 'y', "After rollback, DB1's X is Y" );
  44 is( $db2->{x}, 'y', "After rollback, DB2's X is Y" );
  45
  46 is( $db1->{other_x}, 'foo', "After DB1 transaction is over, DB1 can see other_x" );
  47 is( $db2->{other_x}, 'foo', "After DB1 transaction is over, DB2 can still see other_x" );
  48
  49 $db1->begin_work;
  50
  51     is( $db1->{x}, 'y', "DB1 transaction started, no actions - DB1's X is Y" );
  52     is( $db2->{x}, 'y', "DB1 transaction started, no actions - DB2's X is Y" );
  53
  54     $db1->{x} = 'z';
  55     is( $db1->{x}, 'z', "Within DB1 transaction, DB1's X is Z" );
  56     is( $db2->{x}, 'y', "Within DB1 transaction, DB2's X is still Y" );
  57
  58     $db2->{other_x} = 'bar';
  59     is( $db2->{other_x}, 'bar', "DB2 set other_x within DB1's transaction, so DB2 can see it" );
  60     is( $db1->{other_x}, 'foo', "Since other_x was modified after the transaction began, DB1 doesn't see the change." );
  61
  62     cmp_bag( [ keys %$db1 ], [qw( x other_x )], "DB1 keys correct" );
  63     cmp_bag( [ keys %$db2 ], [qw( x other_x )], "DB2 keys correct" );
  64
  65 $db1->commit;
  66
  67 is( $db1->{x}, 'z', "After commit, DB1's X is Z" );
  68 is( $db2->{x}, 'z', "After commit, DB2's X is Z" );
  69
  70 $db1->begin_work;
  71
  72     delete $db2->{other_x};
  73     ok( !exists $db2->{other_x}, "DB2 deleted other_x in DB1's transaction, so it can't see it anymore" );
  74     is( $db1->{other_x}, 'bar', "Since other_x was deleted after the transaction began, DB1 still sees it." );
  75
  76     cmp_bag( [ keys %$db1 ], [qw( x other_x )], "DB1 keys correct" );
  77     cmp_bag( [ keys %$db2 ], [qw( x )], "DB2 keys correct" );
  78
  79     delete $db1->{x};
  80     ok( !exists $db1->{x}, "DB1 deleted X in a transaction, so it can't see it anymore" );
  81     is( $db2->{x}, 'z', "But, DB2 can still see it" );
  82
  83     cmp_bag( [ keys %$db1 ], [qw( other_x )], "DB1 keys correct" );
  84     cmp_bag( [ keys %$db2 ], [qw( x )], "DB2 keys correct" );
  85
  86 $db1->rollback;
  87
  88 ok( !exists $db2->{other_x}, "It's still deleted for DB2" );
  89 ok( !exists $db1->{other_x}, "And now DB1 sees the deletion" );
  90
  91 is( $db1->{x}, 'z', "The transaction was rolled back, so DB1 can see X now" );
  92 is( $db2->{x}, 'z', "DB2 can still see it" );
  93
  94 cmp_bag( [ keys %$db1 ], [qw( x )], "DB1 keys correct" );
  95 cmp_bag( [ keys %$db2 ], [qw( x )], "DB2 keys correct" );
  96
  97 $db1->begin_work;
  98
  99     delete $db1->{x};
 100     ok( !exists $db1->{x}, "DB1 deleted X in a transaction, so it can't see it anymore" );
 101 #__END__
 102     is( $db2->{x}, 'z', "But, DB2 can still see it" );
 103
 104     cmp_bag( [ keys %$db1 ], [qw()], "DB1 keys correct" );
 105     cmp_bag( [ keys %$db2 ], [qw( x )], "DB2 keys correct" );
 106
 107 $db1->commit;
 108
 109 ok( !exists $db1->{x}, "The transaction was committed, so DB1 still deleted X" );
 110 ok( !exists $db2->{x}, "DB2 can now see the deletion of X" );
 111
 112 $db1->{foo} = 'bar';
 113 is( $db1->{foo}, 'bar', "Set foo to bar in DB1" );
 114 is( $db2->{foo}, 'bar', "Set foo to bar in DB2" );
 115
 116 cmp_bag( [ keys %$db1 ], [qw( foo )], "DB1 keys correct" );
 117 cmp_bag( [ keys %$db2 ], [qw( foo )], "DB2 keys correct" );
 118
 119 $db1->begin_work;
 120
 121     %$db1 = (); # clear()
 122     ok( !exists $db1->{foo}, "Cleared foo" );
 123     is( $db2->{foo}, 'bar', "But in DB2, we can still see it" );
 124
 125     cmp_bag( [ keys %$db1 ], [qw()], "DB1 keys correct" );
 126     cmp_bag( [ keys %$db2 ], [qw( foo )], "DB2 keys correct" );
 127
 128 $db1->rollback;
 129
 130 is( $db1->{foo}, 'bar', "Rollback means 'foo' is still there" );
 131 is( $db2->{foo}, 'bar', "Rollback means 'foo' is still there" );
 132
 133 cmp_bag( [ keys %$db1 ], [qw( foo )], "DB1 keys correct" );
 134 cmp_bag( [ keys %$db2 ], [qw( foo )], "DB2 keys correct" );
 135
 136 SKIP: {
 137     skip "Optimize tests skipped on Win32", 5
 138         if $^O eq 'MSWin32' || $^O eq 'cygwin';
 139
 140     $db1->optimize;
 141
 142     is( $db1->{foo}, 'bar', 'After optimize, everything is ok' );
 143     is( $db2->{foo}, 'bar', 'After optimize, everything is ok' );
 144
 145     cmp_bag( [ keys %$db1 ], [qw( foo )], "DB1 keys correct" );
 146     cmp_bag( [ keys %$db2 ], [qw( foo )], "DB2 keys correct" );
 147
 148     $db1->begin_work;
 149
 150         cmp_ok( $db1->_storage->transaction_id, '==', 1, "Transaction ID has been reset after optimize" );
 151
 152     $db1->rollback;
 153 }
 154
 155 __END__
 156
 157 Tests to add:
 158 * Two transactions running at the same time
 159 * Doing a clear on the head while a transaction is running
 160 # More than just two keys