t/02_hash.t

   1 ##
   2 # DBM::Deep Test
   3 ##
   4 use strict;
   5 use Test::More tests => 30;
   6 use Test::Exception;
   7 use File::Temp qw( tempfile tempdir );
   8
   9 use_ok( 'DBM::Deep' );
  10
  11 my $dir = tempdir( CLEANUP => 1 );
  12 my ($fh, $filename) = tempfile( 'tmpXXXX', UNLINK => 1, DIR => $dir );
  13 my $db = DBM::Deep->new( $filename );
  14
  15 ##
  16 # put/get key
  17 ##
  18 $db->{key1} = "value1";
  19 is( $db->get("key1"), "value1", "get() works with hash assignment" );
  20 is( $db->fetch("key1"), "value1", "... fetch() works with hash assignment" );
  21 is( $db->{key1}, "value1", "... and hash-access also works" );
  22
  23 $db->put("key2", undef);
  24 is( $db->get("key2"), undef, "get() works with put()" );
  25 is( $db->fetch("key2"), undef, "... fetch() works with put()" );
  26 is( $db->{key2}, undef, "... and hash-access also works" );
  27
  28 $db->store( "key3", "value3" );
  29 is( $db->get("key3"), "value3", "get() works with store()" );
  30 is( $db->fetch("key3"), "value3", "... fetch() works with put()" );
  31 is( $db->{key3}, 'value3', "... and hash-access also works" );
  32
  33 ok( $db->exists("key1"), "exists() function works" );
  34 ok( exists $db->{key2}, "exists() works against tied hash" );
  35
  36 ##
  37 # count keys
  38 ##
  39 is( scalar keys %$db, 3, "keys() works against tied hash" );
  40
  41 ##
  42 # step through keys
  43 ##
  44 my $temphash = {};
  45 while ( my ($key, $value) = each %$db ) {
  46         $temphash->{$key} = $value;
  47 }
  48
  49 is( $temphash->{key1}, 'value1', "First key copied successfully using tied interface" );
  50 is( $temphash->{key2}, undef, "Second key copied successfully" );
  51 is( $temphash->{key3}, 'value3', "Third key copied successfully" );
  52
  53 $temphash = {};
  54 my $key = $db->first_key();
  55 while ($key) {
  56         $temphash->{$key} = $db->get($key);
  57         $key = $db->next_key($key);
  58 }
  59
  60 is( $temphash->{key1}, 'value1', "First key copied successfully using OO interface" );
  61 is( $temphash->{key2}, undef, "Second key copied successfully" );
  62 is( $temphash->{key3}, 'value3', "Third key copied successfully" );
  63
  64 ##
  65 # delete keys
  66 ##
  67 is( delete $db->{key2}, undef, "delete through tied inteface works" );
  68 is( $db->delete("key1"), 'value1', "delete through OO inteface works" );
  69 is( $db->{key3}, 'value3', "The other key is still there" );
  70
  71 is( scalar keys %$db, 1, "After deleting two keys, 1 remains" );
  72
  73 ##
  74 # delete all keys
  75 ##
  76 ok( $db->clear(), "clear() returns true" );
  77
  78 is( scalar keys %$db, 0, "After clear(), everything is removed" );
  79
  80 ##
  81 # replace key
  82 ##
  83 $db->put("key1", "value1");
  84 is( $db->get("key1"), "value1", "Assignment still works" );
  85
  86 $db->put("key1", "value2");
  87 is( $db->get("key1"), "value2", "... and replacement works" );
  88
  89 $db->put("key1", "value222222222222222222222222");
  90
  91 is( $db->get("key1"), "value222222222222222222222222", "We set a value before closing the file" );
  92
  93 ##
  94 # Make sure DB still works after closing / opening
  95 ##
  96 undef $db;
  97 $db = DBM::Deep->new( $filename );
  98 is( $db->get("key1"), "value222222222222222222222222", "The value we set is still there after closure" );
  99
 100 ##
 101 # Make sure keys are still fetchable after replacing values
 102 # with smaller ones (bug found by John Cardenas, DBM::Deep 0.93)
 103 ##
 104 $db->clear();
 105 $db->put("key1", "long value here");
 106 $db->put("key2", "longer value here");
 107
 108 $db->put("key1", "short value");
 109 $db->put("key2", "shorter v");
 110
 111 my $first_key = $db->first_key();
 112 my $next_key = $db->next_key($first_key);
 113
 114 ok(
 115         (($first_key eq "key1") || ($first_key eq "key2")) &&
 116         (($next_key eq "key1") || ($next_key eq "key2")) &&
 117         ($first_key ne $next_key)
 118     ,"keys() still works if you replace long values with shorter ones"
 119 );