3 perluniintro - Perl Unicode introduction
7 This document gives a general idea of Unicode and how to use Unicode
12 Unicode is a character set standard which plans to codify all of the
13 writing systems of the world, plus many other symbols.
15 Unicode and ISO/IEC 10646 are coordinated standards that provide code
16 points for characters in almost all modern character set standards,
17 covering more than 30 writing systems and hundreds of languages,
18 including all commercially-important modern languages. All characters
19 in the largest Chinese, Japanese, and Korean dictionaries are also
20 encoded. The standards will eventually cover almost all characters in
21 more than 250 writing systems and thousands of languages.
22 Unicode 1.0 was released in October 1991, and 4.0 in April 2003.
24 A Unicode I<character> is an abstract entity. It is not bound to any
25 particular integer width, especially not to the C language C<char>.
26 Unicode is language-neutral and display-neutral: it does not encode the
27 language of the text and it does not define fonts or other graphical
28 layout details. Unicode operates on characters and on text built from
31 Unicode defines characters like C<LATIN CAPITAL LETTER A> or C<GREEK
32 SMALL LETTER ALPHA> and unique numbers for the characters, in this
33 case 0x0041 and 0x03B1, respectively. These unique numbers are called
36 The Unicode standard prefers using hexadecimal notation for the code
37 points. If numbers like C<0x0041> are unfamiliar to you, take a peek
38 at a later section, L</"Hexadecimal Notation">. The Unicode standard
39 uses the notation C<U+0041 LATIN CAPITAL LETTER A>, to give the
40 hexadecimal code point and the normative name of the character.
42 Unicode also defines various I<properties> for the characters, like
43 "uppercase" or "lowercase", "decimal digit", or "punctuation";
44 these properties are independent of the names of the characters.
45 Furthermore, various operations on the characters like uppercasing,
46 lowercasing, and collating (sorting) are defined.
48 A Unicode character consists either of a single code point, or a
49 I<base character> (like C<LATIN CAPITAL LETTER A>), followed by one or
50 more I<modifiers> (like C<COMBINING ACUTE ACCENT>). This sequence of
51 base character and modifiers is called a I<combining character
54 Whether to call these combining character sequences "characters"
55 depends on your point of view. If you are a programmer, you probably
56 would tend towards seeing each element in the sequences as one unit,
57 or "character". The whole sequence could be seen as one "character",
58 however, from the user's point of view, since that's probably what it
59 looks like in the context of the user's language.
61 With this "whole sequence" view of characters, the total number of
62 characters is open-ended. But in the programmer's "one unit is one
63 character" point of view, the concept of "characters" is more
64 deterministic. In this document, we take that second point of view:
65 one "character" is one Unicode code point, be it a base character or
66 a combining character.
68 For some combinations, there are I<precomposed> characters.
69 C<LATIN CAPITAL LETTER A WITH ACUTE>, for example, is defined as
70 a single code point. These precomposed characters are, however,
71 only available for some combinations, and are mainly
72 meant to support round-trip conversions between Unicode and legacy
73 standards (like the ISO 8859). In the general case, the composing
74 method is more extensible. To support conversion between
75 different compositions of the characters, various I<normalization
76 forms> to standardize representations are also defined.
78 Because of backward compatibility with legacy encodings, the "a unique
79 number for every character" idea breaks down a bit: instead, there is
80 "at least one number for every character". The same character could
81 be represented differently in several legacy encodings. The
82 converse is also not true: some code points do not have an assigned
83 character. Firstly, there are unallocated code points within
84 otherwise used blocks. Secondly, there are special Unicode control
85 characters that do not represent true characters.
87 A common myth about Unicode is that it would be "16-bit", that is,
88 Unicode is only represented as C<0x10000> (or 65536) characters from
89 C<0x0000> to C<0xFFFF>. B<This is untrue.> Since Unicode 2.0 (July
90 1996), Unicode has been defined all the way up to 21 bits (C<0x10FFFF>),
91 and since Unicode 3.1 (March 2001), characters have been defined
92 beyond C<0xFFFF>. The first C<0x10000> characters are called the
93 I<Plane 0>, or the I<Basic Multilingual Plane> (BMP). With Unicode
94 3.1, 17 (yes, seventeen) planes in all were defined--but they are
95 nowhere near full of defined characters, yet.
97 Another myth is that the 256-character blocks have something to
98 do with languages--that each block would define the characters used
99 by a language or a set of languages. B<This is also untrue.>
100 The division into blocks exists, but it is almost completely
101 accidental--an artifact of how the characters have been and
102 still are allocated. Instead, there is a concept called I<scripts>,
103 which is more useful: there is C<Latin> script, C<Greek> script, and
104 so on. Scripts usually span varied parts of several blocks.
105 For further information see L<Unicode::UCD>.
107 The Unicode code points are just abstract numbers. To input and
108 output these abstract numbers, the numbers must be I<encoded> or
109 I<serialised> somehow. Unicode defines several I<character encoding
110 forms>, of which I<UTF-8> is perhaps the most popular. UTF-8 is a
111 variable length encoding that encodes Unicode characters as 1 to 6
112 bytes (only 4 with the currently defined characters). Other encodings
113 include UTF-16 and UTF-32 and their big- and little-endian variants
114 (UTF-8 is byte-order independent) The ISO/IEC 10646 defines the UCS-2
115 and UCS-4 encoding forms.
117 For more information about encodings--for instance, to learn what
118 I<surrogates> and I<byte order marks> (BOMs) are--see L<perlunicode>.
120 =head2 Perl's Unicode Support
122 Starting from Perl 5.6.0, Perl has had the capacity to handle Unicode
123 natively. Perl 5.8.0, however, is the first recommended release for
124 serious Unicode work. The maintenance release 5.6.1 fixed many of the
125 problems of the initial Unicode implementation, but for example
126 regular expressions still do not work with Unicode in 5.6.1.
128 B<Starting from Perl 5.8.0, the use of C<use utf8> is no longer
129 necessary.> In earlier releases the C<utf8> pragma was used to declare
130 that operations in the current block or file would be Unicode-aware.
131 This model was found to be wrong, or at least clumsy: the "Unicodeness"
132 is now carried with the data, instead of being attached to the
133 operations. Only one case remains where an explicit C<use utf8> is
134 needed: if your Perl script itself is encoded in UTF-8, you can use
135 UTF-8 in your identifier names, and in string and regular expression
136 literals, by saying C<use utf8>. This is not the default because
137 scripts with legacy 8-bit data in them would break. See L<utf8>.
139 =head2 Perl's Unicode Model
141 Perl supports both pre-5.6 strings of eight-bit native bytes, and
142 strings of Unicode characters. The principle is that Perl tries to
143 keep its data as eight-bit bytes for as long as possible, but as soon
144 as Unicodeness cannot be avoided, the data is transparently upgraded
147 Internally, Perl currently uses either whatever the native eight-bit
148 character set of the platform (for example Latin-1) is, defaulting to
149 UTF-8, to encode Unicode strings. Specifically, if all code points in
150 the string are C<0xFF> or less, Perl uses the native eight-bit
151 character set. Otherwise, it uses UTF-8.
153 A user of Perl does not normally need to know nor care how Perl
154 happens to encode its internal strings, but it becomes relevant when
155 outputting Unicode strings to a stream without a PerlIO layer -- one with
156 the "default" encoding. In such a case, the raw bytes used internally
157 (the native character set or UTF-8, as appropriate for each string)
158 will be used, and a "Wide character" warning will be issued if those
159 strings contain a character beyond 0x00FF.
163 perl -e 'print "\x{DF}\n", "\x{0100}\x{DF}\n"'
165 produces a fairly useless mixture of native bytes and UTF-8, as well
168 Wide character in print at ...
170 To output UTF-8, use the C<:utf8> output layer. Prepending
172 binmode(STDOUT, ":utf8");
174 to this sample program ensures that the output is completely UTF-8,
175 and removes the program's warning.
177 You can enable automatic UTF-8-ification of your standard file
178 handles, default C<open()> layer, and C<@ARGV> by using either
179 the C<-C> command line switch or the C<PERL_UNICODE> environment
180 variable, see L<perlrun> for the documentation of the C<-C> switch.
182 Note that this means that Perl expects other software to work, too:
183 if Perl has been led to believe that STDIN should be UTF-8, but then
184 STDIN coming in from another command is not UTF-8, Perl will complain
185 about the malformed UTF-8.
187 All features that combine Unicode and I/O also require using the new
188 PerlIO feature. Almost all Perl 5.8 platforms do use PerlIO, though:
189 you can see whether yours is by running "perl -V" and looking for
192 =head2 Unicode and EBCDIC
194 Perl 5.8.0 also supports Unicode on EBCDIC platforms. There,
195 Unicode support is somewhat more complex to implement since
196 additional conversions are needed at every step. Some problems
197 remain, see L<perlebcdic> for details.
199 In any case, the Unicode support on EBCDIC platforms is better than
200 in the 5.6 series, which didn't work much at all for EBCDIC platform.
201 On EBCDIC platforms, the internal Unicode encoding form is UTF-EBCDIC
202 instead of UTF-8. The difference is that as UTF-8 is "ASCII-safe" in
203 that ASCII characters encode to UTF-8 as-is, while UTF-EBCDIC is
206 =head2 Creating Unicode
208 To create Unicode characters in literals for code points above C<0xFF>,
209 use the C<\x{...}> notation in double-quoted strings:
211 my $smiley = "\x{263a}";
213 Similarly, it can be used in regular expression literals
215 $smiley =~ /\x{263a}/;
217 At run-time you can use C<chr()>:
219 my $hebrew_alef = chr(0x05d0);
221 See L</"Further Resources"> for how to find all these numeric codes.
223 Naturally, C<ord()> will do the reverse: it turns a character into
226 Note that C<\x..> (no C<{}> and only two hexadecimal digits), C<\x{...}>,
227 and C<chr(...)> for arguments less than C<0x100> (decimal 256)
228 generate an eight-bit character for backward compatibility with older
229 Perls. For arguments of C<0x100> or more, Unicode characters are
230 always produced. If you want to force the production of Unicode
231 characters regardless of the numeric value, use C<pack("U", ...)>
232 instead of C<\x..>, C<\x{...}>, or C<chr()>.
234 You can also use the C<charnames> pragma to invoke characters
235 by name in double-quoted strings:
237 use charnames ':full';
238 my $arabic_alef = "\N{ARABIC LETTER ALEF}";
240 And, as mentioned above, you can also C<pack()> numbers into Unicode
243 my $georgian_an = pack("U", 0x10a0);
245 Note that both C<\x{...}> and C<\N{...}> are compile-time string
246 constants: you cannot use variables in them. if you want similar
247 run-time functionality, use C<chr()> and C<charnames::vianame()>.
249 If you want to force the result to Unicode characters, use the special
250 C<"U0"> prefix. It consumes no arguments but causes the following bytes
251 to be interpreted as the UTF-8 encoding of Unicode characters:
253 my $chars = pack("U0W*", 0x80, 0x42);
255 Likewise, you can stop such UTF-8 interpretation by using the special
258 =head2 Handling Unicode
260 Handling Unicode is for the most part transparent: just use the
261 strings as usual. Functions like C<index()>, C<length()>, and
262 C<substr()> will work on the Unicode characters; regular expressions
263 will work on the Unicode characters (see L<perlunicode> and L<perlretut>).
265 Note that Perl considers combining character sequences to be
266 separate characters, so for example
268 use charnames ':full';
269 print length("\N{LATIN CAPITAL LETTER A}\N{COMBINING ACUTE ACCENT}"), "\n";
271 will print 2, not 1. The only exception is that regular expressions
272 have C<\X> for matching a combining character sequence.
274 Life is not quite so transparent, however, when working with legacy
275 encodings, I/O, and certain special cases:
277 =head2 Legacy Encodings
279 When you combine legacy data and Unicode the legacy data needs
280 to be upgraded to Unicode. Normally ISO 8859-1 (or EBCDIC, if
281 applicable) is assumed. You can override this assumption by
282 using the C<encoding> pragma, for example
284 use encoding 'latin2'; # ISO 8859-2
286 in which case literals (string or regular expressions), C<chr()>,
287 and C<ord()> in your whole script are assumed to produce Unicode
288 characters from ISO 8859-2 code points. Note that the matching for
289 encoding names is forgiving: instead of C<latin2> you could have
290 said C<Latin 2>, or C<iso8859-2>, or other variations. With just
294 the environment variable C<PERL_ENCODING> will be consulted.
295 If that variable isn't set, the encoding pragma will fail.
297 The C<Encode> module knows about many encodings and has interfaces
298 for doing conversions between those encodings:
301 $data = decode("iso-8859-3", $data); # convert from legacy to utf-8
305 Normally, writing out Unicode data
307 print FH $some_string_with_unicode, "\n";
309 produces raw bytes that Perl happens to use to internally encode the
310 Unicode string. Perl's internal encoding depends on the system as
311 well as what characters happen to be in the string at the time. If
312 any of the characters are at code points C<0x100> or above, you will get
313 a warning. To ensure that the output is explicitly rendered in the
314 encoding you desire--and to avoid the warning--open the stream with
315 the desired encoding. Some examples:
317 open FH, ">:utf8", "file";
319 open FH, ">:encoding(ucs2)", "file";
320 open FH, ">:encoding(UTF-8)", "file";
321 open FH, ">:encoding(shift_jis)", "file";
323 and on already open streams, use C<binmode()>:
325 binmode(STDOUT, ":utf8");
327 binmode(STDOUT, ":encoding(ucs2)");
328 binmode(STDOUT, ":encoding(UTF-8)");
329 binmode(STDOUT, ":encoding(shift_jis)");
331 The matching of encoding names is loose: case does not matter, and
332 many encodings have several aliases. Note that the C<:utf8> layer
333 must always be specified exactly like that; it is I<not> subject to
334 the loose matching of encoding names.
336 See L<PerlIO> for the C<:utf8> layer, L<PerlIO::encoding> and
337 L<Encode::PerlIO> for the C<:encoding()> layer, and
338 L<Encode::Supported> for many encodings supported by the C<Encode>
341 Reading in a file that you know happens to be encoded in one of the
342 Unicode or legacy encodings does not magically turn the data into
343 Unicode in Perl's eyes. To do that, specify the appropriate
344 layer when opening files
346 open(my $fh,'<:utf8', 'anything');
347 my $line_of_unicode = <$fh>;
349 open(my $fh,'<:encoding(Big5)', 'anything');
350 my $line_of_unicode = <$fh>;
352 The I/O layers can also be specified more flexibly with
353 the C<open> pragma. See L<open>, or look at the following example.
355 use open ':utf8'; # input and output default layer will be UTF-8
357 print X chr(0x100), "\n";
360 printf "%#x\n", ord(<Y>); # this should print 0x100
363 With the C<open> pragma you can use the C<:locale> layer
365 BEGIN { $ENV{LC_ALL} = $ENV{LANG} = 'ru_RU.KOI8-R' }
366 # the :locale will probe the locale environment variables like LC_ALL
367 use open OUT => ':locale'; # russki parusski
369 print O chr(0x430); # Unicode CYRILLIC SMALL LETTER A = KOI8-R 0xc1
372 printf "%#x\n", ord(<I>), "\n"; # this should print 0xc1
375 or you can also use the C<':encoding(...)'> layer
377 open(my $epic,'<:encoding(iso-8859-7)','iliad.greek');
378 my $line_of_unicode = <$epic>;
380 These methods install a transparent filter on the I/O stream that
381 converts data from the specified encoding when it is read in from the
382 stream. The result is always Unicode.
384 The L<open> pragma affects all the C<open()> calls after the pragma by
385 setting default layers. If you want to affect only certain
386 streams, use explicit layers directly in the C<open()> call.
388 You can switch encodings on an already opened stream by using
389 C<binmode()>; see L<perlfunc/binmode>.
391 The C<:locale> does not currently (as of Perl 5.8.0) work with
392 C<open()> and C<binmode()>, only with the C<open> pragma. The
393 C<:utf8> and C<:encoding(...)> methods do work with all of C<open()>,
394 C<binmode()>, and the C<open> pragma.
396 Similarly, you may use these I/O layers on output streams to
397 automatically convert Unicode to the specified encoding when it is
398 written to the stream. For example, the following snippet copies the
399 contents of the file "text.jis" (encoded as ISO-2022-JP, aka JIS) to
400 the file "text.utf8", encoded as UTF-8:
402 open(my $nihongo, '<:encoding(iso-2022-jp)', 'text.jis');
403 open(my $unicode, '>:utf8', 'text.utf8');
404 while (<$nihongo>) { print $unicode $_ }
406 The naming of encodings, both by the C<open()> and by the C<open>
407 pragma, is similar to the C<encoding> pragma in that it allows for
408 flexible names: C<koi8-r> and C<KOI8R> will both be understood.
410 Common encodings recognized by ISO, MIME, IANA, and various other
411 standardisation organisations are recognised; for a more detailed
412 list see L<Encode::Supported>.
414 C<read()> reads characters and returns the number of characters.
415 C<seek()> and C<tell()> operate on byte counts, as do C<sysread()>
418 Notice that because of the default behaviour of not doing any
419 conversion upon input if there is no default layer,
420 it is easy to mistakenly write code that keeps on expanding a file
421 by repeatedly encoding the data:
425 local $/; ## read in the whole file of 8-bit characters
428 open F, ">:utf8", "file";
429 print F $t; ## convert to UTF-8 on output
432 If you run this code twice, the contents of the F<file> will be twice
433 UTF-8 encoded. A C<use open ':utf8'> would have avoided the bug, or
434 explicitly opening also the F<file> for input as UTF-8.
436 B<NOTE>: the C<:utf8> and C<:encoding> features work only if your
437 Perl has been built with the new PerlIO feature (which is the default
440 =head2 Displaying Unicode As Text
442 Sometimes you might want to display Perl scalars containing Unicode as
443 simple ASCII (or EBCDIC) text. The following subroutine converts
444 its argument so that Unicode characters with code points greater than
445 255 are displayed as C<\x{...}>, control characters (like C<\n>) are
446 displayed as C<\x..>, and the rest of the characters as themselves:
450 map { $_ > 255 ? # if wide character...
451 sprintf("\\x{%04X}", $_) : # \x{...}
452 chr($_) =~ /[[:cntrl:]]/ ? # else if control character ...
453 sprintf("\\x%02X", $_) : # \x..
454 quotemeta(chr($_)) # else quoted or as themselves
455 } unpack("W*", $_[0])); # unpack Unicode characters
460 nice_string("foo\x{100}bar\n")
466 which is ready to be printed.
474 Bit Complement Operator ~ And vec()
476 The bit complement operator C<~> may produce surprising results if
477 used on strings containing characters with ordinal values above
478 255. In such a case, the results are consistent with the internal
479 encoding of the characters, but not with much else. So don't do
480 that. Similarly for C<vec()>: you will be operating on the
481 internally-encoded bit patterns of the Unicode characters, not on
482 the code point values, which is very probably not what you want.
486 Peeking At Perl's Internal Encoding
488 Normal users of Perl should never care how Perl encodes any particular
489 Unicode string (because the normal ways to get at the contents of a
490 string with Unicode--via input and output--should always be via
491 explicitly-defined I/O layers). But if you must, there are two
492 ways of looking behind the scenes.
494 One way of peeking inside the internal encoding of Unicode characters
495 is to use C<unpack("C*", ...> to get the bytes of whatever the string
496 encoding happens to be, or C<unpack("U0..", ...)> to get the bytes of the
499 # this prints c4 80 for the UTF-8 bytes 0xc4 0x80
500 print join(" ", unpack("U0(H2)*", pack("U", 0x100))), "\n";
502 Yet another way would be to use the Devel::Peek module:
504 perl -MDevel::Peek -e 'Dump(chr(0x100))'
506 That shows the C<UTF8> flag in FLAGS and both the UTF-8 bytes
507 and Unicode characters in C<PV>. See also later in this document
508 the discussion about the C<utf8::is_utf8()> function.
512 =head2 Advanced Topics
520 The question of string equivalence turns somewhat complicated
521 in Unicode: what do you mean by "equal"?
523 (Is C<LATIN CAPITAL LETTER A WITH ACUTE> equal to
524 C<LATIN CAPITAL LETTER A>?)
526 The short answer is that by default Perl compares equivalence (C<eq>,
527 C<ne>) based only on code points of the characters. In the above
528 case, the answer is no (because 0x00C1 != 0x0041). But sometimes, any
529 CAPITAL LETTER As should be considered equal, or even As of any case.
531 The long answer is that you need to consider character normalization
532 and casing issues: see L<Unicode::Normalize>, Unicode Technical
533 Reports #15 and #21, I<Unicode Normalization Forms> and I<Case
534 Mappings>, http://www.unicode.org/unicode/reports/tr15/ and
535 http://www.unicode.org/unicode/reports/tr21/
537 As of Perl 5.8.0, the "Full" case-folding of I<Case
538 Mappings/SpecialCasing> is implemented.
544 People like to see their strings nicely sorted--or as Unicode
545 parlance goes, collated. But again, what do you mean by collate?
547 (Does C<LATIN CAPITAL LETTER A WITH ACUTE> come before or after
548 C<LATIN CAPITAL LETTER A WITH GRAVE>?)
550 The short answer is that by default, Perl compares strings (C<lt>,
551 C<le>, C<cmp>, C<ge>, C<gt>) based only on the code points of the
552 characters. In the above case, the answer is "after", since
553 C<0x00C1> > C<0x00C0>.
555 The long answer is that "it depends", and a good answer cannot be
556 given without knowing (at the very least) the language context.
557 See L<Unicode::Collate>, and I<Unicode Collation Algorithm>
558 http://www.unicode.org/unicode/reports/tr10/
568 Character Ranges and Classes
570 Character ranges in regular expression character classes (C</[a-z]/>)
571 and in the C<tr///> (also known as C<y///>) operator are not magically
572 Unicode-aware. What this means that C<[A-Za-z]> will not magically start
573 to mean "all alphabetic letters"; not that it does mean that even for
574 8-bit characters, you should be using C</[[:alpha:]]/> in that case.
576 For specifying character classes like that in regular expressions,
577 you can use the various Unicode properties--C<\pL>, or perhaps
578 C<\p{Alphabetic}>, in this particular case. You can use Unicode
579 code points as the end points of character ranges, but there is no
580 magic associated with specifying a certain range. For further
581 information--there are dozens of Unicode character classes--see
586 String-To-Number Conversions
588 Unicode does define several other decimal--and numeric--characters
589 besides the familiar 0 to 9, such as the Arabic and Indic digits.
590 Perl does not support string-to-number conversion for digits other
591 than ASCII 0 to 9 (and ASCII a to f for hexadecimal).
595 =head2 Questions With Answers
601 Will My Old Scripts Break?
603 Very probably not. Unless you are generating Unicode characters
604 somehow, old behaviour should be preserved. About the only behaviour
605 that has changed and which could start generating Unicode is the old
606 behaviour of C<chr()> where supplying an argument more than 255
607 produced a character modulo 255. C<chr(300)>, for example, was equal
608 to C<chr(45)> or "-" (in ASCII), now it is LATIN CAPITAL LETTER I WITH
613 How Do I Make My Scripts Work With Unicode?
615 Very little work should be needed since nothing changes until you
616 generate Unicode data. The most important thing is getting input as
617 Unicode; for that, see the earlier I/O discussion.
621 How Do I Know Whether My String Is In Unicode?
623 You shouldn't care. No, you really shouldn't. No, really. If you
624 have to care--beyond the cases described above--it means that we
625 didn't get the transparency of Unicode quite right.
629 print utf8::is_utf8($string) ? 1 : 0, "\n";
631 But note that this doesn't mean that any of the characters in the
632 string are necessary UTF-8 encoded, or that any of the characters have
633 code points greater than 0xFF (255) or even 0x80 (128), or that the
634 string has any characters at all. All the C<is_utf8()> does is to
635 return the value of the internal "utf8ness" flag attached to the
636 C<$string>. If the flag is off, the bytes in the scalar are interpreted
637 as a single byte encoding. If the flag is on, the bytes in the scalar
638 are interpreted as the (multi-byte, variable-length) UTF-8 encoded code
639 points of the characters. Bytes added to an UTF-8 encoded string are
640 automatically upgraded to UTF-8. If mixed non-UTF-8 and UTF-8 scalars
641 are merged (double-quoted interpolation, explicit concatenation, and
642 printf/sprintf parameter substitution), the result will be UTF-8 encoded
643 as if copies of the byte strings were upgraded to UTF-8: for example,
649 the output string will be UTF-8-encoded C<ab\x80c = \x{100}\n>, but
650 C<$a> will stay byte-encoded.
652 Sometimes you might really need to know the byte length of a string
653 instead of the character length. For that use either the
654 C<Encode::encode_utf8()> function or the C<bytes> pragma and its only
655 defined function C<length()>:
657 my $unicode = chr(0x100);
658 print length($unicode), "\n"; # will print 1
660 print length(Encode::encode_utf8($unicode)), "\n"; # will print 2
662 print length($unicode), "\n"; # will also print 2
663 # (the 0xC4 0x80 of the UTF-8)
667 How Do I Detect Data That's Not Valid In a Particular Encoding?
669 Use the C<Encode> package to try converting it.
672 use Encode 'decode_utf8';
673 if (decode_utf8($string_of_bytes_that_I_think_is_utf8)) {
679 Or use C<unpack> to try decoding it:
682 @chars = unpack("C0U*", $string_of_bytes_that_I_think_is_utf8);
684 If invalid, a C<Malformed UTF-8 character (byte 0x##) in unpack>
685 warning is produced. The "C0" means
686 "process the string character per character". Without that the
687 C<unpack("U*", ...)> would work in C<U0> mode (the default if the format
688 string starts with C<U>) and it would return the bytes making up the UTF-8
689 encoding of the target string, something that will always work.
693 How Do I Convert Binary Data Into a Particular Encoding, Or Vice Versa?
695 This probably isn't as useful as you might think.
696 Normally, you shouldn't need to.
698 In one sense, what you are asking doesn't make much sense: encodings
699 are for characters, and binary data are not "characters", so converting
700 "data" into some encoding isn't meaningful unless you know in what
701 character set and encoding the binary data is in, in which case it's
702 not just binary data, now is it?
704 If you have a raw sequence of bytes that you know should be
705 interpreted via a particular encoding, you can use C<Encode>:
707 use Encode 'from_to';
708 from_to($data, "iso-8859-1", "utf-8"); # from latin-1 to utf-8
710 The call to C<from_to()> changes the bytes in C<$data>, but nothing
711 material about the nature of the string has changed as far as Perl is
712 concerned. Both before and after the call, the string C<$data>
713 contains just a bunch of 8-bit bytes. As far as Perl is concerned,
714 the encoding of the string remains as "system-native 8-bit bytes".
716 You might relate this to a fictional 'Translate' module:
720 Translate::from_to($phrase, 'english', 'deutsch');
721 ## phrase now contains "Ja"
723 The contents of the string changes, but not the nature of the string.
724 Perl doesn't know any more after the call than before that the
725 contents of the string indicates the affirmative.
727 Back to converting data. If you have (or want) data in your system's
728 native 8-bit encoding (e.g. Latin-1, EBCDIC, etc.), you can use
729 pack/unpack to convert to/from Unicode.
731 $native_string = pack("W*", unpack("U*", $Unicode_string));
732 $Unicode_string = pack("U*", unpack("W*", $native_string));
734 If you have a sequence of bytes you B<know> is valid UTF-8,
735 but Perl doesn't know it yet, you can make Perl a believer, too:
737 use Encode 'decode_utf8';
738 $Unicode = decode_utf8($bytes);
742 $Unicode = pack("U0a*", $bytes);
744 You can convert well-formed UTF-8 to a sequence of bytes, but if
745 you just want to convert random binary data into UTF-8, you can't.
746 B<Any random collection of bytes isn't well-formed UTF-8>. You can
747 use C<unpack("C*", $string)> for the former, and you can create
748 well-formed Unicode data by C<pack("U*", 0xff, ...)>.
752 How Do I Display Unicode? How Do I Input Unicode?
754 See http://www.alanwood.net/unicode/ and
755 http://www.cl.cam.ac.uk/~mgk25/unicode.html
759 How Does Unicode Work With Traditional Locales?
761 In Perl, not very well. Avoid using locales through the C<locale>
762 pragma. Use only one or the other. But see L<perlrun> for the
763 description of the C<-C> switch and its environment counterpart,
764 C<$ENV{PERL_UNICODE}> to see how to enable various Unicode features,
765 for example by using locale settings.
769 =head2 Hexadecimal Notation
771 The Unicode standard prefers using hexadecimal notation because
772 that more clearly shows the division of Unicode into blocks of 256 characters.
773 Hexadecimal is also simply shorter than decimal. You can use decimal
774 notation, too, but learning to use hexadecimal just makes life easier
775 with the Unicode standard. The C<U+HHHH> notation uses hexadecimal,
778 The C<0x> prefix means a hexadecimal number, the digits are 0-9 I<and>
779 a-f (or A-F, case doesn't matter). Each hexadecimal digit represents
780 four bits, or half a byte. C<print 0x..., "\n"> will show a
781 hexadecimal number in decimal, and C<printf "%x\n", $decimal> will
782 show a decimal number in hexadecimal. If you have just the
783 "hex digits" of a hexadecimal number, you can use the C<hex()> function.
785 print 0x0009, "\n"; # 9
786 print 0x000a, "\n"; # 10
787 print 0x000f, "\n"; # 15
788 print 0x0010, "\n"; # 16
789 print 0x0011, "\n"; # 17
790 print 0x0100, "\n"; # 256
792 print 0x0041, "\n"; # 65
794 printf "%x\n", 65; # 41
795 printf "%#x\n", 65; # 0x41
797 print hex("41"), "\n"; # 65
799 =head2 Further Resources
807 http://www.unicode.org/
813 http://www.unicode.org/unicode/faq/
819 http://www.unicode.org/glossary/
823 Unicode Useful Resources
825 http://www.unicode.org/unicode/onlinedat/resources.html
829 Unicode and Multilingual Support in HTML, Fonts, Web Browsers and Other Applications
831 http://www.alanwood.net/unicode/
835 UTF-8 and Unicode FAQ for Unix/Linux
837 http://www.cl.cam.ac.uk/~mgk25/unicode.html
841 Legacy Character Sets
843 http://www.czyborra.com/
844 http://www.eki.ee/letter/
848 The Unicode support files live within the Perl installation in the
851 $Config{installprivlib}/unicore
853 in Perl 5.8.0 or newer, and
855 $Config{installprivlib}/unicode
857 in the Perl 5.6 series. (The renaming to F<lib/unicore> was done to
858 avoid naming conflicts with lib/Unicode in case-insensitive filesystems.)
859 The main Unicode data file is F<UnicodeData.txt> (or F<Unicode.301> in
860 Perl 5.6.1.) You can find the C<$Config{installprivlib}> by
862 perl "-V:installprivlib"
864 You can explore various information from the Unicode data files using
865 the C<Unicode::UCD> module.
869 =head1 UNICODE IN OLDER PERLS
871 If you cannot upgrade your Perl to 5.8.0 or later, you can still
872 do some Unicode processing by using the modules C<Unicode::String>,
873 C<Unicode::Map8>, and C<Unicode::Map>, available from CPAN.
874 If you have the GNU recode installed, you can also use the
875 Perl front-end C<Convert::Recode> for character conversions.
877 The following are fast conversions from ISO 8859-1 (Latin-1) bytes
878 to UTF-8 bytes and back, the code works even with older Perl 5 versions.
880 # ISO 8859-1 to UTF-8
881 s/([\x80-\xFF])/chr(0xC0|ord($1)>>6).chr(0x80|ord($1)&0x3F)/eg;
883 # UTF-8 to ISO 8859-1
884 s/([\xC2\xC3])([\x80-\xBF])/chr(ord($1)<<6&0xC0|ord($2)&0x3F)/eg;
888 L<perlunicode>, L<Encode>, L<encoding>, L<open>, L<utf8>, L<bytes>,
889 L<perlretut>, L<perlrun>, L<Unicode::Collate>, L<Unicode::Normalize>,
892 =head1 ACKNOWLEDGMENTS
894 Thanks to the kind readers of the perl5-porters@perl.org,
895 perl-unicode@perl.org, linux-utf8@nl.linux.org, and unicore@unicode.org
896 mailing lists for their valuable feedback.
898 =head1 AUTHOR, COPYRIGHT, AND LICENSE
900 Copyright 2001-2002 Jarkko Hietaniemi E<lt>jhi@iki.fiE<gt>
902 This document may be distributed under the same terms as Perl itself.