pod/perltrap.pod

   1 =head1 NAME
   2
   3 perltrap - Perl traps for the unwary
   4
   5 =head1 DESCRIPTION
   6
   7 The biggest trap of all is forgetting to use the B<-w> switch; see
   8 L<perlrun>.  The second biggest trap is not making your entire program
   9 runnable under C<use strict>.  The third biggest trap is not reading
  10 the list of changes in this version of Perl; see L<perldelta>.
  11
  12 =head2 Awk Traps
  13
  14 Accustomed B<awk> users should take special note of the following:
  15
  16 =over 4
  17
  18 =item *
  19
  20 The English module, loaded via
  21
  22     use English;
  23
  24 allows you to refer to special variables (like C<$/>) with names (like
  25 C<$RS>), as though they were in B<awk>; see L<perlvar> for details.
  26
  27 =item *
  28
  29 Semicolons are required after all simple statements in Perl (except
  30 at the end of a block).  Newline is not a statement delimiter.
  31
  32 =item *
  33
  34 Curly brackets are required on C<if>s and C<while>s.
  35
  36 =item *
  37
  38 Variables begin with "$" or "@" in Perl.
  39
  40 =item *
  41
  42 Arrays index from 0.  Likewise string positions in substr() and
  43 index().
  44
  45 =item *
  46
  47 You have to decide whether your array has numeric or string indices.
  48
  49 =item *
  50
  51 Hash values do not spring into existence upon mere reference.
  52
  53 =item *
  54
  55 You have to decide whether you want to use string or numeric
  56 comparisons.
  57
  58 =item *
  59
  60 Reading an input line does not split it for you.  You get to split it
  61 to an array yourself.  And the split() operator has different
  62 arguments than B<awk>'s.
  63
  64 =item *
  65
  66 The current input line is normally in $_, not $0.  It generally does
  67 not have the newline stripped.  ($0 is the name of the program
  68 executed.)  See L<perlvar>.
  69
  70 =item *
  71
  72 $E<lt>I<digit>E<gt> does not refer to fields--it refers to substrings matched
  73 by the last match pattern.
  74
  75 =item *
  76
  77 The print() statement does not add field and record separators unless
  78 you set C<$,> and C<$\>.  You can set $OFS and $ORS if you're using
  79 the English module.
  80
  81 =item *
  82
  83 You must open your files before you print to them.
  84
  85 =item *
  86
  87 The range operator is "..", not comma.  The comma operator works as in
  88 C.
  89
  90 =item *
  91
  92 The match operator is "=~", not "~".  ("~" is the one's complement
  93 operator, as in C.)
  94
  95 =item *
  96
  97 The exponentiation operator is "**", not "^".  "^" is the XOR
  98 operator, as in C.  (You know, one could get the feeling that B<awk> is
  99 basically incompatible with C.)
 100
 101 =item *
 102
 103 The concatenation operator is ".", not the null string.  (Using the
 104 null string would render C</pat/ /pat/> unparsable, because the third slash
 105 would be interpreted as a division operator--the tokenizer is in fact
 106 slightly context sensitive for operators like "/", "?", and "E<gt>".
 107 And in fact, "." itself can be the beginning of a number.)
 108
 109 =item *
 110
 111 The C<next>, C<exit>, and C<continue> keywords work differently.
 112
 113 =item *
 114
 115
 116 The following variables work differently:
 117
 118       Awk       Perl
 119       ARGC      $#ARGV or scalar @ARGV
 120       ARGV[0]   $0
 121       FILENAME  $ARGV
 122       FNR       $. - something
 123       FS        (whatever you like)
 124       NF        $#Fld, or some such
 125       NR        $.
 126       OFMT      $#
 127       OFS       $,
 128       ORS       $\
 129       RLENGTH   length($&)
 130       RS        $/
 131       RSTART    length($`)
 132       SUBSEP    $;
 133
 134 =item *
 135
 136 You cannot set $RS to a pattern, only a string.
 137
 138 =item *
 139
 140 When in doubt, run the B<awk> construct through B<a2p> and see what it
 141 gives you.
 142
 143 =back
 144
 145 =head2 C Traps
 146
 147 Cerebral C programmers should take note of the following:
 148
 149 =over 4
 150
 151 =item *
 152
 153 Curly brackets are required on C<if>'s and C<while>'s.
 154
 155 =item *
 156
 157 You must use C<elsif> rather than C<else if>.
 158
 159 =item *
 160
 161 The C<break> and C<continue> keywords from C become in
 162 Perl C<last> and C<next>, respectively.
 163 Unlike in C, these do I<NOT> work within a C<do { } while> construct.
 164
 165 =item *
 166
 167 There's no switch statement.  (But it's easy to build one on the fly.)
 168
 169 =item *
 170
 171 Variables begin with "$" or "@" in Perl.
 172
 173 =item *
 174
 175 C<printf()> does not implement the "*" format for interpolating
 176 field widths, but it's trivial to use interpolation of double-quoted
 177 strings to achieve the same effect.
 178
 179 =item *
 180
 181 Comments begin with "#", not "/*".
 182
 183 =item *
 184
 185 You can't take the address of anything, although a similar operator
 186 in Perl is the backslash, which creates a reference.
 187
 188 =item *
 189
 190 C<ARGV> must be capitalized.  C<$ARGV[0]> is C's C<argv[1]>, and C<argv[0]>
 191 ends up in C<$0>.
 192
 193 =item *
 194
 195 System calls such as link(), unlink(), rename(), etc. return nonzero for
 196 success, not 0.
 197
 198 =item *
 199
 200 Signal handlers deal with signal names, not numbers.  Use C<kill -l>
 201 to find their names on your system.
 202
 203 =back
 204
 205 =head2 Sed Traps
 206
 207 Seasoned B<sed> programmers should take note of the following:
 208
 209 =over 4
 210
 211 =item *
 212
 213 Backreferences in substitutions use "$" rather than "\".
 214
 215 =item *
 216
 217 The pattern matching metacharacters "(", ")", and "|" do not have backslashes
 218 in front.
 219
 220 =item *
 221
 222 The range operator is C<...>, rather than comma.
 223
 224 =back
 225
 226 =head2 Shell Traps
 227
 228 Sharp shell programmers should take note of the following:
 229
 230 =over 4
 231
 232 =item *
 233
 234 The backtick operator does variable interpolation without regard to
 235 the presence of single quotes in the command.
 236
 237 =item *
 238
 239 The backtick operator does no translation of the return value, unlike B<csh>.
 240
 241 =item *
 242
 243 Shells (especially B<csh>) do several levels of substitution on each
 244 command line.  Perl does substitution in only certain constructs
 245 such as double quotes, backticks, angle brackets, and search patterns.
 246
 247 =item *
 248
 249 Shells interpret scripts a little bit at a time.  Perl compiles the
 250 entire program before executing it (except for C<BEGIN> blocks, which
 251 execute at compile time).
 252
 253 =item *
 254
 255 The arguments are available via @ARGV, not $1, $2, etc.
 256
 257 =item *
 258
 259 The environment is not automatically made available as separate scalar
 260 variables.
 261
 262 =back
 263
 264 =head2 Perl Traps
 265
 266 Practicing Perl Programmers should take note of the following:
 267
 268 =over 4
 269
 270 =item *
 271
 272 Remember that many operations behave differently in a list
 273 context than they do in a scalar one.  See L<perldata> for details.
 274
 275 =item *
 276
 277 Avoid barewords if you can, especially all lowercase ones.
 278 You can't tell by just looking at it whether a bareword is
 279 a function or a string.  By using quotes on strings and
 280 parentheses on function calls, you won't ever get them confused.
 281
 282 =item *
 283
 284 You cannot discern from mere inspection which builtins
 285 are unary operators (like chop() and chdir())
 286 and which are list operators (like print() and unlink()).
 287 (User-defined subroutines can be B<only> list operators, never
 288 unary ones.)  See L<perlop>.
 289
 290 =item *
 291
 292 People have a hard time remembering that some functions
 293 default to $_, or @ARGV, or whatever, but that others which
 294 you might expect to do not.
 295
 296 =item *
 297
 298 The E<lt>FHE<gt> construct is not the name of the filehandle, it is a readline
 299 operation on that handle.  The data read is assigned to $_ only if the
 300 file read is the sole condition in a while loop:
 301
 302     while (<FH>)      { }
 303     while (defined($_ = <FH>)) { }..
 304     <FH>;  # data discarded!
 305
 306 =item *
 307
 308 Remember not to use "C<=>" when you need "C<=~>";
 309 these two constructs are quite different:
 310
 311     $x =  /foo/;
 312     $x =~ /foo/;
 313
 314 =item *
 315
 316 The C<do {}> construct isn't a real loop that you can use
 317 loop control on.
 318
 319 =item *
 320
 321 Use C<my()> for local variables whenever you can get away with
 322 it (but see L<perlform> for where you can't).
 323 Using C<local()> actually gives a local value to a global
 324 variable, which leaves you open to unforeseen side-effects
 325 of dynamic scoping.
 326
 327 =item *
 328
 329 If you localize an exported variable in a module, its exported value will
 330 not change.  The local name becomes an alias to a new value but the
 331 external name is still an alias for the original.
 332
 333 =back
 334
 335 =head2 Perl4 to Perl5 Traps
 336
 337 Practicing Perl4 Programmers should take note of the following
 338 Perl4-to-Perl5 specific traps.
 339
 340 They're crudely ordered according to the following list:
 341
 342 =over 4
 343
 344 =item Discontinuance, Deprecation, and BugFix traps
 345
 346 Anything that's been fixed as a perl4 bug, removed as a perl4 feature
 347 or deprecated as a perl4 feature with the intent to encourage usage of
 348 some other perl5 feature.
 349
 350 =item Parsing Traps
 351
 352 Traps that appear to stem from the new parser.
 353
 354 =item Numerical Traps
 355
 356 Traps having to do with numerical or mathematical operators.
 357
 358 =item General data type traps
 359
 360 Traps involving perl standard data types.
 361
 362 =item Context Traps - scalar, list contexts
 363
 364 Traps related to context within lists, scalar statements/declarations.
 365
 366 =item Precedence Traps
 367
 368 Traps related to the precedence of parsing, evaluation, and execution of
 369 code.
 370
 371 =item General Regular Expression Traps using s///, etc.
 372
 373 Traps related to the use of pattern matching.
 374
 375 =item Subroutine, Signal, Sorting Traps
 376
 377 Traps related to the use of signals and signal handlers, general subroutines,
 378 and sorting, along with sorting subroutines.
 379
 380 =item OS Traps
 381
 382 OS-specific traps.
 383
 384 =item DBM Traps
 385
 386 Traps specific to the use of C<dbmopen()>, and specific dbm implementations.
 387
 388 =item Unclassified Traps
 389
 390 Everything else.
 391
 392 =back
 393
 394 If you find an example of a conversion trap that is not listed here,
 395 please submit it to Bill Middleton <F<wjm@best.com>> for inclusion.
 396 Also note that at least some of these can be caught with B<-w>.
 397
 398 =head2 Discontinuance, Deprecation, and BugFix traps
 399
 400 Anything that has been discontinued, deprecated, or fixed as
 401 a bug from perl4.
 402
 403 =over 4
 404
 405 =item * Discontinuance
 406
 407 Symbols starting with "_" are no longer forced into package main, except
 408 for C<$_> itself (and C<@_>, etc.).
 409
 410     package test;
 411     $_legacy = 1;
 412
 413     package main;
 414     print "\$_legacy is ",$_legacy,"\n";
 415
 416     # perl4 prints: $_legacy is 1
 417     # perl5 prints: $_legacy is
 418
 419 =item * Deprecation
 420
 421 Double-colon is now a valid package separator in a variable name.  Thus these
 422 behave differently in perl4 vs. perl5, because the packages don't exist.
 423
 424     $a=1;$b=2;$c=3;$var=4;
 425     print "$a::$b::$c ";
 426     print "$var::abc::xyz\n";
 427
 428     # perl4 prints: 1::2::3 4::abc::xyz
 429     # perl5 prints: 3
 430
 431 Given that C<::> is now the preferred package delimiter, it is debatable
 432 whether this should be classed as a bug or not.
 433 (The older package delimiter, ' ,is used here)
 434
 435     $x = 10 ;
 436     print "x=${'x}\n" ;
 437
 438     # perl4 prints: x=10
 439     # perl5 prints: Can't find string terminator "'" anywhere before EOF
 440
 441 Also see precedence traps, for parsing C<$:>.
 442
 443 =item * BugFix
 444
 445 The second and third arguments of C<splice()> are now evaluated in scalar
 446 context (as the Camel says) rather than list context.
 447
 448     sub sub1{return(0,2) }          # return a 2-elem array
 449     sub sub2{ return(1,2,3)}        # return a 3-elem array
 450     @a1 = ("a","b","c","d","e");
 451     @a2 = splice(@a1,&sub1,&sub2);
 452     print join(' ',@a2),"\n";
 453
 454     # perl4 prints: a b
 455     # perl5 prints: c d e
 456
 457 =item * Discontinuance
 458
 459 You can't do a C<goto> into a block that is optimized away.  Darn.
 460
 461     goto marker1;
 462
 463     for(1){
 464     marker1:
 465         print "Here I is!\n";
 466     }
 467
 468     # perl4 prints: Here I is!
 469     # perl5 dumps core (SEGV)
 470
 471 =item * Discontinuance
 472
 473 It is no longer syntactically legal to use whitespace as the name
 474 of a variable, or as a delimiter for any kind of quote construct.
 475 Double darn.
 476
 477     $a = ("foo bar");
 478     $b = q baz ;
 479     print "a is $a, b is $b\n";
 480
 481     # perl4 prints: a is foo bar, b is baz
 482     # perl5 errors: Bareword found where operator expected
 483
 484 =item * Discontinuance
 485
 486 The archaic while/if BLOCK BLOCK syntax is no longer supported.
 487
 488     if { 1 } {
 489         print "True!";
 490     }
 491     else {
 492         print "False!";
 493     }
 494
 495     # perl4 prints: True!
 496     # perl5 errors: syntax error at test.pl line 1, near "if {"
 497
 498 =item * BugFix
 499
 500 The C<**> operator now binds more tightly than unary minus.
 501 It was documented to work this way before, but didn't.
 502
 503     print -4**2,"\n";
 504
 505     # perl4 prints: 16
 506     # perl5 prints: -16
 507
 508 =item * Discontinuance
 509
 510 The meaning of C<foreach{}> has changed slightly when it is iterating over a
 511 list which is not an array.  This used to assign the list to a
 512 temporary array, but no longer does so (for efficiency).  This means
 513 that you'll now be iterating over the actual values, not over copies of
 514 the values.  Modifications to the loop variable can change the original
 515 values.
 516
 517     @list = ('ab','abc','bcd','def');
 518     foreach $var (grep(/ab/,@list)){
 519         $var = 1;
 520     }
 521     print (join(':',@list));
 522
 523     # perl4 prints: ab:abc:bcd:def
 524     # perl5 prints: 1:1:bcd:def
 525
 526 To retain Perl4 semantics you need to assign your list
 527 explicitly to a temporary array and then iterate over that.  For
 528 example, you might need to change
 529
 530     foreach $var (grep(/ab/,@list)){
 531
 532 to
 533
 534     foreach $var (@tmp = grep(/ab/,@list)){
 535
 536 Otherwise changing $var will clobber the values of @list.  (This most often
 537 happens when you use C<$_> for the loop variable, and call subroutines in
 538 the loop that don't properly localize C<$_>.)
 539
 540 =item * Discontinuance
 541
 542 C<split> with no arguments now behaves like C<split ' '> (which doesn't
 543 return an initial null field if $_ starts with whitespace), it used to
 544 behave like C<split /\s+/> (which does).
 545
 546     $_ = ' hi mom';
 547     print join(':', split);
 548
 549     # perl4 prints: :hi:mom
 550     # perl5 prints: hi:mom
 551
 552 =item * BugFix
 553
 554 Perl 4 would ignore any text which was attached to an B<-e> switch,
 555 always taking the code snippet from the following arg.  Additionally, it
 556 would silently accept an B<-e> switch without a following arg.  Both of
 557 these behaviors have been fixed.
 558
 559     perl -e'print "attached to -e"' 'print "separate arg"'
 560
 561     # perl4 prints: separate arg
 562     # perl5 prints: attached to -e
 563
 564     perl -e
 565
 566     # perl4 prints:
 567     # perl5 dies: No code specified for -e.
 568
 569 =item * Discontinuance
 570
 571 In Perl 4 the return value of C<push> was undocumented, but it was
 572 actually the last value being pushed onto the target list.  In Perl 5
 573 the return value of C<push> is documented, but has changed, it is the
 574 number of elements in the resulting list.
 575
 576     @x = ('existing');
 577     print push(@x, 'first new', 'second new');
 578
 579     # perl4 prints: second new
 580     # perl5 prints: 3
 581
 582 =item * Discontinuance
 583
 584 In Perl 4 (and versions of Perl 5 before 5.004), C<'\r'> characters in
 585 Perl code were silently allowed, although they could cause (mysterious!)
 586 failures in certain constructs, particularly here documents.  Now,
 587 C<'\r'> characters cause an immediate fatal error.  (Note: In this
 588 example, the notation B<\015> represents the incorrect line
 589 ending. Depending upon your text viewer, it will look different.)
 590
 591     print "foo";\015
 592     print "bar";
 593
 594     # perl4     prints: foobar
 595     # perl5.003 prints: foobar
 596     # perl5.004 dies: Illegal character \015 (carriage return)
 597
 598 See L<perldiag> for full details.
 599
 600 =item * Deprecation
 601
 602 Some error messages will be different.
 603
 604 =item * Discontinuance
 605
 606 Some bugs may have been inadvertently removed.  :-)
 607
 608 =back
 609
 610 =head2 Parsing Traps
 611
 612 Perl4-to-Perl5 traps from having to do with parsing.
 613
 614 =over 4
 615
 616 =item * Parsing
 617
 618 Note the space between . and =
 619
 620     $string . = "more string";
 621     print $string;
 622
 623     # perl4 prints: more string
 624     # perl5 prints: syntax error at - line 1, near ". ="
 625
 626 =item * Parsing
 627
 628 Better parsing in perl 5
 629
 630     sub foo {}
 631     &foo
 632     print("hello, world\n");
 633
 634     # perl4 prints: hello, world
 635     # perl5 prints: syntax error
 636
 637 =item * Parsing
 638
 639 "if it looks like a function, it is a function" rule.
 640
 641   print
 642     ($foo == 1) ? "is one\n" : "is zero\n";
 643
 644     # perl4 prints: is zero
 645     # perl5 warns: "Useless use of a constant in void context" if using -w
 646
 647 =back
 648
 649 =head2 Numerical Traps
 650
 651 Perl4-to-Perl5 traps having to do with numerical operators,
 652 operands, or output from same.
 653
 654 =over 5
 655
 656 =item * Numerical
 657
 658 Formatted output and significant digits
 659
 660     print 7.373504 - 0, "\n";
 661     printf "%20.18f\n", 7.373504 - 0;
 662
 663     # Perl4 prints:
 664     7.375039999999996141
 665     7.37503999999999614
 666
 667     # Perl5 prints:
 668     7.373504
 669     7.37503999999999614
 670
 671 =item * Numerical
 672
 673 This specific item has been deleted.  It demonstrated how the auto-increment
 674 operator would not catch when a number went over the signed int limit.  Fixed
 675 in version 5.003_04.  But always be wary when using large integers.
 676 If in doubt:
 677
 678    use Math::BigInt;
 679
 680 =item * Numerical
 681
 682 Assignment of return values from numeric equality tests
 683 does not work in perl5 when the test evaluates to false (0).
 684 Logical tests now return an null, instead of 0
 685
 686     $p = ($test == 1);
 687     print $p,"\n";
 688
 689     # perl4 prints: 0
 690     # perl5 prints:
 691
 692 Also see L<"General Regular Expression Traps using s///, etc.">
 693 for another example of this new feature...
 694
 695 =back
 696
 697 =head2 General data type traps
 698
 699 Perl4-to-Perl5 traps involving most data-types, and their usage
 700 within certain expressions and/or context.
 701
 702 =over 5
 703
 704 =item * (Arrays)
 705
 706 Negative array subscripts now count from the end of the array.
 707
 708     @a = (1, 2, 3, 4, 5);
 709     print "The third element of the array is $a[3] also expressed as $a[-2] \n";
 710
 711     # perl4 prints: The third element of the array is 4 also expressed as
 712     # perl5 prints: The third element of the array is 4 also expressed as 4
 713
 714 =item * (Arrays)
 715
 716 Setting C<$#array> lower now discards array elements, and makes them
 717 impossible to recover.
 718
 719     @a = (a,b,c,d,e);
 720     print "Before: ",join('',@a);
 721     $#a =1;
 722     print ", After: ",join('',@a);
 723     $#a =3;
 724     print ", Recovered: ",join('',@a),"\n";
 725
 726     # perl4 prints: Before: abcde, After: ab, Recovered: abcd
 727     # perl5 prints: Before: abcde, After: ab, Recovered: ab
 728
 729 =item * (Hashes)
 730
 731 Hashes get defined before use
 732
 733     local($s,@a,%h);
 734     die "scalar \$s defined" if defined($s);
 735     die "array \@a defined" if defined(@a);
 736     die "hash \%h defined" if defined(%h);
 737
 738     # perl4 prints:
 739     # perl5 dies: hash %h defined
 740
 741 =item * (Globs)
 742
 743 glob assignment from variable to variable will fail if the assigned
 744 variable is localized subsequent to the assignment
 745
 746     @a = ("This is Perl 4");
 747     *b = *a;
 748     local(@a);
 749     print @b,"\n";
 750
 751     # perl4 prints: This is Perl 4
 752     # perl5 prints:
 753
 754     # Another example
 755
 756     *fred = *barney; # fred is aliased to barney
 757     @barney = (1, 2, 4);
 758     # @fred;
 759     print "@fred";  # should print "1, 2, 4"
 760
 761     # perl4 prints: 1 2 4
 762     # perl5 prints: In string, @fred now must be written as \@fred
 763
 764 =item * (Scalar String)
 765
 766 Changes in unary negation (of strings)
 767 This change effects both the return value and what it
 768 does to auto(magic)increment.
 769
 770     $x = "aaa";
 771     print ++$x," : ";
 772     print -$x," : ";
 773     print ++$x,"\n";
 774
 775     # perl4 prints: aab : -0 : 1
 776     # perl5 prints: aab : -aab : aac
 777
 778 =item * (Constants)
 779
 780 perl 4 lets you modify constants:
 781
 782     $foo = "x";
 783     &mod($foo);
 784     for ($x = 0; $x < 3; $x++) {
 785         &mod("a");
 786     }
 787     sub mod {
 788         print "before: $_[0]";
 789         $_[0] = "m";
 790         print "  after: $_[0]\n";
 791     }
 792
 793     # perl4:
 794     # before: x  after: m
 795     # before: a  after: m
 796     # before: m  after: m
 797     # before: m  after: m
 798
 799     # Perl5:
 800     # before: x  after: m
 801     # Modification of a read-only value attempted at foo.pl line 12.
 802     # before: a
 803
 804 =item * (Scalars)
 805
 806 The behavior is slightly different for:
 807
 808     print "$x", defined $x
 809
 810     # perl 4: 1
 811     # perl 5: <no output, $x is not called into existence>
 812
 813 =item * (Variable Suicide)
 814
 815 Variable suicide behavior is more consistent under Perl 5.
 816 Perl5 exhibits the same behavior for hashes and scalars,
 817 that perl4 exhibits for only scalars.
 818
 819     $aGlobal{ "aKey" } = "global value";
 820     print "MAIN:", $aGlobal{"aKey"}, "\n";
 821     $GlobalLevel = 0;
 822     &test( *aGlobal );
 823
 824     sub test {
 825         local( *theArgument ) = @_;
 826         local( %aNewLocal ); # perl 4 != 5.001l,m
 827         $aNewLocal{"aKey"} = "this should never appear";
 828         print "SUB: ", $theArgument{"aKey"}, "\n";
 829         $aNewLocal{"aKey"} = "level $GlobalLevel";   # what should print
 830         $GlobalLevel++;
 831         if( $GlobalLevel<4 ) {
 832             &test( *aNewLocal );
 833         }
 834     }
 835
 836     # Perl4:
 837     # MAIN:global value
 838     # SUB: global value
 839     # SUB: level 0
 840     # SUB: level 1
 841     # SUB: level 2
 842
 843     # Perl5:
 844     # MAIN:global value
 845     # SUB: global value
 846     # SUB: this should never appear
 847     # SUB: this should never appear
 848     # SUB: this should never appear
 849
 850 =back
 851
 852 =head2 Context Traps - scalar, list contexts
 853
 854 =over 5
 855
 856 =item * (list context)
 857
 858 The elements of argument lists for formats are now evaluated in list
 859 context.  This means you can interpolate list values now.
 860
 861     @fmt = ("foo","bar","baz");
 862     format STDOUT=
 863     @<<<<< @||||| @>>>>>
 864     @fmt;
 865     .
 866     write;
 867
 868     # perl4 errors:  Please use commas to separate fields in file
 869     # perl5 prints: foo     bar      baz
 870
 871 =item * (scalar context)
 872
 873 The C<caller()> function now returns a false value in a scalar context
 874 if there is no caller.  This lets library files determine if they're
 875 being required.
 876
 877     caller() ? (print "You rang?\n") : (print "Got a 0\n");
 878
 879     # perl4 errors: There is no caller
 880     # perl5 prints: Got a 0
 881
 882 =item * (scalar context)
 883
 884 The comma operator in a scalar context is now guaranteed to give a
 885 scalar context to its arguments.
 886
 887     @y= ('a','b','c');
 888     $x = (1, 2, @y);
 889     print "x = $x\n";
 890
 891     # Perl4 prints:  x = c   # Thinks list context interpolates list
 892     # Perl5 prints:  x = 3   # Knows scalar uses length of list
 893
 894 =item * (list, builtin)
 895
 896 C<sprintf()> funkiness (array argument converted to scalar array count)
 897 This test could be added to t/op/sprintf.t
 898
 899     @z = ('%s%s', 'foo', 'bar');
 900     $x = sprintf(@z);
 901     if ($x eq 'foobar') {print "ok 2\n";} else {print "not ok 2 '$x'\n";}
 902
 903     # perl4 prints: ok 2
 904     # perl5 prints: not ok 2
 905
 906 C<printf()> works fine, though:
 907
 908     printf STDOUT (@z);
 909     print "\n";
 910
 911     # perl4 prints: foobar
 912     # perl5 prints: foobar
 913
 914 Probably a bug.
 915
 916 =back
 917
 918 =head2 Precedence Traps
 919
 920 Perl4-to-Perl5 traps involving precedence order.
 921
 922 =over 5
 923
 924 =item * Precedence
 925
 926 LHS vs. RHS when both sides are getting an op.
 927
 928     @arr = ( 'left', 'right' );
 929     $a{shift @arr} = shift @arr;
 930     print join( ' ', keys %a );
 931
 932     # perl4 prints: left
 933     # perl5 prints: right
 934
 935 =item * Precedence
 936
 937 These are now semantic errors because of precedence:
 938
 939     @list = (1,2,3,4,5);
 940     %map = ("a",1,"b",2,"c",3,"d",4);
 941     $n = shift @list + 2;   # first item in list plus 2
 942     print "n is $n, ";
 943     $m = keys %map + 2;     # number of items in hash plus 2
 944     print "m is $m\n";
 945
 946     # perl4 prints: n is 3, m is 6
 947     # perl5 errors and fails to compile
 948
 949 =item * Precedence
 950
 951 The precedence of assignment operators is now the same as the precedence
 952 of assignment.  Perl 4 mistakenly gave them the precedence of the associated
 953 operator.  So you now must parenthesize them in expressions like
 954
 955     /foo/ ? ($a += 2) : ($a -= 2);
 956
 957 Otherwise
 958
 959     /foo/ ? $a += 2 : $a -= 2
 960
 961 would be erroneously parsed as
 962
 963     (/foo/ ? $a += 2 : $a) -= 2;
 964
 965 On the other hand,
 966
 967     $a += /foo/ ? 1 : 2;
 968
 969 now works as a C programmer would expect.
 970
 971 =item * Precedence
 972
 973     open FOO || die;
 974
 975 is now incorrect.  You need parentheses around the filehandle.
 976 Otherwise, perl5 leaves the statement as its default precedence:
 977
 978     open(FOO || die);
 979
 980     # perl4 opens or dies
 981     # perl5 errors: Precedence problem: open FOO should be open(FOO)
 982
 983 =item * Precedence
 984
 985 perl4 gives the special variable, C<$:> precedence, where perl5
 986 treats C<$::> as main C<package>
 987
 988     $a = "x"; print "$::a";
 989
 990     # perl 4 prints: -:a
 991     # perl 5 prints: x
 992
 993 =item * Precedence
 994
 995 concatenation precedence over filetest operator?
 996
 997     -e $foo .= "q"
 998
 999     # perl4 prints: no output
1000     # perl5 prints: Can't modify -e in concatenation
1001
1002 =item * Precedence
1003
1004 Assignment to value takes precedence over assignment to key in
1005 perl5 when using the shift operator on both sides.
1006
1007     @arr = ( 'left', 'right' );
1008     $a{shift @arr} = shift @arr;
1009     print join( ' ', keys %a );
1010
1011     # perl4 prints: left
1012     # perl5 prints: right
1013
1014 =back
1015
1016 =head2 General Regular Expression Traps using s///, etc.
1017
1018 All types of RE traps.
1019
1020 =over 5
1021
1022 =item * Regular Expression
1023
1024 C<s'$lhs'$rhs'> now does no interpolation on either side.  It used to
1025 interpolate C<$lhs> but not C<$rhs>.  (And still does not match a literal
1026 '$' in string)
1027
1028     $a=1;$b=2;
1029     $string = '1 2 $a $b';
1030     $string =~ s'$a'$b';
1031     print $string,"\n";
1032
1033     # perl4 prints: $b 2 $a $b
1034     # perl5 prints: 1 2 $a $b
1035
1036 =item * Regular Expression
1037
1038 C<m//g> now attaches its state to the searched string rather than the
1039 regular expression.  (Once the scope of a block is left for the sub, the
1040 state of the searched string is lost)
1041
1042     $_ = "ababab";
1043     while(m/ab/g){
1044         &doit("blah");
1045     }
1046     sub doit{local($_) = shift; print "Got $_ "}
1047
1048     # perl4 prints: blah blah blah
1049     # perl5 prints: infinite loop blah...
1050
1051 =item * Regular Expression
1052
1053 Currently, if you use the C<m//o> qualifier on a regular expression
1054 within an anonymous sub, I<all> closures generated from that anonymous
1055 sub will use the regular expression as it was compiled when it was used
1056 the very first time in any such closure.  For instance, if you say
1057
1058     sub build_match {
1059         my($left,$right) = @_;
1060         return sub { $_[0] =~ /$left stuff $right/o; };
1061     }
1062
1063 build_match() will always return a sub which matches the contents of
1064 C<$left> and C<$right> as they were the I<first> time that build_match()
1065 was called, not as they are in the current call.
1066
1067 This is probably a bug, and may change in future versions of Perl.
1068
1069 =item * Regular Expression
1070
1071 If no parentheses are used in a match, Perl4 sets C<$+> to
1072 the whole match, just like C<$&>. Perl5 does not.
1073
1074     "abcdef" =~ /b.*e/;
1075     print "\$+ = $+\n";
1076
1077     # perl4 prints: bcde
1078     # perl5 prints:
1079
1080 =item * Regular Expression
1081
1082 substitution now returns the null string if it fails
1083
1084     $string = "test";
1085     $value = ($string =~ s/foo//);
1086     print $value, "\n";
1087
1088     # perl4 prints: 0
1089     # perl5 prints:
1090
1091 Also see L<Numerical Traps> for another example of this new feature.
1092
1093 =item * Regular Expression
1094
1095 C<s`lhs`rhs`> (using backticks) is now a normal substitution, with no
1096 backtick expansion
1097
1098     $string = "";
1099     $string =~ s`^`hostname`;
1100     print $string, "\n";
1101
1102     # perl4 prints: <the local hostname>
1103     # perl5 prints: hostname
1104
1105 =item * Regular Expression
1106
1107 Stricter parsing of variables used in regular expressions
1108
1109     s/^([^$grpc]*$grpc[$opt$plus$rep]?)//o;
1110
1111     # perl4: compiles w/o error
1112     # perl5: with Scalar found where operator expected ..., near "$opt$plus"
1113
1114 an added component of this example, apparently from the same script, is
1115 the actual value of the s'd string after the substitution.
1116 C<[$opt]> is a character class in perl4 and an array subscript in perl5
1117
1118     $grpc = 'a';
1119     $opt  = 'r';
1120     $_ = 'bar';
1121     s/^([^$grpc]*$grpc[$opt]?)/foo/;
1122     print ;
1123
1124     # perl4 prints: foo
1125     # perl5 prints: foobar
1126
1127 =item * Regular Expression
1128
1129 Under perl5, C<m?x?> matches only once, like C<?x?>. Under perl4, it matched
1130 repeatedly, like C</x/> or C<m!x!>.
1131
1132     $test = "once";
1133     sub match { $test =~ m?once?; }
1134     &match();
1135     if( &match() ) {
1136         # m?x? matches more then once
1137         print "perl4\n";
1138     } else {
1139         # m?x? matches only once
1140         print "perl5\n";
1141     }
1142
1143     # perl4 prints: perl4
1144     # perl5 prints: perl5
1145
1146
1147 =item * Regular Expression
1148
1149 Under perl4 and upto version 5.003, a failed C<m//g> match used to
1150 reset the internal iterator, so that subsequent C<m//g> match attempts
1151 began from the beginning of the string.  In perl version 5.004 and later,
1152 failed C<m//g> matches do not reset the iterator position (which can be
1153 found using the C<pos()> function--see L<perlfunc/pos>).
1154
1155     $test = "foop";
1156     for (1..3) {
1157         print $1 while ($test =~ /(o)/g);
1158         # pos $test = 0;     # to get old behavior
1159     }
1160
1161     # perl4     prints: oooooo
1162     # perl5.004 prints: oo
1163
1164 You may always reset the iterator yourself as shown in the commented line
1165 to get the old behavior.
1166
1167 =back
1168
1169 =head2 Subroutine, Signal, Sorting Traps
1170
1171 The general group of Perl4-to-Perl5 traps having to do with
1172 Signals, Sorting, and their related subroutines, as well as
1173 general subroutine traps.  Includes some OS-Specific traps.
1174
1175 =over 5
1176
1177 =item * (Signals)
1178
1179 Barewords that used to look like strings to Perl will now look like subroutine
1180 calls if a subroutine by that name is defined before the compiler sees them.
1181
1182     sub SeeYa { warn"Hasta la vista, baby!" }
1183     $SIG{'TERM'} = SeeYa;
1184     print "SIGTERM is now $SIG{'TERM'}\n";
1185
1186     # perl4 prints: SIGTERM is main'SeeYa
1187     # perl5 prints: SIGTERM is now main::1
1188
1189 Use B<-w> to catch this one
1190
1191 =item * (Sort Subroutine)
1192
1193 reverse is no longer allowed as the name of a sort subroutine.
1194
1195     sub reverse{ print "yup "; $a <=> $b }
1196     print sort reverse a,b,c;
1197
1198     # perl4 prints: yup yup yup yup abc
1199     # perl5 prints: abc
1200
1201 =item * warn() won't let you specify a filehandle.
1202
1203 Although it _always_ printed to STDERR, warn() would let you specify a
1204 filehandle in perl4.  With perl5 it does not.
1205
1206     warn STDERR "Foo!";
1207
1208     # perl4 prints: Foo!
1209     # perl5 prints: String found where operator expected
1210
1211 =back
1212
1213 =head2 OS Traps
1214
1215 =over 5
1216
1217 =item * (SysV)
1218
1219 Under HPUX, and some other SysV OSes, one had to reset any signal handler,
1220 within  the signal handler function, each time a signal was handled with
1221 perl4.  With perl5, the reset is now done correctly.  Any code relying
1222 on the handler _not_ being reset will have to be reworked.
1223
1224 Since version 5.002, Perl uses sigaction() under SysV.
1225
1226     sub gotit {
1227         print "Got @_... ";
1228     }
1229     $SIG{'INT'} = 'gotit';
1230
1231     $| = 1;
1232     $pid = fork;
1233     if ($pid) {
1234         kill('INT', $pid);
1235         sleep(1);
1236         kill('INT', $pid);
1237     } else {
1238         while (1) {sleep(10);}
1239     }
1240
1241     # perl4 (HPUX) prints: Got INT...
1242     # perl5 (HPUX) prints: Got INT... Got INT...
1243
1244 =item * (SysV)
1245
1246 Under SysV OSes, C<seek()> on a file opened to append C<E<gt>E<gt>> now does
1247 the right thing w.r.t. the fopen() manpage. e.g., - When a file is opened
1248 for append,  it  is  impossible to overwrite information already in
1249 the file.
1250
1251     open(TEST,">>seek.test");
1252     $start = tell TEST ;
1253     foreach(1 .. 9){
1254         print TEST "$_ ";
1255     }
1256     $end = tell TEST ;
1257     seek(TEST,$start,0);
1258     print TEST "18 characters here";
1259
1260     # perl4 (solaris) seek.test has: 18 characters here
1261     # perl5 (solaris) seek.test has: 1 2 3 4 5 6 7 8 9 18 characters here
1262
1263
1264
1265 =back
1266
1267 =head2 Interpolation Traps
1268
1269 Perl4-to-Perl5 traps having to do with how things get interpolated
1270 within certain expressions, statements, contexts, or whatever.
1271
1272 =over 5
1273
1274 =item * Interpolation
1275
1276 @ now always interpolates an array in double-quotish strings.
1277
1278     print "To: someone@somewhere.com\n";
1279
1280     # perl4 prints: To:someone@somewhere.com
1281     # perl5 errors : In string, @somewhere now must be written as \@somewhere
1282
1283 =item * Interpolation
1284
1285 Double-quoted strings may no longer end with an unescaped $ or @.
1286
1287     $foo = "foo$";
1288     $bar = "bar@";
1289     print "foo is $foo, bar is $bar\n";
1290
1291     # perl4 prints: foo is foo$, bar is bar@
1292     # perl5 errors: Final $ should be \$ or $name
1293
1294 Note: perl5 DOES NOT error on the terminating @ in $bar
1295
1296 =item * Interpolation
1297
1298 Perl now sometimes evaluates arbitrary expressions inside braces that occur
1299 within double quotes (usually when the opening brace is preceded by C<$>
1300 or C<@>).
1301
1302     @www = "buz";
1303     $foo = "foo";
1304     $bar = "bar";
1305     sub foo { return "bar" };
1306     print "|@{w.w.w}|${main'foo}|";
1307
1308     # perl4 prints: |@{w.w.w}|foo|
1309     # perl5 prints: |buz|bar|
1310
1311 Note that you can C<use strict;> to ward off such trappiness under perl5.
1312
1313 =item * Interpolation
1314
1315 The construct "this is $$x" used to interpolate the pid at that
1316 point, but now apparently tries to dereference C<$x>.  C<$$> by itself still
1317 works fine, however.
1318
1319     print "this is $$x\n";
1320
1321     # perl4 prints: this is XXXx   (XXX is the current pid)
1322     # perl5 prints: this is
1323
1324 =item * Interpolation
1325
1326 Creation of hashes on the fly with C<eval "EXPR"> now requires either both
1327 C<$>'s to be protected in the specification of the hash name, or both curlies
1328 to be protected.  If both curlies are protected, the result will be compatible
1329 with perl4 and perl5.  This is a very common practice, and should be changed
1330 to use the block form of C<eval{}>  if possible.
1331
1332     $hashname = "foobar";
1333     $key = "baz";
1334     $value = 1234;
1335     eval "\$$hashname{'$key'} = q|$value|";
1336     (defined($foobar{'baz'})) ?  (print "Yup") : (print "Nope");
1337
1338     # perl4 prints: Yup
1339     # perl5 prints: Nope
1340
1341 Changing
1342
1343     eval "\$$hashname{'$key'} = q|$value|";
1344
1345 to
1346
1347     eval "\$\$hashname{'$key'} = q|$value|";
1348
1349 causes the following result:
1350
1351     # perl4 prints: Nope
1352     # perl5 prints: Yup
1353
1354 or, changing to
1355
1356     eval "\$$hashname\{'$key'\} = q|$value|";
1357
1358 causes the following result:
1359
1360     # perl4 prints: Yup
1361     # perl5 prints: Yup
1362     # and is compatible for both versions
1363
1364
1365 =item * Interpolation
1366
1367 perl4 programs which unconsciously rely on the bugs in earlier perl versions.
1368
1369     perl -e '$bar=q/not/; print "This is $foo{$bar} perl5"'
1370
1371     # perl4 prints: This is not perl5
1372     # perl5 prints: This is perl5
1373
1374 =item * Interpolation
1375
1376 You also have to be careful about array references.
1377
1378     print "$foo{"
1379
1380     perl 4 prints: {
1381     perl 5 prints: syntax error
1382
1383 =item * Interpolation
1384
1385 Similarly, watch out for:
1386
1387     $foo = "array";
1388     print "\$$foo{bar}\n";
1389
1390     # perl4 prints: $array{bar}
1391     # perl5 prints: $
1392
1393 Perl 5 is looking for C<$array{bar}> which doesn't exist, but perl 4 is
1394 happy just to expand $foo to "array" by itself.  Watch out for this
1395 especially in C<eval>'s.
1396
1397 =item * Interpolation
1398
1399 C<qq()> string passed to C<eval>
1400
1401     eval qq(
1402         foreach \$y (keys %\$x\) {
1403             \$count++;
1404         }
1405     );
1406
1407     # perl4 runs this ok
1408     # perl5 prints: Can't find string terminator ")"
1409
1410 =back
1411
1412 =head2 DBM Traps
1413
1414 General DBM traps.
1415
1416 =over 5
1417
1418 =item * DBM
1419
1420 Existing dbm databases created under perl4 (or any other dbm/ndbm tool)
1421 may cause the same script, run under perl5, to fail.  The build of perl5
1422 must have been linked with the same dbm/ndbm as the default for C<dbmopen()>
1423 to function properly without C<tie>'ing to an extension dbm implementation.
1424
1425     dbmopen (%dbm, "file", undef);
1426     print "ok\n";
1427
1428     # perl4 prints: ok
1429     # perl5 prints: ok (IFF linked with -ldbm or -lndbm)
1430
1431
1432 =item * DBM
1433
1434 Existing dbm databases created under perl4 (or any other dbm/ndbm tool)
1435 may cause the same script, run under perl5, to fail.  The error generated
1436 when exceeding the limit on the key/value size will cause perl5 to exit
1437 immediately.
1438
1439     dbmopen(DB, "testdb",0600) || die "couldn't open db! $!";
1440     $DB{'trap'} = "x" x 1024;  # value too large for most dbm/ndbm
1441     print "YUP\n";
1442
1443     # perl4 prints:
1444     dbm store returned -1, errno 28, key "trap" at - line 3.
1445     YUP
1446
1447     # perl5 prints:
1448     dbm store returned -1, errno 28, key "trap" at - line 3.
1449
1450 =back
1451
1452 =head2 Unclassified Traps
1453
1454 Everything else.
1455
1456 =over 5
1457
1458 =item * Unclassified
1459
1460 C<require>/C<do> trap using returned value
1461
1462 If the file doit.pl has:
1463
1464     sub foo {
1465         $rc = do "./do.pl";
1466         return 8;
1467     }
1468     print &foo, "\n";
1469
1470 And the do.pl file has the following single line:
1471
1472     return 3;
1473
1474 Running doit.pl gives the following:
1475
1476     # perl 4 prints: 3 (aborts the subroutine early)
1477     # perl 5 prints: 8
1478
1479 Same behavior if you replace C<do> with C<require>.
1480
1481 =back
1482
1483 As always, if any of these are ever officially declared as bugs,
1484 they'll be fixed and removed.
1485