pod/perltrap.pod

   1 =head1 NAME
   2
   3 perltrap - Perl traps for the unwary
   4
   5 =head1 DESCRIPTION
   6
   7 The biggest trap of all is forgetting to use the B<-w> switch; see
   8 L<perlrun>.  The second biggest trap is not making your entire program
   9 runnable under C<use strict>.  The third biggest trap is not reading
  10 the list of changes in this version of Perl; see L<perldelta>.
  11
  12 =head2 Awk Traps
  13
  14 Accustomed B<awk> users should take special note of the following:
  15
  16 =over 4
  17
  18 =item *
  19
  20 The English module, loaded via
  21
  22     use English;
  23
  24 allows you to refer to special variables (like C<$/>) with names (like
  25 C<$RS>), as though they were in B<awk>; see L<perlvar> for details.
  26
  27 =item *
  28
  29 Semicolons are required after all simple statements in Perl (except
  30 at the end of a block).  Newline is not a statement delimiter.
  31
  32 =item *
  33
  34 Curly brackets are required on C<if>s and C<while>s.
  35
  36 =item *
  37
  38 Variables begin with "$", "@" or "%" in Perl.
  39
  40 =item *
  41
  42 Arrays index from 0.  Likewise string positions in substr() and
  43 index().
  44
  45 =item *
  46
  47 You have to decide whether your array has numeric or string indices.
  48
  49 =item *
  50
  51 Hash values do not spring into existence upon mere reference.
  52
  53 =item *
  54
  55 You have to decide whether you want to use string or numeric
  56 comparisons.
  57
  58 =item *
  59
  60 Reading an input line does not split it for you.  You get to split it
  61 to an array yourself.  And the split() operator has different
  62 arguments than B<awk>'s.
  63
  64 =item *
  65
  66 The current input line is normally in $_, not $0.  It generally does
  67 not have the newline stripped.  ($0 is the name of the program
  68 executed.)  See L<perlvar>.
  69
  70 =item *
  71
  72 $E<lt>I<digit>E<gt> does not refer to fields--it refers to substrings matched
  73 by the last match pattern.
  74
  75 =item *
  76
  77 The print() statement does not add field and record separators unless
  78 you set C<$,> and C<$\>.  You can set $OFS and $ORS if you're using
  79 the English module.
  80
  81 =item *
  82
  83 You must open your files before you print to them.
  84
  85 =item *
  86
  87 The range operator is "..", not comma.  The comma operator works as in
  88 C.
  89
  90 =item *
  91
  92 The match operator is "=~", not "~".  ("~" is the one's complement
  93 operator, as in C.)
  94
  95 =item *
  96
  97 The exponentiation operator is "**", not "^".  "^" is the XOR
  98 operator, as in C.  (You know, one could get the feeling that B<awk> is
  99 basically incompatible with C.)
 100
 101 =item *
 102
 103 The concatenation operator is ".", not the null string.  (Using the
 104 null string would render C</pat/ /pat/> unparsable, because the third slash
 105 would be interpreted as a division operator--the tokenizer is in fact
 106 slightly context sensitive for operators like "/", "?", and "E<gt>".
 107 And in fact, "." itself can be the beginning of a number.)
 108
 109 =item *
 110
 111 The C<next>, C<exit>, and C<continue> keywords work differently.
 112
 113 =item *
 114
 115
 116 The following variables work differently:
 117
 118       Awk       Perl
 119       ARGC      $#ARGV or scalar @ARGV
 120       ARGV[0]   $0
 121       FILENAME  $ARGV
 122       FNR       $. - something
 123       FS        (whatever you like)
 124       NF        $#Fld, or some such
 125       NR        $.
 126       OFMT      $#
 127       OFS       $,
 128       ORS       $\
 129       RLENGTH   length($&)
 130       RS        $/
 131       RSTART    length($`)
 132       SUBSEP    $;
 133
 134 =item *
 135
 136 You cannot set $RS to a pattern, only a string.
 137
 138 =item *
 139
 140 When in doubt, run the B<awk> construct through B<a2p> and see what it
 141 gives you.
 142
 143 =back
 144
 145 =head2 C Traps
 146
 147 Cerebral C programmers should take note of the following:
 148
 149 =over 4
 150
 151 =item *
 152
 153 Curly brackets are required on C<if>'s and C<while>'s.
 154
 155 =item *
 156
 157 You must use C<elsif> rather than C<else if>.
 158
 159 =item *
 160
 161 The C<break> and C<continue> keywords from C become in
 162 Perl C<last> and C<next>, respectively.
 163 Unlike in C, these do I<NOT> work within a C<do { } while> construct.
 164
 165 =item *
 166
 167 There's no switch statement.  (But it's easy to build one on the fly.)
 168
 169 =item *
 170
 171 Variables begin with "$", "@" or "%" in Perl.
 172
 173 =item *
 174
 175 C<printf()> does not implement the "*" format for interpolating
 176 field widths, but it's trivial to use interpolation of double-quoted
 177 strings to achieve the same effect.
 178
 179 =item *
 180
 181 Comments begin with "#", not "/*".
 182
 183 =item *
 184
 185 You can't take the address of anything, although a similar operator
 186 in Perl is the backslash, which creates a reference.
 187
 188 =item *
 189
 190 C<ARGV> must be capitalized.  C<$ARGV[0]> is C's C<argv[1]>, and C<argv[0]>
 191 ends up in C<$0>.
 192
 193 =item *
 194
 195 System calls such as link(), unlink(), rename(), etc. return nonzero for
 196 success, not 0.
 197
 198 =item *
 199
 200 Signal handlers deal with signal names, not numbers.  Use C<kill -l>
 201 to find their names on your system.
 202
 203 =back
 204
 205 =head2 Sed Traps
 206
 207 Seasoned B<sed> programmers should take note of the following:
 208
 209 =over 4
 210
 211 =item *
 212
 213 Backreferences in substitutions use "$" rather than "\".
 214
 215 =item *
 216
 217 The pattern matching metacharacters "(", ")", and "|" do not have backslashes
 218 in front.
 219
 220 =item *
 221
 222 The range operator is C<...>, rather than comma.
 223
 224 =back
 225
 226 =head2 Shell Traps
 227
 228 Sharp shell programmers should take note of the following:
 229
 230 =over 4
 231
 232 =item *
 233
 234 The backtick operator does variable interpolation without regard to
 235 the presence of single quotes in the command.
 236
 237 =item *
 238
 239 The backtick operator does no translation of the return value, unlike B<csh>.
 240
 241 =item *
 242
 243 Shells (especially B<csh>) do several levels of substitution on each
 244 command line.  Perl does substitution in only certain constructs
 245 such as double quotes, backticks, angle brackets, and search patterns.
 246
 247 =item *
 248
 249 Shells interpret scripts a little bit at a time.  Perl compiles the
 250 entire program before executing it (except for C<BEGIN> blocks, which
 251 execute at compile time).
 252
 253 =item *
 254
 255 The arguments are available via @ARGV, not $1, $2, etc.
 256
 257 =item *
 258
 259 The environment is not automatically made available as separate scalar
 260 variables.
 261
 262 =back
 263
 264 =head2 Perl Traps
 265
 266 Practicing Perl Programmers should take note of the following:
 267
 268 =over 4
 269
 270 =item *
 271
 272 Remember that many operations behave differently in a list
 273 context than they do in a scalar one.  See L<perldata> for details.
 274
 275 =item *
 276
 277 Avoid barewords if you can, especially all lowercase ones.
 278 You can't tell by just looking at it whether a bareword is
 279 a function or a string.  By using quotes on strings and
 280 parentheses on function calls, you won't ever get them confused.
 281
 282 =item *
 283
 284 You cannot discern from mere inspection which builtins
 285 are unary operators (like chop() and chdir())
 286 and which are list operators (like print() and unlink()).
 287 (User-defined subroutines can be B<only> list operators, never
 288 unary ones.)  See L<perlop>.
 289
 290 =item *
 291
 292 People have a hard time remembering that some functions
 293 default to $_, or @ARGV, or whatever, but that others which
 294 you might expect to do not.
 295
 296 =item *
 297
 298 The E<lt>FHE<gt> construct is not the name of the filehandle, it is a readline
 299 operation on that handle.  The data read is assigned to $_ only if the
 300 file read is the sole condition in a while loop:
 301
 302     while (<FH>)      { }
 303     while (defined($_ = <FH>)) { }..
 304     <FH>;  # data discarded!
 305
 306 =item *
 307
 308 Remember not to use "C<=>" when you need "C<=~>";
 309 these two constructs are quite different:
 310
 311     $x =  /foo/;
 312     $x =~ /foo/;
 313
 314 =item *
 315
 316 The C<do {}> construct isn't a real loop that you can use
 317 loop control on.
 318
 319 =item *
 320
 321 Use C<my()> for local variables whenever you can get away with
 322 it (but see L<perlform> for where you can't).
 323 Using C<local()> actually gives a local value to a global
 324 variable, which leaves you open to unforeseen side-effects
 325 of dynamic scoping.
 326
 327 =item *
 328
 329 If you localize an exported variable in a module, its exported value will
 330 not change.  The local name becomes an alias to a new value but the
 331 external name is still an alias for the original.
 332
 333 =back
 334
 335 =head2 Perl4 to Perl5 Traps
 336
 337 Practicing Perl4 Programmers should take note of the following
 338 Perl4-to-Perl5 specific traps.
 339
 340 They're crudely ordered according to the following list:
 341
 342 =over 4
 343
 344 =item Discontinuance, Deprecation, and BugFix traps
 345
 346 Anything that's been fixed as a perl4 bug, removed as a perl4 feature
 347 or deprecated as a perl4 feature with the intent to encourage usage of
 348 some other perl5 feature.
 349
 350 =item Parsing Traps
 351
 352 Traps that appear to stem from the new parser.
 353
 354 =item Numerical Traps
 355
 356 Traps having to do with numerical or mathematical operators.
 357
 358 =item General data type traps
 359
 360 Traps involving perl standard data types.
 361
 362 =item Context Traps - scalar, list contexts
 363
 364 Traps related to context within lists, scalar statements/declarations.
 365
 366 =item Precedence Traps
 367
 368 Traps related to the precedence of parsing, evaluation, and execution of
 369 code.
 370
 371 =item General Regular Expression Traps using s///, etc.
 372
 373 Traps related to the use of pattern matching.
 374
 375 =item Subroutine, Signal, Sorting Traps
 376
 377 Traps related to the use of signals and signal handlers, general subroutines,
 378 and sorting, along with sorting subroutines.
 379
 380 =item OS Traps
 381
 382 OS-specific traps.
 383
 384 =item DBM Traps
 385
 386 Traps specific to the use of C<dbmopen()>, and specific dbm implementations.
 387
 388 =item Unclassified Traps
 389
 390 Everything else.
 391
 392 =back
 393
 394 If you find an example of a conversion trap that is not listed here,
 395 please submit it to Bill Middleton <F<wjm@best.com>> for inclusion.
 396 Also note that at least some of these can be caught with B<-w>.
 397
 398 =head2 Discontinuance, Deprecation, and BugFix traps
 399
 400 Anything that has been discontinued, deprecated, or fixed as
 401 a bug from perl4.
 402
 403 =over 4
 404
 405 =item * Discontinuance
 406
 407 Symbols starting with "_" are no longer forced into package main, except
 408 for C<$_> itself (and C<@_>, etc.).
 409
 410     package test;
 411     $_legacy = 1;
 412
 413     package main;
 414     print "\$_legacy is ",$_legacy,"\n";
 415
 416     # perl4 prints: $_legacy is 1
 417     # perl5 prints: $_legacy is
 418
 419 =item * Deprecation
 420
 421 Double-colon is now a valid package separator in a variable name.  Thus these
 422 behave differently in perl4 vs. perl5, because the packages don't exist.
 423
 424     $a=1;$b=2;$c=3;$var=4;
 425     print "$a::$b::$c ";
 426     print "$var::abc::xyz\n";
 427
 428     # perl4 prints: 1::2::3 4::abc::xyz
 429     # perl5 prints: 3
 430
 431 Given that C<::> is now the preferred package delimiter, it is debatable
 432 whether this should be classed as a bug or not.
 433 (The older package delimiter, ' ,is used here)
 434
 435     $x = 10 ;
 436     print "x=${'x}\n" ;
 437
 438     # perl4 prints: x=10
 439     # perl5 prints: Can't find string terminator "'" anywhere before EOF
 440
 441 You can avoid this problem, and remain compatible with perl4, if you
 442 always explicitly include the package name:
 443
 444     $x = 10 ;
 445     print "x=${main'x}\n" ;
 446
 447 Also see precedence traps, for parsing C<$:>.
 448
 449 =item * BugFix
 450
 451 The second and third arguments of C<splice()> are now evaluated in scalar
 452 context (as the Camel says) rather than list context.
 453
 454     sub sub1{return(0,2) }          # return a 2-element list
 455     sub sub2{ return(1,2,3)}        # return a 3-element list
 456     @a1 = ("a","b","c","d","e");
 457     @a2 = splice(@a1,&sub1,&sub2);
 458     print join(' ',@a2),"\n";
 459
 460     # perl4 prints: a b
 461     # perl5 prints: c d e
 462
 463 =item * Discontinuance
 464
 465 You can't do a C<goto> into a block that is optimized away.  Darn.
 466
 467     goto marker1;
 468
 469     for(1){
 470     marker1:
 471         print "Here I is!\n";
 472     }
 473
 474     # perl4 prints: Here I is!
 475     # perl5 dumps core (SEGV)
 476
 477 =item * Discontinuance
 478
 479 It is no longer syntactically legal to use whitespace as the name
 480 of a variable, or as a delimiter for any kind of quote construct.
 481 Double darn.
 482
 483     $a = ("foo bar");
 484     $b = q baz ;
 485     print "a is $a, b is $b\n";
 486
 487     # perl4 prints: a is foo bar, b is baz
 488     # perl5 errors: Bareword found where operator expected
 489
 490 =item * Discontinuance
 491
 492 The archaic while/if BLOCK BLOCK syntax is no longer supported.
 493
 494     if { 1 } {
 495         print "True!";
 496     }
 497     else {
 498         print "False!";
 499     }
 500
 501     # perl4 prints: True!
 502     # perl5 errors: syntax error at test.pl line 1, near "if {"
 503
 504 =item * BugFix
 505
 506 The C<**> operator now binds more tightly than unary minus.
 507 It was documented to work this way before, but didn't.
 508
 509     print -4**2,"\n";
 510
 511     # perl4 prints: 16
 512     # perl5 prints: -16
 513
 514 =item * Discontinuance
 515
 516 The meaning of C<foreach{}> has changed slightly when it is iterating over a
 517 list which is not an array.  This used to assign the list to a
 518 temporary array, but no longer does so (for efficiency).  This means
 519 that you'll now be iterating over the actual values, not over copies of
 520 the values.  Modifications to the loop variable can change the original
 521 values.
 522
 523     @list = ('ab','abc','bcd','def');
 524     foreach $var (grep(/ab/,@list)){
 525         $var = 1;
 526     }
 527     print (join(':',@list));
 528
 529     # perl4 prints: ab:abc:bcd:def
 530     # perl5 prints: 1:1:bcd:def
 531
 532 To retain Perl4 semantics you need to assign your list
 533 explicitly to a temporary array and then iterate over that.  For
 534 example, you might need to change
 535
 536     foreach $var (grep(/ab/,@list)){
 537
 538 to
 539
 540     foreach $var (@tmp = grep(/ab/,@list)){
 541
 542 Otherwise changing $var will clobber the values of @list.  (This most often
 543 happens when you use C<$_> for the loop variable, and call subroutines in
 544 the loop that don't properly localize C<$_>.)
 545
 546 =item * Discontinuance
 547
 548 C<split> with no arguments now behaves like C<split ' '> (which doesn't
 549 return an initial null field if $_ starts with whitespace), it used to
 550 behave like C<split /\s+/> (which does).
 551
 552     $_ = ' hi mom';
 553     print join(':', split);
 554
 555     # perl4 prints: :hi:mom
 556     # perl5 prints: hi:mom
 557
 558 =item * BugFix
 559
 560 Perl 4 would ignore any text which was attached to an B<-e> switch,
 561 always taking the code snippet from the following arg.  Additionally, it
 562 would silently accept an B<-e> switch without a following arg.  Both of
 563 these behaviors have been fixed.
 564
 565     perl -e'print "attached to -e"' 'print "separate arg"'
 566
 567     # perl4 prints: separate arg
 568     # perl5 prints: attached to -e
 569
 570     perl -e
 571
 572     # perl4 prints:
 573     # perl5 dies: No code specified for -e.
 574
 575 =item * Discontinuance
 576
 577 In Perl 4 the return value of C<push> was undocumented, but it was
 578 actually the last value being pushed onto the target list.  In Perl 5
 579 the return value of C<push> is documented, but has changed, it is the
 580 number of elements in the resulting list.
 581
 582     @x = ('existing');
 583     print push(@x, 'first new', 'second new');
 584
 585     # perl4 prints: second new
 586     # perl5 prints: 3
 587
 588 =item * Discontinuance
 589
 590 In Perl 4 (and versions of Perl 5 before 5.004), C<'\r'> characters in
 591 Perl code were silently allowed, although they could cause (mysterious!)
 592 failures in certain constructs, particularly here documents.  Now,
 593 C<'\r'> characters cause an immediate fatal error.  (Note: In this
 594 example, the notation B<\015> represents the incorrect line
 595 ending. Depending upon your text viewer, it will look different.)
 596
 597     print "foo";\015
 598     print "bar";
 599
 600     # perl4     prints: foobar
 601     # perl5.003 prints: foobar
 602     # perl5.004 dies: Illegal character \015 (carriage return)
 603
 604 See L<perldiag> for full details.
 605
 606 =item * Deprecation
 607
 608 Some error messages will be different.
 609
 610 =item * Discontinuance
 611
 612 Some bugs may have been inadvertently removed.  :-)
 613
 614 =back
 615
 616 =head2 Parsing Traps
 617
 618 Perl4-to-Perl5 traps from having to do with parsing.
 619
 620 =over 4
 621
 622 =item * Parsing
 623
 624 Note the space between . and =
 625
 626     $string . = "more string";
 627     print $string;
 628
 629     # perl4 prints: more string
 630     # perl5 prints: syntax error at - line 1, near ". ="
 631
 632 =item * Parsing
 633
 634 Better parsing in perl 5
 635
 636     sub foo {}
 637     &foo
 638     print("hello, world\n");
 639
 640     # perl4 prints: hello, world
 641     # perl5 prints: syntax error
 642
 643 =item * Parsing
 644
 645 "if it looks like a function, it is a function" rule.
 646
 647   print
 648     ($foo == 1) ? "is one\n" : "is zero\n";
 649
 650     # perl4 prints: is zero
 651     # perl5 warns: "Useless use of a constant in void context" if using -w
 652
 653 =back
 654
 655 =head2 Numerical Traps
 656
 657 Perl4-to-Perl5 traps having to do with numerical operators,
 658 operands, or output from same.
 659
 660 =over 5
 661
 662 =item * Numerical
 663
 664 Formatted output and significant digits
 665
 666     print 7.373504 - 0, "\n";
 667     printf "%20.18f\n", 7.373504 - 0;
 668
 669     # Perl4 prints:
 670     7.375039999999996141
 671     7.37503999999999614
 672
 673     # Perl5 prints:
 674     7.373504
 675     7.37503999999999614
 676
 677 =item * Numerical
 678
 679 This specific item has been deleted.  It demonstrated how the auto-increment
 680 operator would not catch when a number went over the signed int limit.  Fixed
 681 in version 5.003_04.  But always be wary when using large integers.
 682 If in doubt:
 683
 684    use Math::BigInt;
 685
 686 =item * Numerical
 687
 688 Assignment of return values from numeric equality tests
 689 does not work in perl5 when the test evaluates to false (0).
 690 Logical tests now return an null, instead of 0
 691
 692     $p = ($test == 1);
 693     print $p,"\n";
 694
 695     # perl4 prints: 0
 696     # perl5 prints:
 697
 698 Also see L<"General Regular Expression Traps using s///, etc.">
 699 for another example of this new feature...
 700
 701 =back
 702
 703 =head2 General data type traps
 704
 705 Perl4-to-Perl5 traps involving most data-types, and their usage
 706 within certain expressions and/or context.
 707
 708 =over 5
 709
 710 =item * (Arrays)
 711
 712 Negative array subscripts now count from the end of the array.
 713
 714     @a = (1, 2, 3, 4, 5);
 715     print "The third element of the array is $a[3] also expressed as $a[-2] \n";
 716
 717     # perl4 prints: The third element of the array is 4 also expressed as
 718     # perl5 prints: The third element of the array is 4 also expressed as 4
 719
 720 =item * (Arrays)
 721
 722 Setting C<$#array> lower now discards array elements, and makes them
 723 impossible to recover.
 724
 725     @a = (a,b,c,d,e);
 726     print "Before: ",join('',@a);
 727     $#a =1;
 728     print ", After: ",join('',@a);
 729     $#a =3;
 730     print ", Recovered: ",join('',@a),"\n";
 731
 732     # perl4 prints: Before: abcde, After: ab, Recovered: abcd
 733     # perl5 prints: Before: abcde, After: ab, Recovered: ab
 734
 735 =item * (Hashes)
 736
 737 Hashes get defined before use
 738
 739     local($s,@a,%h);
 740     die "scalar \$s defined" if defined($s);
 741     die "array \@a defined" if defined(@a);
 742     die "hash \%h defined" if defined(%h);
 743
 744     # perl4 prints:
 745     # perl5 dies: hash %h defined
 746
 747 =item * (Globs)
 748
 749 glob assignment from variable to variable will fail if the assigned
 750 variable is localized subsequent to the assignment
 751
 752     @a = ("This is Perl 4");
 753     *b = *a;
 754     local(@a);
 755     print @b,"\n";
 756
 757     # perl4 prints: This is Perl 4
 758     # perl5 prints:
 759
 760 =item * (Globs)
 761
 762 Assigning C<undef> to a glob has no effect in Perl 5.   In Perl 4
 763 it undefines the associated scalar (but may have other side effects
 764 including SEGVs).
 765
 766 =item * (Scalar String)
 767
 768 Changes in unary negation (of strings)
 769 This change effects both the return value and what it
 770 does to auto(magic)increment.
 771
 772     $x = "aaa";
 773     print ++$x," : ";
 774     print -$x," : ";
 775     print ++$x,"\n";
 776
 777     # perl4 prints: aab : -0 : 1
 778     # perl5 prints: aab : -aab : aac
 779
 780 =item * (Constants)
 781
 782 perl 4 lets you modify constants:
 783
 784     $foo = "x";
 785     &mod($foo);
 786     for ($x = 0; $x < 3; $x++) {
 787         &mod("a");
 788     }
 789     sub mod {
 790         print "before: $_[0]";
 791         $_[0] = "m";
 792         print "  after: $_[0]\n";
 793     }
 794
 795     # perl4:
 796     # before: x  after: m
 797     # before: a  after: m
 798     # before: m  after: m
 799     # before: m  after: m
 800
 801     # Perl5:
 802     # before: x  after: m
 803     # Modification of a read-only value attempted at foo.pl line 12.
 804     # before: a
 805
 806 =item * (Scalars)
 807
 808 The behavior is slightly different for:
 809
 810     print "$x", defined $x
 811
 812     # perl 4: 1
 813     # perl 5: <no output, $x is not called into existence>
 814
 815 =item * (Variable Suicide)
 816
 817 Variable suicide behavior is more consistent under Perl 5.
 818 Perl5 exhibits the same behavior for hashes and scalars,
 819 that perl4 exhibits for only scalars.
 820
 821     $aGlobal{ "aKey" } = "global value";
 822     print "MAIN:", $aGlobal{"aKey"}, "\n";
 823     $GlobalLevel = 0;
 824     &test( *aGlobal );
 825
 826     sub test {
 827         local( *theArgument ) = @_;
 828         local( %aNewLocal ); # perl 4 != 5.001l,m
 829         $aNewLocal{"aKey"} = "this should never appear";
 830         print "SUB: ", $theArgument{"aKey"}, "\n";
 831         $aNewLocal{"aKey"} = "level $GlobalLevel";   # what should print
 832         $GlobalLevel++;
 833         if( $GlobalLevel<4 ) {
 834             &test( *aNewLocal );
 835         }
 836     }
 837
 838     # Perl4:
 839     # MAIN:global value
 840     # SUB: global value
 841     # SUB: level 0
 842     # SUB: level 1
 843     # SUB: level 2
 844
 845     # Perl5:
 846     # MAIN:global value
 847     # SUB: global value
 848     # SUB: this should never appear
 849     # SUB: this should never appear
 850     # SUB: this should never appear
 851
 852 =back
 853
 854 =head2 Context Traps - scalar, list contexts
 855
 856 =over 5
 857
 858 =item * (list context)
 859
 860 The elements of argument lists for formats are now evaluated in list
 861 context.  This means you can interpolate list values now.
 862
 863     @fmt = ("foo","bar","baz");
 864     format STDOUT=
 865     @<<<<< @||||| @>>>>>
 866     @fmt;
 867     .
 868     write;
 869
 870     # perl4 errors:  Please use commas to separate fields in file
 871     # perl5 prints: foo     bar      baz
 872
 873 =item * (scalar context)
 874
 875 The C<caller()> function now returns a false value in a scalar context
 876 if there is no caller.  This lets library files determine if they're
 877 being required.
 878
 879     caller() ? (print "You rang?\n") : (print "Got a 0\n");
 880
 881     # perl4 errors: There is no caller
 882     # perl5 prints: Got a 0
 883
 884 =item * (scalar context)
 885
 886 The comma operator in a scalar context is now guaranteed to give a
 887 scalar context to its arguments.
 888
 889     @y= ('a','b','c');
 890     $x = (1, 2, @y);
 891     print "x = $x\n";
 892
 893     # Perl4 prints:  x = c   # Thinks list context interpolates list
 894     # Perl5 prints:  x = 3   # Knows scalar uses length of list
 895
 896 =item * (list, builtin)
 897
 898 C<sprintf()> funkiness (array argument converted to scalar array count)
 899 This test could be added to t/op/sprintf.t
 900
 901     @z = ('%s%s', 'foo', 'bar');
 902     $x = sprintf(@z);
 903     if ($x eq 'foobar') {print "ok 2\n";} else {print "not ok 2 '$x'\n";}
 904
 905     # perl4 prints: ok 2
 906     # perl5 prints: not ok 2
 907
 908 C<printf()> works fine, though:
 909
 910     printf STDOUT (@z);
 911     print "\n";
 912
 913     # perl4 prints: foobar
 914     # perl5 prints: foobar
 915
 916 Probably a bug.
 917
 918 =back
 919
 920 =head2 Precedence Traps
 921
 922 Perl4-to-Perl5 traps involving precedence order.
 923
 924 Perl 4 has almost the same precedence rules as Perl 5 for the operators
 925 that they both have.  Perl 4 however, seems to have had some
 926 inconsistencies that made the behavior differ from what was documented.
 927
 928 =over 5
 929
 930 =item * Precedence
 931
 932 LHS vs. RHS of any assignment operator.  LHS is evaluated first
 933 in perl4, second in perl5; this can affect the relationship
 934 between side-effects in sub-expressions.
 935
 936     @arr = ( 'left', 'right' );
 937     $a{shift @arr} = shift @arr;
 938     print join( ' ', keys %a );
 939
 940     # perl4 prints: left
 941     # perl5 prints: right
 942
 943 =item * Precedence
 944
 945 These are now semantic errors because of precedence:
 946
 947     @list = (1,2,3,4,5);
 948     %map = ("a",1,"b",2,"c",3,"d",4);
 949     $n = shift @list + 2;   # first item in list plus 2
 950     print "n is $n, ";
 951     $m = keys %map + 2;     # number of items in hash plus 2
 952     print "m is $m\n";
 953
 954     # perl4 prints: n is 3, m is 6
 955     # perl5 errors and fails to compile
 956
 957 =item * Precedence
 958
 959 The precedence of assignment operators is now the same as the precedence
 960 of assignment.  Perl 4 mistakenly gave them the precedence of the associated
 961 operator.  So you now must parenthesize them in expressions like
 962
 963     /foo/ ? ($a += 2) : ($a -= 2);
 964
 965 Otherwise
 966
 967     /foo/ ? $a += 2 : $a -= 2
 968
 969 would be erroneously parsed as
 970
 971     (/foo/ ? $a += 2 : $a) -= 2;
 972
 973 On the other hand,
 974
 975     $a += /foo/ ? 1 : 2;
 976
 977 now works as a C programmer would expect.
 978
 979 =item * Precedence
 980
 981     open FOO || die;
 982
 983 is now incorrect.  You need parentheses around the filehandle.
 984 Otherwise, perl5 leaves the statement as its default precedence:
 985
 986     open(FOO || die);
 987
 988     # perl4 opens or dies
 989     # perl5 errors: Precedence problem: open FOO should be open(FOO)
 990
 991 =item * Precedence
 992
 993 perl4 gives the special variable, C<$:> precedence, where perl5
 994 treats C<$::> as main C<package>
 995
 996     $a = "x"; print "$::a";
 997
 998     # perl 4 prints: -:a
 999     # perl 5 prints: x
1000
1001 =item * Precedence
1002
1003 perl4 had buggy precedence for the file test operators vis-a-vis
1004 the assignment operators.  Thus, although the precedence table
1005 for perl4 leads one to believe C<-e $foo .= "q"> should parse as
1006 C<((-e $foo) .= "q")>, it actually parses as C<(-e ($foo .= "q"))>.
1007 In perl5, the precedence is as documented.
1008
1009     -e $foo .= "q"
1010
1011     # perl4 prints: no output
1012     # perl5 prints: Can't modify -e in concatenation
1013
1014 =item * Precedence
1015
1016 In perl4, keys(), each() and values() were special high-precedence operators
1017 that operated on a single hash, but in perl5, they are regular named unary
1018 operators.  As documented, named unary operators have lower precedence
1019 than the arithmetic and concatenation operators C<+ - .>, but the perl4
1020 variants of these operators actually bind tighter than C<+ - .>.
1021 Thus, for:
1022
1023     %foo = 1..10;
1024     print keys %foo - 1
1025
1026     # perl4 prints: 4
1027     # perl5 prints: Type of arg 1 to keys must be hash (not subtraction)
1028
1029 The perl4 behavior was probably more useful, if less consistent.
1030
1031 =back
1032
1033 =head2 General Regular Expression Traps using s///, etc.
1034
1035 All types of RE traps.
1036
1037 =over 5
1038
1039 =item * Regular Expression
1040
1041 C<s'$lhs'$rhs'> now does no interpolation on either side.  It used to
1042 interpolate C<$lhs> but not C<$rhs>.  (And still does not match a literal
1043 '$' in string)
1044
1045     $a=1;$b=2;
1046     $string = '1 2 $a $b';
1047     $string =~ s'$a'$b';
1048     print $string,"\n";
1049
1050     # perl4 prints: $b 2 $a $b
1051     # perl5 prints: 1 2 $a $b
1052
1053 =item * Regular Expression
1054
1055 C<m//g> now attaches its state to the searched string rather than the
1056 regular expression.  (Once the scope of a block is left for the sub, the
1057 state of the searched string is lost)
1058
1059     $_ = "ababab";
1060     while(m/ab/g){
1061         &doit("blah");
1062     }
1063     sub doit{local($_) = shift; print "Got $_ "}
1064
1065     # perl4 prints: blah blah blah
1066     # perl5 prints: infinite loop blah...
1067
1068 =item * Regular Expression
1069
1070 Currently, if you use the C<m//o> qualifier on a regular expression
1071 within an anonymous sub, I<all> closures generated from that anonymous
1072 sub will use the regular expression as it was compiled when it was used
1073 the very first time in any such closure.  For instance, if you say
1074
1075     sub build_match {
1076         my($left,$right) = @_;
1077         return sub { $_[0] =~ /$left stuff $right/o; };
1078     }
1079
1080 build_match() will always return a sub which matches the contents of
1081 C<$left> and C<$right> as they were the I<first> time that build_match()
1082 was called, not as they are in the current call.
1083
1084 This is probably a bug, and may change in future versions of Perl.
1085
1086 =item * Regular Expression
1087
1088 If no parentheses are used in a match, Perl4 sets C<$+> to
1089 the whole match, just like C<$&>. Perl5 does not.
1090
1091     "abcdef" =~ /b.*e/;
1092     print "\$+ = $+\n";
1093
1094     # perl4 prints: bcde
1095     # perl5 prints:
1096
1097 =item * Regular Expression
1098
1099 substitution now returns the null string if it fails
1100
1101     $string = "test";
1102     $value = ($string =~ s/foo//);
1103     print $value, "\n";
1104
1105     # perl4 prints: 0
1106     # perl5 prints:
1107
1108 Also see L<Numerical Traps> for another example of this new feature.
1109
1110 =item * Regular Expression
1111
1112 C<s`lhs`rhs`> (using backticks) is now a normal substitution, with no
1113 backtick expansion
1114
1115     $string = "";
1116     $string =~ s`^`hostname`;
1117     print $string, "\n";
1118
1119     # perl4 prints: <the local hostname>
1120     # perl5 prints: hostname
1121
1122 =item * Regular Expression
1123
1124 Stricter parsing of variables used in regular expressions
1125
1126     s/^([^$grpc]*$grpc[$opt$plus$rep]?)//o;
1127
1128     # perl4: compiles w/o error
1129     # perl5: with Scalar found where operator expected ..., near "$opt$plus"
1130
1131 an added component of this example, apparently from the same script, is
1132 the actual value of the s'd string after the substitution.
1133 C<[$opt]> is a character class in perl4 and an array subscript in perl5
1134
1135     $grpc = 'a';
1136     $opt  = 'r';
1137     $_ = 'bar';
1138     s/^([^$grpc]*$grpc[$opt]?)/foo/;
1139     print ;
1140
1141     # perl4 prints: foo
1142     # perl5 prints: foobar
1143
1144 =item * Regular Expression
1145
1146 Under perl5, C<m?x?> matches only once, like C<?x?>. Under perl4, it matched
1147 repeatedly, like C</x/> or C<m!x!>.
1148
1149     $test = "once";
1150     sub match { $test =~ m?once?; }
1151     &match();
1152     if( &match() ) {
1153         # m?x? matches more then once
1154         print "perl4\n";
1155     } else {
1156         # m?x? matches only once
1157         print "perl5\n";
1158     }
1159
1160     # perl4 prints: perl4
1161     # perl5 prints: perl5
1162
1163
1164 =back
1165
1166 =head2 Subroutine, Signal, Sorting Traps
1167
1168 The general group of Perl4-to-Perl5 traps having to do with
1169 Signals, Sorting, and their related subroutines, as well as
1170 general subroutine traps.  Includes some OS-Specific traps.
1171
1172 =over 5
1173
1174 =item * (Signals)
1175
1176 Barewords that used to look like strings to Perl will now look like subroutine
1177 calls if a subroutine by that name is defined before the compiler sees them.
1178
1179     sub SeeYa { warn"Hasta la vista, baby!" }
1180     $SIG{'TERM'} = SeeYa;
1181     print "SIGTERM is now $SIG{'TERM'}\n";
1182
1183     # perl4 prints: SIGTERM is main'SeeYa
1184     # perl5 prints: SIGTERM is now main::1
1185
1186 Use B<-w> to catch this one
1187
1188 =item * (Sort Subroutine)
1189
1190 reverse is no longer allowed as the name of a sort subroutine.
1191
1192     sub reverse{ print "yup "; $a <=> $b }
1193     print sort reverse a,b,c;
1194
1195     # perl4 prints: yup yup yup yup abc
1196     # perl5 prints: abc
1197
1198 =item * warn() won't let you specify a filehandle.
1199
1200 Although it _always_ printed to STDERR, warn() would let you specify a
1201 filehandle in perl4.  With perl5 it does not.
1202
1203     warn STDERR "Foo!";
1204
1205     # perl4 prints: Foo!
1206     # perl5 prints: String found where operator expected
1207
1208 =back
1209
1210 =head2 OS Traps
1211
1212 =over 5
1213
1214 =item * (SysV)
1215
1216 Under HPUX, and some other SysV OSes, one had to reset any signal handler,
1217 within  the signal handler function, each time a signal was handled with
1218 perl4.  With perl5, the reset is now done correctly.  Any code relying
1219 on the handler _not_ being reset will have to be reworked.
1220
1221 Since version 5.002, Perl uses sigaction() under SysV.
1222
1223     sub gotit {
1224         print "Got @_... ";
1225     }
1226     $SIG{'INT'} = 'gotit';
1227
1228     $| = 1;
1229     $pid = fork;
1230     if ($pid) {
1231         kill('INT', $pid);
1232         sleep(1);
1233         kill('INT', $pid);
1234     } else {
1235         while (1) {sleep(10);}
1236     }
1237
1238     # perl4 (HPUX) prints: Got INT...
1239     # perl5 (HPUX) prints: Got INT... Got INT...
1240
1241 =item * (SysV)
1242
1243 Under SysV OSes, C<seek()> on a file opened to append C<E<gt>E<gt>> now does
1244 the right thing w.r.t. the fopen() manpage. e.g., - When a file is opened
1245 for append,  it  is  impossible to overwrite information already in
1246 the file.
1247
1248     open(TEST,">>seek.test");
1249     $start = tell TEST ;
1250     foreach(1 .. 9){
1251         print TEST "$_ ";
1252     }
1253     $end = tell TEST ;
1254     seek(TEST,$start,0);
1255     print TEST "18 characters here";
1256
1257     # perl4 (solaris) seek.test has: 18 characters here
1258     # perl5 (solaris) seek.test has: 1 2 3 4 5 6 7 8 9 18 characters here
1259
1260
1261
1262 =back
1263
1264 =head2 Interpolation Traps
1265
1266 Perl4-to-Perl5 traps having to do with how things get interpolated
1267 within certain expressions, statements, contexts, or whatever.
1268
1269 =over 5
1270
1271 =item * Interpolation
1272
1273 @ now always interpolates an array in double-quotish strings.
1274
1275     print "To: someone@somewhere.com\n";
1276
1277     # perl4 prints: To:someone@somewhere.com
1278     # perl5 errors : In string, @somewhere now must be written as \@somewhere
1279
1280 =item * Interpolation
1281
1282 Double-quoted strings may no longer end with an unescaped $ or @.
1283
1284     $foo = "foo$";
1285     $bar = "bar@";
1286     print "foo is $foo, bar is $bar\n";
1287
1288     # perl4 prints: foo is foo$, bar is bar@
1289     # perl5 errors: Final $ should be \$ or $name
1290
1291 Note: perl5 DOES NOT error on the terminating @ in $bar
1292
1293 =item * Interpolation
1294
1295 Perl now sometimes evaluates arbitrary expressions inside braces that occur
1296 within double quotes (usually when the opening brace is preceded by C<$>
1297 or C<@>).
1298
1299     @www = "buz";
1300     $foo = "foo";
1301     $bar = "bar";
1302     sub foo { return "bar" };
1303     print "|@{w.w.w}|${main'foo}|";
1304
1305     # perl4 prints: |@{w.w.w}|foo|
1306     # perl5 prints: |buz|bar|
1307
1308 Note that you can C<use strict;> to ward off such trappiness under perl5.
1309
1310 =item * Interpolation
1311
1312 The construct "this is $$x" used to interpolate the pid at that
1313 point, but now apparently tries to dereference C<$x>.  C<$$> by itself still
1314 works fine, however.
1315
1316     print "this is $$x\n";
1317
1318     # perl4 prints: this is XXXx   (XXX is the current pid)
1319     # perl5 prints: this is
1320
1321 =item * Interpolation
1322
1323 Creation of hashes on the fly with C<eval "EXPR"> now requires either both
1324 C<$>'s to be protected in the specification of the hash name, or both curlies
1325 to be protected.  If both curlies are protected, the result will be compatible
1326 with perl4 and perl5.  This is a very common practice, and should be changed
1327 to use the block form of C<eval{}>  if possible.
1328
1329     $hashname = "foobar";
1330     $key = "baz";
1331     $value = 1234;
1332     eval "\$$hashname{'$key'} = q|$value|";
1333     (defined($foobar{'baz'})) ?  (print "Yup") : (print "Nope");
1334
1335     # perl4 prints: Yup
1336     # perl5 prints: Nope
1337
1338 Changing
1339
1340     eval "\$$hashname{'$key'} = q|$value|";
1341
1342 to
1343
1344     eval "\$\$hashname{'$key'} = q|$value|";
1345
1346 causes the following result:
1347
1348     # perl4 prints: Nope
1349     # perl5 prints: Yup
1350
1351 or, changing to
1352
1353     eval "\$$hashname\{'$key'\} = q|$value|";
1354
1355 causes the following result:
1356
1357     # perl4 prints: Yup
1358     # perl5 prints: Yup
1359     # and is compatible for both versions
1360
1361
1362 =item * Interpolation
1363
1364 perl4 programs which unconsciously rely on the bugs in earlier perl versions.
1365
1366     perl -e '$bar=q/not/; print "This is $foo{$bar} perl5"'
1367
1368     # perl4 prints: This is not perl5
1369     # perl5 prints: This is perl5
1370
1371 =item * Interpolation
1372
1373 You also have to be careful about array references.
1374
1375     print "$foo{"
1376
1377     perl 4 prints: {
1378     perl 5 prints: syntax error
1379
1380 =item * Interpolation
1381
1382 Similarly, watch out for:
1383
1384     $foo = "array";
1385     print "\$$foo{bar}\n";
1386
1387     # perl4 prints: $array{bar}
1388     # perl5 prints: $
1389
1390 Perl 5 is looking for C<$array{bar}> which doesn't exist, but perl 4 is
1391 happy just to expand $foo to "array" by itself.  Watch out for this
1392 especially in C<eval>'s.
1393
1394 =item * Interpolation
1395
1396 C<qq()> string passed to C<eval>
1397
1398     eval qq(
1399         foreach \$y (keys %\$x\) {
1400             \$count++;
1401         }
1402     );
1403
1404     # perl4 runs this ok
1405     # perl5 prints: Can't find string terminator ")"
1406
1407 =back
1408
1409 =head2 DBM Traps
1410
1411 General DBM traps.
1412
1413 =over 5
1414
1415 =item * DBM
1416
1417 Existing dbm databases created under perl4 (or any other dbm/ndbm tool)
1418 may cause the same script, run under perl5, to fail.  The build of perl5
1419 must have been linked with the same dbm/ndbm as the default for C<dbmopen()>
1420 to function properly without C<tie>'ing to an extension dbm implementation.
1421
1422     dbmopen (%dbm, "file", undef);
1423     print "ok\n";
1424
1425     # perl4 prints: ok
1426     # perl5 prints: ok (IFF linked with -ldbm or -lndbm)
1427
1428
1429 =item * DBM
1430
1431 Existing dbm databases created under perl4 (or any other dbm/ndbm tool)
1432 may cause the same script, run under perl5, to fail.  The error generated
1433 when exceeding the limit on the key/value size will cause perl5 to exit
1434 immediately.
1435
1436     dbmopen(DB, "testdb",0600) || die "couldn't open db! $!";
1437     $DB{'trap'} = "x" x 1024;  # value too large for most dbm/ndbm
1438     print "YUP\n";
1439
1440     # perl4 prints:
1441     dbm store returned -1, errno 28, key "trap" at - line 3.
1442     YUP
1443
1444     # perl5 prints:
1445     dbm store returned -1, errno 28, key "trap" at - line 3.
1446
1447 =back
1448
1449 =head2 Unclassified Traps
1450
1451 Everything else.
1452
1453 =over 5
1454
1455 =item * C<require>/C<do> trap using returned value
1456
1457 If the file doit.pl has:
1458
1459     sub foo {
1460         $rc = do "./do.pl";
1461         return 8;
1462     }
1463     print &foo, "\n";
1464
1465 And the do.pl file has the following single line:
1466
1467     return 3;
1468
1469 Running doit.pl gives the following:
1470
1471     # perl 4 prints: 3 (aborts the subroutine early)
1472     # perl 5 prints: 8
1473
1474 Same behavior if you replace C<do> with C<require>.
1475
1476 =item * C<split> on empty string with LIMIT specified
1477
1478         $string = '';
1479     @list = split(/foo/, $string, 2)
1480
1481 Perl4 returns a one element list containing the empty string but Perl5
1482 returns an empty list.
1483
1484 =back
1485
1486 As always, if any of these are ever officially declared as bugs,
1487 they'll be fixed and removed.
1488