t/02_hash.t

   1 ##
   2 # DBM::Deep Test
   3 ##
   4 use strict;
   5 use Test::More tests => 49;
   6 use Test::Exception;
   7 use t::common qw( new_fh );
   8
   9 use_ok( 'DBM::Deep' );
  10
  11 my ($fh, $filename) = new_fh();
  12 my $db = DBM::Deep->new(
  13     file => $filename,
  14     fh => $fh,
  15 );
  16
  17 ##
  18 # put/get key
  19 ##
  20 $db->{key1} = "value1";
  21 is( $db->get("key1"), "value1", "get() works with hash assignment" );
  22 is( $db->fetch("key1"), "value1", "... fetch() works with hash assignment" );
  23 is( $db->{key1}, "value1", "... and hash-access also works" );
  24
  25 $db->put("key2", undef);
  26 is( $db->get("key2"), undef, "get() works with put()" );
  27 is( $db->fetch("key2"), undef, "... fetch() works with put()" );
  28 is( $db->{key2}, undef, "... and hash-access also works" );
  29
  30 $db->store( "key3", "value3" );
  31 is( $db->get("key3"), "value3", "get() works with store()" );
  32 is( $db->fetch("key3"), "value3", "... fetch() works with put()" );
  33 is( $db->{key3}, 'value3', "... and hash-access also works" );
  34
  35 # Verify that the keyval pairs are still correct.
  36 is( $db->{key1}, "value1", "Key1 is still correct" );
  37 is( $db->{key2}, undef, "Key2 is still correct" );
  38 is( $db->{key3}, 'value3', "Key3 is still correct" );
  39
  40 ok( $db->exists("key1"), "exists() function works" );
  41 ok( exists $db->{key2}, "exists() works against tied hash" );
  42
  43 ok( !exists $db->{key4}, "exists() function works for keys that aren't there" );
  44 is( $db->{key4}, undef, "Autovivified key4" );
  45 ok( exists $db->{key4}, "Autovivified key4 now exists" );
  46
  47 delete $db->{key4};
  48 ok( !exists $db->{key4}, "And key4 doesn't exists anymore" );
  49
  50 # Keys will be done via an iterator that keeps a breadcrumb trail of the last
  51 # key it provided. There will also be an "edit revision number" on the
  52 # reference so that resetting the iterator can be done.
  53 #
  54 # Q: How do we make sure that the iterator is unique? Is it supposed to be?
  55
  56 ##
  57 # count keys
  58 ##
  59 is( scalar keys %$db, 3, "keys() works against tied hash" );
  60
  61 ##
  62 # step through keys
  63 ##
  64 my $temphash = {};
  65 while ( my ($key, $value) = each %$db ) {
  66     $temphash->{$key} = $value;
  67 }
  68
  69 is( $temphash->{key1}, 'value1', "First key copied successfully using tied interface" );
  70 is( $temphash->{key2}, undef, "Second key copied successfully" );
  71 is( $temphash->{key3}, 'value3', "Third key copied successfully" );
  72
  73 $temphash = {};
  74 my $key = $db->first_key();
  75 while ($key) {
  76     $temphash->{$key} = $db->get($key);
  77     $key = $db->next_key($key);
  78 }
  79
  80 is( $temphash->{key1}, 'value1', "First key copied successfully using OO interface" );
  81 is( $temphash->{key2}, undef, "Second key copied successfully" );
  82 is( $temphash->{key3}, 'value3', "Third key copied successfully" );
  83
  84 ##
  85 # delete keys
  86 ##
  87 is( delete $db->{key2}, undef, "delete through tied inteface works" );
  88 is( $db->delete("key1"), 'value1', "delete through OO inteface works" );
  89 is( $db->{key3}, 'value3', "The other key is still there" );
  90 ok( !exists $db->{key1}, "key1 doesn't exist" );
  91 ok( !exists $db->{key2}, "key2 doesn't exist" );
  92
  93 is( scalar keys %$db, 1, "After deleting two keys, 1 remains" );
  94
  95 ##
  96 # delete all keys
  97 ##
  98 ok( $db->clear(), "clear() returns true" );
  99
 100 is( scalar keys %$db, 0, "After clear(), everything is removed" );
 101
 102 ##
 103 # replace key
 104 ##
 105 $db->put("key1", "value1");
 106 is( $db->get("key1"), "value1", "Assignment still works" );
 107
 108 $db->put("key1", "value2");
 109 is( $db->get("key1"), "value2", "... and replacement works" );
 110
 111 $db->put("key1", "value222222222222222222222222");
 112 is( $db->get("key1"), "value222222222222222222222222", "We set a value before closing the file" );
 113
 114 ##
 115 # Make sure DB still works after closing / opening
 116 ##
 117 undef $db;
 118 open $fh, '+<', $filename;
 119 $db = DBM::Deep->new(
 120     file => $filename,
 121     fh => $fh,
 122 );
 123 is( $db->get("key1"), "value222222222222222222222222", "The value we set is still there after closure" );
 124
 125 ##
 126 # Make sure keys are still fetchable after replacing values
 127 # with smaller ones (bug found by John Cardenas, DBM::Deep 0.93)
 128 ##
 129 $db->clear();
 130 $db->put("key1", "long value here");
 131 $db->put("key2", "longer value here");
 132
 133 $db->put("key1", "short value");
 134 $db->put("key2", "shorter v");
 135
 136 my $first_key = $db->first_key();
 137 my $next_key = $db->next_key($first_key);
 138
 139 ok(
 140     (($first_key eq "key1") || ($first_key eq "key2")) &&
 141     (($next_key eq "key1") || ($next_key eq "key2")) &&
 142     ($first_key ne $next_key)
 143     ,"keys() still works if you replace long values with shorter ones"
 144 );
 145
 146 # Test autovivification
 147 $db->{unknown}{bar} = 1;
 148 ok( $db->{unknown}, 'Autovivified hash exists' );
 149 cmp_ok( $db->{unknown}{bar}, '==', 1, 'And the value stored is there' );
 150
 151 # Test failures
 152 throws_ok {
 153     $db->fetch();
 154 } qr/Cannot use an undefined hash key/, "FETCH fails on an undefined key";
 155
 156 throws_ok {
 157     $db->fetch(undef);
 158 } qr/Cannot use an undefined hash key/, "FETCH fails on an undefined key";
 159
 160 throws_ok {
 161     $db->store();
 162 } qr/Cannot use an undefined hash key/, "STORE fails on an undefined key";
 163
 164 throws_ok {
 165     $db->store(undef, undef);
 166 } qr/Cannot use an undefined hash key/, "STORE fails on an undefined key";
 167
 168 throws_ok {
 169     $db->delete();
 170 } qr/Cannot use an undefined hash key/, "DELETE fails on an undefined key";
 171
 172 throws_ok {
 173     $db->delete(undef);
 174 } qr/Cannot use an undefined hash key/, "DELETE fails on an undefined key";
 175
 176 throws_ok {
 177     $db->exists();
 178 } qr/Cannot use an undefined hash key/, "EXISTS fails on an undefined key";
 179
 180 throws_ok {
 181     $db->exists(undef);
 182 } qr/Cannot use an undefined hash key/, "EXISTS fails on an undefined key";
 183