script/dbicadmin

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5
   6 BEGIN {
   7   use DBIx::Class;
   8   die (  'The following modules are required for the dbicadmin utility: '
   9        . DBIx::Class::Optional::Dependencies->req_missing_for ('admin_script')
  10        . "\n"
  11   ) unless DBIx::Class::Optional::Dependencies->req_ok_for ('admin_script');
  12 }
  13
  14 use DBIx::Class::Admin::Descriptive;
  15 #use Getopt::Long::Descriptive;
  16 use DBIx::Class::Admin;
  17
  18 my $short_description = "utility for administrating DBIx::Class schemata";
  19 my $synopsis_text =q|
  20   deploy a schema to a database
  21   %c --schema=MyApp::Schema \
  22     --connect='["dbi:SQLite:my.db", "", ""]' \
  23     --deploy
  24
  25   update an existing record
  26   %c --schema=MyApp::Schema --class=Employee \
  27     --connect='["dbi:SQLite:my.db", "", ""]' \
  28     --op=update --set='{ "name": "New_Employee" }'
  29 |;
  30
  31 my ($opts, $usage) = describe_options(
  32     "%c: %o",
  33   (
  34     ['Actions'],
  35     ["action" => hidden => { one_of => [
  36       ['create' => 'Create version diffs needs preversion',],
  37       ['upgrade' => 'Upgrade the database to the current schema '],
  38       ['install' => 'Install the schema version tables to an existing database',],
  39       ['deploy' => 'Deploy the schema to the database',],
  40       ['select'   => 'Select data from the schema', ],
  41       ['insert'   => 'Insert data into the schema', ],
  42       ['update'   => 'Update data in the schema', ],
  43       ['delete'   => 'Delete data from the schema',],
  44       ['op:s' => 'compatiblity option all of the above can be suppied as --op=<action>'],
  45       ['help' => 'display this help', { implies => { schema_class => '__dummy__' } } ],
  46       ['selfinject-pod' => 'hidden', { implies => { schema_class => '__dummy__' } } ],
  47     ], required=> 1 }],
  48     ['Arguments'],
  49     ['schema-class:s' => 'The class of the schema to load', { required => 1 } ],
  50     ['resultset|resultset-class|class:s' => 'The resultset to operate on for data manipulation' ],
  51     ['config-stanza:s' => 'Where in the config to find the connection_info, supply in form MyApp::Model::DB',],
  52     ['config:s' => 'Supply the config file for parsing by Config::Any', { depends => 'config_stanza'} ],
  53     ['connect-info:s%' => 'Supply the connect info as additonal options ie -I dsn=<dsn> user=<user> password=<pass> '],
  54     ['connect:s' => 'Supply the connect info as a json string' ],
  55     ['sql-dir:s' => 'The directory where sql diffs will be created'],
  56     ['sql-type:s' => 'The RDBMs flavour you wish to use'],
  57     ['version:i' => 'Supply a version install'],
  58     ['preversion:s' => 'The previous version to diff against',],
  59     ['set:s' => 'JSON data used to perform data operations' ],
  60     ['attrs:s' => 'JSON string to be used for the second argument for search'],
  61     ['where:s' => 'JSON string to be used for the where clause of search'],
  62     ['force' => 'Be forceful with some operations'],
  63     ['trace' => 'Turn on DBIx::Class trace output'],
  64     ['quiet' => 'Be less verbose'],
  65     ['I:s@' => 'Same as perl\'s -I, prepended to current @INC'],
  66   )
  67 );
  68
  69 die "please only use one of --config or --connect-info\n" if ($opts->{config} and $opts->{connect_info});
  70
  71 if($opts->{selfinject_pod}) {
  72
  73     die "This is an internal method, do not call!!!\n"
  74       unless $ENV{MAKELEVEL};
  75
  76     $usage->synopsis($synopsis_text);
  77     $usage->short_description($short_description);
  78     exec (
  79       $^X,
  80       qw/-p -0777 -i -e/,
  81       (
  82         's/^# auto_pod_begin.*^# auto_pod_end/'
  83       . quotemeta($usage->pod)
  84       . '/ms'
  85       ),
  86       __FILE__
  87     );
  88 }
  89
  90 # FIXME - lowercasing will eventually go away when Getopt::Long::Descriptive is fixed
  91 if($opts->{i}) {
  92     $opts->{include_dirs} = delete $opts->{i};
  93 }
  94
  95 if($opts->{help}) {
  96     $usage->die();
  97 }
  98
  99 # option compatability mangle
 100 if($opts->{connect}) {
 101   $opts->{connect_info} = delete $opts->{connect};
 102 }
 103 my $admin = DBIx::Class::Admin->new( %$opts );
 104
 105 my $action = $opts->{action};
 106
 107 $action = $opts->{op} if ($action eq 'op');
 108
 109 print "Performing action $action...\n";
 110
 111 my $res = $admin->$action();
 112 if ($action eq 'select') {
 113
 114   my $format = $opts->{format} || 'tsv';
 115   die('Invalid format') if ($format!~/^tsv|csv$/s);
 116
 117   require Text::CSV;
 118
 119   my $csv = Text::CSV->new({
 120     sep_char => ( $format eq 'tsv' ? "\t" : ',' ),
 121   });
 122
 123   foreach my $row (@$res) {
 124     $csv->combine( @$row );
 125     print $csv->string()."\n";
 126   }
 127 }
 128
 129
 130 __END__
 131
 132 # auto_pod_begin
 133 #
 134 # This will be replaced by the actual pod when selfinject-pod is invoked
 135 #
 136 # auto_pod_end
 137
 138 # vim: et ft=perl