pod/pod2text.PL

   1 #!/usr/local/bin/perl
   2
   3 use Config;
   4 use File::Basename qw(&basename &dirname);
   5 use Cwd;
   6
   7 # List explicitly here the variables you want Configure to
   8 # generate.  Metaconfig only looks for shell variables, so you
   9 # have to mention them as if they were shell variables, not
  10 # %Config entries.  Thus you write
  11 #  $startperl
  12 # to ensure Configure will look for $Config{startperl}.
  13
  14 # This forces PL files to create target in same directory as PL file.
  15 # This is so that make depend always knows where to find PL derivatives.
  16 $origdir = cwd;
  17 chdir dirname($0);
  18 $file = basename($0, '.PL');
  19 $file .= '.com' if $^O eq 'VMS';
  20
  21 open OUT,">$file" or die "Can't create $file: $!";
  22
  23 print "Extracting $file (with variable substitutions)\n";
  24
  25 # In this section, perl variables will be expanded during extraction.
  26 # You can use $Config{...} to use Configure variables.
  27
  28 print OUT <<"!GROK!THIS!";
  29 $Config{startperl}
  30     eval 'exec $Config{perlpath} -S \$0 \${1+"\$@"}'
  31         if \$running_under_some_shell;
  32 !GROK!THIS!
  33
  34 # In the following, perl variables are not expanded during extraction.
  35
  36 print OUT <<'!NO!SUBS!';
  37
  38 # pod2text -- Convert POD data to formatted ASCII text.
  39 #
  40 # Copyright 1999, 2000, 2001, 2004, 2006, 2008 Russ Allbery <rra@stanford.edu>
  41 #
  42 # This program is free software; you may redistribute it and/or modify it
  43 # under the same terms as Perl itself.
  44 #
  45 # The driver script for Pod::Text, Pod::Text::Termcap, and Pod::Text::Color,
  46 # invoked by perldoc -t among other things.
  47
  48 require 5.004;
  49
  50 use Getopt::Long qw(GetOptions);
  51 use Pod::Text ();
  52 use Pod::Usage qw(pod2usage);
  53
  54 use strict;
  55
  56 # Silence -w warnings.
  57 use vars qw($running_under_some_shell);
  58
  59 # Take an initial pass through our options, looking for one of the form
  60 # -<number>.  We turn that into -w <number> for compatibility with the
  61 # original pod2text script.
  62 for (my $i = 0; $i < @ARGV; $i++) {
  63     last if $ARGV[$i] =~ /^--$/;
  64     if ($ARGV[$i] =~ /^-(\d+)$/) {
  65         splice (@ARGV, $i++, 1, '-w', $1);
  66     }
  67 }
  68
  69 # Insert -- into @ARGV before any single dash argument to hide it from
  70 # Getopt::Long; we want to interpret it as meaning stdin (which Pod::Simple
  71 # does correctly).
  72 my $stdin;
  73 @ARGV = map { $_ eq '-' && !$stdin++ ? ('--', $_) : $_ } @ARGV;
  74
  75 # Parse our options.  Use the same names as Pod::Text for simplicity, and
  76 # default to sentence boundaries turned off for compatibility.
  77 my %options;
  78 $options{sentence} = 0;
  79 Getopt::Long::config ('bundling');
  80 GetOptions (\%options, 'alt|a', 'code', 'color|c', 'help|h', 'indent|i=i',
  81             'loose|l', 'margin|left-margin|m=i', 'overstrike|o',
  82             'quotes|q=s', 'sentence|s', 'stderr', 'termcap|t', 'width|w=i')
  83     or exit 1;
  84 pod2usage (1) if $options{help};
  85
  86 # Figure out what formatter we're going to use.  -c overrides -t.
  87 my $formatter = 'Pod::Text';
  88 if ($options{color}) {
  89     $formatter = 'Pod::Text::Color';
  90     eval { require Term::ANSIColor };
  91     if ($@) { die "-c (--color) requires Term::ANSIColor be installed\n" }
  92     require Pod::Text::Color;
  93 } elsif ($options{termcap}) {
  94     $formatter = 'Pod::Text::Termcap';
  95     require Pod::Text::Termcap;
  96 } elsif ($options{overstrike}) {
  97     $formatter = 'Pod::Text::Overstrike';
  98     require Pod::Text::Overstrike;
  99 }
 100 delete @options{'color', 'termcap', 'overstrike'};
 101
 102 # Initialize and run the formatter.
 103 my $parser = $formatter->new (%options);
 104 do {
 105     my ($input, $output) = splice (@ARGV, 0, 2);
 106     $parser->parse_from_file ($input, $output);
 107 } while (@ARGV);
 108
 109 __END__
 110
 111 =head1 NAME
 112
 113 pod2text - Convert POD data to formatted ASCII text
 114
 115 =for stopwords
 116 -aclost --alt --stderr Allbery
 117
 118 =head1 SYNOPSIS
 119
 120 pod2text [B<-aclost>] [B<--code>] [B<-i> I<indent>] S<[B<-q> I<quotes>]>
 121     [B<--stderr>] S<[B<-w> I<width>]> [I<input> [I<output> ...]]
 122
 123 pod2text B<-h>
 124
 125 =head1 DESCRIPTION
 126
 127 B<pod2text> is a front-end for Pod::Text and its subclasses.  It uses them
 128 to generate formatted ASCII text from POD source.  It can optionally use
 129 either termcap sequences or ANSI color escape sequences to format the text.
 130
 131 I<input> is the file to read for POD source (the POD can be embedded in
 132 code).  If I<input> isn't given, it defaults to C<STDIN>.  I<output>, if
 133 given, is the file to which to write the formatted output.  If I<output>
 134 isn't given, the formatted output is written to C<STDOUT>.  Several POD
 135 files can be processed in the same B<pod2text> invocation (saving module
 136 load and compile times) by providing multiple pairs of I<input> and
 137 I<output> files on the command line.
 138
 139 =head1 OPTIONS
 140
 141 =over 4
 142
 143 =item B<-a>, B<--alt>
 144
 145 Use an alternate output format that, among other things, uses a different
 146 heading style and marks C<=item> entries with a colon in the left margin.
 147
 148 =item B<--code>
 149
 150 Include any non-POD text from the input file in the output as well.  Useful
 151 for viewing code documented with POD blocks with the POD rendered and the
 152 code left intact.
 153
 154 =item B<-c>, B<--color>
 155
 156 Format the output with ANSI color escape sequences.  Using this option
 157 requires that Term::ANSIColor be installed on your system.
 158
 159 =item B<-i> I<indent>, B<--indent=>I<indent>
 160
 161 Set the number of spaces to indent regular text, and the default indentation
 162 for C<=over> blocks.  Defaults to 4 spaces if this option isn't given.
 163
 164 =item B<-h>, B<--help>
 165
 166 Print out usage information and exit.
 167
 168 =item B<-l>, B<--loose>
 169
 170 Print a blank line after a C<=head1> heading.  Normally, no blank line is
 171 printed after C<=head1>, although one is still printed after C<=head2>,
 172 because this is the expected formatting for manual pages; if you're
 173 formatting arbitrary text documents, using this option is recommended.
 174
 175 =item B<-m> I<width>, B<--left-margin>=I<width>, B<--margin>=I<width>
 176
 177 The width of the left margin in spaces.  Defaults to 0.  This is the margin
 178 for all text, including headings, not the amount by which regular text is
 179 indented; for the latter, see B<-i> option.
 180
 181 =item B<-o>, B<--overstrike>
 182
 183 Format the output with overstrike printing.  Bold text is rendered as
 184 character, backspace, character.  Italics and file names are rendered as
 185 underscore, backspace, character.  Many pagers, such as B<less>, know how
 186 to convert this to bold or underlined text.
 187
 188 =item B<-q> I<quotes>, B<--quotes>=I<quotes>
 189
 190 Sets the quote marks used to surround CE<lt>> text to I<quotes>.  If
 191 I<quotes> is a single character, it is used as both the left and right
 192 quote; if I<quotes> is two characters, the first character is used as the
 193 left quote and the second as the right quoted; and if I<quotes> is four
 194 characters, the first two are used as the left quote and the second two as
 195 the right quote.
 196
 197 I<quotes> may also be set to the special value C<none>, in which case no
 198 quote marks are added around CE<lt>> text.
 199
 200 =item B<-s>, B<--sentence>
 201
 202 Assume each sentence ends with two spaces and try to preserve that spacing.
 203 Without this option, all consecutive whitespace in non-verbatim paragraphs
 204 is compressed into a single space.
 205
 206 =item B<--stderr>
 207
 208 By default, B<pod2text> puts any errors detected in the POD input in a POD
 209 ERRORS section in the output manual page.  If B<--stderr> is given, errors
 210 are sent to standard error instead and the POD ERRORS section is
 211 suppressed.
 212
 213 =item B<-t>, B<--termcap>
 214
 215 Try to determine the width of the screen and the bold and underline
 216 sequences for the terminal from termcap, and use that information in
 217 formatting the output.  Output will be wrapped at two columns less than the
 218 width of your terminal device.  Using this option requires that your system
 219 have a termcap file somewhere where Term::Cap can find it and requires that
 220 your system support termios.  With this option, the output of B<pod2text>
 221 will contain terminal control sequences for your current terminal type.
 222
 223 =item B<-w>, B<--width=>I<width>, B<->I<width>
 224
 225 The column at which to wrap text on the right-hand side.  Defaults to 76,
 226 unless B<-t> is given, in which case it's two columns less than the width of
 227 your terminal device.
 228
 229 =back
 230
 231 =head1 DIAGNOSTICS
 232
 233 If B<pod2text> fails with errors, see L<Pod::Text> and L<Pod::Simple> for
 234 information about what those errors might mean.  Internally, it can also
 235 produce the following diagnostics:
 236
 237 =over 4
 238
 239 =item -c (--color) requires Term::ANSIColor be installed
 240
 241 (F) B<-c> or B<--color> were given, but Term::ANSIColor could not be
 242 loaded.
 243
 244 =item Unknown option: %s
 245
 246 (F) An unknown command line option was given.
 247
 248 =back
 249
 250 In addition, other L<Getopt::Long> error messages may result from invalid
 251 command-line options.
 252
 253 =head1 ENVIRONMENT
 254
 255 =over 4
 256
 257 =item COLUMNS
 258
 259 If B<-t> is given, B<pod2text> will take the current width of your screen
 260 from this environment variable, if available.  It overrides terminal width
 261 information in TERMCAP.
 262
 263 =item TERMCAP
 264
 265 If B<-t> is given, B<pod2text> will use the contents of this environment
 266 variable if available to determine the correct formatting sequences for your
 267 current terminal device.
 268
 269 =back
 270
 271 =head1 SEE ALSO
 272
 273 L<Pod::Text>, L<Pod::Text::Color>, L<Pod::Text::Overstrike>,
 274 L<Pod::Text::Termcap>, L<Pod::Simple>
 275
 276 The current version of this script is always available from its web site at
 277 L<http://www.eyrie.org/~eagle/software/podlators/>.  It is also part of the
 278 Perl core distribution as of 5.6.0.
 279
 280 =head1 AUTHOR
 281
 282 Russ Allbery <rra@stanford.edu>.
 283
 284 =head1 COPYRIGHT AND LICENSE
 285
 286 Copyright 1999, 2000, 2001, 2004, 2006, 2008 Russ Allbery
 287 <rra@stanford.edu>.
 288
 289 This program is free software; you may redistribute it and/or modify it
 290 under the same terms as Perl itself.
 291
 292 =cut
 293 !NO!SUBS!
 294
 295 close OUT or die "Can't close $file: $!";
 296 chmod 0755, $file or die "Can't reset permissions for $file: $!\n";
 297 exec("$Config{'eunicefix'} $file") if $Config{'eunicefix'} ne ':';
 298 chdir $origdir;