t/150-composite-role-application.t

   1 #!/usr/bin/env perl
   2 use strict;
   3 use warnings;
   4
   5 use Test::More tests => 7;
   6 use Test::Exception;
   7
   8 do {
   9     package MyCompositeRoleA;
  10     use MooseX::Role::Parameterized;
  11
  12     parameter attribute => (
  13         isa => 'Str',
  14         required => 1,
  15     );
  16
  17     role {
  18         my $p = shift;
  19
  20         has $p->attribute => (
  21             is => 'rw',
  22         );
  23     };
  24 };
  25
  26 do {
  27     package MyCompositeRoleB;
  28     use MooseX::Role::Parameterized;
  29
  30     parameter accessor => (
  31         isa => 'Str',
  32         required => 1,
  33     );
  34
  35     role {
  36         my $p = shift;
  37
  38         has $p->accessor => (
  39             is => 'rw',
  40             isa => 'Int',
  41         );
  42     };
  43 };
  44
  45 do {
  46     package MyDoubleConsumer;
  47     use Moose;
  48     with MyCompositeRoleA => { attribute => 'foo' },
  49          MyCompositeRoleB => { accessor  => 'bar' };
  50 };
  51
  52 ok(MyDoubleConsumer->can('foo'), 'first role in composite applied successfully');
  53 ok(MyDoubleConsumer->can('bar'), 'second role in composite applied successfully');
  54
  55 do {
  56     package MyExtendingRole;
  57     use MooseX::Role::Parameterized;
  58
  59     parameter foo => (
  60         isa => 'Int',
  61     );
  62
  63     role {
  64         my $p = shift;
  65
  66         with 'MyCompositeRoleA', { attribute => 'bar' };
  67
  68         has foo => (
  69             is => 'rw',
  70             default => sub { $p->foo },
  71         );
  72     };
  73 };
  74
  75 do {
  76     package MyExtendedConsumer;
  77     use Moose;
  78     with MyCompositeRoleA => { attribute => 'baz' },
  79          MyExtendingRole  => { foo => 23 };
  80 };
  81
  82 ok(MyExtendedConsumer->can('baz'), 'role composed directly applied successfully');
  83 ok(MyExtendedConsumer->can('bar'), 'role composed through other role applied successfully');
  84 is(eval { MyExtendedConsumer->new->foo }, 23, 'role composing other role applied successfully');
  85
  86 do {
  87     package MyRoleProxy;
  88     use MooseX::Role::Parameterized;
  89
  90     parameter rolename   => (isa => "Str");
  91     parameter roleparams => (isa => "HashRef");
  92
  93     role {
  94         my $p = shift;
  95
  96         with $p->rolename, $p->roleparams;
  97     };
  98 };
  99
 100 do {
 101     package MyProxyConsumer;
 102     use Moose;
 103     with(
 104         MyRoleProxy => {
 105             rolename   => 'MyCompositeRoleA',
 106             roleparams => { attribute => 'baz' },
 107         },
 108         MyCompositeRoleB => {
 109             accessor => 'qux',
 110         },
 111     );
 112 };
 113
 114 ok(MyProxyConsumer->can('baz'), 'proxied role got applied successfully');
 115 ok(MyProxyConsumer->can('qux'), 'other role besides proxied one got applied successfully');
 116