t/21-leaks-debug.t

   1 #!/usr/bin/env perl
   2 use strict;
   3 use warnings;
   4 use lib 't/lib';
   5 use Test::More;
   6 use Test::Fatal;
   7 use Test::Requires 'Test::LeakTrace';
   8
   9 BEGIN { $^P |= 0x210 } # PERLDBf_SUBLINE
  10
  11 use Package::Stash;
  12 use Symbol;
  13
  14 {
  15     package Bar;
  16 }
  17
  18 {
  19     package Baz;
  20     our $foo;
  21     sub bar { }
  22     use constant baz => 1;
  23     our %quux = (a => 'b');
  24 }
  25
  26 {
  27     no_leaks_ok {
  28         Package::Stash->new('Foo');
  29     } "object construction doesn't leak";
  30 }
  31
  32 {
  33     no_leaks_ok {
  34         Package::Stash->new('Bar');
  35     } "object construction doesn't leak, with an existing package";
  36 }
  37
  38 {
  39     no_leaks_ok {
  40         Package::Stash->new('Baz');
  41     } "object construction doesn't leak, with an existing package with things in it";
  42 }
  43
  44 {
  45     my $foo = Package::Stash->new('Foo');
  46     no_leaks_ok {
  47         $foo->name;
  48         $foo->namespace;
  49     } "accessors don't leak";
  50 }
  51
  52 {
  53     my $foo = Package::Stash->new('Foo');
  54     no_leaks_ok {
  55         $foo->add_symbol('$scalar');
  56         $foo->add_symbol('@array');
  57         $foo->add_symbol('%hash');
  58         $foo->add_symbol('io');
  59     } "add_symbol doesn't leak";
  60 }
  61
  62 {
  63     my $foo = Package::Stash->new('Foo');
  64     no_leaks_ok {
  65         $foo->add_symbol('$scalar_init' => 1);
  66         $foo->add_symbol('@array_init' => []);
  67         $foo->add_symbol('%hash_init' => {});
  68         $foo->add_symbol('&code_init' => sub { "foo" });
  69         $foo->add_symbol('io_init' => Symbol::geniosym);
  70     } "add_symbol doesn't leak";
  71     is(exception {
  72         is(Foo->code_init, 'foo', "sub installed correctly")
  73     }, undef, "code_init exists");
  74 }
  75
  76 {
  77     my $foo = Package::Stash->new('Foo');
  78     no_leaks_ok {
  79         $foo->remove_symbol('$scalar_init');
  80         $foo->remove_symbol('@array_init');
  81         $foo->remove_symbol('%hash_init');
  82         $foo->remove_symbol('&code_init');
  83         $foo->remove_symbol('io_init');
  84     } "remove_symbol doesn't leak";
  85 }
  86
  87 {
  88     my $foo = Package::Stash->new('Foo');
  89     $foo->add_symbol("${_}glob") for ('$', '@', '%', '&', '');
  90     no_leaks_ok {
  91         $foo->remove_glob('glob');
  92     } "remove_glob doesn't leak";
  93 }
  94
  95 {
  96     my $foo = Package::Stash->new('Foo');
  97     no_leaks_ok {
  98         $foo->has_symbol('io');
  99         $foo->has_symbol('%hash');
 100         $foo->has_symbol('@array_init');
 101         $foo->has_symbol('$glob');
 102         $foo->has_symbol('&something_else');
 103     } "has_symbol doesn't leak";
 104 }
 105
 106 {
 107     my $foo = Package::Stash->new('Foo');
 108     no_leaks_ok {
 109         $foo->get_symbol('io');
 110         $foo->get_symbol('%hash');
 111         $foo->get_symbol('@array_init');
 112         $foo->get_symbol('$glob');
 113         $foo->get_symbol('&something_else');
 114     } "get_symbol doesn't leak";
 115 }
 116
 117 {
 118     my $foo = Package::Stash->new('Foo');
 119     ok(!$foo->has_symbol('$glob'));
 120     ok(!$foo->has_symbol('@array_init'));
 121     no_leaks_ok {
 122         $foo->get_or_add_symbol('io');
 123         $foo->get_or_add_symbol('%hash');
 124         my @super = ('Exporter');
 125         @{$foo->get_or_add_symbol('@ISA')} = @super;
 126         $foo->get_or_add_symbol('$glob');
 127     } "get_or_add_symbol doesn't leak";
 128     { local $TODO = $] < 5.010 ? "undef scalars aren't visible on 5.8" : undef;
 129     ok($foo->has_symbol('$glob'));
 130     }
 131     is(ref($foo->get_symbol('$glob')), 'SCALAR');
 132     ok($foo->has_symbol('@ISA'));
 133     is(ref($foo->get_symbol('@ISA')), 'ARRAY');
 134     is_deeply($foo->get_symbol('@ISA'), ['Exporter']);
 135     isa_ok('Foo', 'Exporter');
 136 }
 137
 138 {
 139     my $foo = Package::Stash->new('Foo');
 140     my $baz = Package::Stash->new('Baz');
 141     no_leaks_ok {
 142         $foo->list_all_symbols;
 143         $foo->list_all_symbols('SCALAR');
 144         $foo->list_all_symbols('CODE');
 145         $baz->list_all_symbols('CODE');
 146     } "list_all_symbols doesn't leak";
 147 }
 148
 149 {
 150     package Blah;
 151     use constant 'baz';
 152 }
 153
 154 {
 155     my $foo = Package::Stash->new('Foo');
 156     my $blah = Package::Stash->new('Blah');
 157     no_leaks_ok {
 158         $foo->get_all_symbols;
 159         $foo->get_all_symbols('SCALAR');
 160         $foo->get_all_symbols('CODE');
 161         $blah->get_all_symbols('CODE');
 162     } "list_all_symbols doesn't leak";
 163 }
 164
 165 # mimic CMOP::create_anon_class
 166 {
 167     local $TODO = $] < 5.010 ? "deleting stashes is inherently leaky on 5.8"
 168                              : undef;
 169     my $i = 0;
 170     no_leaks_ok {
 171         $i++;
 172         eval "package Quux$i; 1;";
 173         my $quux = Package::Stash->new("Quux$i");
 174         $quux->get_or_add_symbol('@ISA');
 175         delete $::{'Quux' . $i . '::'};
 176     } "get_symbol doesn't leak during glob expansion";
 177 }
 178
 179 {
 180     my $foo = Package::Stash->new('Foo');
 181     no_leaks_ok {
 182         eval { $foo->get_or_add_symbol('&blorg') };
 183     } "doesn't leak on errors";
 184 }
 185
 186 done_testing;