t/03podcoverage.t

   1 use warnings;
   2 use strict;
   3
   4 use Test::More;
   5 use List::Util ();
   6 use lib qw(t/lib);
   7 use DBICTest;
   8
   9 my @MODULES = (
  10   'Test::Pod::Coverage 1.08',
  11   'Pod::Coverage 0.20',
  12 );
  13
  14 # Don't run tests for installs
  15 unless ( DBICTest::AuthorCheck->is_author || $ENV{AUTOMATED_TESTING} || $ENV{RELEASE_TESTING} ) {
  16   plan( skip_all => "Author tests not required for installation" );
  17 }
  18
  19 # Load the testing modules
  20 foreach my $MODULE ( @MODULES ) {
  21   eval "use $MODULE";
  22   if ( $@ ) {
  23     $ENV{RELEASE_TESTING}
  24     ? die( "Failed to load required release-testing module $MODULE" )
  25     : plan( skip_all => "$MODULE not available for testing" );
  26   }
  27 }
  28
  29 # Since this is about checking documentation, a little documentation
  30 # of what this is doing might be in order.
  31 # The exceptions structure below is a hash keyed by the module
  32 # name. Any * in a name is treated like a wildcard and will behave
  33 # as expected. Modules are matched by longest string first, so
  34 # A::B::C will match even if there is A::B*
  35
  36 # The value for each is a hash, which contains one or more
  37 # (although currently more than one makes no sense) of the following
  38 # things:-
  39 #   skip   => a true value means this module is not checked
  40 #   ignore => array ref containing list of methods which
  41 #             do not need to be documented.
  42 my $exceptions = {
  43     'DBIx::Class' => {
  44         ignore => [qw/
  45             MODIFY_CODE_ATTRIBUTES
  46             component_base_class
  47             mk_classdata
  48             mk_classaccessor
  49         /]
  50     },
  51     'DBIx::Class::Row' => {
  52         ignore => [qw/
  53             MULTICREATE_DEBUG
  54         /],
  55     },
  56     'DBIx::Class::ResultSource' => {
  57         ignore => [qw/
  58             compare_relationship_keys
  59             pk_depends_on
  60             resolve_condition
  61             resolve_join
  62             resolve_prefetch
  63         /],
  64     },
  65     'DBIx::Class::ResultSourceHandle' => {
  66         ignore => [qw/
  67             schema
  68             source_moniker
  69         /],
  70     },
  71     'DBIx::Class::Storage' => {
  72         ignore => [qw/
  73             schema
  74             cursor
  75         /]
  76     },
  77     'DBIx::Class::Schema' => {
  78         ignore => [qw/
  79             setup_connection_class
  80         /]
  81     },
  82
  83     'DBIx::Class::Schema::Versioned' => {
  84         ignore => [ qw/
  85             connection
  86         /]
  87     },
  88
  89     'DBIx::Class::ClassResolver::PassThrough'       => { skip => 1 },
  90     'DBIx::Class::Componentised'                    => { skip => 1 },
  91     'DBIx::Class::Relationship::*'                  => { skip => 1 },
  92     'DBIx::Class::ResultSetProxy'                   => { skip => 1 },
  93     'DBIx::Class::ResultSourceProxy'                => { skip => 1 },
  94     'DBIx::Class::Storage::Statistics'              => { skip => 1 },
  95     'DBIx::Class::Storage::DBI::Replicated::Types'  => { skip => 1 },
  96
  97 # test some specific components whose parents are exempt below
  98     'DBIx::Class::Storage::DBI::Replicated*'        => {},
  99     'DBIx::Class::Relationship::Base'               => {},
 100
 101 # internals
 102     'DBIx::Class::SQLAHacks*'                       => { skip => 1 },
 103     'DBIx::Class::Storage::DBI*'                    => { skip => 1 },
 104     'SQL::Translator::*'                            => { skip => 1 },
 105
 106 # deprecated / backcompat stuff
 107     'DBIx::Class::CDBICompat*'                      => { skip => 1 },
 108     'DBIx::Class::ResultSetManager'                 => { skip => 1 },
 109     'DBIx::Class::DB'                               => { skip => 1 },
 110
 111 # skipped because the synopsis covers it clearly
 112     'DBIx::Class::InflateColumn::File'              => { skip => 1 },
 113 };
 114
 115 my $ex_lookup = {};
 116 for my $string (keys %$exceptions) {
 117   my $ex = $exceptions->{$string};
 118   $string =~ s/\*/'.*?'/ge;
 119   my $re = qr/^$string$/;
 120   $ex_lookup->{$re} = $ex;
 121 }
 122
 123 my @modules = sort { $a cmp $b } (Test::Pod::Coverage::all_modules());
 124
 125 foreach my $module (@modules) {
 126   SKIP: {
 127
 128     my ($match) = List::Util::first
 129       { $module =~ $_ }
 130       (sort { length $b <=> length $a || $b cmp $a } (keys %$ex_lookup) )
 131     ;
 132
 133     my $ex = $ex_lookup->{$match} if $match;
 134
 135     skip ("$module exempt", 1) if ($ex->{skip});
 136
 137     # build parms up from ignore list
 138     my $parms = {};
 139     $parms->{trustme} =
 140       [ map { qr/^$_$/ } @{ $ex->{ignore} } ]
 141         if exists($ex->{ignore});
 142
 143     # run the test with the potentially modified parm set
 144     pod_coverage_ok($module, $parms, "$module POD coverage");
 145   }
 146 }
 147
 148 done_testing;