3 perluniintro - Perl Unicode introduction
7 This document gives a general idea of Unicode and how to use Unicode
12 Unicode is a character set standard which plans to codify all of the
13 writing systems of the world, plus many other symbols.
15 Unicode and ISO/IEC 10646 are coordinated standards that provide code
16 points for characters in almost all modern character set standards,
17 covering more than 30 writing systems and hundreds of languages,
18 including all commercially-important modern languages. All characters
19 in the largest Chinese, Japanese, and Korean dictionaries are also
20 encoded. The standards will eventually cover almost all characters in
21 more than 250 writing systems and thousands of languages.
23 A Unicode I<character> is an abstract entity. It is not bound to any
24 particular integer width, especially not to the C language C<char>.
25 Unicode is language-neutral and display-neutral: it does not encode the
26 language of the text and it does not define fonts or other graphical
27 layout details. Unicode operates on characters and on text built from
30 Unicode defines characters like C<LATIN CAPITAL LETTER A> or C<GREEK
31 SMALL LETTER ALPHA> and unique numbers for the characters, in this
32 case 0x0041 and 0x03B1, respectively. These unique numbers are called
35 The Unicode standard prefers using hexadecimal notation for the code
36 points. If numbers like C<0x0041> are unfamiliar to
37 you, take a peek at a later section, L</"Hexadecimal Notation">.
38 The Unicode standard uses the notation C<U+0041 LATIN CAPITAL LETTER A>,
39 to give the hexadecimal code point and the normative name of
42 Unicode also defines various I<properties> for the characters, like
43 "uppercase" or "lowercase", "decimal digit", or "punctuation";
44 these properties are independent of the names of the characters.
45 Furthermore, various operations on the characters like uppercasing,
46 lowercasing, and collating (sorting) are defined.
48 A Unicode character consists either of a single code point, or a
49 I<base character> (like C<LATIN CAPITAL LETTER A>), followed by one or
50 more I<modifiers> (like C<COMBINING ACUTE ACCENT>). This sequence of
51 base character and modifiers is called a I<combining character
54 Whether to call these combining character sequences "characters"
55 depends on your point of view. If you are a programmer, you probably
56 would tend towards seeing each element in the sequences as one unit,
57 or "character". The whole sequence could be seen as one "character",
58 however, from the user's point of view, since that's probably what it
59 looks like in the context of the user's language.
61 With this "whole sequence" view of characters, the total number of
62 characters is open-ended. But in the programmer's "one unit is one
63 character" point of view, the concept of "characters" is more
64 deterministic. In this document, we take that second point of view:
65 one "character" is one Unicode code point, be it a base character or
66 a combining character.
68 For some combinations, there are I<precomposed> characters.
69 C<LATIN CAPITAL LETTER A WITH ACUTE>, for example, is defined as
70 a single code point. These precomposed characters are, however,
71 only available for some combinations, and are mainly
72 meant to support round-trip conversions between Unicode and legacy
73 standards (like the ISO 8859). In the general case, the composing
74 method is more extensible. To support conversion between
75 different compositions of the characters, various I<normalization
76 forms> to standardize representations are also defined.
78 Because of backward compatibility with legacy encodings, the "a unique
79 number for every character" idea breaks down a bit: instead, there is
80 "at least one number for every character". The same character could
81 be represented differently in several legacy encodings. The
82 converse is also not true: some code points do not have an assigned
83 character. Firstly, there are unallocated code points within
84 otherwise used blocks. Secondly, there are special Unicode control
85 characters that do not represent true characters.
87 A common myth about Unicode is that it would be "16-bit", that is,
88 Unicode is only represented as C<0x10000> (or 65536) characters from
89 C<0x0000> to C<0xFFFF>. B<This is untrue.> Since Unicode 2.0, Unicode
90 has been defined all the way up to 21 bits (C<0x10FFFF>), and since
91 Unicode 3.1, characters have been defined beyond C<0xFFFF>. The first
92 C<0x10000> characters are called the I<Plane 0>, or the I<Basic
93 Multilingual Plane> (BMP). With Unicode 3.1, 17 planes in all are
94 defined--but nowhere near full of defined characters, yet.
96 Another myth is that the 256-character blocks have something to
97 do with languages--that each block would define the characters used
98 by a language or a set of languages. B<This is also untrue.>
99 The division into blocks exists, but it is almost completely
100 accidental--an artifact of how the characters have been and
101 still are allocated. Instead, there is a concept called I<scripts>,
102 which is more useful: there is C<Latin> script, C<Greek> script, and
103 so on. Scripts usually span varied parts of several blocks.
104 For further information see L<Unicode::UCD>.
106 The Unicode code points are just abstract numbers. To input and
107 output these abstract numbers, the numbers must be I<encoded> somehow.
108 Unicode defines several I<character encoding forms>, of which I<UTF-8>
109 is perhaps the most popular. UTF-8 is a variable length encoding that
110 encodes Unicode characters as 1 to 6 bytes (only 4 with the currently
111 defined characters). Other encodings include UTF-16 and UTF-32 and their
112 big- and little-endian variants (UTF-8 is byte-order independent)
113 The ISO/IEC 10646 defines the UCS-2 and UCS-4 encoding forms.
115 For more information about encodings--for instance, to learn what
116 I<surrogates> and I<byte order marks> (BOMs) are--see L<perlunicode>.
118 =head2 Perl's Unicode Support
120 Starting from Perl 5.6.0, Perl has had the capacity to handle Unicode
121 natively. Perl 5.8.0, however, is the first recommended release for
122 serious Unicode work. The maintenance release 5.6.1 fixed many of the
123 problems of the initial Unicode implementation, but for example
124 regular expressions still do not work with Unicode in 5.6.1.
126 B<Starting from Perl 5.8.0, the use of C<use utf8> is no longer
127 necessary.> In earlier releases the C<utf8> pragma was used to declare
128 that operations in the current block or file would be Unicode-aware.
129 This model was found to be wrong, or at least clumsy: the "Unicodeness"
130 is now carried with the data, instead of being attached to the
131 operations. Only one case remains where an explicit C<use utf8> is
132 needed: if your Perl script itself is encoded in UTF-8, you can use
133 UTF-8 in your identifier names, and in string and regular expression
134 literals, by saying C<use utf8>. This is not the default because
135 scripts with legacy 8-bit data in them would break. See L<utf8>.
137 =head2 Perl's Unicode Model
139 Perl supports both pre-5.6 strings of eight-bit native bytes, and
140 strings of Unicode characters. The principle is that Perl tries to
141 keep its data as eight-bit bytes for as long as possible, but as soon
142 as Unicodeness cannot be avoided, the data is transparently upgraded
145 Internally, Perl currently uses either whatever the native eight-bit
146 character set of the platform (for example Latin-1) is, defaulting to
147 UTF-8, to encode Unicode strings. Specifically, if all code points in
148 the string are C<0xFF> or less, Perl uses the native eight-bit
149 character set. Otherwise, it uses UTF-8.
151 A user of Perl does not normally need to know nor care how Perl
152 happens to encode its internal strings, but it becomes relevant when
153 outputting Unicode strings to a stream without a PerlIO layer -- one with
154 the "default" encoding. In such a case, the raw bytes used internally
155 (the native character set or UTF-8, as appropriate for each string)
156 will be used, and a "Wide character" warning will be issued if those
157 strings contain a character beyond 0x00FF.
161 perl -e 'print "\x{DF}\n", "\x{0100}\x{DF}\n"'
163 produces a fairly useless mixture of native bytes and UTF-8, as well
166 Wide character in print at ...
168 To output UTF-8, use the C<:utf8> output layer. Prepending
170 binmode(STDOUT, ":utf8");
172 to this sample program ensures that the output is completely UTF-8,
173 and removes the program's warning.
175 If your locale environment variables (C<LC_ALL>, C<LC_CTYPE>, C<LANG>)
176 contain the strings 'UTF-8' or 'UTF8' (matched case-insensitively)
177 B<and> you enable using UTF-8 either by using the C<-C> command line
178 switch or by setting the PERL_UTF8_LOCALE environment variable to
179 a true value, then the default encoding of your STDIN, STDOUT, and
180 STDERR, and of B<any subsequent file open>, is UTF-8. Note that this
181 means that Perl expects other software to work, too: if Perl has been
182 led to believe that STDIN should be UTF-8, but then STDIN coming in
183 from another command is not UTF-8, Perl will complain about the
186 All features that combine Unicode and I/O also require using the new
187 PerlIO feature. Almost all Perl 5.8 platforms do use PerlIO, though:
188 you can see whether yours is by running "perl -V" and looking for
191 =head2 Unicode and EBCDIC
193 Perl 5.8.0 also supports Unicode on EBCDIC platforms. There,
194 Unicode support is somewhat more complex to implement since
195 additional conversions are needed at every step. Some problems
196 remain, see L<perlebcdic> for details.
198 In any case, the Unicode support on EBCDIC platforms is better than
199 in the 5.6 series, which didn't work much at all for EBCDIC platform.
200 On EBCDIC platforms, the internal Unicode encoding form is UTF-EBCDIC
201 instead of UTF-8. The difference is that as UTF-8 is "ASCII-safe" in
202 that ASCII characters encode to UTF-8 as-is, while UTF-EBCDIC is
205 =head2 Creating Unicode
207 To create Unicode characters in literals for code points above C<0xFF>,
208 use the C<\x{...}> notation in double-quoted strings:
210 my $smiley = "\x{263a}";
212 Similarly, it can be used in regular expression literals
214 $smiley =~ /\x{263a}/;
216 At run-time you can use C<chr()>:
218 my $hebrew_alef = chr(0x05d0);
220 See L</"Further Resources"> for how to find all these numeric codes.
222 Naturally, C<ord()> will do the reverse: it turns a character into
225 Note that C<\x..> (no C<{}> and only two hexadecimal digits), C<\x{...}>,
226 and C<chr(...)> for arguments less than C<0x100> (decimal 256)
227 generate an eight-bit character for backward compatibility with older
228 Perls. For arguments of C<0x100> or more, Unicode characters are
229 always produced. If you want to force the production of Unicode
230 characters regardless of the numeric value, use C<pack("U", ...)>
231 instead of C<\x..>, C<\x{...}>, or C<chr()>.
233 You can also use the C<charnames> pragma to invoke characters
234 by name in double-quoted strings:
236 use charnames ':full';
237 my $arabic_alef = "\N{ARABIC LETTER ALEF}";
239 And, as mentioned above, you can also C<pack()> numbers into Unicode
242 my $georgian_an = pack("U", 0x10a0);
244 Note that both C<\x{...}> and C<\N{...}> are compile-time string
245 constants: you cannot use variables in them. if you want similar
246 run-time functionality, use C<chr()> and C<charnames::vianame()>.
248 Also note that if all the code points for pack "U" are below 0x100,
249 bytes will be generated, just like if you were using C<chr()>.
251 my $bytes = pack("U*", 0x80, 0xFF);
253 If you want to force the result to Unicode characters, use the special
254 C<"U0"> prefix. It consumes no arguments but forces the result to be
255 in Unicode characters, instead of bytes.
257 my $chars = pack("U0U*", 0x80, 0xFF);
259 =head2 Handling Unicode
261 Handling Unicode is for the most part transparent: just use the
262 strings as usual. Functions like C<index()>, C<length()>, and
263 C<substr()> will work on the Unicode characters; regular expressions
264 will work on the Unicode characters (see L<perlunicode> and L<perlretut>).
266 Note that Perl considers combining character sequences to be
267 characters, so for example
269 use charnames ':full';
270 print length("\N{LATIN CAPITAL LETTER A}\N{COMBINING ACUTE ACCENT}"), "\n";
272 will print 2, not 1. The only exception is that regular expressions
273 have C<\X> for matching a combining character sequence.
275 Life is not quite so transparent, however, when working with legacy
276 encodings, I/O, and certain special cases:
278 =head2 Legacy Encodings
280 When you combine legacy data and Unicode the legacy data needs
281 to be upgraded to Unicode. Normally ISO 8859-1 (or EBCDIC, if
282 applicable) is assumed. You can override this assumption by
283 using the C<encoding> pragma, for example
285 use encoding 'latin2'; # ISO 8859-2
287 in which case literals (string or regular expressions), C<chr()>,
288 and C<ord()> in your whole script are assumed to produce Unicode
289 characters from ISO 8859-2 code points. Note that the matching for
290 encoding names is forgiving: instead of C<latin2> you could have
291 said C<Latin 2>, or C<iso8859-2>, or other variations. With just
295 the environment variable C<PERL_ENCODING> will be consulted.
296 If that variable isn't set, the encoding pragma will fail.
298 The C<Encode> module knows about many encodings and has interfaces
299 for doing conversions between those encodings:
301 use Encode 'from_to';
302 from_to($data, "iso-8859-3", "utf-8"); # from legacy to utf-8
306 Normally, writing out Unicode data
308 print FH $some_string_with_unicode, "\n";
310 produces raw bytes that Perl happens to use to internally encode the
311 Unicode string. Perl's internal encoding depends on the system as
312 well as what characters happen to be in the string at the time. If
313 any of the characters are at code points C<0x100> or above, you will get
314 a warning. To ensure that the output is explicitly rendered in the
315 encoding you desire--and to avoid the warning--open the stream with
316 the desired encoding. Some examples:
318 open FH, ">:utf8", "file";
320 open FH, ">:encoding(ucs2)", "file";
321 open FH, ">:encoding(UTF-8)", "file";
322 open FH, ">:encoding(shift_jis)", "file";
324 and on already open streams, use C<binmode()>:
326 binmode(STDOUT, ":utf8");
328 binmode(STDOUT, ":encoding(ucs2)");
329 binmode(STDOUT, ":encoding(UTF-8)");
330 binmode(STDOUT, ":encoding(shift_jis)");
332 The matching of encoding names is loose: case does not matter, and
333 many encodings have several aliases. Note that the C<:utf8> layer
334 must always be specified exactly like that; it is I<not> subject to
335 the loose matching of encoding names.
337 See L<PerlIO> for the C<:utf8> layer, L<PerlIO::encoding> and
338 L<Encode::PerlIO> for the C<:encoding()> layer, and
339 L<Encode::Supported> for many encodings supported by the C<Encode>
342 Reading in a file that you know happens to be encoded in one of the
343 Unicode or legacy encodings does not magically turn the data into
344 Unicode in Perl's eyes. To do that, specify the appropriate
345 layer when opening files
347 open(my $fh,'<:utf8', 'anything');
348 my $line_of_unicode = <$fh>;
350 open(my $fh,'<:encoding(Big5)', 'anything');
351 my $line_of_unicode = <$fh>;
353 The I/O layers can also be specified more flexibly with
354 the C<open> pragma. See L<open>, or look at the following example.
356 use open ':utf8'; # input and output default layer will be UTF-8
358 print X chr(0x100), "\n";
361 printf "%#x\n", ord(<Y>); # this should print 0x100
364 With the C<open> pragma you can use the C<:locale> layer
366 BEGIN { $ENV{LC_ALL} = $ENV{LANG} = 'ru_RU.KOI8-R' }
367 # the :locale will probe the locale environment variables like LC_ALL
368 use open OUT => ':locale'; # russki parusski
370 print O chr(0x430); # Unicode CYRILLIC SMALL LETTER A = KOI8-R 0xc1
373 printf "%#x\n", ord(<I>), "\n"; # this should print 0xc1
376 or you can also use the C<':encoding(...)'> layer
378 open(my $epic,'<:encoding(iso-8859-7)','iliad.greek');
379 my $line_of_unicode = <$epic>;
381 These methods install a transparent filter on the I/O stream that
382 converts data from the specified encoding when it is read in from the
383 stream. The result is always Unicode.
385 The L<open> pragma affects all the C<open()> calls after the pragma by
386 setting default layers. If you want to affect only certain
387 streams, use explicit layers directly in the C<open()> call.
389 You can switch encodings on an already opened stream by using
390 C<binmode()>; see L<perlfunc/binmode>.
392 The C<:locale> does not currently (as of Perl 5.8.0) work with
393 C<open()> and C<binmode()>, only with the C<open> pragma. The
394 C<:utf8> and C<:encoding(...)> methods do work with all of C<open()>,
395 C<binmode()>, and the C<open> pragma.
397 Similarly, you may use these I/O layers on output streams to
398 automatically convert Unicode to the specified encoding when it is
399 written to the stream. For example, the following snippet copies the
400 contents of the file "text.jis" (encoded as ISO-2022-JP, aka JIS) to
401 the file "text.utf8", encoded as UTF-8:
403 open(my $nihongo, '<:encoding(iso-2022-jp)', 'text.jis');
404 open(my $unicode, '>:utf8', 'text.utf8');
405 while (<$nihongo>) { print $unicode $_ }
407 The naming of encodings, both by the C<open()> and by the C<open>
408 pragma, is similar to the C<encoding> pragma in that it allows for
409 flexible names: C<koi8-r> and C<KOI8R> will both be understood.
411 Common encodings recognized by ISO, MIME, IANA, and various other
412 standardisation organisations are recognised; for a more detailed
413 list see L<Encode::Supported>.
415 C<read()> reads characters and returns the number of characters.
416 C<seek()> and C<tell()> operate on byte counts, as do C<sysread()>
419 Notice that because of the default behaviour of not doing any
420 conversion upon input if there is no default layer,
421 it is easy to mistakenly write code that keeps on expanding a file
422 by repeatedly encoding the data:
426 local $/; ## read in the whole file of 8-bit characters
429 open F, ">:utf8", "file";
430 print F $t; ## convert to UTF-8 on output
433 If you run this code twice, the contents of the F<file> will be twice
434 UTF-8 encoded. A C<use open ':utf8'> would have avoided the bug, or
435 explicitly opening also the F<file> for input as UTF-8.
437 B<NOTE>: the C<:utf8> and C<:encoding> features work only if your
438 Perl has been built with the new PerlIO feature (which is the default
441 =head2 Displaying Unicode As Text
443 Sometimes you might want to display Perl scalars containing Unicode as
444 simple ASCII (or EBCDIC) text. The following subroutine converts
445 its argument so that Unicode characters with code points greater than
446 255 are displayed as C<\x{...}>, control characters (like C<\n>) are
447 displayed as C<\x..>, and the rest of the characters as themselves:
451 map { $_ > 255 ? # if wide character...
452 sprintf("\\x{%04X}", $_) : # \x{...}
453 chr($_) =~ /[[:cntrl:]]/ ? # else if control character ...
454 sprintf("\\x%02X", $_) : # \x..
455 chr($_) # else as themselves
456 } unpack("U*", $_[0])); # unpack Unicode characters
461 nice_string("foo\x{100}bar\n")
473 Bit Complement Operator ~ And vec()
475 The bit complement operator C<~> may produce surprising results if
476 used on strings containing characters with ordinal values above
477 255. In such a case, the results are consistent with the internal
478 encoding of the characters, but not with much else. So don't do
479 that. Similarly for C<vec()>: you will be operating on the
480 internally-encoded bit patterns of the Unicode characters, not on
481 the code point values, which is very probably not what you want.
485 Peeking At Perl's Internal Encoding
487 Normal users of Perl should never care how Perl encodes any particular
488 Unicode string (because the normal ways to get at the contents of a
489 string with Unicode--via input and output--should always be via
490 explicitly-defined I/O layers). But if you must, there are two
491 ways of looking behind the scenes.
493 One way of peeking inside the internal encoding of Unicode characters
494 is to use C<unpack("C*", ...> to get the bytes or C<unpack("H*", ...)>
495 to display the bytes:
497 # this prints c4 80 for the UTF-8 bytes 0xc4 0x80
498 print join(" ", unpack("H*", pack("U", 0x100))), "\n";
500 Yet another way would be to use the Devel::Peek module:
502 perl -MDevel::Peek -e 'Dump(chr(0x100))'
504 That shows the UTF8 flag in FLAGS and both the UTF-8 bytes
505 and Unicode characters in C<PV>. See also later in this document
506 the discussion about the C<is_utf8> function of the C<Encode> module.
510 =head2 Advanced Topics
518 The question of string equivalence turns somewhat complicated
519 in Unicode: what do you mean by "equal"?
521 (Is C<LATIN CAPITAL LETTER A WITH ACUTE> equal to
522 C<LATIN CAPITAL LETTER A>?)
524 The short answer is that by default Perl compares equivalence (C<eq>,
525 C<ne>) based only on code points of the characters. In the above
526 case, the answer is no (because 0x00C1 != 0x0041). But sometimes, any
527 CAPITAL LETTER As should be considered equal, or even As of any case.
529 The long answer is that you need to consider character normalization
530 and casing issues: see L<Unicode::Normalize>, Unicode Technical
531 Reports #15 and #21, I<Unicode Normalization Forms> and I<Case
532 Mappings>, http://www.unicode.org/unicode/reports/tr15/ and
533 http://www.unicode.org/unicode/reports/tr21/
535 As of Perl 5.8.0, the "Full" case-folding of I<Case
536 Mappings/SpecialCasing> is implemented.
542 People like to see their strings nicely sorted--or as Unicode
543 parlance goes, collated. But again, what do you mean by collate?
545 (Does C<LATIN CAPITAL LETTER A WITH ACUTE> come before or after
546 C<LATIN CAPITAL LETTER A WITH GRAVE>?)
548 The short answer is that by default, Perl compares strings (C<lt>,
549 C<le>, C<cmp>, C<ge>, C<gt>) based only on the code points of the
550 characters. In the above case, the answer is "after", since
551 C<0x00C1> > C<0x00C0>.
553 The long answer is that "it depends", and a good answer cannot be
554 given without knowing (at the very least) the language context.
555 See L<Unicode::Collate>, and I<Unicode Collation Algorithm>
556 http://www.unicode.org/unicode/reports/tr10/
566 Character Ranges and Classes
568 Character ranges in regular expression character classes (C</[a-z]/>)
569 and in the C<tr///> (also known as C<y///>) operator are not magically
570 Unicode-aware. What this means that C<[A-Za-z]> will not magically start
571 to mean "all alphabetic letters"; not that it does mean that even for
572 8-bit characters, you should be using C</[[:alpha:]]/> in that case.
574 For specifying character classes like that in regular expressions,
575 you can use the various Unicode properties--C<\pL>, or perhaps
576 C<\p{Alphabetic}>, in this particular case. You can use Unicode
577 code points as the end points of character ranges, but there is no
578 magic associated with specifying a certain range. For further
579 information--there are dozens of Unicode character classes--see
584 String-To-Number Conversions
586 Unicode does define several other decimal--and numeric--characters
587 besides the familiar 0 to 9, such as the Arabic and Indic digits.
588 Perl does not support string-to-number conversion for digits other
589 than ASCII 0 to 9 (and ASCII a to f for hexadecimal).
593 =head2 Questions With Answers
599 Will My Old Scripts Break?
601 Very probably not. Unless you are generating Unicode characters
602 somehow, old behaviour should be preserved. About the only behaviour
603 that has changed and which could start generating Unicode is the old
604 behaviour of C<chr()> where supplying an argument more than 255
605 produced a character modulo 255. C<chr(300)>, for example, was equal
606 to C<chr(45)> or "-" (in ASCII), now it is LATIN CAPITAL LETTER I WITH
611 How Do I Make My Scripts Work With Unicode?
613 Very little work should be needed since nothing changes until you
614 generate Unicode data. The most important thing is getting input as
615 Unicode; for that, see the earlier I/O discussion.
619 How Do I Know Whether My String Is In Unicode?
621 You shouldn't care. No, you really shouldn't. No, really. If you
622 have to care--beyond the cases described above--it means that we
623 didn't get the transparency of Unicode quite right.
627 use Encode 'is_utf8';
628 print is_utf8($string) ? 1 : 0, "\n";
630 But note that this doesn't mean that any of the characters in the
631 string are necessary UTF-8 encoded, or that any of the characters have
632 code points greater than 0xFF (255) or even 0x80 (128), or that the
633 string has any characters at all. All the C<is_utf8()> does is to
634 return the value of the internal "utf8ness" flag attached to the
635 C<$string>. If the flag is off, the bytes in the scalar are interpreted
636 as a single byte encoding. If the flag is on, the bytes in the scalar
637 are interpreted as the (multi-byte, variable-length) UTF-8 encoded code
638 points of the characters. Bytes added to an UTF-8 encoded string are
639 automatically upgraded to UTF-8. If mixed non-UTF8 and UTF-8 scalars
640 are merged (double-quoted interpolation, explicit concatenation, and
641 printf/sprintf parameter substitution), the result will be UTF-8 encoded
642 as if copies of the byte strings were upgraded to UTF-8: for example,
648 the output string will be UTF-8-encoded C<ab\x80c\x{100}\n>, but note
649 that C<$a> will stay byte-encoded.
651 Sometimes you might really need to know the byte length of a string
652 instead of the character length. For that use either the
653 C<Encode::encode_utf8()> function or the C<bytes> pragma and its only
654 defined function C<length()>:
656 my $unicode = chr(0x100);
657 print length($unicode), "\n"; # will print 1
659 print length(Encode::encode_utf8($unicode)), "\n"; # will print 2
661 print length($unicode), "\n"; # will also print 2
662 # (the 0xC4 0x80 of the UTF-8)
666 How Do I Detect Data That's Not Valid In a Particular Encoding?
668 Use the C<Encode> package to try converting it.
671 use Encode 'encode_utf8';
672 if (encode_utf8($string_of_bytes_that_I_think_is_utf8)) {
678 For UTF-8 only, you can use:
681 @chars = unpack("U0U*", $string_of_bytes_that_I_think_is_utf8);
683 If invalid, a C<Malformed UTF-8 character (byte 0x##) in unpack>
684 warning is produced. The "U0" means "expect strictly UTF-8 encoded
685 Unicode". Without that the C<unpack("U*", ...)> would accept also
686 data like C<chr(0xFF>), similarly to the C<pack> as we saw earlier.
690 How Do I Convert Binary Data Into a Particular Encoding, Or Vice Versa?
692 This probably isn't as useful as you might think.
693 Normally, you shouldn't need to.
695 In one sense, what you are asking doesn't make much sense: encodings
696 are for characters, and binary data are not "characters", so converting
697 "data" into some encoding isn't meaningful unless you know in what
698 character set and encoding the binary data is in, in which case it's
699 not just binary data, now is it?
701 If you have a raw sequence of bytes that you know should be
702 interpreted via a particular encoding, you can use C<Encode>:
704 use Encode 'from_to';
705 from_to($data, "iso-8859-1", "utf-8"); # from latin-1 to utf-8
707 The call to C<from_to()> changes the bytes in C<$data>, but nothing
708 material about the nature of the string has changed as far as Perl is
709 concerned. Both before and after the call, the string C<$data>
710 contains just a bunch of 8-bit bytes. As far as Perl is concerned,
711 the encoding of the string remains as "system-native 8-bit bytes".
713 You might relate this to a fictional 'Translate' module:
717 Translate::from_to($phrase, 'english', 'deutsch');
718 ## phrase now contains "Ja"
720 The contents of the string changes, but not the nature of the string.
721 Perl doesn't know any more after the call than before that the
722 contents of the string indicates the affirmative.
724 Back to converting data. If you have (or want) data in your system's
725 native 8-bit encoding (e.g. Latin-1, EBCDIC, etc.), you can use
726 pack/unpack to convert to/from Unicode.
728 $native_string = pack("C*", unpack("U*", $Unicode_string));
729 $Unicode_string = pack("U*", unpack("C*", $native_string));
731 If you have a sequence of bytes you B<know> is valid UTF-8,
732 but Perl doesn't know it yet, you can make Perl a believer, too:
734 use Encode 'decode_utf8';
735 $Unicode = decode_utf8($bytes);
737 You can convert well-formed UTF-8 to a sequence of bytes, but if
738 you just want to convert random binary data into UTF-8, you can't.
739 B<Any random collection of bytes isn't well-formed UTF-8>. You can
740 use C<unpack("C*", $string)> for the former, and you can create
741 well-formed Unicode data by C<pack("U*", 0xff, ...)>.
745 How Do I Display Unicode? How Do I Input Unicode?
747 See http://www.alanwood.net/unicode/ and
748 http://www.cl.cam.ac.uk/~mgk25/unicode.html
752 How Does Unicode Work With Traditional Locales?
754 In Perl, not very well. Avoid using locales through the C<locale>
755 pragma. Use only one or the other.
759 =head2 Hexadecimal Notation
761 The Unicode standard prefers using hexadecimal notation because
762 that more clearly shows the division of Unicode into blocks of 256 characters.
763 Hexadecimal is also simply shorter than decimal. You can use decimal
764 notation, too, but learning to use hexadecimal just makes life easier
765 with the Unicode standard. The C<U+HHHH> notation uses hexadecimal,
768 The C<0x> prefix means a hexadecimal number, the digits are 0-9 I<and>
769 a-f (or A-F, case doesn't matter). Each hexadecimal digit represents
770 four bits, or half a byte. C<print 0x..., "\n"> will show a
771 hexadecimal number in decimal, and C<printf "%x\n", $decimal> will
772 show a decimal number in hexadecimal. If you have just the
773 "hex digits" of a hexadecimal number, you can use the C<hex()> function.
775 print 0x0009, "\n"; # 9
776 print 0x000a, "\n"; # 10
777 print 0x000f, "\n"; # 15
778 print 0x0010, "\n"; # 16
779 print 0x0011, "\n"; # 17
780 print 0x0100, "\n"; # 256
782 print 0x0041, "\n"; # 65
784 printf "%x\n", 65; # 41
785 printf "%#x\n", 65; # 0x41
787 print hex("41"), "\n"; # 65
789 =head2 Further Resources
797 http://www.unicode.org/
803 http://www.unicode.org/unicode/faq/
809 http://www.unicode.org/glossary/
813 Unicode Useful Resources
815 http://www.unicode.org/unicode/onlinedat/resources.html
819 Unicode and Multilingual Support in HTML, Fonts, Web Browsers and Other Applications
821 http://www.alanwood.net/unicode/
825 UTF-8 and Unicode FAQ for Unix/Linux
827 http://www.cl.cam.ac.uk/~mgk25/unicode.html
831 Legacy Character Sets
833 http://www.czyborra.com/
834 http://www.eki.ee/letter/
838 The Unicode support files live within the Perl installation in the
841 $Config{installprivlib}/unicore
843 in Perl 5.8.0 or newer, and
845 $Config{installprivlib}/unicode
847 in the Perl 5.6 series. (The renaming to F<lib/unicore> was done to
848 avoid naming conflicts with lib/Unicode in case-insensitive filesystems.)
849 The main Unicode data file is F<UnicodeData.txt> (or F<Unicode.301> in
850 Perl 5.6.1.) You can find the C<$Config{installprivlib}> by
852 perl "-V:installprivlib"
854 You can explore various information from the Unicode data files using
855 the C<Unicode::UCD> module.
859 =head1 UNICODE IN OLDER PERLS
861 If you cannot upgrade your Perl to 5.8.0 or later, you can still
862 do some Unicode processing by using the modules C<Unicode::String>,
863 C<Unicode::Map8>, and C<Unicode::Map>, available from CPAN.
864 If you have the GNU recode installed, you can also use the
865 Perl front-end C<Convert::Recode> for character conversions.
867 The following are fast conversions from ISO 8859-1 (Latin-1) bytes
868 to UTF-8 bytes and back, the code works even with older Perl 5 versions.
870 # ISO 8859-1 to UTF-8
871 s/([\x80-\xFF])/chr(0xC0|ord($1)>>6).chr(0x80|ord($1)&0x3F)/eg;
873 # UTF-8 to ISO 8859-1
874 s/([\xC2\xC3])([\x80-\xBF])/chr(ord($1)<<6&0xC0|ord($2)&0x3F)/eg;
878 L<perlunicode>, L<Encode>, L<encoding>, L<open>, L<utf8>, L<bytes>,
879 L<perlretut>, L<Unicode::Collate>, L<Unicode::Normalize>, L<Unicode::UCD>
881 =head1 ACKNOWLEDGMENTS
883 Thanks to the kind readers of the perl5-porters@perl.org,
884 perl-unicode@perl.org, linux-utf8@nl.linux.org, and unicore@unicode.org
885 mailing lists for their valuable feedback.
887 =head1 AUTHOR, COPYRIGHT, AND LICENSE
889 Copyright 2001-2002 Jarkko Hietaniemi <jhi@iki.fi>
891 This document may be distributed under the same terms as Perl itself.