pod/perltrap.pod

   1 =head1 NAME
   2
   3 perltrap - Perl traps for the unwary
   4
   5 =head1 DESCRIPTION
   6
   7 The biggest trap of all is forgetting to use the B<-w> switch; see
   8 L<perlrun>.  The second biggest trap is not making your entire program
   9 runnable under C<use strict>.
  10
  11 =head2 Awk Traps
  12
  13 Accustomed B<awk> users should take special note of the following:
  14
  15 =over 4
  16
  17 =item *
  18
  19 The English module, loaded via
  20
  21     use English;
  22
  23 allows you to refer to special variables (like C<$/>) with names (like
  24 C<$RS>), as though they were in B<awk>; see L<perlvar> for details.
  25
  26 =item *
  27
  28 Semicolons are required after all simple statements in Perl (except
  29 at the end of a block).  Newline is not a statement delimiter.
  30
  31 =item *
  32
  33 Curly brackets are required on C<if>s and C<while>s.
  34
  35 =item *
  36
  37 Variables begin with "$" or "@" in Perl.
  38
  39 =item *
  40
  41 Arrays index from 0.  Likewise string positions in substr() and
  42 index().
  43
  44 =item *
  45
  46 You have to decide whether your array has numeric or string indices.
  47
  48 =item *
  49
  50 Hash values do not spring into existence upon mere reference.
  51
  52 =item *
  53
  54 You have to decide whether you want to use string or numeric
  55 comparisons.
  56
  57 =item *
  58
  59 Reading an input line does not split it for you.  You get to split it
  60 to an array yourself.  And the split() operator has different
  61 arguments than B<awk>'s.
  62
  63 =item *
  64
  65 The current input line is normally in $_, not $0.  It generally does
  66 not have the newline stripped.  ($0 is the name of the program
  67 executed.)  See L<perlvar>.
  68
  69 =item *
  70
  71 $E<lt>I<digit>E<gt> does not refer to fields--it refers to substrings matched
  72 by the last match pattern.
  73
  74 =item *
  75
  76 The print() statement does not add field and record separators unless
  77 you set C<$,> and C<$\>.  You can set $OFS and $ORS if you're using
  78 the English module.
  79
  80 =item *
  81
  82 You must open your files before you print to them.
  83
  84 =item *
  85
  86 The range operator is "..", not comma.  The comma operator works as in
  87 C.
  88
  89 =item *
  90
  91 The match operator is "=~", not "~".  ("~" is the one's complement
  92 operator, as in C.)
  93
  94 =item *
  95
  96 The exponentiation operator is "**", not "^".  "^" is the XOR
  97 operator, as in C.  (You know, one could get the feeling that B<awk> is
  98 basically incompatible with C.)
  99
 100 =item *
 101
 102 The concatenation operator is ".", not the null string.  (Using the
 103 null string would render C</pat/ /pat/> unparsable, because the third slash
 104 would be interpreted as a division operator--the tokenizer is in fact
 105 slightly context sensitive for operators like "/", "?", and "E<gt>".
 106 And in fact, "." itself can be the beginning of a number.)
 107
 108 =item *
 109
 110 The C<next>, C<exit>, and C<continue> keywords work differently.
 111
 112 =item *
 113
 114
 115 The following variables work differently:
 116
 117       Awk       Perl
 118       ARGC      $#ARGV or scalar @ARGV
 119       ARGV[0]   $0
 120       FILENAME  $ARGV
 121       FNR       $. - something
 122       FS        (whatever you like)
 123       NF        $#Fld, or some such
 124       NR        $.
 125       OFMT      $#
 126       OFS       $,
 127       ORS       $\
 128       RLENGTH   length($&)
 129       RS        $/
 130       RSTART    length($`)
 131       SUBSEP    $;
 132
 133 =item *
 134
 135 You cannot set $RS to a pattern, only a string.
 136
 137 =item *
 138
 139 When in doubt, run the B<awk> construct through B<a2p> and see what it
 140 gives you.
 141
 142 =back
 143
 144 =head2 C Traps
 145
 146 Cerebral C programmers should take note of the following:
 147
 148 =over 4
 149
 150 =item *
 151
 152 Curly brackets are required on C<if>'s and C<while>'s.
 153
 154 =item *
 155
 156 You must use C<elsif> rather than C<else if>.
 157
 158 =item *
 159
 160 The C<break> and C<continue> keywords from C become in
 161 Perl C<last> and C<next>, respectively.
 162 Unlike in C, these do I<NOT> work within a C<do { } while> construct.
 163
 164 =item *
 165
 166 There's no switch statement.  (But it's easy to build one on the fly.)
 167
 168 =item *
 169
 170 Variables begin with "$" or "@" in Perl.
 171
 172 =item *
 173
 174 C<printf()> does not implement the "*" format for interpolating
 175 field widths, but it's trivial to use interpolation of double-quoted
 176 strings to achieve the same effect.
 177
 178 =item *
 179
 180 Comments begin with "#", not "/*".
 181
 182 =item *
 183
 184 You can't take the address of anything, although a similar operator
 185 in Perl is the backslash, which creates a reference.
 186
 187 =item *
 188
 189 C<ARGV> must be capitalized.  C<$ARGV[0]> is C's C<argv[1]>, and C<argv[0]>
 190 ends up in C<$0>.
 191
 192 =item *
 193
 194 System calls such as link(), unlink(), rename(), etc. return nonzero for
 195 success, not 0.
 196
 197 =item *
 198
 199 Signal handlers deal with signal names, not numbers.  Use C<kill -l>
 200 to find their names on your system.
 201
 202 =back
 203
 204 =head2 Sed Traps
 205
 206 Seasoned B<sed> programmers should take note of the following:
 207
 208 =over 4
 209
 210 =item *
 211
 212 Backreferences in substitutions use "$" rather than "\".
 213
 214 =item *
 215
 216 The pattern matching metacharacters "(", ")", and "|" do not have backslashes
 217 in front.
 218
 219 =item *
 220
 221 The range operator is C<...>, rather than comma.
 222
 223 =back
 224
 225 =head2 Shell Traps
 226
 227 Sharp shell programmers should take note of the following:
 228
 229 =over 4
 230
 231 =item *
 232
 233 The backtick operator does variable interpolation without regard to
 234 the presence of single quotes in the command.
 235
 236 =item *
 237
 238 The backtick operator does no translation of the return value, unlike B<csh>.
 239
 240 =item *
 241
 242 Shells (especially B<csh>) do several levels of substitution on each
 243 command line.  Perl does substitution in only certain constructs
 244 such as double quotes, backticks, angle brackets, and search patterns.
 245
 246 =item *
 247
 248 Shells interpret scripts a little bit at a time.  Perl compiles the
 249 entire program before executing it (except for C<BEGIN> blocks, which
 250 execute at compile time).
 251
 252 =item *
 253
 254 The arguments are available via @ARGV, not $1, $2, etc.
 255
 256 =item *
 257
 258 The environment is not automatically made available as separate scalar
 259 variables.
 260
 261 =back
 262
 263 =head2 Perl Traps
 264
 265 Practicing Perl Programmers should take note of the following:
 266
 267 =over 4
 268
 269 =item *
 270
 271 Remember that many operations behave differently in a list
 272 context than they do in a scalar one.  See L<perldata> for details.
 273
 274 =item *
 275
 276 Avoid barewords if you can, especially all lowercase ones.
 277 You can't tell by just looking at it whether a bareword is
 278 a function or a string.  By using quotes on strings and
 279 parentheses on function calls, you won't ever get them confused.
 280
 281 =item *
 282
 283 You cannot discern from mere inspection which builtins
 284 are unary operators (like chop() and chdir())
 285 and which are list operators (like print() and unlink()).
 286 (User-defined subroutines can be B<only> list operators, never
 287 unary ones.)  See L<perlop>.
 288
 289 =item *
 290
 291 People have a hard time remembering that some functions
 292 default to $_, or @ARGV, or whatever, but that others which
 293 you might expect to do not.
 294
 295 =item *
 296
 297 The E<lt>FHE<gt> construct is not the name of the filehandle, it is a readline
 298 operation on that handle.  The data read is assigned to $_ only if the
 299 file read is the sole condition in a while loop:
 300
 301     while (<FH>)      { }
 302     while (defined($_ = <FH>)) { }..
 303     <FH>;  # data discarded!
 304
 305 =item *
 306
 307 Remember not to use "C<=>" when you need "C<=~>";
 308 these two constructs are quite different:
 309
 310     $x =  /foo/;
 311     $x =~ /foo/;
 312
 313 =item *
 314
 315 The C<do {}> construct isn't a real loop that you can use
 316 loop control on.
 317
 318 =item *
 319
 320 Use C<my()> for local variables whenever you can get away with
 321 it (but see L<perlform> for where you can't).
 322 Using C<local()> actually gives a local value to a global
 323 variable, which leaves you open to unforeseen side-effects
 324 of dynamic scoping.
 325
 326 =item *
 327
 328 If you localize an exported variable in a module, its exported value will
 329 not change.  The local name becomes an alias to a new value but the
 330 external name is still an alias for the original.
 331
 332 =back
 333
 334 =head2 Perl4 to Perl5 Traps
 335
 336 Practicing Perl4 Programmers should take note of the following
 337 Perl4-to-Perl5 specific traps.
 338
 339 They're crudely ordered according to the following list:
 340
 341 =over 4
 342
 343 =item Discontinuance, Deprecation, and BugFix traps
 344
 345 Anything that's been fixed as a perl4 bug, removed as a perl4 feature
 346 or deprecated as a perl4 feature with the intent to encourage usage of
 347 some other perl5 feature.
 348
 349 =item Parsing Traps
 350
 351 Traps that appear to stem from the new parser.
 352
 353 =item Numerical Traps
 354
 355 Traps having to do with numerical or mathematical operators.
 356
 357 =item General data type traps
 358
 359 Traps involving perl standard data types.
 360
 361 =item Context Traps - scalar, list contexts
 362
 363 Traps related to context within lists, scalar statements/declarations.
 364
 365 =item Precedence Traps
 366
 367 Traps related to the precedence of parsing, evaluation, and execution of
 368 code.
 369
 370 =item General Regular Expression Traps using s///, etc.
 371
 372 Traps related to the use of pattern matching.
 373
 374 =item Subroutine, Signal, Sorting Traps
 375
 376 Traps related to the use of signals and signal handlers, general subroutines,
 377 and sorting, along with sorting subroutines.
 378
 379 =item OS Traps
 380
 381 OS-specific traps.
 382
 383 =item DBM Traps
 384
 385 Traps specific to the use of C<dbmopen()>, and specific dbm implementations.
 386
 387 =item Unclassified Traps
 388
 389 Everything else.
 390
 391 =back
 392
 393 If you find an example of a conversion trap that is not listed here,
 394 please submit it to Bill Middleton <F<wjm@best.com>> for inclusion.
 395 Also note that at least some of these can be caught with B<-w>.
 396
 397 =head2 Discontinuance, Deprecation, and BugFix traps
 398
 399 Anything that has been discontinued, deprecated, or fixed as
 400 a bug from perl4.
 401
 402 =over 4
 403
 404 =item * Discontinuance
 405
 406 Symbols starting with "_" are no longer forced into package main, except
 407 for C<$_> itself (and C<@_>, etc.).
 408
 409     package test;
 410     $_legacy = 1;
 411
 412     package main;
 413     print "\$_legacy is ",$_legacy,"\n";
 414
 415     # perl4 prints: $_legacy is 1
 416     # perl5 prints: $_legacy is
 417
 418 =item * Deprecation
 419
 420 Double-colon is now a valid package separator in a variable name.  Thus these
 421 behave differently in perl4 vs. perl5, because the packages don't exist.
 422
 423     $a=1;$b=2;$c=3;$var=4;
 424     print "$a::$b::$c ";
 425     print "$var::abc::xyz\n";
 426
 427     # perl4 prints: 1::2::3 4::abc::xyz
 428     # perl5 prints: 3
 429
 430 Given that C<::> is now the preferred package delimiter, it is debatable
 431 whether this should be classed as a bug or not.
 432 (The older package delimiter, ' ,is used here)
 433
 434     $x = 10 ;
 435     print "x=${'x}\n" ;
 436
 437     # perl4 prints: x=10
 438     # perl5 prints: Can't find string terminator "'" anywhere before EOF
 439
 440 Also see precedence traps, for parsing C<$:>.
 441
 442 =item * BugFix
 443
 444 The second and third arguments of C<splice()> are now evaluated in scalar
 445 context (as the Camel says) rather than list context.
 446
 447     sub sub1{return(0,2) }          # return a 2-elem array
 448     sub sub2{ return(1,2,3)}        # return a 3-elem array
 449     @a1 = ("a","b","c","d","e");
 450     @a2 = splice(@a1,&sub1,&sub2);
 451     print join(' ',@a2),"\n";
 452
 453     # perl4 prints: a b
 454     # perl5 prints: c d e
 455
 456 =item * Discontinuance
 457
 458 You can't do a C<goto> into a block that is optimized away.  Darn.
 459
 460     goto marker1;
 461
 462     for(1){
 463     marker1:
 464         print "Here I is!\n";
 465     }
 466
 467     # perl4 prints: Here I is!
 468     # perl5 dumps core (SEGV)
 469
 470 =item * Discontinuance
 471
 472 It is no longer syntactically legal to use whitespace as the name
 473 of a variable, or as a delimiter for any kind of quote construct.
 474 Double darn.
 475
 476     $a = ("foo bar");
 477     $b = q baz ;
 478     print "a is $a, b is $b\n";
 479
 480     # perl4 prints: a is foo bar, b is baz
 481     # perl5 errors: Bareword found where operator expected
 482
 483 =item * Discontinuance
 484
 485 The archaic while/if BLOCK BLOCK syntax is no longer supported.
 486
 487     if { 1 } {
 488         print "True!";
 489     }
 490     else {
 491         print "False!";
 492     }
 493
 494     # perl4 prints: True!
 495     # perl5 errors: syntax error at test.pl line 1, near "if {"
 496
 497 =item * BugFix
 498
 499 The C<**> operator now binds more tightly than unary minus.
 500 It was documented to work this way before, but didn't.
 501
 502     print -4**2,"\n";
 503
 504     # perl4 prints: 16
 505     # perl5 prints: -16
 506
 507 =item * Discontinuance
 508
 509 The meaning of C<foreach{}> has changed slightly when it is iterating over a
 510 list which is not an array.  This used to assign the list to a
 511 temporary array, but no longer does so (for efficiency).  This means
 512 that you'll now be iterating over the actual values, not over copies of
 513 the values.  Modifications to the loop variable can change the original
 514 values.
 515
 516     @list = ('ab','abc','bcd','def');
 517     foreach $var (grep(/ab/,@list)){
 518         $var = 1;
 519     }
 520     print (join(':',@list));
 521
 522     # perl4 prints: ab:abc:bcd:def
 523     # perl5 prints: 1:1:bcd:def
 524
 525 To retain Perl4 semantics you need to assign your list
 526 explicitly to a temporary array and then iterate over that.  For
 527 example, you might need to change
 528
 529     foreach $var (grep(/ab/,@list)){
 530
 531 to
 532
 533     foreach $var (@tmp = grep(/ab/,@list)){
 534
 535 Otherwise changing $var will clobber the values of @list.  (This most often
 536 happens when you use C<$_> for the loop variable, and call subroutines in
 537 the loop that don't properly localize C<$_>.)
 538
 539 =item * Discontinuance
 540
 541 C<split> with no arguments now behaves like C<split ' '> (which doesn't
 542 return an initial null field if $_ starts with whitespace), it used to
 543 behave like C<split /\s+/> (which does).
 544
 545     $_ = ' hi mom';
 546     print join(':', split);
 547
 548     # perl4 prints: :hi:mom
 549     # perl5 prints: hi:mom
 550
 551 =item * BugFix
 552
 553 Perl 4 would ignore any text which was attached to an B<-e> switch,
 554 always taking the code snippet from the following arg.  Additionally, it
 555 would silently accept an B<-e> switch without a following arg.  Both of
 556 these behaviors have been fixed.
 557
 558     perl -e'print "attached to -e"' 'print "separate arg"'
 559
 560     # perl4 prints: separate arg
 561     # perl5 prints: attached to -e
 562
 563     perl -e
 564
 565     # perl4 prints:
 566     # perl5 dies: No code specified for -e.
 567
 568 =item * Discontinuance
 569
 570 In Perl 4 the return value of C<push> was undocumented, but it was
 571 actually the last value being pushed onto the target list.  In Perl 5
 572 the return value of C<push> is documented, but has changed, it is the
 573 number of elements in the resulting list.
 574
 575     @x = ('existing');
 576     print push(@x, 'first new', 'second new');
 577
 578     # perl4 prints: second new
 579     # perl5 prints: 3
 580
 581 =item * Discontinuance
 582
 583 In Perl 4 (and versions of Perl 5 before 5.004), C<'\r'> characters in
 584 Perl code were silently allowed, although they could cause (mysterious!)
 585 failures in certain constructs, particularly here documents.  Now,
 586 C<'\r'> characters cause an immediate fatal error.  (Note: In this
 587 example, the notation B<\015> represents the incorrect line
 588 ending. Depending upon your text viewer, it will look different.)
 589
 590     print "foo";\015
 591     print "bar";
 592
 593     # perl4     prints: foobar
 594     # perl5.003 prints: foobar
 595     # perl5.004 dies: Illegal character \015 (carriage return)
 596
 597 See L<perldiag> for full details.
 598
 599 =item * Deprecation
 600
 601 Some error messages will be different.
 602
 603 =item * Discontinuance
 604
 605 Some bugs may have been inadvertently removed.  :-)
 606
 607 =back
 608
 609 =head2 Parsing Traps
 610
 611 Perl4-to-Perl5 traps from having to do with parsing.
 612
 613 =over 4
 614
 615 =item * Parsing
 616
 617 Note the space between . and =
 618
 619     $string . = "more string";
 620     print $string;
 621
 622     # perl4 prints: more string
 623     # perl5 prints: syntax error at - line 1, near ". ="
 624
 625 =item * Parsing
 626
 627 Better parsing in perl 5
 628
 629     sub foo {}
 630     &foo
 631     print("hello, world\n");
 632
 633     # perl4 prints: hello, world
 634     # perl5 prints: syntax error
 635
 636 =item * Parsing
 637
 638 "if it looks like a function, it is a function" rule.
 639
 640   print
 641     ($foo == 1) ? "is one\n" : "is zero\n";
 642
 643     # perl4 prints: is zero
 644     # perl5 warns: "Useless use of a constant in void context" if using -w
 645
 646 =back
 647
 648 =head2 Numerical Traps
 649
 650 Perl4-to-Perl5 traps having to do with numerical operators,
 651 operands, or output from same.
 652
 653 =over 5
 654
 655 =item * Numerical
 656
 657 Formatted output and significant digits
 658
 659     print 7.373504 - 0, "\n";
 660     printf "%20.18f\n", 7.373504 - 0;
 661
 662     # Perl4 prints:
 663     7.375039999999996141
 664     7.37503999999999614
 665
 666     # Perl5 prints:
 667     7.373504
 668     7.37503999999999614
 669
 670 =item * Numerical
 671
 672 This specific item has been deleted.  It demonstrated how the auto-increment
 673 operator would not catch when a number went over the signed int limit.  Fixed
 674 in version 5.003_04.  But always be wary when using large integers.
 675 If in doubt:
 676
 677    use Math::BigInt;
 678
 679 =item * Numerical
 680
 681 Assignment of return values from numeric equality tests
 682 does not work in perl5 when the test evaluates to false (0).
 683 Logical tests now return an null, instead of 0
 684
 685     $p = ($test == 1);
 686     print $p,"\n";
 687
 688     # perl4 prints: 0
 689     # perl5 prints:
 690
 691 Also see L<"General Regular Expression Traps using s///, etc.">
 692 for another example of this new feature...
 693
 694 =back
 695
 696 =head2 General data type traps
 697
 698 Perl4-to-Perl5 traps involving most data-types, and their usage
 699 within certain expressions and/or context.
 700
 701 =over 5
 702
 703 =item * (Arrays)
 704
 705 Negative array subscripts now count from the end of the array.
 706
 707     @a = (1, 2, 3, 4, 5);
 708     print "The third element of the array is $a[3] also expressed as $a[-2] \n";
 709
 710     # perl4 prints: The third element of the array is 4 also expressed as
 711     # perl5 prints: The third element of the array is 4 also expressed as 4
 712
 713 =item * (Arrays)
 714
 715 Setting C<$#array> lower now discards array elements, and makes them
 716 impossible to recover.
 717
 718     @a = (a,b,c,d,e);
 719     print "Before: ",join('',@a);
 720     $#a =1;
 721     print ", After: ",join('',@a);
 722     $#a =3;
 723     print ", Recovered: ",join('',@a),"\n";
 724
 725     # perl4 prints: Before: abcde, After: ab, Recovered: abcd
 726     # perl5 prints: Before: abcde, After: ab, Recovered: ab
 727
 728 =item * (Hashes)
 729
 730 Hashes get defined before use
 731
 732     local($s,@a,%h);
 733     die "scalar \$s defined" if defined($s);
 734     die "array \@a defined" if defined(@a);
 735     die "hash \%h defined" if defined(%h);
 736
 737     # perl4 prints:
 738     # perl5 dies: hash %h defined
 739
 740 =item * (Globs)
 741
 742 glob assignment from variable to variable will fail if the assigned
 743 variable is localized subsequent to the assignment
 744
 745     @a = ("This is Perl 4");
 746     *b = *a;
 747     local(@a);
 748     print @b,"\n";
 749
 750     # perl4 prints: This is Perl 4
 751     # perl5 prints:
 752
 753     # Another example
 754
 755     *fred = *barney; # fred is aliased to barney
 756     @barney = (1, 2, 4);
 757     # @fred;
 758     print "@fred";  # should print "1, 2, 4"
 759
 760     # perl4 prints: 1 2 4
 761     # perl5 prints: In string, @fred now must be written as \@fred
 762
 763 =item * (Scalar String)
 764
 765 Changes in unary negation (of strings)
 766 This change effects both the return value and what it
 767 does to auto(magic)increment.
 768
 769     $x = "aaa";
 770     print ++$x," : ";
 771     print -$x," : ";
 772     print ++$x,"\n";
 773
 774     # perl4 prints: aab : -0 : 1
 775     # perl5 prints: aab : -aab : aac
 776
 777 =item * (Constants)
 778
 779 perl 4 lets you modify constants:
 780
 781     $foo = "x";
 782     &mod($foo);
 783     for ($x = 0; $x < 3; $x++) {
 784         &mod("a");
 785     }
 786     sub mod {
 787         print "before: $_[0]";
 788         $_[0] = "m";
 789         print "  after: $_[0]\n";
 790     }
 791
 792     # perl4:
 793     # before: x  after: m
 794     # before: a  after: m
 795     # before: m  after: m
 796     # before: m  after: m
 797
 798     # Perl5:
 799     # before: x  after: m
 800     # Modification of a read-only value attempted at foo.pl line 12.
 801     # before: a
 802
 803 =item * (Scalars)
 804
 805 The behavior is slightly different for:
 806
 807     print "$x", defined $x
 808
 809     # perl 4: 1
 810     # perl 5: <no output, $x is not called into existence>
 811
 812 =item * (Variable Suicide)
 813
 814 Variable suicide behavior is more consistent under Perl 5.
 815 Perl5 exhibits the same behavior for hashes and scalars,
 816 that perl4 exhibits for only scalars.
 817
 818     $aGlobal{ "aKey" } = "global value";
 819     print "MAIN:", $aGlobal{"aKey"}, "\n";
 820     $GlobalLevel = 0;
 821     &test( *aGlobal );
 822
 823     sub test {
 824         local( *theArgument ) = @_;
 825         local( %aNewLocal ); # perl 4 != 5.001l,m
 826         $aNewLocal{"aKey"} = "this should never appear";
 827         print "SUB: ", $theArgument{"aKey"}, "\n";
 828         $aNewLocal{"aKey"} = "level $GlobalLevel";   # what should print
 829         $GlobalLevel++;
 830         if( $GlobalLevel<4 ) {
 831             &test( *aNewLocal );
 832         }
 833     }
 834
 835     # Perl4:
 836     # MAIN:global value
 837     # SUB: global value
 838     # SUB: level 0
 839     # SUB: level 1
 840     # SUB: level 2
 841
 842     # Perl5:
 843     # MAIN:global value
 844     # SUB: global value
 845     # SUB: this should never appear
 846     # SUB: this should never appear
 847     # SUB: this should never appear
 848
 849 =back
 850
 851 =head2 Context Traps - scalar, list contexts
 852
 853 =over 5
 854
 855 =item * (list context)
 856
 857 The elements of argument lists for formats are now evaluated in list
 858 context.  This means you can interpolate list values now.
 859
 860     @fmt = ("foo","bar","baz");
 861     format STDOUT=
 862     @<<<<< @||||| @>>>>>
 863     @fmt;
 864     .
 865     write;
 866
 867     # perl4 errors:  Please use commas to separate fields in file
 868     # perl5 prints: foo     bar      baz
 869
 870 =item * (scalar context)
 871
 872 The C<caller()> function now returns a false value in a scalar context
 873 if there is no caller.  This lets library files determine if they're
 874 being required.
 875
 876     caller() ? (print "You rang?\n") : (print "Got a 0\n");
 877
 878     # perl4 errors: There is no caller
 879     # perl5 prints: Got a 0
 880
 881 =item * (scalar context)
 882
 883 The comma operator in a scalar context is now guaranteed to give a
 884 scalar context to its arguments.
 885
 886     @y= ('a','b','c');
 887     $x = (1, 2, @y);
 888     print "x = $x\n";
 889
 890     # Perl4 prints:  x = c   # Thinks list context interpolates list
 891     # Perl5 prints:  x = 3   # Knows scalar uses length of list
 892
 893 =item * (list, builtin)
 894
 895 C<sprintf()> funkiness (array argument converted to scalar array count)
 896 This test could be added to t/op/sprintf.t
 897
 898     @z = ('%s%s', 'foo', 'bar');
 899     $x = sprintf(@z);
 900     if ($x eq 'foobar') {print "ok 2\n";} else {print "not ok 2 '$x'\n";}
 901
 902     # perl4 prints: ok 2
 903     # perl5 prints: not ok 2
 904
 905 C<printf()> works fine, though:
 906
 907     printf STDOUT (@z);
 908     print "\n";
 909
 910     # perl4 prints: foobar
 911     # perl5 prints: foobar
 912
 913 Probably a bug.
 914
 915 =back
 916
 917 =head2 Precedence Traps
 918
 919 Perl4-to-Perl5 traps involving precedence order.
 920
 921 =over 5
 922
 923 =item * Precedence
 924
 925 LHS vs. RHS when both sides are getting an op.
 926
 927     @arr = ( 'left', 'right' );
 928     $a{shift @arr} = shift @arr;
 929     print join( ' ', keys %a );
 930
 931     # perl4 prints: left
 932     # perl5 prints: right
 933
 934 =item * Precedence
 935
 936 These are now semantic errors because of precedence:
 937
 938     @list = (1,2,3,4,5);
 939     %map = ("a",1,"b",2,"c",3,"d",4);
 940     $n = shift @list + 2;   # first item in list plus 2
 941     print "n is $n, ";
 942     $m = keys %map + 2;     # number of items in hash plus 2
 943     print "m is $m\n";
 944
 945     # perl4 prints: n is 3, m is 6
 946     # perl5 errors and fails to compile
 947
 948 =item * Precedence
 949
 950 The precedence of assignment operators is now the same as the precedence
 951 of assignment.  Perl 4 mistakenly gave them the precedence of the associated
 952 operator.  So you now must parenthesize them in expressions like
 953
 954     /foo/ ? ($a += 2) : ($a -= 2);
 955
 956 Otherwise
 957
 958     /foo/ ? $a += 2 : $a -= 2
 959
 960 would be erroneously parsed as
 961
 962     (/foo/ ? $a += 2 : $a) -= 2;
 963
 964 On the other hand,
 965
 966     $a += /foo/ ? 1 : 2;
 967
 968 now works as a C programmer would expect.
 969
 970 =item * Precedence
 971
 972     open FOO || die;
 973
 974 is now incorrect.  You need parentheses around the filehandle.
 975 Otherwise, perl5 leaves the statement as its default precedence:
 976
 977     open(FOO || die);
 978
 979     # perl4 opens or dies
 980     # perl5 errors: Precedence problem: open FOO should be open(FOO)
 981
 982 =item * Precedence
 983
 984 perl4 gives the special variable, C<$:> precedence, where perl5
 985 treats C<$::> as main C<package>
 986
 987     $a = "x"; print "$::a";
 988
 989     # perl 4 prints: -:a
 990     # perl 5 prints: x
 991
 992 =item * Precedence
 993
 994 concatenation precedence over filetest operator?
 995
 996     -e $foo .= "q"
 997
 998     # perl4 prints: no output
 999     # perl5 prints: Can't modify -e in concatenation
1000
1001 =item * Precedence
1002
1003 Assignment to value takes precedence over assignment to key in
1004 perl5 when using the shift operator on both sides.
1005
1006     @arr = ( 'left', 'right' );
1007     $a{shift @arr} = shift @arr;
1008     print join( ' ', keys %a );
1009
1010     # perl4 prints: left
1011     # perl5 prints: right
1012
1013 =back
1014
1015 =head2 General Regular Expression Traps using s///, etc.
1016
1017 All types of RE traps.
1018
1019 =over 5
1020
1021 =item * Regular Expression
1022
1023 C<s'$lhs'$rhs'> now does no interpolation on either side.  It used to
1024 interpolate C<$lhs> but not C<$rhs>.  (And still does not match a literal
1025 '$' in string)
1026
1027     $a=1;$b=2;
1028     $string = '1 2 $a $b';
1029     $string =~ s'$a'$b';
1030     print $string,"\n";
1031
1032     # perl4 prints: $b 2 $a $b
1033     # perl5 prints: 1 2 $a $b
1034
1035 =item * Regular Expression
1036
1037 C<m//g> now attaches its state to the searched string rather than the
1038 regular expression.  (Once the scope of a block is left for the sub, the
1039 state of the searched string is lost)
1040
1041     $_ = "ababab";
1042     while(m/ab/g){
1043         &doit("blah");
1044     }
1045     sub doit{local($_) = shift; print "Got $_ "}
1046
1047     # perl4 prints: blah blah blah
1048     # perl5 prints: infinite loop blah...
1049
1050 =item * Regular Expression
1051
1052 Currently, if you use the C<m//o> qualifier on a regular expression
1053 within an anonymous sub, I<all> closures generated from that anonymous
1054 sub will use the regular expression as it was compiled when it was used
1055 the very first time in any such closure.  For instance, if you say
1056
1057     sub build_match {
1058         my($left,$right) = @_;
1059         return sub { $_[0] =~ /$left stuff $right/o; };
1060     }
1061
1062 build_match() will always return a sub which matches the contents of
1063 C<$left> and C<$right> as they were the I<first> time that build_match()
1064 was called, not as they are in the current call.
1065
1066 This is probably a bug, and may change in future versions of Perl.
1067
1068 =item * Regular Expression
1069
1070 If no parentheses are used in a match, Perl4 sets C<$+> to
1071 the whole match, just like C<$&>. Perl5 does not.
1072
1073     "abcdef" =~ /b.*e/;
1074     print "\$+ = $+\n";
1075
1076     # perl4 prints: bcde
1077     # perl5 prints:
1078
1079 =item * Regular Expression
1080
1081 substitution now returns the null string if it fails
1082
1083     $string = "test";
1084     $value = ($string =~ s/foo//);
1085     print $value, "\n";
1086
1087     # perl4 prints: 0
1088     # perl5 prints:
1089
1090 Also see L<Numerical Traps> for another example of this new feature.
1091
1092 =item * Regular Expression
1093
1094 C<s`lhs`rhs`> (using backticks) is now a normal substitution, with no
1095 backtick expansion
1096
1097     $string = "";
1098     $string =~ s`^`hostname`;
1099     print $string, "\n";
1100
1101     # perl4 prints: <the local hostname>
1102     # perl5 prints: hostname
1103
1104 =item * Regular Expression
1105
1106 Stricter parsing of variables used in regular expressions
1107
1108     s/^([^$grpc]*$grpc[$opt$plus$rep]?)//o;
1109
1110     # perl4: compiles w/o error
1111     # perl5: with Scalar found where operator expected ..., near "$opt$plus"
1112
1113 an added component of this example, apparently from the same script, is
1114 the actual value of the s'd string after the substitution.
1115 C<[$opt]> is a character class in perl4 and an array subscript in perl5
1116
1117     $grpc = 'a';
1118     $opt  = 'r';
1119     $_ = 'bar';
1120     s/^([^$grpc]*$grpc[$opt]?)/foo/;
1121     print ;
1122
1123     # perl4 prints: foo
1124     # perl5 prints: foobar
1125
1126 =item * Regular Expression
1127
1128 Under perl5, C<m?x?> matches only once, like C<?x?>. Under perl4, it matched
1129 repeatedly, like C</x/> or C<m!x!>.
1130
1131     $test = "once";
1132     sub match { $test =~ m?once?; }
1133     &match();
1134     if( &match() ) {
1135         # m?x? matches more then once
1136         print "perl4\n";
1137     } else {
1138         # m?x? matches only once
1139         print "perl5\n";
1140     }
1141
1142     # perl4 prints: perl4
1143     # perl5 prints: perl5
1144
1145
1146 =item * Regular Expression
1147
1148 Under perl4 and upto version 5.003, a failed C<m//g> match used to
1149 reset the internal iterator, so that subsequent C<m//g> match attempts
1150 began from the beginning of the string.  In perl version 5.004 and later,
1151 failed C<m//g> matches do not reset the iterator position (which can be
1152 found using the C<pos()> function--see L<perlfunc/pos>).
1153
1154     $test = "foop";
1155     for (1..3) {
1156         print $1 while ($test =~ /(o)/g);
1157         # pos $test = 0;     # to get old behavior
1158     }
1159
1160     # perl4     prints: oooooo
1161     # perl5.004 prints: oo
1162
1163 You may always reset the iterator yourself as shown in the commented line
1164 to get the old behavior.
1165
1166 =back
1167
1168 =head2 Subroutine, Signal, Sorting Traps
1169
1170 The general group of Perl4-to-Perl5 traps having to do with
1171 Signals, Sorting, and their related subroutines, as well as
1172 general subroutine traps.  Includes some OS-Specific traps.
1173
1174 =over 5
1175
1176 =item * (Signals)
1177
1178 Barewords that used to look like strings to Perl will now look like subroutine
1179 calls if a subroutine by that name is defined before the compiler sees them.
1180
1181     sub SeeYa { warn"Hasta la vista, baby!" }
1182     $SIG{'TERM'} = SeeYa;
1183     print "SIGTERM is now $SIG{'TERM'}\n";
1184
1185     # perl4 prints: SIGTERM is main'SeeYa
1186     # perl5 prints: SIGTERM is now main::1
1187
1188 Use B<-w> to catch this one
1189
1190 =item * (Sort Subroutine)
1191
1192 reverse is no longer allowed as the name of a sort subroutine.
1193
1194     sub reverse{ print "yup "; $a <=> $b }
1195     print sort reverse a,b,c;
1196
1197     # perl4 prints: yup yup yup yup abc
1198     # perl5 prints: abc
1199
1200 =item * warn() won't let you specify a filehandle.
1201
1202 Although it _always_ printed to STDERR, warn() would let you specify a
1203 filehandle in perl4.  With perl5 it does not.
1204
1205     warn STDERR "Foo!";
1206
1207     # perl4 prints: Foo!
1208     # perl5 prints: String found where operator expected
1209
1210 =back
1211
1212 =head2 OS Traps
1213
1214 =over 5
1215
1216 =item * (SysV)
1217
1218 Under HPUX, and some other SysV OSes, one had to reset any signal handler,
1219 within  the signal handler function, each time a signal was handled with
1220 perl4.  With perl5, the reset is now done correctly.  Any code relying
1221 on the handler _not_ being reset will have to be reworked.
1222
1223 Since version 5.002, Perl uses sigaction() under SysV.
1224
1225     sub gotit {
1226         print "Got @_... ";
1227     }
1228     $SIG{'INT'} = 'gotit';
1229
1230     $| = 1;
1231     $pid = fork;
1232     if ($pid) {
1233         kill('INT', $pid);
1234         sleep(1);
1235         kill('INT', $pid);
1236     } else {
1237         while (1) {sleep(10);}
1238     }
1239
1240     # perl4 (HPUX) prints: Got INT...
1241     # perl5 (HPUX) prints: Got INT... Got INT...
1242
1243 =item * (SysV)
1244
1245 Under SysV OSes, C<seek()> on a file opened to append C<E<gt>E<gt>> now does
1246 the right thing w.r.t. the fopen() manpage. e.g., - When a file is opened
1247 for append,  it  is  impossible to overwrite information already in
1248 the file.
1249
1250     open(TEST,">>seek.test");
1251     $start = tell TEST ;
1252     foreach(1 .. 9){
1253         print TEST "$_ ";
1254     }
1255     $end = tell TEST ;
1256     seek(TEST,$start,0);
1257     print TEST "18 characters here";
1258
1259     # perl4 (solaris) seek.test has: 18 characters here
1260     # perl5 (solaris) seek.test has: 1 2 3 4 5 6 7 8 9 18 characters here
1261
1262
1263
1264 =back
1265
1266 =head2 Interpolation Traps
1267
1268 Perl4-to-Perl5 traps having to do with how things get interpolated
1269 within certain expressions, statements, contexts, or whatever.
1270
1271 =over 5
1272
1273 =item * Interpolation
1274
1275 @ now always interpolates an array in double-quotish strings.
1276
1277     print "To: someone@somewhere.com\n";
1278
1279     # perl4 prints: To:someone@somewhere.com
1280     # perl5 errors : In string, @somewhere now must be written as \@somewhere
1281
1282 =item * Interpolation
1283
1284 Double-quoted strings may no longer end with an unescaped $ or @.
1285
1286     $foo = "foo$";
1287     $bar = "bar@";
1288     print "foo is $foo, bar is $bar\n";
1289
1290     # perl4 prints: foo is foo$, bar is bar@
1291     # perl5 errors: Final $ should be \$ or $name
1292
1293 Note: perl5 DOES NOT error on the terminating @ in $bar
1294
1295 =item * Interpolation
1296
1297 Perl now sometimes evaluates arbitrary expressions inside braces that occur
1298 within double quotes (usually when the opening brace is preceded by C<$>
1299 or C<@>).
1300
1301     @www = "buz";
1302     $foo = "foo";
1303     $bar = "bar";
1304     sub foo { return "bar" };
1305     print "|@{w.w.w}|${main'foo}|";
1306
1307     # perl4 prints: |@{w.w.w}|foo|
1308     # perl5 prints: |buz|bar|
1309
1310 Note that you can C<use strict;> to ward off such trappiness under perl5.
1311
1312 =item * Interpolation
1313
1314 The construct "this is $$x" used to interpolate the pid at that
1315 point, but now apparently tries to dereference C<$x>.  C<$$> by itself still
1316 works fine, however.
1317
1318     print "this is $$x\n";
1319
1320     # perl4 prints: this is XXXx   (XXX is the current pid)
1321     # perl5 prints: this is
1322
1323 =item * Interpolation
1324
1325 Creation of hashes on the fly with C<eval "EXPR"> now requires either both
1326 C<$>'s to be protected in the specification of the hash name, or both curlies
1327 to be protected.  If both curlies are protected, the result will be compatible
1328 with perl4 and perl5.  This is a very common practice, and should be changed
1329 to use the block form of C<eval{}>  if possible.
1330
1331     $hashname = "foobar";
1332     $key = "baz";
1333     $value = 1234;
1334     eval "\$$hashname{'$key'} = q|$value|";
1335     (defined($foobar{'baz'})) ?  (print "Yup") : (print "Nope");
1336
1337     # perl4 prints: Yup
1338     # perl5 prints: Nope
1339
1340 Changing
1341
1342     eval "\$$hashname{'$key'} = q|$value|";
1343
1344 to
1345
1346     eval "\$\$hashname{'$key'} = q|$value|";
1347
1348 causes the following result:
1349
1350     # perl4 prints: Nope
1351     # perl5 prints: Yup
1352
1353 or, changing to
1354
1355     eval "\$$hashname\{'$key'\} = q|$value|";
1356
1357 causes the following result:
1358
1359     # perl4 prints: Yup
1360     # perl5 prints: Yup
1361     # and is compatible for both versions
1362
1363
1364 =item * Interpolation
1365
1366 perl4 programs which unconsciously rely on the bugs in earlier perl versions.
1367
1368     perl -e '$bar=q/not/; print "This is $foo{$bar} perl5"'
1369
1370     # perl4 prints: This is not perl5
1371     # perl5 prints: This is perl5
1372
1373 =item * Interpolation
1374
1375 You also have to be careful about array references.
1376
1377     print "$foo{"
1378
1379     perl 4 prints: {
1380     perl 5 prints: syntax error
1381
1382 =item * Interpolation
1383
1384 Similarly, watch out for:
1385
1386     $foo = "array";
1387     print "\$$foo{bar}\n";
1388
1389     # perl4 prints: $array{bar}
1390     # perl5 prints: $
1391
1392 Perl 5 is looking for C<$array{bar}> which doesn't exist, but perl 4 is
1393 happy just to expand $foo to "array" by itself.  Watch out for this
1394 especially in C<eval>'s.
1395
1396 =item * Interpolation
1397
1398 C<qq()> string passed to C<eval>
1399
1400     eval qq(
1401         foreach \$y (keys %\$x\) {
1402             \$count++;
1403         }
1404     );
1405
1406     # perl4 runs this ok
1407     # perl5 prints: Can't find string terminator ")"
1408
1409 =back
1410
1411 =head2 DBM Traps
1412
1413 General DBM traps.
1414
1415 =over 5
1416
1417 =item * DBM
1418
1419 Existing dbm databases created under perl4 (or any other dbm/ndbm tool)
1420 may cause the same script, run under perl5, to fail.  The build of perl5
1421 must have been linked with the same dbm/ndbm as the default for C<dbmopen()>
1422 to function properly without C<tie>'ing to an extension dbm implementation.
1423
1424     dbmopen (%dbm, "file", undef);
1425     print "ok\n";
1426
1427     # perl4 prints: ok
1428     # perl5 prints: ok (IFF linked with -ldbm or -lndbm)
1429
1430
1431 =item * DBM
1432
1433 Existing dbm databases created under perl4 (or any other dbm/ndbm tool)
1434 may cause the same script, run under perl5, to fail.  The error generated
1435 when exceeding the limit on the key/value size will cause perl5 to exit
1436 immediately.
1437
1438     dbmopen(DB, "testdb",0600) || die "couldn't open db! $!";
1439     $DB{'trap'} = "x" x 1024;  # value too large for most dbm/ndbm
1440     print "YUP\n";
1441
1442     # perl4 prints:
1443     dbm store returned -1, errno 28, key "trap" at - line 3.
1444     YUP
1445
1446     # perl5 prints:
1447     dbm store returned -1, errno 28, key "trap" at - line 3.
1448
1449 =back
1450
1451 =head2 Unclassified Traps
1452
1453 Everything else.
1454
1455 =over 5
1456
1457 =item * Unclassified
1458
1459 C<require>/C<do> trap using returned value
1460
1461 If the file doit.pl has:
1462
1463     sub foo {
1464         $rc = do "./do.pl";
1465         return 8;
1466     }
1467     print &foo, "\n";
1468
1469 And the do.pl file has the following single line:
1470
1471     return 3;
1472
1473 Running doit.pl gives the following:
1474
1475     # perl 4 prints: 3 (aborts the subroutine early)
1476     # perl 5 prints: 8
1477
1478 Same behavior if you replace C<do> with C<require>.
1479
1480 =back
1481
1482 As always, if any of these are ever officially declared as bugs,
1483 they'll be fixed and removed.
1484