t/003_methods.t

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More tests => 66;
   7 use Test::Exception;
   8
   9 use Scalar::Util qw/reftype/;
  10
  11 BEGIN {
  12     use_ok('Class::MOP');
  13     use_ok('Class::MOP::Class');
  14 }
  15
  16 {   # This package tries to test &has_method
  17     # as exhaustively as possible. More corner
  18     # cases are welcome :)
  19     package Foo;
  20
  21     # import a sub
  22     use Scalar::Util 'blessed';
  23
  24     sub pie;
  25     sub cake ();
  26
  27     use constant FOO_CONSTANT => 'Foo-CONSTANT';
  28
  29     # define a sub in package
  30     sub bar { 'Foo::bar' }
  31     *baz = \&bar;
  32
  33     { # method named with Sub::Name inside the package scope
  34         no strict 'refs';
  35         *{'Foo::floob'} = Sub::Name::subname 'floob' => sub { '!floob!' };
  36     }
  37
  38     # We hateses the "used only once" warnings
  39     { my $temp = \&Foo::baz }
  40
  41     package OinkyBoinky;
  42     our @ISA = "Foo";
  43
  44     sub elk { 'OinkyBoinky::elk' }
  45
  46     package main;
  47
  48     sub Foo::blah { $_[0]->Foo::baz() }
  49
  50     {
  51         no strict 'refs';
  52         *{'Foo::bling'} = sub { '$$Bling$$' };
  53         *{'Foo::bang'} = Sub::Name::subname 'Foo::bang' => sub { '!BANG!' };
  54         *{'Foo::boom'} = Sub::Name::subname 'boom' => sub { '!BOOM!' };
  55
  56         eval "package Foo; sub evaled_foo { 'Foo::evaled_foo' }";
  57     }
  58 }
  59
  60 my $Foo = Class::MOP::Class->initialize('Foo');
  61
  62 ok(!$Foo->has_method('pie'), '... got the method stub pie');
  63 ok(!$Foo->has_method('cake'), '... got the constant method stub cake');
  64
  65 my $foo = sub { 'Foo::foo' };
  66
  67 ok(!UNIVERSAL::isa($foo, 'Class::MOP::Method'), '... our method is not yet blessed');
  68
  69 lives_ok {
  70     $Foo->add_method('foo' => $foo);
  71 } '... we added the method successfully';
  72
  73 my $foo_method = $Foo->get_method('foo');
  74
  75 isa_ok($foo_method, 'Class::MOP::Method');
  76
  77 is($foo_method->name, 'foo', '... got the right name for the method');
  78 is($foo_method->package_name, 'Foo', '... got the right package name for the method');
  79
  80 ok($Foo->has_method('foo'), '... Foo->has_method(foo) (defined with Sub::Name)');
  81
  82 is($Foo->get_method('foo')->body, $foo, '... Foo->get_method(foo) == \&foo');
  83 is(Foo->foo(), 'Foo::foo', '... Foo->foo() returns "Foo::foo"');
  84
  85 # now check all our other items ...
  86
  87 ok($Foo->has_method('FOO_CONSTANT'), '... Foo->has_method(FOO_CONSTANT) (defined w/ use constant)');
  88 ok($Foo->has_method('bar'), '... Foo->has_method(bar) (defined in Foo)');
  89 ok($Foo->has_method('baz'), '... Foo->has_method(baz) (typeglob aliased within Foo)');
  90 ok($Foo->has_method('floob'), '... Foo->has_method(floob) (defined in Foo:: using symbol tables and Sub::Name w/out package name)');
  91 ok($Foo->has_method('blah'), '... Foo->has_method(blah) (defined in main:: using fully qualified package name)');
  92 ok($Foo->has_method('bling'), '... Foo->has_method(bling) (defined in main:: using symbol tables (no Sub::Name))');
  93 ok($Foo->has_method('bang'), '... Foo->has_method(bang) (defined in main:: using symbol tables and Sub::Name)');
  94 ok($Foo->has_method('evaled_foo'), '... Foo->has_method(evaled_foo) (evaled in main::)');
  95
  96 my $OinkyBoinky = Class::MOP::Class->initialize('OinkyBoinky');
  97
  98 ok($OinkyBoinky->has_method('elk'), "the method 'elk' is defined in OinkyBoinky");
  99
 100 ok(!$OinkyBoinky->has_method('bar'), "the method 'bar' is not defined in OinkyBoinky");
 101
 102 ok(my $bar = $OinkyBoinky->find_method_by_name('bar'), "but if you look in the inheritence chain then 'bar' does exist");
 103
 104 is( reftype($bar->body), "CODE", "the returned value is a code ref" );
 105
 106
 107 # calling get_method blessed them all
 108 for my $method_name (qw/FOO_CONSTANT
 109                         bar
 110                         baz
 111                         floob
 112                         blah
 113                         bling
 114                         bang
 115                         evaled_foo/) {
 116     isa_ok($Foo->get_method($method_name), 'Class::MOP::Method');
 117     {
 118         no strict 'refs';
 119         is($Foo->get_method($method_name)->body, \&{'Foo::' . $method_name}, '... body matches CODE ref in package');
 120     }
 121 }
 122
 123 {
 124     package Foo::Aliasing;
 125     use metaclass;
 126     sub alias_me { '...' }
 127 }
 128
 129 $Foo->alias_method('alias_me' => Foo::Aliasing->meta->get_method('alias_me'));
 130
 131 ok(!$Foo->has_method('alias_me'), '... !Foo->has_method(alias_me) (aliased from Foo::Aliasing)');
 132 ok(defined &Foo::alias_me, '... Foo does have a symbol table slow for alias_me though');
 133
 134 ok(!$Foo->has_method('blessed'), '... !Foo->has_method(blessed) (imported into Foo)');
 135 ok(!$Foo->has_method('boom'), '... !Foo->has_method(boom) (defined in main:: using symbol tables and Sub::Name w/out package name)');
 136
 137 ok(!$Foo->has_method('not_a_real_method'), '... !Foo->has_method(not_a_real_method) (does not exist)');
 138 is($Foo->get_method('not_a_real_method'), undef, '... Foo->get_method(not_a_real_method) == undef');
 139
 140 is_deeply(
 141     [ sort $Foo->get_method_list ],
 142     [ qw(FOO_CONSTANT bang bar baz blah bling evaled_foo floob foo) ],
 143     '... got the right method list for Foo');
 144
 145 is_deeply(
 146     [ sort { $a->{name} cmp $b->{name} } $Foo->compute_all_applicable_methods() ],
 147     [
 148         map {
 149             {
 150             name  => $_,
 151             class => 'Foo',
 152             code  => $Foo->get_method($_)
 153             }
 154         } qw(
 155             FOO_CONSTANT
 156             bang
 157             bar
 158             baz
 159             blah
 160             bling
 161             evaled_foo
 162             floob
 163             foo
 164         )
 165     ],
 166     '... got the right list of applicable methods for Foo');
 167
 168 is($Foo->remove_method('foo')->body, $foo, '... removed the foo method');
 169 ok(!$Foo->has_method('foo'), '... !Foo->has_method(foo) we just removed it');
 170 dies_ok { Foo->foo } '... cannot call Foo->foo because it is not there';
 171
 172 is_deeply(
 173     [ sort $Foo->get_method_list ],
 174     [ qw(FOO_CONSTANT bang bar baz blah bling evaled_foo floob) ],
 175     '... got the right method list for Foo');
 176
 177 ok($Foo->remove_method('FOO_CONSTANT'), '... removed the FOO_CONSTANT method');
 178 ok(!$Foo->has_method('FOO_CONSTANT'), '... !Foo->has_method(FOO_CONSTANT) we just removed it');
 179 dies_ok { Foo->FOO_CONSTANT } '... cannot call Foo->FOO_CONSTANT because it is not there';
 180
 181 is_deeply(
 182     [ sort $Foo->get_method_list ],
 183     [ qw(bang bar baz blah bling evaled_foo floob) ],
 184     '... got the right method list for Foo');
 185
 186 # ... test our class creator
 187
 188 my $Bar = Class::MOP::Class->create(
 189             'Bar' => (
 190                 superclasses => [ 'Foo' ],
 191                 methods => {
 192                     foo => sub { 'Bar::foo' },
 193                     bar => sub { 'Bar::bar' },
 194                 }
 195             ));
 196 isa_ok($Bar, 'Class::MOP::Class');
 197
 198 ok($Bar->has_method('foo'), '... Bar->has_method(foo)');
 199 ok($Bar->has_method('bar'), '... Bar->has_method(bar)');
 200
 201 is(Bar->foo, 'Bar::foo', '... Bar->foo == Bar::foo');
 202 is(Bar->bar, 'Bar::bar', '... Bar->bar == Bar::bar');
 203
 204 lives_ok {
 205     $Bar->add_method('foo' => sub { 'Bar::foo v2' });
 206 } '... overwriting a method is fine';
 207
 208 ok($Bar->has_method('foo'), '... Bar-> (still) has_method(foo)');
 209 is(Bar->foo, 'Bar::foo v2', '... Bar->foo == "Bar::foo v2"');
 210
 211 is_deeply(
 212     [ sort $Bar->get_method_list ],
 213     [ qw(bar foo meta) ],
 214     '... got the right method list for Bar');
 215
 216 is_deeply(
 217     [ sort { $a->{name} cmp $b->{name} } $Bar->compute_all_applicable_methods() ],
 218     [
 219         {
 220             name  => 'bang',
 221             class => 'Foo',
 222             code  => $Foo->get_method('bang')
 223         },
 224         {
 225             name  => 'bar',
 226             class => 'Bar',
 227             code  => $Bar->get_method('bar')
 228         },
 229         (map {
 230             {
 231                 name  => $_,
 232                 class => 'Foo',
 233                 code  => $Foo->get_method($_)
 234             }
 235         } qw(
 236             baz
 237             blah
 238             bling
 239             evaled_foo
 240             floob
 241         )),
 242         {
 243             name  => 'foo',
 244             class => 'Bar',
 245             code  => $Bar->get_method('foo')
 246         },
 247         {
 248             name  => 'meta',
 249             class => 'Bar',
 250             code  => $Bar->get_method('meta')
 251         }
 252     ],
 253     '... got the right list of applicable methods for Bar');
 254
 255