t/07-edge-cases.t

   1 #!/usr/bin/env perl
   2 use strict;
   3 use warnings;
   4 use lib 't/lib';
   5 use Test::More;
   6
   7 use Package::Stash;
   8
   9 {
  10     package Foo;
  11     use constant FOO => 1;
  12     use constant BAR => \1;
  13     use constant BAZ => [];
  14     use constant QUUX => {};
  15     use constant QUUUX => sub { };
  16     sub normal { }
  17     sub stub;
  18     sub normal_with_proto () { }
  19     sub stub_with_proto ();
  20
  21     our $SCALAR;
  22     our $SCALAR_WITH_VALUE = 1;
  23     our @ARRAY;
  24     our %HASH;
  25 }
  26
  27 my $stash = Package::Stash->new('Foo');
  28 { local $TODO = $] < 5.010 ? "undef scalars aren't visible on 5.8" : undef;
  29 ok($stash->has_symbol('$SCALAR'), '$SCALAR');
  30 }
  31 ok($stash->has_symbol('$SCALAR_WITH_VALUE'), '$SCALAR_WITH_VALUE');
  32 ok($stash->has_symbol('@ARRAY'), '@ARRAY');
  33 ok($stash->has_symbol('%HASH'), '%HASH');
  34 is_deeply(
  35     [sort $stash->list_all_symbols('CODE')],
  36     [qw(BAR BAZ FOO QUUUX QUUX normal normal_with_proto stub stub_with_proto)],
  37     "can see all code symbols"
  38 );
  39
  40 $stash->add_symbol('%added', {});
  41 ok(!$stash->has_symbol('$added'), '$added');
  42 ok(!$stash->has_symbol('@added'), '@added');
  43 ok($stash->has_symbol('%added'), '%added');
  44
  45 my $constant = $stash->get_symbol('&FOO');
  46 is(ref($constant), 'CODE', "expanded a constant into a coderef");
  47
  48 done_testing;