pod/perlvar.pod

   1 =head1 NAME
   2
   3 perlvar - Perl predefined variables
   4
   5 =head1 DESCRIPTION
   6
   7 =head2 Predefined Names
   8
   9 The following names have special meaning to Perl.  Most of the
  10 punctuation names have reasonable mnemonics, or analogues in one of
  11 the shells.  Nevertheless, if you wish to use the long variable names,
  12 you just need to say
  13
  14     use English;
  15
  16 at the top of your program.  This will alias all the short names to the
  17 long names in the current package.  Some of them even have medium names,
  18 generally borrowed from B<awk>.
  19
  20 To go a step further, those variables that depend on the currently
  21 selected filehandle may instead be set by calling an object method on
  22 the FileHandle object.  (Summary lines below for this contain the word
  23 HANDLE.)  First you must say
  24
  25     use FileHandle;
  26
  27 after which you may use either
  28
  29     method HANDLE EXPR
  30
  31 or
  32
  33     HANDLE->method(EXPR)
  34
  35 Each of the methods returns the old value of the FileHandle attribute.
  36 The methods each take an optional EXPR, which if supplied specifies the
  37 new value for the FileHandle attribute in question.  If not supplied,
  38 most of the methods do nothing to the current value, except for
  39 autoflush(), which will assume a 1 for you, just to be different.
  40
  41 A few of these variables are considered "read-only".  This means that if
  42 you try to assign to this variable, either directly or indirectly through
  43 a reference, you'll raise a run-time exception.
  44
  45 =over 8
  46
  47 =item $ARG
  48
  49 =item $_
  50
  51 The default input and pattern-searching space.  The following pairs are
  52 equivalent:
  53
  54     while (<>) {...}    # equivalent in only while!
  55     while (defined($_ = <>)) {...}
  56
  57     /^Subject:/
  58     $_ =~ /^Subject:/
  59
  60     tr/a-z/A-Z/
  61     $_ =~ tr/a-z/A-Z/
  62
  63     chop
  64     chop($_)
  65
  66 Here are the places where Perl will assume $_ even if you
  67 don't use it:
  68
  69 =over 3
  70
  71 =item *
  72
  73 Various unary functions, including functions like ord() and int(), as well
  74 as the all file tests (C<-f>, C<-d>) except for C<-t>, which defaults to
  75 STDIN.
  76
  77 =item *
  78
  79 Various list functions like print() and unlink().
  80
  81 =item *
  82
  83 The pattern matching operations C<m//>, C<s///>, and C<tr///> when used
  84 without an C<=~> operator.
  85
  86 =item *
  87
  88 The default iterator variable in a C<foreach> loop if no other
  89 variable is supplied.
  90
  91 =item *
  92
  93 The implicit iterator variable in the grep() and map() functions.
  94
  95 =item *
  96
  97 The default place to put an input record when a C<E<lt>FHE<gt>>
  98 operation's result is tested by itself as the sole criterion of a C<while>
  99 test.  Note that outside of a C<while> test, this will not happen.
 100
 101 =back
 102
 103 (Mnemonic: underline is understood in certain operations.)
 104
 105 =back
 106
 107 =over 8
 108
 109 =item $E<lt>I<digit>E<gt>
 110
 111 Contains the subpattern from the corresponding set of parentheses in
 112 the last pattern matched, not counting patterns matched in nested
 113 blocks that have been exited already.  (Mnemonic: like \digit.)
 114 These variables are all read-only.
 115
 116 =item $MATCH
 117
 118 =item $&
 119
 120 The string matched by the last successful pattern match (not counting
 121 any matches hidden within a BLOCK or eval() enclosed by the current
 122 BLOCK).  (Mnemonic: like & in some editors.)  This variable is read-only.
 123
 124 =item $PREMATCH
 125
 126 =item $`
 127
 128 The string preceding whatever was matched by the last successful
 129 pattern match (not counting any matches hidden within a BLOCK or eval
 130 enclosed by the current BLOCK).  (Mnemonic: C<`> often precedes a quoted
 131 string.)  This variable is read-only.
 132
 133 =item $POSTMATCH
 134
 135 =item $'
 136
 137 The string following whatever was matched by the last successful
 138 pattern match (not counting any matches hidden within a BLOCK or eval()
 139 enclosed by the current BLOCK).  (Mnemonic: C<'> often follows a quoted
 140 string.)  Example:
 141
 142     $_ = 'abcdefghi';
 143     /def/;
 144     print "$`:$&:$'\n";         # prints abc:def:ghi
 145
 146 This variable is read-only.
 147
 148 =item $LAST_PAREN_MATCH
 149
 150 =item $+
 151
 152 The last bracket matched by the last search pattern.  This is useful if
 153 you don't know which of a set of alternative patterns matched.  For
 154 example:
 155
 156     /Version: (.*)|Revision: (.*)/ && ($rev = $+);
 157
 158 (Mnemonic: be positive and forward looking.)
 159 This variable is read-only.
 160
 161 =item $MULTILINE_MATCHING
 162
 163 =item $*
 164
 165 Set to 1 to do multi-line matching within a string, 0 to tell Perl
 166 that it can assume that strings contain a single line, for the purpose
 167 of optimizing pattern matches.  Pattern matches on strings containing
 168 multiple newlines can produce confusing results when "C<$*>" is 0.  Default
 169 is 0.  (Mnemonic: * matches multiple things.)  Note that this variable
 170 influences the interpretation of only "C<^>" and "C<$>".  A literal newline can
 171 be searched for even when C<$* == 0>.
 172
 173 Use of "C<$*>" is deprecated in modern perls.
 174
 175 =item input_line_number HANDLE EXPR
 176
 177 =item $INPUT_LINE_NUMBER
 178
 179 =item $NR
 180
 181 =item $.
 182
 183 The current input line number for the last file handle from
 184 which you read (or performed a C<seek> or C<tell> on).  An
 185 explicit close on a filehandle resets the line number.  Because
 186 "C<E<lt>E<gt>>" never does an explicit close, line numbers increase
 187 across ARGV files (but see examples under eof()).  Localizing C<$.> has
 188 the effect of also localizing Perl's notion of "the last read
 189 filehandle".  (Mnemonic: many programs use "." to mean the current line
 190 number.)
 191
 192 =item input_record_separator HANDLE EXPR
 193
 194 =item $INPUT_RECORD_SEPARATOR
 195
 196 =item $RS
 197
 198 =item $/
 199
 200 The input record separator, newline by default.  Works like B<awk>'s RS
 201 variable, including treating empty lines as delimiters if set to the
 202 null string.  (Note: An empty line cannot contain any spaces or tabs.)
 203 You may set it to a multi-character string to match a multi-character
 204 delimiter, or to C<undef> to read to end of file.  Note that setting it
 205 to C<"\n\n"> means something slightly different than setting it to
 206 C<"">, if the file contains consecutive empty lines.  Setting it to
 207 C<""> will treat two or more consecutive empty lines as a single empty
 208 line.  Setting it to C<"\n\n"> will blindly assume that the next input
 209 character belongs to the next paragraph, even if it's a newline.
 210 (Mnemonic: / is used to delimit line boundaries when quoting poetry.)
 211
 212     undef $/;
 213     $_ = <FH>;          # whole file now here
 214     s/\n[ \t]+/ /g;
 215
 216 Remember: the value of $/ is a string, not a regexp.  AWK has to be
 217 better for something :-)
 218
 219 =item autoflush HANDLE EXPR
 220
 221 =item $OUTPUT_AUTOFLUSH
 222
 223 =item $|
 224
 225 If set to nonzero, forces a flush right away and after every write or print on the
 226 currently selected output channel.  Default is 0 (regardless of whether
 227 the channel is actually buffered by the system or not; C<$|> tells you
 228 only whether you've asked Perl explicitly to flush after each write).
 229 Note that STDOUT will typically be line buffered if output is to the
 230 terminal and block buffered otherwise.  Setting this variable is useful
 231 primarily when you are outputting to a pipe, such as when you are running
 232 a Perl script under rsh and want to see the output as it's happening.  This
 233 has no effect on input buffering.
 234 (Mnemonic: when you want your pipes to be piping hot.)
 235
 236 =item output_field_separator HANDLE EXPR
 237
 238 =item $OUTPUT_FIELD_SEPARATOR
 239
 240 =item $OFS
 241
 242 =item $,
 243
 244 The output field separator for the print operator.  Ordinarily the
 245 print operator simply prints out the comma-separated fields you
 246 specify.  To get behavior more like B<awk>, set this variable
 247 as you would set B<awk>'s OFS variable to specify what is printed
 248 between fields.  (Mnemonic: what is printed when there is a , in your
 249 print statement.)
 250
 251 =item output_record_separator HANDLE EXPR
 252
 253 =item $OUTPUT_RECORD_SEPARATOR
 254
 255 =item $ORS
 256
 257 =item $\
 258
 259 The output record separator for the print operator.  Ordinarily the
 260 print operator simply prints out the comma-separated fields you
 261 specify, with no trailing newline or record separator assumed.
 262 To get behavior more like B<awk>, set this variable as you would
 263 set B<awk>'s ORS variable to specify what is printed at the end of the
 264 print.  (Mnemonic: you set "C<$\>" instead of adding \n at the end of the
 265 print.  Also, it's just like C<$/>, but it's what you get "back" from
 266 Perl.)
 267
 268 =item $LIST_SEPARATOR
 269
 270 =item $"
 271
 272 This is like "C<$,>" except that it applies to array values interpolated
 273 into a double-quoted string (or similar interpreted string).  Default
 274 is a space.  (Mnemonic: obvious, I think.)
 275
 276 =item $SUBSCRIPT_SEPARATOR
 277
 278 =item $SUBSEP
 279
 280 =item $;
 281
 282 The subscript separator for multidimensional array emulation.  If you
 283 refer to a hash element as
 284
 285     $foo{$a,$b,$c}
 286
 287 it really means
 288
 289     $foo{join($;, $a, $b, $c)}
 290
 291 But don't put
 292
 293     @foo{$a,$b,$c}      # a slice--note the @
 294
 295 which means
 296
 297     ($foo{$a},$foo{$b},$foo{$c})
 298
 299 Default is "\034", the same as SUBSEP in B<awk>.  Note that if your
 300 keys contain binary data there might not be any safe value for "C<$;>".
 301 (Mnemonic: comma (the syntactic subscript separator) is a
 302 semi-semicolon.  Yeah, I know, it's pretty lame, but "C<$,>" is already
 303 taken for something more important.)
 304
 305 Consider using "real" multidimensional arrays.
 306
 307 =item $OFMT
 308
 309 =item $#
 310
 311 The output format for printed numbers.  This variable is a half-hearted
 312 attempt to emulate B<awk>'s OFMT variable.  There are times, however,
 313 when B<awk> and Perl have differing notions of what is in fact
 314 numeric.  The initial value is %.I<n>g, where I<n> is the value
 315 of the macro DBL_DIG from your system's F<float.h>.  This is different from
 316 B<awk>'s default OFMT setting of %.6g, so you need to set "C<$#>"
 317 explicitly to get B<awk>'s value.  (Mnemonic: # is the number sign.)
 318
 319 Use of "C<$#>" is deprecated.
 320
 321 =item format_page_number HANDLE EXPR
 322
 323 =item $FORMAT_PAGE_NUMBER
 324
 325 =item $%
 326
 327 The current page number of the currently selected output channel.
 328 (Mnemonic: % is page number in B<nroff>.)
 329
 330 =item format_lines_per_page HANDLE EXPR
 331
 332 =item $FORMAT_LINES_PER_PAGE
 333
 334 =item $=
 335
 336 The current page length (printable lines) of the currently selected
 337 output channel.  Default is 60.  (Mnemonic: = has horizontal lines.)
 338
 339 =item format_lines_left HANDLE EXPR
 340
 341 =item $FORMAT_LINES_LEFT
 342
 343 =item $-
 344
 345 The number of lines left on the page of the currently selected output
 346 channel.  (Mnemonic: lines_on_page - lines_printed.)
 347
 348 =item format_name HANDLE EXPR
 349
 350 =item $FORMAT_NAME
 351
 352 =item $~
 353
 354 The name of the current report format for the currently selected output
 355 channel.  Default is name of the filehandle.  (Mnemonic: brother to
 356 "C<$^>".)
 357
 358 =item format_top_name HANDLE EXPR
 359
 360 =item $FORMAT_TOP_NAME
 361
 362 =item $^
 363
 364 The name of the current top-of-page format for the currently selected
 365 output channel.  Default is name of the filehandle with _TOP
 366 appended.  (Mnemonic: points to top of page.)
 367
 368 =item format_line_break_characters HANDLE EXPR
 369
 370 =item $FORMAT_LINE_BREAK_CHARACTERS
 371
 372 =item $:
 373
 374 The current set of characters after which a string may be broken to
 375 fill continuation fields (starting with ^) in a format.  Default is
 376 S<" \n-">, to break on whitespace or hyphens.  (Mnemonic: a "colon" in
 377 poetry is a part of a line.)
 378
 379 =item format_formfeed HANDLE EXPR
 380
 381 =item $FORMAT_FORMFEED
 382
 383 =item $^L
 384
 385 What formats output to perform a form feed.  Default is \f.
 386
 387 =item $ACCUMULATOR
 388
 389 =item $^A
 390
 391 The current value of the write() accumulator for format() lines.  A format
 392 contains formline() commands that put their result into C<$^A>.  After
 393 calling its format, write() prints out the contents of C<$^A> and empties.
 394 So you never actually see the contents of C<$^A> unless you call
 395 formline() yourself and then look at it.  See L<perlform> and
 396 L<perlfunc/formline()>.
 397
 398 =item $CHILD_ERROR
 399
 400 =item $?
 401
 402 The status returned by the last pipe close, backtick (C<``>) command,
 403 or system() operator.  Note that this is the status word returned by
 404 the wait() system call (or else is made up to look like it).  Thus,
 405 the exit value of the subprocess is actually (C<$? E<gt>E<gt> 8>), and
 406 C<$? & 255> gives which signal, if any, the process died from, and
 407 whether there was a core dump.  (Mnemonic: similar to B<sh> and
 408 B<ksh>.)
 409
 410 Note that if you have installed a signal handler for C<SIGCHLD>, the
 411 value of C<$?> will usually be wrong outside that handler.
 412
 413 Inside an C<END> subroutine C<$?> contains the value that is going to be
 414 given to C<exit()>.  You can modify C<$?> in an C<END> subroutine to
 415 change the exit status of the script.
 416
 417 Under VMS, the pragma C<use vmsish 'status'> makes C<$?> reflect the
 418 actual VMS exit status, instead of the default emulation of POSIX
 419 status.
 420
 421 =item $OS_ERROR
 422
 423 =item $ERRNO
 424
 425 =item $!
 426
 427 If used in a numeric context, yields the current value of errno, with
 428 all the usual caveats.  (This means that you shouldn't depend on the
 429 value of "C<$!>" to be anything in particular unless you've gotten a
 430 specific error return indicating a system error.)  If used in a string
 431 context, yields the corresponding system error string.  You can assign
 432 to "C<$!>" to set I<errno> if, for instance, you want "C<$!>" to return the
 433 string for error I<n>, or you want to set the exit value for the die()
 434 operator.  (Mnemonic: What just went bang?)
 435
 436 =item $EXTENDED_OS_ERROR
 437
 438 =item $^E
 439
 440 More specific information about the last system error than that provided by
 441 C<$!>, if available.  (If not, it's just C<$!> again, except under OS/2.)
 442 At the moment, this differs from C<$!> under only VMS and OS/2, where it
 443 provides the VMS status value from the last system error, and OS/2 error
 444 code of the last call to OS/2 API which was not directed via CRT.  The
 445 caveats mentioned in the description of C<$!> apply here, too.
 446 (Mnemonic: Extra error explanation.)
 447
 448 Note that under OS/2 C<$!> and C<$^E> do not track each other, so if an
 449 OS/2-specific call is performed, you may need to check both.
 450
 451 =item $EVAL_ERROR
 452
 453 =item $@
 454
 455 The Perl syntax error message from the last eval() command.  If null, the
 456 last eval() parsed and executed correctly (although the operations you
 457 invoked may have failed in the normal fashion).  (Mnemonic: Where was
 458 the syntax error "at"?)
 459
 460 Note that warning messages are not collected in this variable.  You can,
 461 however, set up a routine to process warnings by setting C<$SIG{__WARN__}>
 462 as described below.
 463
 464 =item $PROCESS_ID
 465
 466 =item $PID
 467
 468 =item $$
 469
 470 The process number of the Perl running this script.  (Mnemonic: same
 471 as shells.)
 472
 473 =item $REAL_USER_ID
 474
 475 =item $UID
 476
 477 =item $<
 478
 479 The real uid of this process.  (Mnemonic: it's the uid you came I<FROM>,
 480 if you're running setuid.)
 481
 482 =item $EFFECTIVE_USER_ID
 483
 484 =item $EUID
 485
 486 =item $>
 487
 488 The effective uid of this process.  Example:
 489
 490     $< = $>;            # set real to effective uid
 491     ($<,$>) = ($>,$<);  # swap real and effective uid
 492
 493 (Mnemonic: it's the uid you went I<TO>, if you're running setuid.)
 494 Note: "C<$E<lt>>" and "C<$E<gt>>" can be swapped only on machines
 495 supporting setreuid().
 496
 497 =item $REAL_GROUP_ID
 498
 499 =item $GID
 500
 501 =item $(
 502
 503 The real gid of this process.  If you are on a machine that supports
 504 membership in multiple groups simultaneously, gives a space separated
 505 list of groups you are in.  The first number is the one returned by
 506 getgid(), and the subsequent ones by getgroups(), one of which may be
 507 the same as the first number.
 508
 509 However, a value assigned to "C<$(>" must be a single number used to
 510 set the real gid.  So the value given by "C<$(>" should I<not> be assigned
 511 back to "C<$(>" without being forced numeric, such as by adding zero.
 512
 513 (Mnemonic: parentheses are used to I<GROUP> things.  The real gid is the
 514 group you I<LEFT>, if you're running setgid.)
 515
 516 =item $EFFECTIVE_GROUP_ID
 517
 518 =item $EGID
 519
 520 =item $)
 521
 522 The effective gid of this process.  If you are on a machine that
 523 supports membership in multiple groups simultaneously, gives a space
 524 separated list of groups you are in.  The first number is the one
 525 returned by getegid(), and the subsequent ones by getgroups(), one of
 526 which may be the same as the first number.
 527
 528 Similarly, a value assigned to "C<$)>" must also be a space-separated
 529 list of numbers.  The first number is used to set the effective gid, and
 530 the rest (if any) are passed to setgroups().  To get the effect of an
 531 empty list for setgroups(), just repeat the new effective gid; that is,
 532 to force an effective gid of 5 and an effectively empty setgroups()
 533 list, say C< $) = "5 5" >.
 534
 535 (Mnemonic: parentheses are used to I<GROUP> things.  The effective gid
 536 is the group that's I<RIGHT> for you, if you're running setgid.)
 537
 538 Note: "C<$E<lt>>", "C<$E<gt>>", "C<$(>" and "C<$)>" can be set only on
 539 machines that support the corresponding I<set[re][ug]id()> routine.  "C<$(>"
 540 and "C<$)>" can be swapped only on machines supporting setregid().
 541
 542 =item $PROGRAM_NAME
 543
 544 =item $0
 545
 546 Contains the name of the file containing the Perl script being
 547 executed.  On some operating systems
 548 assigning to "C<$0>" modifies the argument area that the ps(1)
 549 program sees.  This is more useful as a way of indicating the
 550 current program state than it is for hiding the program you're running.
 551 (Mnemonic: same as B<sh> and B<ksh>.)
 552
 553 =item $[
 554
 555 The index of the first element in an array, and of the first character
 556 in a substring.  Default is 0, but you could set it to 1 to make
 557 Perl behave more like B<awk> (or Fortran) when subscripting and when
 558 evaluating the index() and substr() functions.  (Mnemonic: [ begins
 559 subscripts.)
 560
 561 As of Perl 5, assignment to "C<$[>" is treated as a compiler directive,
 562 and cannot influence the behavior of any other file.  Its use is
 563 discouraged.
 564
 565 =item $PERL_VERSION
 566
 567 =item $]
 568
 569 The version + patchlevel / 1000 of the Perl interpreter.  This variable
 570 can be used to determine whether the Perl interpreter executing a
 571 script is in the right range of versions.  (Mnemonic: Is this version
 572 of perl in the right bracket?)  Example:
 573
 574     warn "No checksumming!\n" if $] < 3.019;
 575
 576 See also the documentation of C<use VERSION> and C<require VERSION>
 577 for a convenient way to fail if the Perl interpreter is too old.
 578
 579 =item $DEBUGGING
 580
 581 =item $^D
 582
 583 The current value of the debugging flags.  (Mnemonic: value of B<-D>
 584 switch.)
 585
 586 =item $SYSTEM_FD_MAX
 587
 588 =item $^F
 589
 590 The maximum system file descriptor, ordinarily 2.  System file
 591 descriptors are passed to exec()ed processes, while higher file
 592 descriptors are not.  Also, during an open(), system file descriptors are
 593 preserved even if the open() fails.  (Ordinary file descriptors are
 594 closed before the open() is attempted.)  Note that the close-on-exec
 595 status of a file descriptor will be decided according to the value of
 596 C<$^F> at the time of the open, not the time of the exec.
 597
 598 =item $^H
 599
 600 The current set of syntax checks enabled by C<use strict>.  See the
 601 documentation of C<strict> for more details.
 602
 603 =item $INPLACE_EDIT
 604
 605 =item $^I
 606
 607 The current value of the inplace-edit extension.  Use C<undef> to disable
 608 inplace editing.  (Mnemonic: value of B<-i> switch.)
 609
 610 =item $OSNAME
 611
 612 =item $^O
 613
 614 The name of the operating system under which this copy of Perl was
 615 built, as determined during the configuration process.  The value
 616 is identical to C<$Config{'osname'}>.
 617
 618 =item $PERLDB
 619
 620 =item $^P
 621
 622 The internal flag that the debugger clears so that it doesn't debug
 623 itself.  You could conceivably disable debugging yourself by clearing
 624 it.
 625
 626 =item $BASETIME
 627
 628 =item $^T
 629
 630 The time at which the script began running, in seconds since the
 631 epoch (beginning of 1970).  The values returned by the B<-M>, B<-A>,
 632 and B<-C> filetests are
 633 based on this value.
 634
 635 =item $WARNING
 636
 637 =item $^W
 638
 639 The current value of the warning switch, either TRUE or FALSE.
 640 (Mnemonic: related to the B<-w> switch.)
 641
 642 =item $EXECUTABLE_NAME
 643
 644 =item $^X
 645
 646 The name that the Perl binary itself was executed as, from C's C<argv[0]>.
 647
 648 =item $ARGV
 649
 650 contains the name of the current file when reading from E<lt>E<gt>.
 651
 652 =item @ARGV
 653
 654 The array @ARGV contains the command line arguments intended for the
 655 script.  Note that C<$#ARGV> is the generally number of arguments minus
 656 one, because C<$ARGV[0]> is the first argument, I<NOT> the command name.  See
 657 "C<$0>" for the command name.
 658
 659 =item @INC
 660
 661 The array @INC contains the list of places to look for Perl scripts to
 662 be evaluated by the C<do EXPR>, C<require>, or C<use> constructs.  It
 663 initially consists of the arguments to any B<-I> command line switches,
 664 followed by the default Perl library, probably F</usr/local/lib/perl>,
 665 followed by ".", to represent the current directory.  If you need to
 666 modify this at runtime, you should use the C<use lib> pragma
 667 to get the machine-dependent library properly loaded also:
 668
 669     use lib '/mypath/libdir/';
 670     use SomeMod;
 671
 672 =item %INC
 673
 674 The hash %INC contains entries for each filename that has
 675 been included via C<do> or C<require>.  The key is the filename you
 676 specified, and the value is the location of the file actually found.
 677 The C<require> command uses this array to determine whether a given file
 678 has already been included.
 679
 680 =item $ENV{expr}
 681
 682 The hash %ENV contains your current environment.  Setting a
 683 value in C<ENV> changes the environment for child processes.
 684
 685 =item $SIG{expr}
 686
 687 The hash %SIG is used to set signal handlers for various
 688 signals.  Example:
 689
 690     sub handler {       # 1st argument is signal name
 691         local($sig) = @_;
 692         print "Caught a SIG$sig--shutting down\n";
 693         close(LOG);
 694         exit(0);
 695     }
 696
 697     $SIG{'INT'} = 'handler';
 698     $SIG{'QUIT'} = 'handler';
 699     ...
 700     $SIG{'INT'} = 'DEFAULT';    # restore default action
 701     $SIG{'QUIT'} = 'IGNORE';    # ignore SIGQUIT
 702
 703 The %SIG array contains values for only the signals actually set within
 704 the Perl script.  Here are some other examples:
 705
 706     $SIG{PIPE} = Plumber;       # SCARY!!
 707     $SIG{"PIPE"} = "Plumber";   # just fine, assumes main::Plumber
 708     $SIG{"PIPE"} = \&Plumber;   # just fine; assume current Plumber
 709     $SIG{"PIPE"} = Plumber();   # oops, what did Plumber() return??
 710
 711 The one marked scary is problematic because it's a bareword, which means
 712 sometimes it's a string representing the function, and sometimes it's
 713 going to call the subroutine call right then and there!  Best to be sure
 714 and quote it or take a reference to it.  *Plumber works too.  See L<perlsub>.
 715
 716 If your system has the sigaction() function then signal handlers are
 717 installed using it.  This means you get reliable signal handling.  If
 718 your system has the SA_RESTART flag it is used when signals handlers are
 719 installed.  This means that system calls for which it is supported
 720 continue rather than returning when a signal arrives.  If you want your
 721 system calls to be interrupted by signal delivery then do something like
 722 this:
 723
 724     use POSIX ':signal_h';
 725
 726     my $alarm = 0;
 727     sigaction SIGALRM, new POSIX::SigAction sub { $alarm = 1 }
 728         or die "Error setting SIGALRM handler: $!\n";
 729
 730 See L<POSIX>.
 731
 732 Certain internal hooks can be also set using the %SIG hash.  The
 733 routine indicated by C<$SIG{__WARN__}> is called when a warning message is
 734 about to be printed.  The warning message is passed as the first
 735 argument.  The presence of a __WARN__ hook causes the ordinary printing
 736 of warnings to STDERR to be suppressed.  You can use this to save warnings
 737 in a variable, or turn warnings into fatal errors, like this:
 738
 739     local $SIG{__WARN__} = sub { die $_[0] };
 740     eval $proggie;
 741
 742 The routine indicated by C<$SIG{__DIE__}> is called when a fatal exception
 743 is about to be thrown.  The error message is passed as the first
 744 argument.  When a __DIE__ hook routine returns, the exception
 745 processing continues as it would have in the absence of the hook,
 746 unless the hook routine itself exits via a C<goto>, a loop exit, or a die().
 747 The C<__DIE__> handler is explicitly disabled during the call, so that you
 748 can die from a C<__DIE__> handler.  Similarly for C<__WARN__>.  See
 749 L<perlfunc/die>, L<perlfunc/warn> and L<perlfunc/eval>.
 750
 751 =item $^M
 752
 753 By default, running out of memory it is not trappable.  However, if
 754 compiled for this, Perl may use the contents of C<$^M> as an emergency
 755 pool after die()ing with this message.  Suppose that your Perl were
 756 compiled with -DEMERGENCY_SBRK and used Perl's malloc.  Then
 757
 758     $^M = 'a' x (1<<16);
 759
 760 would allocate a 64K buffer for use when in emergency.  See the F<INSTALL>
 761 file for information on how to enable this option.  As a disincentive to
 762 casual use of this advanced feature, there is no L<English> long name for
 763 this variable.
 764
 765 =back