pod/perlvar.pod

   1 =head1 NAME
   2
   3 perlvar - Perl predefined variables
   4
   5 =head1 DESCRIPTION
   6
   7 =head2 Predefined Names
   8
   9 The following names have special meaning to Perl.  Most of the
  10 punctuational names have reasonable mnemonics, or analogues in one of
  11 the shells.  Nevertheless, if you wish to use the long variable names,
  12 you just need to say
  13
  14     use English;
  15
  16 at the top of your program.  This will alias all the short names to the
  17 long names in the current package.  Some of them even have medium names,
  18 generally borrowed from B<awk>.
  19
  20 To go a step further, those variables that depend on the currently
  21 selected filehandle may instead be set by calling an object method on
  22 the FileHandle object.  (Summary lines below for this contain the word
  23 HANDLE.)  First you must say
  24
  25     use FileHandle;
  26
  27 after which you may use either
  28
  29     method HANDLE EXPR
  30
  31 or
  32
  33     HANDLE->method(EXPR)
  34
  35 Each of the methods returns the old value of the FileHandle attribute.
  36 The methods each take an optional EXPR, which if supplied specifies the
  37 new value for the FileHandle attribute in question.  If not supplied,
  38 most of the methods do nothing to the current value, except for
  39 autoflush(), which will assume a 1 for you, just to be different.
  40
  41 A few of these variables are considered "read-only".  This means that if
  42 you try to assign to this variable, either directly or indirectly through
  43 a reference, you'll raise a run-time exception.
  44
  45 =over 8
  46
  47 =item $ARG
  48
  49 =item $_
  50
  51 The default input and pattern-searching space.  The following pairs are
  52 equivalent:
  53
  54     while (<>) {...}    # only equivalent in while!
  55     while ($_ = <>) {...}
  56
  57     /^Subject:/
  58     $_ =~ /^Subject:/
  59
  60     tr/a-z/A-Z/
  61     $_ =~ tr/a-z/A-Z/
  62
  63     chop
  64     chop($_)
  65
  66 (Mnemonic: underline is understood in certain operations.)
  67
  68 =item $<I<digit>>
  69
  70 Contains the subpattern from the corresponding set of parentheses in
  71 the last pattern matched, not counting patterns matched in nested
  72 blocks that have been exited already.  (Mnemonic: like \digit.)
  73 These variables are all read-only.
  74
  75 =item $MATCH
  76
  77 =item $&
  78
  79 The string matched by the last successful pattern match (not counting
  80 any matches hidden within a BLOCK or eval() enclosed by the current
  81 BLOCK).  (Mnemonic: like & in some editors.)  This variable is read-only.
  82
  83 =item $PREMATCH
  84
  85 =item $`
  86
  87 The string preceding whatever was matched by the last successful
  88 pattern match (not counting any matches hidden within a BLOCK or eval
  89 enclosed by the current BLOCK).  (Mnemonic: ` often precedes a quoted
  90 string.)  This variable is read-only.
  91
  92 =item $POSTMATCH
  93
  94 =item $'
  95
  96 The string following whatever was matched by the last successful
  97 pattern match (not counting any matches hidden within a BLOCK or eval()
  98 enclosed by the current BLOCK).  (Mnemonic: ' often follows a quoted
  99 string.)  Example:
 100
 101     $_ = 'abcdefghi';
 102     /def/;
 103     print "$`:$&:$'\n";         # prints abc:def:ghi
 104
 105 This variable is read-only.
 106
 107 =item $LAST_PAREN_MATCH
 108
 109 =item $+
 110
 111 The last bracket matched by the last search pattern.  This is useful if
 112 you don't know which of a set of alternative patterns matched.  For
 113 example:
 114
 115     /Version: (.*)|Revision: (.*)/ && ($rev = $+);
 116
 117 (Mnemonic: be positive and forward looking.)
 118 This variable is read-only.
 119
 120 =item $MULTILINE_MATCHING
 121
 122 =item $*
 123
 124 Set to 1 to do multiline matching within a string, 0 to tell Perl
 125 that it can assume that strings contain a single line, for the purpose
 126 of optimizing pattern matches.  Pattern matches on strings containing
 127 multiple newlines can produce confusing results when "C<$*>" is 0.  Default
 128 is 0.  (Mnemonic: * matches multiple things.)  Note that this variable
 129 only influences the interpretation of "C<^>" and "C<$>".  A literal newline can
 130 be searched for even when C<$* == 0>.
 131
 132 Use of "C<$*>" is deprecated in Perl 5.
 133
 134 =item input_line_number HANDLE EXPR
 135
 136 =item $INPUT_LINE_NUMBER
 137
 138 =item $NR
 139
 140 =item $.
 141
 142 The current input line number of the last filehandle that was read.
 143 This variable should be considered read-only.
 144 Remember that only an explicit close on the filehandle
 145 resets the line number.  Since "C<E<lt>E<gt>>" never does an explicit close, line
 146 numbers increase across ARGV files (but see examples under eof()).
 147 (Mnemonic: many programs use "." to mean the current line number.)
 148
 149 =item input_record_separator HANDLE EXPR
 150
 151 =item $INPUT_RECORD_SEPARATOR
 152
 153 =item $RS
 154
 155 =item $/
 156
 157 The input record separator, newline by default.  Works like B<awk>'s RS
 158 variable, including treating blank lines as delimiters if set to the
 159 null string.  You may set it to a multicharacter string to match a
 160 multi-character delimiter.  Note that setting it to C<"\n\n"> means
 161 something slightly different than setting it to C<"">, if the file
 162 contains consecutive blank lines.  Setting it to C<""> will treat two or
 163 more consecutive blank lines as a single blank line.  Setting it to
 164 C<"\n\n"> will blindly assume that the next input character belongs to the
 165 next paragraph, even if it's a newline.  (Mnemonic: / is used to
 166 delimit line boundaries when quoting poetry.)
 167
 168     undef $/;
 169     $_ = <FH>;          # whole file now here
 170     s/\n[ \t]+/ /g;
 171
 172 =item autoflush HANDLE EXPR
 173
 174 =item $OUTPUT_AUTOFLUSH
 175
 176 =item $|
 177
 178 If set to nonzero, forces a flush after every write or print on the
 179 currently selected output channel.  Default is 0.  Note that STDOUT
 180 will typically be line buffered if output is to the terminal and block
 181 buffered otherwise.  Setting this variable is useful primarily when you
 182 are outputting to a pipe, such as when you are running a Perl script
 183 under rsh and want to see the output as it's happening.  (Mnemonic:
 184 when you want your pipes to be piping hot.)
 185
 186 =item output_field_separator HANDLE EXPR
 187
 188 =item $OUTPUT_FIELD_SEPARATOR
 189
 190 =item $OFS
 191
 192 =item $,
 193
 194 The output field separator for the print operator.  Ordinarily the
 195 print operator simply prints out the comma separated fields you
 196 specify.  In order to get behavior more like B<awk>, set this variable
 197 as you would set B<awk>'s OFS variable to specify what is printed
 198 between fields.  (Mnemonic: what is printed when there is a , in your
 199 print statement.)
 200
 201 =item output_record_separator HANDLE EXPR
 202
 203 =item $OUTPUT_RECORD_SEPARATOR
 204
 205 =item $ORS
 206
 207 =item $\
 208
 209 The output record separator for the print operator.  Ordinarily the
 210 print operator simply prints out the comma separated fields you
 211 specify, with no trailing newline or record separator assumed.  In
 212 order to get behavior more like B<awk>, set this variable as you would
 213 set B<awk>'s ORS variable to specify what is printed at the end of the
 214 print.  (Mnemonic: you set "C<$\>" instead of adding \n at the end of the
 215 print.  Also, it's just like /, but it's what you get "back" from
 216 Perl.)
 217
 218 =item $LIST_SEPARATOR
 219
 220 =item $"
 221
 222 This is like "C<$,>" except that it applies to array values interpolated
 223 into a double-quoted string (or similar interpreted string).  Default
 224 is a space.  (Mnemonic: obvious, I think.)
 225
 226 =item $SUBSCRIPT_SEPARATOR
 227
 228 =item $SUBSEP
 229
 230 =item $;
 231
 232 The subscript separator for multi-dimensional array emulation.  If you
 233 refer to a hash element as
 234
 235     $foo{$a,$b,$c}
 236
 237 it really means
 238
 239     $foo{join($;, $a, $b, $c)}
 240
 241 But don't put
 242
 243     @foo{$a,$b,$c}      # a slice--note the @
 244
 245 which means
 246
 247     ($foo{$a},$foo{$b},$foo{$c})
 248
 249 Default is "\034", the same as SUBSEP in B<awk>.  Note that if your
 250 keys contain binary data there might not be any safe value for "C<$;>".
 251 (Mnemonic: comma (the syntactic subscript separator) is a
 252 semi-semicolon.  Yeah, I know, it's pretty lame, but "C<$,>" is already
 253 taken for something more important.)
 254
 255 Consider using "real" multi-dimensional arrays in Perl 5.
 256
 257 =item $OFMT
 258
 259 =item $#
 260
 261 The output format for printed numbers.  This variable is a half-hearted
 262 attempt to emulate B<awk>'s OFMT variable.  There are times, however,
 263 when B<awk> and Perl have differing notions of what is in fact
 264 numeric.  Also, the initial value is %.20g rather than %.6g, so you
 265 need to set "C<$#>" explicitly to get B<awk>'s value.  (Mnemonic: # is the
 266 number sign.)
 267
 268 Use of "C<$#>" is deprecated in Perl 5.
 269
 270 =item format_page_number HANDLE EXPR
 271
 272 =item $FORMAT_PAGE_NUMBER
 273
 274 =item $%
 275
 276 The current page number of the currently selected output channel.
 277 (Mnemonic: % is page number in B<nroff>.)
 278
 279 =item format_lines_per_page HANDLE EXPR
 280
 281 =item $FORMAT_LINES_PER_PAGE
 282
 283 =item $=
 284
 285 The current page length (printable lines) of the currently selected
 286 output channel.  Default is 60.  (Mnemonic: = has horizontal lines.)
 287
 288 =item format_lines_left HANDLE EXPR
 289
 290 =item $FORMAT_LINES_LEFT
 291
 292 =item $-
 293
 294 The number of lines left on the page of the currently selected output
 295 channel.  (Mnemonic: lines_on_page - lines_printed.)
 296
 297 =item format_name HANDLE EXPR
 298
 299 =item $FORMAT_NAME
 300
 301 =item $~
 302
 303 The name of the current report format for the currently selected output
 304 channel.  Default is name of the filehandle.  (Mnemonic: brother to
 305 "C<$^>".)
 306
 307 =item format_top_name HANDLE EXPR
 308
 309 =item $FORMAT_TOP_NAME
 310
 311 =item $^
 312
 313 The name of the current top-of-page format for the currently selected
 314 output channel.  Default is name of the filehandle with _TOP
 315 appended.  (Mnemonic: points to top of page.)
 316
 317 =item format_line_break_characters HANDLE EXPR
 318
 319 =item $FORMAT_LINE_BREAK_CHARACTERS
 320
 321 =item $:
 322
 323 The current set of characters after which a string may be broken to
 324 fill continuation fields (starting with ^) in a format.  Default is
 325 S<" \n-">, to break on whitespace or hyphens.  (Mnemonic: a "colon" in
 326 poetry is a part of a line.)
 327
 328 =item format_formfeed HANDLE EXPR
 329
 330 =item $FORMAT_FORMFEED
 331
 332 =item $^L
 333
 334 What formats output to perform a formfeed.  Default is \f.
 335
 336 =item $ACCUMULATOR
 337
 338 =item $^A
 339
 340 The current value of the write() accumulator for format() lines.  A format
 341 contains formline() commands that put their result into C<$^A>.  After
 342 calling its format, write() prints out the contents of C<$^A> and empties.
 343 So you never actually see the contents of C<$^A> unless you call
 344 formline() yourself and then look at it.  See L<perlform> and
 345 L<perlfunc/formline()>.
 346
 347 =item $CHILD_ERROR
 348
 349 =item $?
 350
 351 The status returned by the last pipe close, backtick (C<``>) command,
 352 or system() operator.  Note that this is the status word returned by
 353 the wait() system call, so the exit value of the subprocess is actually
 354 (C<$? E<gt>E<gt> 8>).  Thus on many systems, C<$? & 255> gives which signal,
 355 if any, the process died from, and whether there was a core dump.
 356 (Mnemonic: similar to B<sh> and B<ksh>.)
 357
 358 =item $OS_ERROR
 359
 360 =item $ERRNO
 361
 362 =item $!
 363
 364 If used in a numeric context, yields the current value of errno, with
 365 all the usual caveats.  (This means that you shouldn't depend on the
 366 value of "C<$!>" to be anything in particular unless you've gotten a
 367 specific error return indicating a system error.)  If used in a string
 368 context, yields the corresponding system error string.  You can assign
 369 to "C<$!>" in order to set I<errno> if, for instance, you want "C<$!>" to return the
 370 string for error I<n>, or you want to set the exit value for the die()
 371 operator.  (Mnemonic: What just went bang?)
 372
 373 =item $EVAL_ERROR
 374
 375 =item $@
 376
 377 The Perl syntax error message from the last eval() command.  If null, the
 378 last eval() parsed and executed correctly (although the operations you
 379 invoked may have failed in the normal fashion).  (Mnemonic: Where was
 380 the syntax error "at"?)
 381
 382 Note that warning messages are not collected in this variable.  You can,
 383 however, set up a routine to process warnings by setting $SIG{__WARN__} below.
 384
 385 =item $PROCESS_ID
 386
 387 =item $PID
 388
 389 =item $$
 390
 391 The process number of the Perl running this script.  (Mnemonic: same
 392 as shells.)
 393
 394 =item $REAL_USER_ID
 395
 396 =item $UID
 397
 398 =item $<
 399
 400 The real uid of this process.  (Mnemonic: it's the uid you came I<FROM>,
 401 if you're running setuid.)
 402
 403 =item $EFFECTIVE_USER_ID
 404
 405 =item $EUID
 406
 407 =item $>
 408
 409 The effective uid of this process.  Example:
 410
 411     $< = $>;            # set real to effective uid
 412     ($<,$>) = ($>,$<);  # swap real and effective uid
 413
 414 (Mnemonic: it's the uid you went I<TO>, if you're running setuid.)  Note:
 415 "C<$E<lt>>" and "C<$E<gt>>" can only be swapped on machines supporting setreuid().
 416
 417 =item $REAL_GROUP_ID
 418
 419 =item $GID
 420
 421 =item $(
 422
 423 The real gid of this process.  If you are on a machine that supports
 424 membership in multiple groups simultaneously, gives a space separated
 425 list of groups you are in.  The first number is the one returned by
 426 getgid(), and the subsequent ones by getgroups(), one of which may be
 427 the same as the first number.  (Mnemonic: parentheses are used to I<GROUP>
 428 things.  The real gid is the group you I<LEFT>, if you're running setgid.)
 429
 430 =item $EFFECTIVE_GROUP_ID
 431
 432 =item $EGID
 433
 434 =item $)
 435
 436 The effective gid of this process.  If you are on a machine that
 437 supports membership in multiple groups simultaneously, gives a space
 438 separated list of groups you are in.  The first number is the one
 439 returned by getegid(), and the subsequent ones by getgroups(), one of
 440 which may be the same as the first number.  (Mnemonic: parentheses are
 441 used to I<GROUP> things.  The effective gid is the group that's I<RIGHT> for
 442 you, if you're running setgid.)
 443
 444 Note: "C<$E<lt>>", "C<$E<gt>>", "C<$(>" and "C<$)>" can only be set on machines
 445 that support the corresponding I<set[re][ug]id()> routine.  "C<$(>" and "C<$)>"
 446 can only be swapped on machines supporting setregid().
 447
 448 =item $PROGRAM_NAME
 449
 450 =item $0
 451
 452 Contains the name of the file containing the Perl script being
 453 executed.  Assigning to "C<$0>" modifies the argument area that the ps(1)
 454 program sees.  This is more useful as a way of indicating the
 455 current program state than it is for hiding the program you're running.
 456 (Mnemonic: same as B<sh> and B<ksh>.)
 457
 458 =item $[
 459
 460 The index of the first element in an array, and of the first character
 461 in a substring.  Default is 0, but you could set it to 1 to make
 462 Perl behave more like B<awk> (or Fortran) when subscripting and when
 463 evaluating the index() and substr() functions.  (Mnemonic: [ begins
 464 subscripts.)
 465
 466 As of Perl 5, assignment to "C<$[>" is treated as a compiler directive,
 467 and cannot influence the behavior of any other file.  Its use is
 468 discouraged.
 469
 470 =item $PERL_VERSION
 471
 472 =item $]
 473
 474 The string printed out when you say C<perl -v>.  It can be used to
 475 determine at the beginning of a script whether the perl interpreter
 476 executing the script is in the right range of versions.  If used in a
 477 numeric context, returns the version + patchlevel / 1000.  Example:
 478
 479     # see if getc is available
 480     ($version,$patchlevel) =
 481              $] =~ /(\d+\.\d+).*\nPatch level: (\d+)/;
 482     print STDERR "(No filename completion available.)\n"
 483              if $version * 1000 + $patchlevel < 2016;
 484
 485 or, used numerically,
 486
 487     warn "No checksumming!\n" if $] < 3.019;
 488
 489 (Mnemonic: Is this version of perl in the right bracket?)
 490
 491 =item $DEBUGGING
 492
 493 =item $^D
 494
 495 The current value of the debugging flags.  (Mnemonic: value of B<-D>
 496 switch.)
 497
 498 =item $SYSTEM_FD_MAX
 499
 500 =item $^F
 501
 502 The maximum system file descriptor, ordinarily 2.  System file
 503 descriptors are passed to exec()ed processes, while higher file
 504 descriptors are not.  Also, during an open(), system file descriptors are
 505 preserved even if the open() fails.  (Ordinary file descriptors are
 506 closed before the open() is attempted.)  Note that the close-on-exec
 507 status of a file descriptor will be decided according to the value of
 508 C<$^F> at the time of the open, not the time of the exec.
 509
 510 =item $INPLACE_EDIT
 511
 512 =item $^I
 513
 514 The current value of the inplace-edit extension.  Use C<undef> to disable
 515 inplace editing.  (Mnemonic: value of B<-i> switch.)
 516
 517 =item $PERLDB
 518
 519 =item $^P
 520
 521 The internal flag that the debugger clears so that it doesn't debug
 522 itself.  You could conceivable disable debugging yourself by clearing
 523 it.
 524
 525 =item $BASETIME
 526
 527 =item $^T
 528
 529 The time at which the script began running, in seconds since the
 530 epoch (beginning of 1970).  The values returned by the B<-M>, B<-A>
 531 and B<-C> filetests are
 532 based on this value.
 533
 534 =item $WARNING
 535
 536 =item $^W
 537
 538 The current value of the warning switch, either TRUE or FALSE.  (Mnemonic: related to the
 539 B<-w> switch.)
 540
 541 =item $EXECUTABLE_NAME
 542
 543 =item $^X
 544
 545 The name that the Perl binary itself was executed as, from C's C<argv[0]>.
 546
 547 =item $ARGV
 548
 549 contains the name of the current file when reading from <>.
 550
 551 =item @ARGV
 552
 553 The array @ARGV contains the command line arguments intended for the
 554 script.  Note that C<$#ARGV> is the generally number of arguments minus
 555 one, since C<$ARGV[0]> is the first argument, I<NOT> the command name.  See
 556 "C<$0>" for the command name.
 557
 558 =item @INC
 559
 560 The array @INC contains the list of places to look for Perl scripts to
 561 be evaluated by the C<do EXPR>, C<require>, or C<use> constructs.  It
 562 initially consists of the arguments to any B<-I> command line switches,
 563 followed by the default Perl library, probably "/usr/local/lib/perl",
 564 followed by ".", to represent the current directory.
 565
 566 =item %INC
 567
 568 The hash %INC contains entries for each filename that has
 569 been included via C<do> or C<require>.  The key is the filename you
 570 specified, and the value is the location of the file actually found.
 571 The C<require> command uses this array to determine whether a given file
 572 has already been included.
 573
 574 =item $ENV{expr}
 575
 576 The hash %ENV contains your current environment.  Setting a
 577 value in C<ENV> changes the environment for child processes.
 578
 579 =item $SIG{expr}
 580
 581 The hash %SIG is used to set signal handlers for various
 582 signals.  Example:
 583
 584     sub handler {       # 1st argument is signal name
 585         local($sig) = @_;
 586         print "Caught a SIG$sig--shutting down\n";
 587         close(LOG);
 588         exit(0);
 589     }
 590
 591     $SIG{'INT'} = 'handler';
 592     $SIG{'QUIT'} = 'handler';
 593     ...
 594     $SIG{'INT'} = 'DEFAULT';    # restore default action
 595     $SIG{'QUIT'} = 'IGNORE';    # ignore SIGQUIT
 596
 597 The %SIG array only contains values for the signals actually set within
 598 the Perl script.  Here are some other examples:
 599
 600     $SIG{PIPE} = Plumber;       # SCARY!!
 601     $SIG{"PIPE"} = "Plumber";   # just fine, assumes main::Plumber
 602     $SIG{"PIPE"} = \&Plumber;   # just fine; assume current Plumber
 603     $SIG{"PIPE"} = Plumber();   # oops, what did Plumber() return??
 604
 605 The one marked scary is problematic because it's a bareword, which means
 606 sometimes it's a string representing the function, and sometimes it's
 607 going to call the subroutine call right then and there!  Best to be sure
 608 and quote it or take a reference to it.  *Plumber works too.  See L<perlsubs>.
 609
 610 Certain internal hooks can be also set using the %SIG hash.  The
 611 routine indicated by $SIG{__WARN__} is called when a warning message is
 612 about to be printed.  The warning message is passed as the first
 613 argument.  The presence of a __WARN__ hook causes the ordinary printing
 614 of warnings to STDERR to be suppressed.  You can use this to save warnings
 615 in a variable, or turn warnings into fatal errors, like this:
 616
 617     local $SIG{__WARN__} = sub { die $_[0] };
 618     eval $proggie;
 619
 620 The routine indicated by $SIG{__DIE__} is called when a fatal exception
 621 is about to be thrown.  The error message is passed as the first
 622 argument.  When a __DIE__ hook routine returns, the exception
 623 processing continues as it would have in the absence of the hook,
 624 unless the hook routine itself exits via a goto, a loop exit, or a die.
 625
 626 =back
 627