t/003_methods.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6
   7 use Scalar::Util qw/reftype/;
   8
   9 BEGIN {
  10     if ( eval 'use Sub::Name (); 1;' ) {
  11         plan tests => 66;
  12     }
  13     else {
  14         plan skip_all => 'These tests require Sub::Name';
  15     }
  16 }
  17
  18 use Class::MOP;
  19 use Class::MOP::Class;
  20 use Class::MOP::Method;
  21
  22 {   # This package tries to test &has_method
  23     # as exhaustively as possible. More corner
  24     # cases are welcome :)
  25     package Foo;
  26
  27     # import a sub
  28     use Scalar::Util 'blessed';
  29
  30     sub pie;
  31     sub cake ();
  32
  33     use constant FOO_CONSTANT => 'Foo-CONSTANT';
  34
  35     # define a sub in package
  36     sub bar { 'Foo::bar' }
  37     *baz = \&bar;
  38
  39     # create something with the typeglob inside the package
  40     *baaz = sub { 'Foo::baaz' };
  41
  42     { # method named with Sub::Name inside the package scope
  43         no strict 'refs';
  44         *{'Foo::floob'} = Sub::Name::subname 'floob' => sub { '!floob!' };
  45     }
  46
  47     # We hateses the "used only once" warnings
  48     {
  49         my $temp1 = \&Foo::baz;
  50         my $temp2 = \&Foo::baaz;
  51     }
  52
  53     package OinkyBoinky;
  54     our @ISA = "Foo";
  55
  56     sub elk { 'OinkyBoinky::elk' }
  57
  58     package main;
  59
  60     sub Foo::blah { $_[0]->Foo::baz() }
  61
  62     {
  63         no strict 'refs';
  64         *{'Foo::bling'} = sub { '$$Bling$$' };
  65         *{'Foo::bang'} = Sub::Name::subname 'Foo::bang' => sub { '!BANG!' };
  66         *{'Foo::boom'} = Sub::Name::subname 'boom' => sub { '!BOOM!' };
  67
  68         eval "package Foo; sub evaled_foo { 'Foo::evaled_foo' }";
  69     }
  70 }
  71
  72 my $Foo = Class::MOP::Class->initialize('Foo');
  73
  74 ok($Foo->has_method('pie'), '... got the method stub pie');
  75 ok($Foo->has_method('cake'), '... got the constant method stub cake');
  76
  77 my $foo = sub { 'Foo::foo' };
  78
  79 ok(!UNIVERSAL::isa($foo, 'Class::MOP::Method'), '... our method is not yet blessed');
  80
  81 lives_ok {
  82     $Foo->add_method('foo' => $foo);
  83 } '... we added the method successfully';
  84
  85 my $foo_method = $Foo->get_method('foo');
  86
  87 isa_ok($foo_method, 'Class::MOP::Method');
  88
  89 is($foo_method->name, 'foo', '... got the right name for the method');
  90 is($foo_method->package_name, 'Foo', '... got the right package name for the method');
  91
  92 ok($Foo->has_method('foo'), '... Foo->has_method(foo) (defined with Sub::Name)');
  93
  94 is($Foo->get_method('foo')->body, $foo, '... Foo->get_method(foo) == \&foo');
  95 is($Foo->get_method('foo')->execute, 'Foo::foo', '... _method_foo->execute returns "Foo::foo"');
  96 is(Foo->foo(), 'Foo::foo', '... Foo->foo() returns "Foo::foo"');
  97
  98 # now check all our other items ...
  99
 100 ok($Foo->has_method('FOO_CONSTANT'), '... not Foo->has_method(FOO_CONSTANT) (defined w/ use constant)');
 101 ok(!$Foo->has_method('bling'), '... not Foo->has_method(bling) (defined in main:: using symbol tables (no Sub::Name))');
 102
 103 ok($Foo->has_method('bar'), '... Foo->has_method(bar) (defined in Foo)');
 104 ok($Foo->has_method('baz'), '... Foo->has_method(baz) (typeglob aliased within Foo)');
 105 ok($Foo->has_method('baaz'), '... Foo->has_method(baaz) (typeglob aliased within Foo)');
 106 ok($Foo->has_method('floob'), '... Foo->has_method(floob) (defined in Foo:: using symbol tables and Sub::Name w/out package name)');
 107 ok($Foo->has_method('blah'), '... Foo->has_method(blah) (defined in main:: using fully qualified package name)');
 108 ok($Foo->has_method('bang'), '... Foo->has_method(bang) (defined in main:: using symbol tables and Sub::Name)');
 109 ok($Foo->has_method('evaled_foo'), '... Foo->has_method(evaled_foo) (evaled in main::)');
 110
 111 my $OinkyBoinky = Class::MOP::Class->initialize('OinkyBoinky');
 112
 113 ok($OinkyBoinky->has_method('elk'), "the method 'elk' is defined in OinkyBoinky");
 114
 115 ok(!$OinkyBoinky->has_method('bar'), "the method 'bar' is not defined in OinkyBoinky");
 116
 117 ok(my $bar = $OinkyBoinky->find_method_by_name('bar'), "but if you look in the inheritence chain then 'bar' does exist");
 118
 119 is( reftype($bar->body), "CODE", "the returned value is a code ref" );
 120
 121
 122 # calling get_method blessed them all
 123 for my $method_name (qw/baaz
 124                         bar
 125                         baz
 126                         floob
 127                         blah
 128                         bang
 129                         evaled_foo
 130                         FOO_CONSTANT/) {
 131     isa_ok($Foo->get_method($method_name), 'Class::MOP::Method');
 132     {
 133         no strict 'refs';
 134         is($Foo->get_method($method_name)->body, \&{'Foo::' . $method_name}, '... body matches CODE ref in package for ' . $method_name);
 135     }
 136 }
 137
 138 for my $method_name (qw/
 139                     bling
 140                     /) {
 141     is(ref($Foo->get_package_symbol('&' . $method_name)), 'CODE', '... got the __ANON__ methods');
 142     {
 143         no strict 'refs';
 144         is($Foo->get_package_symbol('&' . $method_name), \&{'Foo::' . $method_name}, '... symbol matches CODE ref in package for ' . $method_name);
 145     }
 146 }
 147
 148 {
 149     package Foo::Aliasing;
 150     use metaclass;
 151     sub alias_me { '...' }
 152 }
 153
 154 $Foo->alias_method('alias_me' => Foo::Aliasing->meta->get_method('alias_me'));
 155
 156 ok($Foo->has_method('alias_me'), '... Foo->has_method(alias_me) (aliased from Foo::Aliasing)');
 157 ok(defined &Foo::alias_me, '... Foo does have a symbol table slow for alias_me though');
 158
 159 ok(!$Foo->has_method('blessed'), '... !Foo->has_method(blessed) (imported into Foo)');
 160 ok(!$Foo->has_method('boom'), '... !Foo->has_method(boom) (defined in main:: using symbol tables and Sub::Name w/out package name)');
 161
 162 ok(!$Foo->has_method('not_a_real_method'), '... !Foo->has_method(not_a_real_method) (does not exist)');
 163 is($Foo->get_method('not_a_real_method'), undef, '... Foo->get_method(not_a_real_method) == undef');
 164
 165 is_deeply(
 166     [ sort $Foo->get_method_list ],
 167     [ qw(FOO_CONSTANT alias_me baaz bang bar baz blah cake evaled_foo floob foo pie) ],
 168     '... got the right method list for Foo');
 169
 170 is_deeply(
 171     [ sort { $a->name cmp $b->name } $Foo->get_all_methods() ],
 172     [
 173         map { $Foo->get_method($_) } qw(
 174             FOO_CONSTANT
 175             alias_me
 176             baaz
 177             bang
 178             bar
 179             baz
 180             blah
 181             cake
 182             evaled_foo
 183             floob
 184             foo
 185             pie
 186         )
 187     ],
 188     '... got the right list of applicable methods for Foo');
 189
 190 is($Foo->remove_method('foo')->body, $foo, '... removed the foo method');
 191 ok(!$Foo->has_method('foo'), '... !Foo->has_method(foo) we just removed it');
 192 dies_ok { Foo->foo } '... cannot call Foo->foo because it is not there';
 193
 194 is_deeply(
 195     [ sort $Foo->get_method_list ],
 196     [ qw(FOO_CONSTANT alias_me baaz bang bar baz blah cake evaled_foo floob pie) ],
 197     '... got the right method list for Foo');
 198
 199
 200 # ... test our class creator
 201
 202 my $Bar = Class::MOP::Class->create(
 203     package      => 'Bar',
 204     superclasses => [ 'Foo' ],
 205     methods      => {
 206         foo => sub { 'Bar::foo' },
 207         bar => sub { 'Bar::bar' },
 208     }
 209 );
 210 isa_ok($Bar, 'Class::MOP::Class');
 211
 212 ok($Bar->has_method('foo'), '... Bar->has_method(foo)');
 213 ok($Bar->has_method('bar'), '... Bar->has_method(bar)');
 214
 215 is(Bar->foo, 'Bar::foo', '... Bar->foo == Bar::foo');
 216 is(Bar->bar, 'Bar::bar', '... Bar->bar == Bar::bar');
 217
 218 lives_ok {
 219     $Bar->add_method('foo' => sub { 'Bar::foo v2' });
 220 } '... overwriting a method is fine';
 221
 222 ok($Bar->has_method('foo'), '... Bar-> (still) has_method(foo)');
 223 is(Bar->foo, 'Bar::foo v2', '... Bar->foo == "Bar::foo v2"');
 224
 225 is_deeply(
 226     [ sort $Bar->get_method_list ],
 227     [ qw(bar foo meta) ],
 228     '... got the right method list for Bar');
 229
 230 is_deeply(
 231     [ sort { $a->name cmp $b->name } $Bar->get_all_methods() ],
 232     [
 233         $Foo->get_method('FOO_CONSTANT'),
 234         $Foo->get_method('alias_me'),
 235         $Foo->get_method('baaz'),
 236         $Foo->get_method('bang'),
 237         $Bar->get_method('bar'),
 238         (map { $Foo->get_method($_) } qw(
 239             baz
 240             blah
 241             cake
 242             evaled_foo
 243             floob
 244         )),
 245         $Bar->get_method('foo'),
 246         $Bar->get_method('meta'),
 247         $Foo->get_method('pie'),
 248     ],
 249     '... got the right list of applicable methods for Bar');
 250
 251 my $method = Class::MOP::Method->wrap(
 252     name         => 'objecty',
 253     package_name => 'Whatever',
 254     body         => sub {q{I am an object, and I feel an object's pain}},
 255 );
 256
 257 Bar->meta->add_method( $method->name, $method );
 258
 259 my $new_method = Bar->meta->get_method('objecty');
 260
 261 isnt( $method, $new_method, 'add_method clones method objects as they are added' );
 262 is( $new_method->original_method, $method, '... the cloned method has the correct original method' );