pod/perlvar.pod

   1 =head1 NAME
   2
   3 perlvar - Perl predefined variables
   4
   5 =head1 DESCRIPTION
   6
   7 =head2 Predefined Names
   8
   9 The following names have special meaning to Perl.  Most of the
  10 punctuational names have reasonable mnemonics, or analogues in one of
  11 the shells.  Nevertheless, if you wish to use the long variable names,
  12 you just need to say
  13
  14     use English;
  15
  16 at the top of your program.  This will alias all the short names to the
  17 long names in the current package.  Some of them even have medium names,
  18 generally borrowed from B<awk>.
  19
  20 To go a step further, those variables that depend on the currently
  21 selected filehandle may instead be set by calling an object method on
  22 the FileHandle object.  (Summary lines below for this contain the word
  23 HANDLE.)  First you must say
  24
  25     use FileHandle;
  26
  27 after which you may use either
  28
  29     method HANDLE EXPR
  30
  31 or
  32
  33     HANDLE->method(EXPR)
  34
  35 Each of the methods returns the old value of the FileHandle attribute.
  36 The methods each take an optional EXPR, which if supplied specifies the
  37 new value for the FileHandle attribute in question.  If not supplied,
  38 most of the methods do nothing to the current value, except for
  39 autoflush(), which will assume a 1 for you, just to be different.
  40
  41 A few of these variables are considered "read-only".  This means that if
  42 you try to assign to this variable, either directly or indirectly through
  43 a reference, you'll raise a run-time exception.
  44
  45 =over 8
  46
  47 =item $ARG
  48
  49 =item $_
  50
  51 The default input and pattern-searching space.  The following pairs are
  52 equivalent:
  53
  54     while (<>) {...}    # only equivalent in while!
  55     while ($_ = <>) {...}
  56
  57     /^Subject:/
  58     $_ =~ /^Subject:/
  59
  60     tr/a-z/A-Z/
  61     $_ =~ tr/a-z/A-Z/
  62
  63     chop
  64     chop($_)
  65
  66 (Mnemonic: underline is understood in certain operations.)
  67
  68 =item $<I<digit>>
  69
  70 Contains the subpattern from the corresponding set of parentheses in
  71 the last pattern matched, not counting patterns matched in nested
  72 blocks that have been exited already.  (Mnemonic: like \digit.)
  73 These variables are all read-only.
  74
  75 =item $MATCH
  76
  77 =item $&
  78
  79 The string matched by the last successful pattern match (not counting
  80 any matches hidden within a BLOCK or eval() enclosed by the current
  81 BLOCK).  (Mnemonic: like & in some editors.)  This variable is read-only.
  82
  83 =item $PREMATCH
  84
  85 =item $`
  86
  87 The string preceding whatever was matched by the last successful
  88 pattern match (not counting any matches hidden within a BLOCK or eval
  89 enclosed by the current BLOCK).  (Mnemonic: ` often precedes a quoted
  90 string.)  This variable is read-only.
  91
  92 =item $POSTMATCH
  93
  94 =item $'
  95
  96 The string following whatever was matched by the last successful
  97 pattern match (not counting any matches hidden within a BLOCK or eval()
  98 enclosed by the current BLOCK).  (Mnemonic: ' often follows a quoted
  99 string.)  Example:
 100
 101     $_ = 'abcdefghi';
 102     /def/;
 103     print "$`:$&:$'\n";         # prints abc:def:ghi
 104
 105 This variable is read-only.
 106
 107 =item $LAST_PAREN_MATCH
 108
 109 =item $+
 110
 111 The last bracket matched by the last search pattern.  This is useful if
 112 you don't know which of a set of alternative patterns matched.  For
 113 example:
 114
 115     /Version: (.*)|Revision: (.*)/ && ($rev = $+);
 116
 117 (Mnemonic: be positive and forward looking.)
 118 This variable is read-only.
 119
 120 =item $MULTILINE_MATCHING
 121
 122 =item $*
 123
 124 Set to 1 to do multiline matching within a string, 0 to tell Perl
 125 that it can assume that strings contain a single line, for the purpose
 126 of optimizing pattern matches.  Pattern matches on strings containing
 127 multiple newlines can produce confusing results when "C<$*>" is 0.  Default
 128 is 0.  (Mnemonic: * matches multiple things.)  Note that this variable
 129 only influences the interpretation of "C<^>" and "C<$>".  A literal newline can
 130 be searched for even when C<$* == 0>.
 131
 132 Use of "C<$*>" is deprecated in Perl 5.
 133
 134 =item input_line_number HANDLE EXPR
 135
 136 =item $INPUT_LINE_NUMBER
 137
 138 =item $NR
 139
 140 =item $.
 141
 142 The current input line number of the last filehandle that was read.  An
 143 explicit close on the filehandle resets the line number.  Since
 144 "C<E<lt>E<gt>>" never does an explicit close, line numbers increase
 145 across ARGV files (but see examples under eof()).  Localizing C<$.> has
 146 the effect of also localizing Perl's notion of "the last read
 147 filehandle".  (Mnemonic: many programs use "." to mean the current line
 148 number.)
 149
 150 =item input_record_separator HANDLE EXPR
 151
 152 =item $INPUT_RECORD_SEPARATOR
 153
 154 =item $RS
 155
 156 =item $/
 157
 158 The input record separator, newline by default.  Works like B<awk>'s RS
 159 variable, including treating blank lines as delimiters if set to the
 160 null string.  You may set it to a multicharacter string to match a
 161 multi-character delimiter.  Note that setting it to C<"\n\n"> means
 162 something slightly different than setting it to C<"">, if the file
 163 contains consecutive blank lines.  Setting it to C<""> will treat two or
 164 more consecutive blank lines as a single blank line.  Setting it to
 165 C<"\n\n"> will blindly assume that the next input character belongs to the
 166 next paragraph, even if it's a newline.  (Mnemonic: / is used to
 167 delimit line boundaries when quoting poetry.)
 168
 169     undef $/;
 170     $_ = <FH>;          # whole file now here
 171     s/\n[ \t]+/ /g;
 172
 173 =item autoflush HANDLE EXPR
 174
 175 =item $OUTPUT_AUTOFLUSH
 176
 177 =item $|
 178
 179 If set to nonzero, forces a flush after every write or print on the
 180 currently selected output channel.  Default is 0.  Note that STDOUT
 181 will typically be line buffered if output is to the terminal and block
 182 buffered otherwise.  Setting this variable is useful primarily when you
 183 are outputting to a pipe, such as when you are running a Perl script
 184 under rsh and want to see the output as it's happening.  (Mnemonic:
 185 when you want your pipes to be piping hot.)
 186
 187 =item output_field_separator HANDLE EXPR
 188
 189 =item $OUTPUT_FIELD_SEPARATOR
 190
 191 =item $OFS
 192
 193 =item $,
 194
 195 The output field separator for the print operator.  Ordinarily the
 196 print operator simply prints out the comma separated fields you
 197 specify.  In order to get behavior more like B<awk>, set this variable
 198 as you would set B<awk>'s OFS variable to specify what is printed
 199 between fields.  (Mnemonic: what is printed when there is a , in your
 200 print statement.)
 201
 202 =item output_record_separator HANDLE EXPR
 203
 204 =item $OUTPUT_RECORD_SEPARATOR
 205
 206 =item $ORS
 207
 208 =item $\
 209
 210 The output record separator for the print operator.  Ordinarily the
 211 print operator simply prints out the comma separated fields you
 212 specify, with no trailing newline or record separator assumed.  In
 213 order to get behavior more like B<awk>, set this variable as you would
 214 set B<awk>'s ORS variable to specify what is printed at the end of the
 215 print.  (Mnemonic: you set "C<$\>" instead of adding \n at the end of the
 216 print.  Also, it's just like /, but it's what you get "back" from
 217 Perl.)
 218
 219 =item $LIST_SEPARATOR
 220
 221 =item $"
 222
 223 This is like "C<$,>" except that it applies to array values interpolated
 224 into a double-quoted string (or similar interpreted string).  Default
 225 is a space.  (Mnemonic: obvious, I think.)
 226
 227 =item $SUBSCRIPT_SEPARATOR
 228
 229 =item $SUBSEP
 230
 231 =item $;
 232
 233 The subscript separator for multi-dimensional array emulation.  If you
 234 refer to a hash element as
 235
 236     $foo{$a,$b,$c}
 237
 238 it really means
 239
 240     $foo{join($;, $a, $b, $c)}
 241
 242 But don't put
 243
 244     @foo{$a,$b,$c}      # a slice--note the @
 245
 246 which means
 247
 248     ($foo{$a},$foo{$b},$foo{$c})
 249
 250 Default is "\034", the same as SUBSEP in B<awk>.  Note that if your
 251 keys contain binary data there might not be any safe value for "C<$;>".
 252 (Mnemonic: comma (the syntactic subscript separator) is a
 253 semi-semicolon.  Yeah, I know, it's pretty lame, but "C<$,>" is already
 254 taken for something more important.)
 255
 256 Consider using "real" multi-dimensional arrays in Perl 5.
 257
 258 =item $OFMT
 259
 260 =item $#
 261
 262 The output format for printed numbers.  This variable is a half-hearted
 263 attempt to emulate B<awk>'s OFMT variable.  There are times, however,
 264 when B<awk> and Perl have differing notions of what is in fact
 265 numeric.  Also, the initial value is %.20g rather than %.6g, so you
 266 need to set "C<$#>" explicitly to get B<awk>'s value.  (Mnemonic: # is the
 267 number sign.)
 268
 269 Use of "C<$#>" is deprecated in Perl 5.
 270
 271 =item format_page_number HANDLE EXPR
 272
 273 =item $FORMAT_PAGE_NUMBER
 274
 275 =item $%
 276
 277 The current page number of the currently selected output channel.
 278 (Mnemonic: % is page number in B<nroff>.)
 279
 280 =item format_lines_per_page HANDLE EXPR
 281
 282 =item $FORMAT_LINES_PER_PAGE
 283
 284 =item $=
 285
 286 The current page length (printable lines) of the currently selected
 287 output channel.  Default is 60.  (Mnemonic: = has horizontal lines.)
 288
 289 =item format_lines_left HANDLE EXPR
 290
 291 =item $FORMAT_LINES_LEFT
 292
 293 =item $-
 294
 295 The number of lines left on the page of the currently selected output
 296 channel.  (Mnemonic: lines_on_page - lines_printed.)
 297
 298 =item format_name HANDLE EXPR
 299
 300 =item $FORMAT_NAME
 301
 302 =item $~
 303
 304 The name of the current report format for the currently selected output
 305 channel.  Default is name of the filehandle.  (Mnemonic: brother to
 306 "C<$^>".)
 307
 308 =item format_top_name HANDLE EXPR
 309
 310 =item $FORMAT_TOP_NAME
 311
 312 =item $^
 313
 314 The name of the current top-of-page format for the currently selected
 315 output channel.  Default is name of the filehandle with _TOP
 316 appended.  (Mnemonic: points to top of page.)
 317
 318 =item format_line_break_characters HANDLE EXPR
 319
 320 =item $FORMAT_LINE_BREAK_CHARACTERS
 321
 322 =item $:
 323
 324 The current set of characters after which a string may be broken to
 325 fill continuation fields (starting with ^) in a format.  Default is
 326 S<" \n-">, to break on whitespace or hyphens.  (Mnemonic: a "colon" in
 327 poetry is a part of a line.)
 328
 329 =item format_formfeed HANDLE EXPR
 330
 331 =item $FORMAT_FORMFEED
 332
 333 =item $^L
 334
 335 What formats output to perform a formfeed.  Default is \f.
 336
 337 =item $ACCUMULATOR
 338
 339 =item $^A
 340
 341 The current value of the write() accumulator for format() lines.  A format
 342 contains formline() commands that put their result into C<$^A>.  After
 343 calling its format, write() prints out the contents of C<$^A> and empties.
 344 So you never actually see the contents of C<$^A> unless you call
 345 formline() yourself and then look at it.  See L<perlform> and
 346 L<perlfunc/formline()>.
 347
 348 =item $CHILD_ERROR
 349
 350 =item $?
 351
 352 The status returned by the last pipe close, backtick (C<``>) command,
 353 or system() operator.  Note that this is the status word returned by
 354 the wait() system call, so the exit value of the subprocess is actually
 355 (C<$? E<gt>E<gt> 8>).  Thus on many systems, C<$? & 255> gives which signal,
 356 if any, the process died from, and whether there was a core dump.
 357 (Mnemonic: similar to B<sh> and B<ksh>.)
 358
 359 =item $OS_ERROR
 360
 361 =item $ERRNO
 362
 363 =item $!
 364
 365 If used in a numeric context, yields the current value of errno, with
 366 all the usual caveats.  (This means that you shouldn't depend on the
 367 value of "C<$!>" to be anything in particular unless you've gotten a
 368 specific error return indicating a system error.)  If used in a string
 369 context, yields the corresponding system error string.  You can assign
 370 to "C<$!>" in order to set I<errno> if, for instance, you want "C<$!>" to return the
 371 string for error I<n>, or you want to set the exit value for the die()
 372 operator.  (Mnemonic: What just went bang?)
 373
 374 =item $EVAL_ERROR
 375
 376 =item $@
 377
 378 The Perl syntax error message from the last eval() command.  If null, the
 379 last eval() parsed and executed correctly (although the operations you
 380 invoked may have failed in the normal fashion).  (Mnemonic: Where was
 381 the syntax error "at"?)
 382
 383 Note that warning messages are not collected in this variable.  You can,
 384 however, set up a routine to process warnings by setting $SIG{__WARN__} below.
 385
 386 =item $PROCESS_ID
 387
 388 =item $PID
 389
 390 =item $$
 391
 392 The process number of the Perl running this script.  (Mnemonic: same
 393 as shells.)
 394
 395 =item $REAL_USER_ID
 396
 397 =item $UID
 398
 399 =item $<
 400
 401 The real uid of this process.  (Mnemonic: it's the uid you came I<FROM>,
 402 if you're running setuid.)
 403
 404 =item $EFFECTIVE_USER_ID
 405
 406 =item $EUID
 407
 408 =item $>
 409
 410 The effective uid of this process.  Example:
 411
 412     $< = $>;            # set real to effective uid
 413     ($<,$>) = ($>,$<);  # swap real and effective uid
 414
 415 (Mnemonic: it's the uid you went I<TO>, if you're running setuid.)  Note:
 416 "C<$E<lt>>" and "C<$E<gt>>" can only be swapped on machines supporting setreuid().
 417
 418 =item $REAL_GROUP_ID
 419
 420 =item $GID
 421
 422 =item $(
 423
 424 The real gid of this process.  If you are on a machine that supports
 425 membership in multiple groups simultaneously, gives a space separated
 426 list of groups you are in.  The first number is the one returned by
 427 getgid(), and the subsequent ones by getgroups(), one of which may be
 428 the same as the first number.  (Mnemonic: parentheses are used to I<GROUP>
 429 things.  The real gid is the group you I<LEFT>, if you're running setgid.)
 430
 431 =item $EFFECTIVE_GROUP_ID
 432
 433 =item $EGID
 434
 435 =item $)
 436
 437 The effective gid of this process.  If you are on a machine that
 438 supports membership in multiple groups simultaneously, gives a space
 439 separated list of groups you are in.  The first number is the one
 440 returned by getegid(), and the subsequent ones by getgroups(), one of
 441 which may be the same as the first number.  (Mnemonic: parentheses are
 442 used to I<GROUP> things.  The effective gid is the group that's I<RIGHT> for
 443 you, if you're running setgid.)
 444
 445 Note: "C<$E<lt>>", "C<$E<gt>>", "C<$(>" and "C<$)>" can only be set on machines
 446 that support the corresponding I<set[re][ug]id()> routine.  "C<$(>" and "C<$)>"
 447 can only be swapped on machines supporting setregid().
 448
 449 =item $PROGRAM_NAME
 450
 451 =item $0
 452
 453 Contains the name of the file containing the Perl script being
 454 executed.  Assigning to "C<$0>" modifies the argument area that the ps(1)
 455 program sees.  This is more useful as a way of indicating the
 456 current program state than it is for hiding the program you're running.
 457 (Mnemonic: same as B<sh> and B<ksh>.)
 458
 459 =item $[
 460
 461 The index of the first element in an array, and of the first character
 462 in a substring.  Default is 0, but you could set it to 1 to make
 463 Perl behave more like B<awk> (or Fortran) when subscripting and when
 464 evaluating the index() and substr() functions.  (Mnemonic: [ begins
 465 subscripts.)
 466
 467 As of Perl 5, assignment to "C<$[>" is treated as a compiler directive,
 468 and cannot influence the behavior of any other file.  Its use is
 469 discouraged.
 470
 471 =item $PERL_VERSION
 472
 473 =item $]
 474
 475 The string printed out when you say C<perl -v>.  It can be used to
 476 determine at the beginning of a script whether the perl interpreter
 477 executing the script is in the right range of versions.  If used in a
 478 numeric context, returns the version + patchlevel / 1000.  Example:
 479
 480     # see if getc is available
 481     ($version,$patchlevel) =
 482              $] =~ /(\d+\.\d+).*\nPatch level: (\d+)/;
 483     print STDERR "(No filename completion available.)\n"
 484              if $version * 1000 + $patchlevel < 2016;
 485
 486 or, used numerically,
 487
 488     warn "No checksumming!\n" if $] < 3.019;
 489
 490 (Mnemonic: Is this version of perl in the right bracket?)
 491
 492 =item $DEBUGGING
 493
 494 =item $^D
 495
 496 The current value of the debugging flags.  (Mnemonic: value of B<-D>
 497 switch.)
 498
 499 =item $SYSTEM_FD_MAX
 500
 501 =item $^F
 502
 503 The maximum system file descriptor, ordinarily 2.  System file
 504 descriptors are passed to exec()ed processes, while higher file
 505 descriptors are not.  Also, during an open(), system file descriptors are
 506 preserved even if the open() fails.  (Ordinary file descriptors are
 507 closed before the open() is attempted.)  Note that the close-on-exec
 508 status of a file descriptor will be decided according to the value of
 509 C<$^F> at the time of the open, not the time of the exec.
 510
 511 =item $INPLACE_EDIT
 512
 513 =item $^I
 514
 515 The current value of the inplace-edit extension.  Use C<undef> to disable
 516 inplace editing.  (Mnemonic: value of B<-i> switch.)
 517
 518 =item $PERLDB
 519
 520 =item $^P
 521
 522 The internal flag that the debugger clears so that it doesn't debug
 523 itself.  You could conceivable disable debugging yourself by clearing
 524 it.
 525
 526 =item $BASETIME
 527
 528 =item $^T
 529
 530 The time at which the script began running, in seconds since the
 531 epoch (beginning of 1970).  The values returned by the B<-M>, B<-A>
 532 and B<-C> filetests are
 533 based on this value.
 534
 535 =item $WARNING
 536
 537 =item $^W
 538
 539 The current value of the warning switch, either TRUE or FALSE.  (Mnemonic: related to the
 540 B<-w> switch.)
 541
 542 =item $EXECUTABLE_NAME
 543
 544 =item $^X
 545
 546 The name that the Perl binary itself was executed as, from C's C<argv[0]>.
 547
 548 =item $ARGV
 549
 550 contains the name of the current file when reading from <>.
 551
 552 =item @ARGV
 553
 554 The array @ARGV contains the command line arguments intended for the
 555 script.  Note that C<$#ARGV> is the generally number of arguments minus
 556 one, since C<$ARGV[0]> is the first argument, I<NOT> the command name.  See
 557 "C<$0>" for the command name.
 558
 559 =item @INC
 560
 561 The array @INC contains the list of places to look for Perl scripts to
 562 be evaluated by the C<do EXPR>, C<require>, or C<use> constructs.  It
 563 initially consists of the arguments to any B<-I> command line switches,
 564 followed by the default Perl library, probably "/usr/local/lib/perl",
 565 followed by ".", to represent the current directory.
 566
 567 =item %INC
 568
 569 The hash %INC contains entries for each filename that has
 570 been included via C<do> or C<require>.  The key is the filename you
 571 specified, and the value is the location of the file actually found.
 572 The C<require> command uses this array to determine whether a given file
 573 has already been included.
 574
 575 =item $ENV{expr}
 576
 577 The hash %ENV contains your current environment.  Setting a
 578 value in C<ENV> changes the environment for child processes.
 579
 580 =item $SIG{expr}
 581
 582 The hash %SIG is used to set signal handlers for various
 583 signals.  Example:
 584
 585     sub handler {       # 1st argument is signal name
 586         local($sig) = @_;
 587         print "Caught a SIG$sig--shutting down\n";
 588         close(LOG);
 589         exit(0);
 590     }
 591
 592     $SIG{'INT'} = 'handler';
 593     $SIG{'QUIT'} = 'handler';
 594     ...
 595     $SIG{'INT'} = 'DEFAULT';    # restore default action
 596     $SIG{'QUIT'} = 'IGNORE';    # ignore SIGQUIT
 597
 598 The %SIG array only contains values for the signals actually set within
 599 the Perl script.  Here are some other examples:
 600
 601     $SIG{PIPE} = Plumber;       # SCARY!!
 602     $SIG{"PIPE"} = "Plumber";   # just fine, assumes main::Plumber
 603     $SIG{"PIPE"} = \&Plumber;   # just fine; assume current Plumber
 604     $SIG{"PIPE"} = Plumber();   # oops, what did Plumber() return??
 605
 606 The one marked scary is problematic because it's a bareword, which means
 607 sometimes it's a string representing the function, and sometimes it's
 608 going to call the subroutine call right then and there!  Best to be sure
 609 and quote it or take a reference to it.  *Plumber works too.  See L<perlsubs>.
 610
 611 Certain internal hooks can be also set using the %SIG hash.  The
 612 routine indicated by $SIG{__WARN__} is called when a warning message is
 613 about to be printed.  The warning message is passed as the first
 614 argument.  The presence of a __WARN__ hook causes the ordinary printing
 615 of warnings to STDERR to be suppressed.  You can use this to save warnings
 616 in a variable, or turn warnings into fatal errors, like this:
 617
 618     local $SIG{__WARN__} = sub { die $_[0] };
 619     eval $proggie;
 620
 621 The routine indicated by $SIG{__DIE__} is called when a fatal exception
 622 is about to be thrown.  The error message is passed as the first
 623 argument.  When a __DIE__ hook routine returns, the exception
 624 processing continues as it would have in the absence of the hook,
 625 unless the hook routine itself exits via a goto, a loop exit, or a die.
 626
 627 =back
 628