t/11mysql_common.t

   1 use strict;
   2 use lib qw(t/lib);
   3 use dbixcsl_common_tests;
   4 use Test::More;
   5
   6 my $dsn         = $ENV{DBICTEST_MYSQL_DSN} || '';
   7 my $user        = $ENV{DBICTEST_MYSQL_USER} || '';
   8 my $password    = $ENV{DBICTEST_MYSQL_PASS} || '';
   9 my $test_innodb = $ENV{DBICTEST_MYSQL_INNODB} || 0;
  10
  11 my $skip_rels_msg = 'You need to set the DBICTEST_MYSQL_INNODB environment variable to test relationships';
  12
  13 my $tester = dbixcsl_common_tests->new(
  14     vendor           => 'Mysql',
  15     auto_inc_pk      => 'INTEGER NOT NULL PRIMARY KEY AUTO_INCREMENT',
  16     innodb           => $test_innodb ? q{Engine=InnoDB} : 0,
  17     dsn              => $dsn,
  18     user             => $user,
  19     password         => $password,
  20     connect_info_opts=> { on_connect_call => 'set_strict_mode' },
  21     skip_rels        => $test_innodb ? 0 : $skip_rels_msg,
  22     no_inline_rels   => 1,
  23     no_implicit_rels => 1,
  24     extra            => {
  25         create => [
  26             qq{
  27                 CREATE TABLE mysql_loader_test1 (
  28                     id INTEGER UNSIGNED NOT NULL PRIMARY KEY,
  29                     value ENUM('foo', 'bar', 'baz')
  30                 )
  31             },
  32             qq{
  33                 CREATE TABLE mysql_loader_test2 (
  34                   id INTEGER UNSIGNED NOT NULL PRIMARY KEY,
  35                   somedate TIMESTAMP NOT NULL DEFAULT CURRENT_TIMESTAMP,
  36                   somestr VARCHAR(100) NOT NULL DEFAULT 'foo'
  37                 )
  38             },
  39         ],
  40         drop   => [ qw/ mysql_loader_test1 mysql_loader_test2 / ],
  41         count  => 5,
  42         run    => sub {
  43             my ($schema, $monikers, $classes) = @_;
  44
  45             my $rs = $schema->resultset($monikers->{mysql_loader_test1});
  46             my $column_info = $rs->result_source->column_info('id');
  47
  48             is($column_info->{extra}->{unsigned}, 1, 'Unsigned MySQL columns');
  49
  50             $column_info = $rs->result_source->column_info('value');
  51
  52             like($column_info->{data_type}, qr/^enum$/i, 'MySQL ENUM type');
  53             is_deeply($column_info->{extra}->{list}, [qw/foo bar baz/],
  54                       'MySQL ENUM values');
  55
  56             $rs = $schema->resultset($monikers->{mysql_loader_test2});
  57             $column_info = $rs->result_source->column_info('somedate');
  58             my $default  = $column_info->{default_value};
  59             ok ((ref($default) eq 'SCALAR'),
  60                 'CURRENT_TIMESTAMP default_value is a scalar ref');
  61             like $$default, qr/^CURRENT_TIMESTAMP\z/i,
  62                 'CURRENT_TIMESTAMP default eq "CURRENT_TIMESTAMP"';
  63         },
  64     }
  65 );
  66
  67 if( !$dsn || !$user ) {
  68     $tester->skip_tests('You need to set the DBICTEST_MYSQL_DSN, _USER, and _PASS environment variables');
  69 }
  70 else {
  71     $tester->run_tests();
  72 }