pod/perlvar.pod

   1 =head1 NAME
   2
   3 perlvar - Perl predefined variables
   4
   5 =head1 DESCRIPTION
   6
   7 =head2 Predefined Names
   8
   9 The following names have special meaning to Perl.  Most of the
  10 punctuational names have reasonable mnemonics, or analogues in one of
  11 the shells.  Nevertheless, if you wish to use the long variable names,
  12 you just need to say
  13
  14     use English;
  15
  16 at the top of your program.  This will alias all the short names to the
  17 long names in the current package.  Some of them even have medium names,
  18 generally borrowed from B<awk>.
  19
  20 To go a step further, those variables that depend on the currently
  21 selected filehandle may instead be set by calling an object method on
  22 the FileHandle object.  (Summary lines below for this contain the word
  23 HANDLE.)  First you must say
  24
  25     use FileHandle;
  26
  27 after which you may use either
  28
  29     method HANDLE EXPR
  30
  31 or
  32
  33     HANDLE->method(EXPR)
  34
  35 Each of the methods returns the old value of the FileHandle attribute.
  36 The methods each take an optional EXPR, which if supplied specifies the
  37 new value for the FileHandle attribute in question.  If not supplied,
  38 most of the methods do nothing to the current value, except for
  39 autoflush(), which will assume a 1 for you, just to be different.
  40
  41 A few of these variables are considered "read-only".  This means that if
  42 you try to assign to this variable, either directly or indirectly through
  43 a reference, you'll raise a run-time exception.
  44
  45 =over 8
  46
  47 =item $ARG
  48
  49 =item $_
  50
  51 The default input and pattern-searching space.  The following pairs are
  52 equivalent:
  53
  54     while (<>) {...}    # only equivalent in while!
  55     while ($_ = <>) {...}
  56
  57     /^Subject:/
  58     $_ =~ /^Subject:/
  59
  60     tr/a-z/A-Z/
  61     $_ =~ tr/a-z/A-Z/
  62
  63     chop
  64     chop($_)
  65
  66 Here are the places where Perl will assume $_ even if you
  67 don't use it:
  68
  69 =over 3
  70
  71 =item *
  72
  73 Various unary functions, including functions like ord() and int(), as well
  74 as the all file tests (C<-f>, C<-d>) except for C<-t>, which defaults to
  75 STDIN.
  76
  77 =item *
  78
  79 Various list functions like print() and unlink().
  80
  81 =item *
  82
  83 The pattern matching operations C<m//>, C<s///>, and C<tr///> when used
  84 without an C<=~> operator.
  85
  86 =item *
  87
  88 The default iterator variable in a C<foreach> loop if no other
  89 variable is supplied.
  90
  91 =item *
  92
  93 The implicit iterator variable in the grep() and map() functions.
  94
  95 =item *
  96
  97 The default place to put an input record when a C<E<lt>FHE<gt>>
  98 operation's result is tested by itself as the sole criterion of a C<while>
  99 test.  Note that outside of a C<while> test, this will not happen.
 100
 101 =back
 102
 103 (Mnemonic: underline is understood in certain operations.)
 104
 105 =item $<I<digit>>
 106
 107 Contains the subpattern from the corresponding set of parentheses in
 108 the last pattern matched, not counting patterns matched in nested
 109 blocks that have been exited already.  (Mnemonic: like \digit.)
 110 These variables are all read-only.
 111
 112 =item $MATCH
 113
 114 =item $&
 115
 116 The string matched by the last successful pattern match (not counting
 117 any matches hidden within a BLOCK or eval() enclosed by the current
 118 BLOCK).  (Mnemonic: like & in some editors.)  This variable is read-only.
 119
 120 =item $PREMATCH
 121
 122 =item $`
 123
 124 The string preceding whatever was matched by the last successful
 125 pattern match (not counting any matches hidden within a BLOCK or eval
 126 enclosed by the current BLOCK).  (Mnemonic: ` often precedes a quoted
 127 string.)  This variable is read-only.
 128
 129 =item $POSTMATCH
 130
 131 =item $'
 132
 133 The string following whatever was matched by the last successful
 134 pattern match (not counting any matches hidden within a BLOCK or eval()
 135 enclosed by the current BLOCK).  (Mnemonic: ' often follows a quoted
 136 string.)  Example:
 137
 138     $_ = 'abcdefghi';
 139     /def/;
 140     print "$`:$&:$'\n";         # prints abc:def:ghi
 141
 142 This variable is read-only.
 143
 144 =item $LAST_PAREN_MATCH
 145
 146 =item $+
 147
 148 The last bracket matched by the last search pattern.  This is useful if
 149 you don't know which of a set of alternative patterns matched.  For
 150 example:
 151
 152     /Version: (.*)|Revision: (.*)/ && ($rev = $+);
 153
 154 (Mnemonic: be positive and forward looking.)
 155 This variable is read-only.
 156
 157 =item $MULTILINE_MATCHING
 158
 159 =item $*
 160
 161 Set to 1 to do multiline matching within a string, 0 to tell Perl
 162 that it can assume that strings contain a single line, for the purpose
 163 of optimizing pattern matches.  Pattern matches on strings containing
 164 multiple newlines can produce confusing results when "C<$*>" is 0.  Default
 165 is 0.  (Mnemonic: * matches multiple things.)  Note that this variable
 166 only influences the interpretation of "C<^>" and "C<$>".  A literal newline can
 167 be searched for even when C<$* == 0>.
 168
 169 Use of "C<$*>" is deprecated in Perl 5.
 170
 171 =item input_line_number HANDLE EXPR
 172
 173 =item $INPUT_LINE_NUMBER
 174
 175 =item $NR
 176
 177 =item $.
 178
 179 The current input line number of the last filehandle that was read.  An
 180 explicit close on the filehandle resets the line number.  Since
 181 "C<E<lt>E<gt>>" never does an explicit close, line numbers increase
 182 across ARGV files (but see examples under eof()).  Localizing C<$.> has
 183 the effect of also localizing Perl's notion of "the last read
 184 filehandle".  (Mnemonic: many programs use "." to mean the current line
 185 number.)
 186
 187 =item input_record_separator HANDLE EXPR
 188
 189 =item $INPUT_RECORD_SEPARATOR
 190
 191 =item $RS
 192
 193 =item $/
 194
 195 The input record separator, newline by default.  Works like B<awk>'s RS
 196 variable, including treating blank lines as delimiters if set to the
 197 null string.  You may set it to a multicharacter string to match a
 198 multi-character delimiter.  Note that setting it to C<"\n\n"> means
 199 something slightly different than setting it to C<"">, if the file
 200 contains consecutive blank lines.  Setting it to C<""> will treat two or
 201 more consecutive blank lines as a single blank line.  Setting it to
 202 C<"\n\n"> will blindly assume that the next input character belongs to the
 203 next paragraph, even if it's a newline.  (Mnemonic: / is used to
 204 delimit line boundaries when quoting poetry.)
 205
 206     undef $/;
 207     $_ = <FH>;          # whole file now here
 208     s/\n[ \t]+/ /g;
 209
 210 =item autoflush HANDLE EXPR
 211
 212 =item $OUTPUT_AUTOFLUSH
 213
 214 =item $|
 215
 216 If set to nonzero, forces a flush after every write or print on the
 217 currently selected output channel.  Default is 0.  Note that STDOUT
 218 will typically be line buffered if output is to the terminal and block
 219 buffered otherwise.  Setting this variable is useful primarily when you
 220 are outputting to a pipe, such as when you are running a Perl script
 221 under rsh and want to see the output as it's happening.  This has no
 222 effect on input buffering.
 223 (Mnemonic: when you want your pipes to be piping hot.)
 224
 225 =item output_field_separator HANDLE EXPR
 226
 227 =item $OUTPUT_FIELD_SEPARATOR
 228
 229 =item $OFS
 230
 231 =item $,
 232
 233 The output field separator for the print operator.  Ordinarily the
 234 print operator simply prints out the comma separated fields you
 235 specify.  In order to get behavior more like B<awk>, set this variable
 236 as you would set B<awk>'s OFS variable to specify what is printed
 237 between fields.  (Mnemonic: what is printed when there is a , in your
 238 print statement.)
 239
 240 =item output_record_separator HANDLE EXPR
 241
 242 =item $OUTPUT_RECORD_SEPARATOR
 243
 244 =item $ORS
 245
 246 =item $\
 247
 248 The output record separator for the print operator.  Ordinarily the
 249 print operator simply prints out the comma separated fields you
 250 specify, with no trailing newline or record separator assumed.  In
 251 order to get behavior more like B<awk>, set this variable as you would
 252 set B<awk>'s ORS variable to specify what is printed at the end of the
 253 print.  (Mnemonic: you set "C<$\>" instead of adding \n at the end of the
 254 print.  Also, it's just like /, but it's what you get "back" from
 255 Perl.)
 256
 257 =item $LIST_SEPARATOR
 258
 259 =item $"
 260
 261 This is like "C<$,>" except that it applies to array values interpolated
 262 into a double-quoted string (or similar interpreted string).  Default
 263 is a space.  (Mnemonic: obvious, I think.)
 264
 265 =item $SUBSCRIPT_SEPARATOR
 266
 267 =item $SUBSEP
 268
 269 =item $;
 270
 271 The subscript separator for multi-dimensional array emulation.  If you
 272 refer to a hash element as
 273
 274     $foo{$a,$b,$c}
 275
 276 it really means
 277
 278     $foo{join($;, $a, $b, $c)}
 279
 280 But don't put
 281
 282     @foo{$a,$b,$c}      # a slice--note the @
 283
 284 which means
 285
 286     ($foo{$a},$foo{$b},$foo{$c})
 287
 288 Default is "\034", the same as SUBSEP in B<awk>.  Note that if your
 289 keys contain binary data there might not be any safe value for "C<$;>".
 290 (Mnemonic: comma (the syntactic subscript separator) is a
 291 semi-semicolon.  Yeah, I know, it's pretty lame, but "C<$,>" is already
 292 taken for something more important.)
 293
 294 Consider using "real" multi-dimensional arrays in Perl 5.
 295
 296 =item $OFMT
 297
 298 =item $#
 299
 300 The output format for printed numbers.  This variable is a half-hearted
 301 attempt to emulate B<awk>'s OFMT variable.  There are times, however,
 302 when B<awk> and Perl have differing notions of what is in fact
 303 numeric.  Also, the initial value is %.20g rather than %.6g, so you
 304 need to set "C<$#>" explicitly to get B<awk>'s value.  (Mnemonic: # is the
 305 number sign.)
 306
 307 Use of "C<$#>" is deprecated in Perl 5.
 308
 309 =item format_page_number HANDLE EXPR
 310
 311 =item $FORMAT_PAGE_NUMBER
 312
 313 =item $%
 314
 315 The current page number of the currently selected output channel.
 316 (Mnemonic: % is page number in B<nroff>.)
 317
 318 =item format_lines_per_page HANDLE EXPR
 319
 320 =item $FORMAT_LINES_PER_PAGE
 321
 322 =item $=
 323
 324 The current page length (printable lines) of the currently selected
 325 output channel.  Default is 60.  (Mnemonic: = has horizontal lines.)
 326
 327 =item format_lines_left HANDLE EXPR
 328
 329 =item $FORMAT_LINES_LEFT
 330
 331 =item $-
 332
 333 The number of lines left on the page of the currently selected output
 334 channel.  (Mnemonic: lines_on_page - lines_printed.)
 335
 336 =item format_name HANDLE EXPR
 337
 338 =item $FORMAT_NAME
 339
 340 =item $~
 341
 342 The name of the current report format for the currently selected output
 343 channel.  Default is name of the filehandle.  (Mnemonic: brother to
 344 "C<$^>".)
 345
 346 =item format_top_name HANDLE EXPR
 347
 348 =item $FORMAT_TOP_NAME
 349
 350 =item $^
 351
 352 The name of the current top-of-page format for the currently selected
 353 output channel.  Default is name of the filehandle with _TOP
 354 appended.  (Mnemonic: points to top of page.)
 355
 356 =item format_line_break_characters HANDLE EXPR
 357
 358 =item $FORMAT_LINE_BREAK_CHARACTERS
 359
 360 =item $:
 361
 362 The current set of characters after which a string may be broken to
 363 fill continuation fields (starting with ^) in a format.  Default is
 364 S<" \n-">, to break on whitespace or hyphens.  (Mnemonic: a "colon" in
 365 poetry is a part of a line.)
 366
 367 =item format_formfeed HANDLE EXPR
 368
 369 =item $FORMAT_FORMFEED
 370
 371 =item $^L
 372
 373 What formats output to perform a formfeed.  Default is \f.
 374
 375 =item $ACCUMULATOR
 376
 377 =item $^A
 378
 379 The current value of the write() accumulator for format() lines.  A format
 380 contains formline() commands that put their result into C<$^A>.  After
 381 calling its format, write() prints out the contents of C<$^A> and empties.
 382 So you never actually see the contents of C<$^A> unless you call
 383 formline() yourself and then look at it.  See L<perlform> and
 384 L<perlfunc/formline()>.
 385
 386 =item $CHILD_ERROR
 387
 388 =item $?
 389
 390 The status returned by the last pipe close, backtick (C<``>) command,
 391 or system() operator.  Note that this is the status word returned by
 392 the wait() system call, so the exit value of the subprocess is actually
 393 (C<$? E<gt>E<gt> 8>).  Thus on many systems, C<$? & 255> gives which signal,
 394 if any, the process died from, and whether there was a core dump.
 395 (Mnemonic: similar to B<sh> and B<ksh>.)
 396
 397 =item $OS_ERROR
 398
 399 =item $ERRNO
 400
 401 =item $!
 402
 403 If used in a numeric context, yields the current value of errno, with
 404 all the usual caveats.  (This means that you shouldn't depend on the
 405 value of "C<$!>" to be anything in particular unless you've gotten a
 406 specific error return indicating a system error.)  If used in a string
 407 context, yields the corresponding system error string.  You can assign
 408 to "C<$!>" in order to set I<errno> if, for instance, you want "C<$!>" to return the
 409 string for error I<n>, or you want to set the exit value for the die()
 410 operator.  (Mnemonic: What just went bang?)
 411
 412 =item $EXTENDED_OS_ERROR
 413
 414 =item $^E
 415
 416 More specific information about the last system error than that
 417 provided by C<$!>, if available.  (If not, it's just C<$!> again.)
 418 At the moment, this differs from C<$!> only under VMS, where it
 419 provides the VMS status value from the last system error.  The
 420 caveats mentioned in the description of C<$!> apply here, too.
 421 (Mnemonic: Extra error explanation.)
 422
 423
 424 =item $EVAL_ERROR
 425
 426 =item $@
 427
 428 The Perl syntax error message from the last eval() command.  If null, the
 429 last eval() parsed and executed correctly (although the operations you
 430 invoked may have failed in the normal fashion).  (Mnemonic: Where was
 431 the syntax error "at"?)
 432
 433 Note that warning messages are not collected in this variable.  You can,
 434 however, set up a routine to process warnings by setting $SIG{__WARN__} below.
 435
 436 =item $PROCESS_ID
 437
 438 =item $PID
 439
 440 =item $$
 441
 442 The process number of the Perl running this script.  (Mnemonic: same
 443 as shells.)
 444
 445 =item $REAL_USER_ID
 446
 447 =item $UID
 448
 449 =item $<
 450
 451 The real uid of this process.  (Mnemonic: it's the uid you came I<FROM>,
 452 if you're running setuid.)
 453
 454 =item $EFFECTIVE_USER_ID
 455
 456 =item $EUID
 457
 458 =item $>
 459
 460 The effective uid of this process.  Example:
 461
 462     $< = $>;            # set real to effective uid
 463     ($<,$>) = ($>,$<);  # swap real and effective uid
 464
 465 (Mnemonic: it's the uid you went I<TO>, if you're running setuid.)  Note:
 466 "C<$E<lt>>" and "C<$E<gt>>" can only be swapped on machines supporting setreuid().
 467
 468 =item $REAL_GROUP_ID
 469
 470 =item $GID
 471
 472 =item $(
 473
 474 The real gid of this process.  If you are on a machine that supports
 475 membership in multiple groups simultaneously, gives a space separated
 476 list of groups you are in.  The first number is the one returned by
 477 getgid(), and the subsequent ones by getgroups(), one of which may be
 478 the same as the first number.  (Mnemonic: parentheses are used to I<GROUP>
 479 things.  The real gid is the group you I<LEFT>, if you're running setgid.)
 480
 481 =item $EFFECTIVE_GROUP_ID
 482
 483 =item $EGID
 484
 485 =item $)
 486
 487 The effective gid of this process.  If you are on a machine that
 488 supports membership in multiple groups simultaneously, gives a space
 489 separated list of groups you are in.  The first number is the one
 490 returned by getegid(), and the subsequent ones by getgroups(), one of
 491 which may be the same as the first number.  (Mnemonic: parentheses are
 492 used to I<GROUP> things.  The effective gid is the group that's I<RIGHT> for
 493 you, if you're running setgid.)
 494
 495 Note: "C<$E<lt>>", "C<$E<gt>>", "C<$(>" and "C<$)>" can only be set on machines
 496 that support the corresponding I<set[re][ug]id()> routine.  "C<$(>" and "C<$)>"
 497 can only be swapped on machines supporting setregid().   Because Perl doesn't
 498 currently use initgroups(), you can't set your group vector to multiple groups.
 499
 500 =item $PROGRAM_NAME
 501
 502 =item $0
 503
 504 Contains the name of the file containing the Perl script being
 505 executed.  Assigning to "C<$0>" modifies the argument area that the ps(1)
 506 program sees.  This is more useful as a way of indicating the
 507 current program state than it is for hiding the program you're running.
 508 (Mnemonic: same as B<sh> and B<ksh>.)
 509
 510 =item $[
 511
 512 The index of the first element in an array, and of the first character
 513 in a substring.  Default is 0, but you could set it to 1 to make
 514 Perl behave more like B<awk> (or Fortran) when subscripting and when
 515 evaluating the index() and substr() functions.  (Mnemonic: [ begins
 516 subscripts.)
 517
 518 As of Perl 5, assignment to "C<$[>" is treated as a compiler directive,
 519 and cannot influence the behavior of any other file.  Its use is
 520 discouraged.
 521
 522 =item $PERL_VERSION
 523
 524 =item $]
 525
 526 The string printed out when you say C<perl -v>.
 527 (This is currently I<BROKEN>).
 528 It can be used to
 529 determine at the beginning of a script whether the perl interpreter
 530 executing the script is in the right range of versions.  If used in a
 531 numeric context, returns the version + patchlevel / 1000.  Example:
 532
 533     # see if getc is available
 534     ($version,$patchlevel) =
 535              $] =~ /(\d+\.\d+).*\nPatch level: (\d+)/;
 536     print STDERR "(No filename completion available.)\n"
 537              if $version * 1000 + $patchlevel < 2016;
 538
 539 or, used numerically,
 540
 541     warn "No checksumming!\n" if $] < 3.019;
 542
 543 (Mnemonic: Is this version of perl in the right bracket?)
 544
 545 =item $DEBUGGING
 546
 547 =item $^D
 548
 549 The current value of the debugging flags.  (Mnemonic: value of B<-D>
 550 switch.)
 551
 552 =item $SYSTEM_FD_MAX
 553
 554 =item $^F
 555
 556 The maximum system file descriptor, ordinarily 2.  System file
 557 descriptors are passed to exec()ed processes, while higher file
 558 descriptors are not.  Also, during an open(), system file descriptors are
 559 preserved even if the open() fails.  (Ordinary file descriptors are
 560 closed before the open() is attempted.)  Note that the close-on-exec
 561 status of a file descriptor will be decided according to the value of
 562 C<$^F> at the time of the open, not the time of the exec.
 563
 564 =item $INPLACE_EDIT
 565
 566 =item $^I
 567
 568 The current value of the inplace-edit extension.  Use C<undef> to disable
 569 inplace editing.  (Mnemonic: value of B<-i> switch.)
 570
 571 =item $OSNAME
 572 =item $^O
 573
 574 The name of the operating system under which this copy of Perl was
 575 built, as determined during the configuration process.  The value
 576 is identical to C<$Config{'osname'}>.
 577
 578 =item $PERLDB
 579
 580 =item $^P
 581
 582 The internal flag that the debugger clears so that it doesn't debug
 583 itself.  You could conceivably disable debugging yourself by clearing
 584 it.
 585
 586 =item $BASETIME
 587
 588 =item $^T
 589
 590 The time at which the script began running, in seconds since the
 591 epoch (beginning of 1970).  The values returned by the B<-M>, B<-A>
 592 and B<-C> filetests are
 593 based on this value.
 594
 595 =item $WARNING
 596
 597 =item $^W
 598
 599 The current value of the warning switch, either TRUE or FALSE.  (Mnemonic: related to the
 600 B<-w> switch.)
 601
 602 =item $EXECUTABLE_NAME
 603
 604 =item $^X
 605
 606 The name that the Perl binary itself was executed as, from C's C<argv[0]>.
 607
 608 =item $ARGV
 609
 610 contains the name of the current file when reading from <>.
 611
 612 =item @ARGV
 613
 614 The array @ARGV contains the command line arguments intended for the
 615 script.  Note that C<$#ARGV> is the generally number of arguments minus
 616 one, since C<$ARGV[0]> is the first argument, I<NOT> the command name.  See
 617 "C<$0>" for the command name.
 618
 619 =item @INC
 620
 621 The array @INC contains the list of places to look for Perl scripts to
 622 be evaluated by the C<do EXPR>, C<require>, or C<use> constructs.  It
 623 initially consists of the arguments to any B<-I> command line switches,
 624 followed by the default Perl library, probably "/usr/local/lib/perl",
 625 followed by ".", to represent the current directory.  If you need to
 626 modify this at runtime, you should use the C<use lib> pragma in order
 627 to also get the machine-dependent library properly loaded:
 628
 629     use lib '/mypath/libdir/';
 630     use SomeMod;
 631
 632 =item %INC
 633
 634 The hash %INC contains entries for each filename that has
 635 been included via C<do> or C<require>.  The key is the filename you
 636 specified, and the value is the location of the file actually found.
 637 The C<require> command uses this array to determine whether a given file
 638 has already been included.
 639
 640 =item $ENV{expr}
 641
 642 The hash %ENV contains your current environment.  Setting a
 643 value in C<ENV> changes the environment for child processes.
 644
 645 =item $SIG{expr}
 646
 647 The hash %SIG is used to set signal handlers for various
 648 signals.  Example:
 649
 650     sub handler {       # 1st argument is signal name
 651         local($sig) = @_;
 652         print "Caught a SIG$sig--shutting down\n";
 653         close(LOG);
 654         exit(0);
 655     }
 656
 657     $SIG{'INT'} = 'handler';
 658     $SIG{'QUIT'} = 'handler';
 659     ...
 660     $SIG{'INT'} = 'DEFAULT';    # restore default action
 661     $SIG{'QUIT'} = 'IGNORE';    # ignore SIGQUIT
 662
 663 The %SIG array only contains values for the signals actually set within
 664 the Perl script.  Here are some other examples:
 665
 666     $SIG{PIPE} = Plumber;       # SCARY!!
 667     $SIG{"PIPE"} = "Plumber";   # just fine, assumes main::Plumber
 668     $SIG{"PIPE"} = \&Plumber;   # just fine; assume current Plumber
 669     $SIG{"PIPE"} = Plumber();   # oops, what did Plumber() return??
 670
 671 The one marked scary is problematic because it's a bareword, which means
 672 sometimes it's a string representing the function, and sometimes it's
 673 going to call the subroutine call right then and there!  Best to be sure
 674 and quote it or take a reference to it.  *Plumber works too.  See L<perlsubs>.
 675
 676 Certain internal hooks can be also set using the %SIG hash.  The
 677 routine indicated by $SIG{__WARN__} is called when a warning message is
 678 about to be printed.  The warning message is passed as the first
 679 argument.  The presence of a __WARN__ hook causes the ordinary printing
 680 of warnings to STDERR to be suppressed.  You can use this to save warnings
 681 in a variable, or turn warnings into fatal errors, like this:
 682
 683     local $SIG{__WARN__} = sub { die $_[0] };
 684     eval $proggie;
 685
 686 The routine indicated by $SIG{__DIE__} is called when a fatal exception
 687 is about to be thrown.  The error message is passed as the first
 688 argument.  When a __DIE__ hook routine returns, the exception
 689 processing continues as it would have in the absence of the hook,
 690 unless the hook routine itself exits via a C<goto>, a loop exit, or a die().
 691 The __DIE__ handler is explicitly disabled during the call, so that you
 692 can die from a __DIE__ handler.  Similarly for __WARN__.
 693
 694 =back
 695