pod/perltrap.pod

   1 =head1 NAME
   2
   3 perltrap - Perl traps for the unwary
   4
   5 =head1 DESCRIPTION
   6
   7 The biggest trap of all is forgetting to use the B<-w> switch; see
   8 L<perlrun>.  The second biggest trap is not making your entire program
   9 runnable under C<use strict>.
  10
  11 =head2 Awk Traps
  12
  13 Accustomed B<awk> users should take special note of the following:
  14
  15 =over 4
  16
  17 =item *
  18
  19 The English module, loaded via
  20
  21     use English;
  22
  23 allows you to refer to special variables (like $RS) as
  24 though they were in B<awk>; see L<perlvar> for details.
  25
  26 =item *
  27
  28 Semicolons are required after all simple statements in Perl (except
  29 at the end of a block).  Newline is not a statement delimiter.
  30
  31 =item *
  32
  33 Curly brackets are required on C<if>s and C<while>s.
  34
  35 =item *
  36
  37 Variables begin with "$" or "@" in Perl.
  38
  39 =item *
  40
  41 Arrays index from 0.  Likewise string positions in substr() and
  42 index().
  43
  44 =item *
  45
  46 You have to decide whether your array has numeric or string indices.
  47
  48 =item *
  49
  50 Associative array values do not spring into existence upon mere
  51 reference.
  52
  53 =item *
  54
  55 You have to decide whether you want to use string or numeric
  56 comparisons.
  57
  58 =item *
  59
  60 Reading an input line does not split it for you.  You get to split it
  61 yourself to an array.  And the split() operator has different
  62 arguments.
  63
  64 =item *
  65
  66 The current input line is normally in $_, not $0.  It generally does
  67 not have the newline stripped.  ($0 is the name of the program
  68 executed.)  See L<perlvar>.
  69
  70 =item *
  71
  72 $E<lt>I<digit>E<gt> does not refer to fields--it refers to substrings matched
  73 by the last match pattern.
  74
  75 =item *
  76
  77 The print() statement does not add field and record separators unless
  78 you set C<$,> and C<$\>.  You can set $OFS and $ORS if you're using
  79 the English module.
  80
  81 =item *
  82
  83 You must open your files before you print to them.
  84
  85 =item *
  86
  87 The range operator is "..", not comma.  The comma operator works as in
  88 C.
  89
  90 =item *
  91
  92 The match operator is "=~", not "~".  ("~" is the one's complement
  93 operator, as in C.)
  94
  95 =item *
  96
  97 The exponentiation operator is "**", not "^".  "^" is the XOR
  98 operator, as in C.  (You know, one could get the feeling that B<awk> is
  99 basically incompatible with C.)
 100
 101 =item *
 102
 103 The concatenation operator is ".", not the null string.  (Using the
 104 null string would render C</pat/ /pat/> unparsable, because the third slash
 105 would be interpreted as a division operator--the tokenizer is in fact
 106 slightly context sensitive for operators like "/", "?", and "E<gt>".
 107 And in fact, "." itself can be the beginning of a number.)
 108
 109 =item *
 110
 111 The C<next>, C<exit>, and C<continue> keywords work differently.
 112
 113 =item *
 114
 115
 116 The following variables work differently:
 117
 118       Awk       Perl
 119       ARGC      $#ARGV or scalar @ARGV
 120       ARGV[0]   $0
 121       FILENAME  $ARGV
 122       FNR       $. - something
 123       FS        (whatever you like)
 124       NF        $#Fld, or some such
 125       NR        $.
 126       OFMT      $#
 127       OFS       $,
 128       ORS       $\
 129       RLENGTH   length($&)
 130       RS        $/
 131       RSTART    length($`)
 132       SUBSEP    $;
 133
 134 =item *
 135
 136 You cannot set $RS to a pattern, only a string.
 137
 138 =item *
 139
 140 When in doubt, run the B<awk> construct through B<a2p> and see what it
 141 gives you.
 142
 143 =back
 144
 145 =head2 C Traps
 146
 147 Cerebral C programmers should take note of the following:
 148
 149 =over 4
 150
 151 =item *
 152
 153 Curly brackets are required on C<if>'s and C<while>'s.
 154
 155 =item *
 156
 157 You must use C<elsif> rather than C<else if>.
 158
 159 =item *
 160
 161 The C<break> and C<continue> keywords from C become in
 162 Perl C<last> and C<next>, respectively.
 163 Unlike in C, these do I<NOT> work within a C<do { } while> construct.
 164
 165 =item *
 166
 167 There's no switch statement.  (But it's easy to build one on the fly.)
 168
 169 =item *
 170
 171 Variables begin with "$" or "@" in Perl.
 172
 173 =item *
 174
 175 C<printf()> does not implement the "*" format for interpolating
 176 field widths, but it's trivial to use interpolation of double-quoted
 177 strings to achieve the same effect.
 178
 179 =item *
 180
 181 Comments begin with "#", not "/*".
 182
 183 =item *
 184
 185 You can't take the address of anything, although a similar operator
 186 in Perl 5 is the backslash, which creates a reference.
 187
 188 =item *
 189
 190 C<ARGV> must be capitalized.  C<$ARGV[0]> is C's C<argv[1]>, and C<argv[0]>
 191 ends up in C<$0>.
 192
 193 =item *
 194
 195 System calls such as link(), unlink(), rename(), etc. return nonzero for
 196 success, not 0.
 197
 198 =item *
 199
 200 Signal handlers deal with signal names, not numbers.  Use C<kill -l>
 201 to find their names on your system.
 202
 203 =back
 204
 205 =head2 Sed Traps
 206
 207 Seasoned B<sed> programmers should take note of the following:
 208
 209 =over 4
 210
 211 =item *
 212
 213 Backreferences in substitutions use "$" rather than "\".
 214
 215 =item *
 216
 217 The pattern matching metacharacters "(", ")", and "|" do not have backslashes
 218 in front.
 219
 220 =item *
 221
 222 The range operator is C<...>, rather than comma.
 223
 224 =back
 225
 226 =head2 Shell Traps
 227
 228 Sharp shell programmers should take note of the following:
 229
 230 =over 4
 231
 232 =item *
 233
 234 The back-tick operator does variable interpolation without regard to
 235 the presence of single quotes in the command.
 236
 237 =item *
 238
 239 The back-tick operator does no translation of the return value, unlike B<csh>.
 240
 241 =item *
 242
 243 Shells (especially B<csh>) do several levels of substitution on each
 244 command line.  Perl does substitution in only certain constructs
 245 such as double quotes, back-ticks, angle brackets, and search patterns.
 246
 247 =item *
 248
 249 Shells interpret scripts a little bit at a time.  Perl compiles the
 250 entire program before executing it (except for C<BEGIN> blocks, which
 251 execute at compile time).
 252
 253 =item *
 254
 255 The arguments are available via @ARGV, not $1, $2, etc.
 256
 257 =item *
 258
 259 The environment is not automatically made available as separate scalar
 260 variables.
 261
 262 =back
 263
 264 =head2 Perl Traps
 265
 266 Practicing Perl Programmers should take note of the following:
 267
 268 =over 4
 269
 270 =item *
 271
 272 Remember that many operations behave differently in a list
 273 context than they do in a scalar one.  See L<perldata> for details.
 274
 275 =item *
 276
 277 Avoid barewords if you can, especially all lower-case ones.
 278 You can't tell by just looking at it whether a bareword is
 279 a function or a string.  By using quotes on strings and
 280 parentheses on function calls, you won't ever get them confused.
 281
 282 =item *
 283
 284 You cannot discern from mere inspection which built-ins
 285 are unary operators (like chop() and chdir())
 286 and which are list operators (like print() and unlink()).
 287 (User-defined subroutines can be B<only> list operators, never
 288 unary ones.)  See L<perlop>.
 289
 290 =item *
 291
 292 People have a hard time remembering that some functions
 293 default to $_, or @ARGV, or whatever, but that others which
 294 you might expect to do not.
 295
 296 =item *
 297
 298 The E<lt>FHE<gt> construct is not the name of the filehandle, it is a readline
 299 operation on that handle.  The data read is assigned to $_ only if the
 300 file read is the sole condition in a while loop:
 301
 302     while (<FH>)      { }
 303     while ($_ = <FH>) { }..
 304     <FH>;  # data discarded!
 305
 306 =item *
 307
 308 Remember not to use "C<=>" when you need "C<=~>";
 309 these two constructs are quite different:
 310
 311     $x =  /foo/;
 312     $x =~ /foo/;
 313
 314 =item *
 315
 316 The C<do {}> construct isn't a real loop that you can use
 317 loop control on.
 318
 319 =item *
 320
 321 Use C<my()> for local variables whenever you can get away with
 322 it (but see L<perlform> for where you can't).
 323 Using C<local()> actually gives a local value to a global
 324 variable, which leaves you open to unforeseen side-effects
 325 of dynamic scoping.
 326
 327 =item *
 328
 329 If you localize an exported variable in a module, its exported value will
 330 not change.  The local name becomes an alias to a new value but the
 331 external name is still an alias for the original.
 332
 333 =back
 334
 335 =head2 Perl4 to Perl5  Traps
 336
 337 Practicing Perl4 Programmers should take note of the following
 338 Perl4-to-Perl5 specific traps.
 339
 340 They're crudely ordered according to the following list:
 341
 342 =over 4
 343
 344 =item Discontinuance, Deprecation, and BugFix traps
 345
 346 Anything that's been fixed as a perl4 bug, removed as a perl4 feature
 347 or deprecated as a perl4 feature with the intent to encourage usage of
 348 some other perl5 feature.
 349
 350 =item Parsing Traps
 351
 352 Traps that appear to stem from the new parser.
 353
 354 =item Numerical Traps
 355
 356 Traps having to do with numerical or mathematical operators.
 357
 358 =item General data type traps
 359
 360 Traps involving perl standard data types.
 361
 362 =item Context Traps - scalar, list contexts
 363
 364 Traps related to context within lists, scalar statements/declarations.
 365
 366 =item Precedence Traps
 367
 368 Traps related to the precedence of parsing, evaluation, and execution of
 369 code.
 370
 371 =item General Regular Expression Traps using s///, etc.
 372
 373 Traps related to the use of pattern matching.
 374
 375 =item Subroutine, Signal, Sorting Traps
 376
 377 Traps related to the use of signals and signal handlers, general subroutines,
 378 and sorting, along with sorting subroutines.
 379
 380 =item OS Traps
 381
 382 OS-specific traps.
 383
 384 =item DBM Traps
 385
 386 Traps specific to the use of C<dbmopen()>, and specific dbm implementations.
 387
 388 =item Unclassified Traps
 389
 390 Everything else.
 391
 392 =back
 393
 394 If you find an example of a conversion trap that is not listed here,
 395 please submit it to Bill Middleton F<wjm@best.com> for inclusion.
 396 Also note that at least some of these can be caught with C<-w>.
 397
 398 =head2 Discontinuance, Deprecation, and BugFix traps
 399
 400 Anything that has been discontinued, deprecated, or fixed as
 401 a bug from perl4.
 402
 403 =over 4
 404
 405 =item * Discontinuance
 406
 407 Symbols starting with "_" are no longer forced into package main, except
 408 for C<$_> itself (and C<@_>, etc.).
 409
 410     package test;
 411     $_legacy = 1;
 412
 413     package main;
 414     print "\$_legacy is ",$_legacy,"\n";
 415
 416     # perl4 prints: $_legacy is 1
 417     # perl5 prints: $_legacy is
 418
 419 =item * Deprecation
 420
 421 Double-colon is now a valid package separator in a variable name.  Thus these
 422 behave differently in perl4 vs. perl5, because the packages don't exist.
 423
 424     $a=1;$b=2;$c=3;$var=4;
 425     print "$a::$b::$c ";
 426     print "$var::abc::xyz\n";
 427
 428     # perl4 prints: 1::2::3 4::abc::xyz
 429     # perl5 prints: 3
 430
 431 Given that C<::> is now the preferred package delimiter, it is debatable
 432 whether this should be classed as a bug or not.
 433 (The older package delimiter, ' ,is used here)
 434
 435     $x = 10 ;
 436     print "x=${'x}\n" ;
 437
 438     # perl4 prints: x=10
 439     # perl5 prints: Can't find string terminator "'" anywhere before EOF
 440
 441 Also see precedence traps, for parsing C<$:>.
 442
 443 =item * BugFix
 444
 445 The second and third arguments of C<splice()> are now evaluated in scalar
 446 context (as the Camel says) rather than list context.
 447
 448     sub sub1{return(0,2) }          # return a 2-elem array
 449     sub sub2{ return(1,2,3)}        # return a 3-elem array
 450     @a1 = ("a","b","c","d","e");
 451     @a2 = splice(@a1,&sub1,&sub2);
 452     print join(' ',@a2),"\n";
 453
 454     # perl4 prints: a b
 455     # perl5 prints: c d e
 456
 457 =item * Discontinuance
 458
 459 You can't do a C<goto> into a block that is optimized away.  Darn.
 460
 461     goto marker1;
 462
 463     for(1){
 464     marker1:
 465         print "Here I is!\n";
 466     }
 467
 468     # perl4 prints: Here I is!
 469     # perl5 dumps core (SEGV)
 470
 471 =item * Discontinuance
 472
 473 It is no longer syntactically legal to use whitespace as the name
 474 of a variable, or as a delimiter for any kind of quote construct.
 475 Double darn.
 476
 477     $a = ("foo bar");
 478     $b = q baz ;
 479     print "a is $a, b is $b\n";
 480
 481     # perl4 prints: a is foo bar, b is baz
 482     # perl5 errors: Bare word found where operator expected
 483
 484 =item * Discontinuance
 485
 486 The archaic while/if BLOCK BLOCK syntax is no longer supported.
 487
 488     if { 1 } {
 489         print "True!";
 490     }
 491     else {
 492         print "False!";
 493     }
 494
 495     # perl4 prints: True!
 496     # perl5 errors: syntax error at test.pl line 1, near "if {"
 497
 498 =item * BugFix
 499
 500 The C<**> operator now binds more tightly than unary minus.
 501 It was documented to work this way before, but didn't.
 502
 503     print -4**2,"\n";
 504
 505     # perl4 prints: 16
 506     # perl5 prints: -16
 507
 508 =item * Discontinuance
 509
 510 The meaning of C<foreach{}> has changed slightly when it is iterating over a
 511 list which is not an array.  This used to assign the list to a
 512 temporary array, but no longer does so (for efficiency).  This means
 513 that you'll now be iterating over the actual values, not over copies of
 514 the values.  Modifications to the loop variable can change the original
 515 values.
 516
 517     @list = ('ab','abc','bcd','def');
 518     foreach $var (grep(/ab/,@list)){
 519         $var = 1;
 520     }
 521     print (join(':',@list));
 522
 523     # perl4 prints: ab:abc:bcd:def
 524     # perl5 prints: 1:1:bcd:def
 525
 526 To retain Perl4 semantics you need to assign your list
 527 explicitly to a temporary array and then iterate over that.  For
 528 example, you might need to change
 529
 530     foreach $var (grep(/ab/,@list)){
 531
 532 to
 533
 534     foreach $var (@tmp = grep(/ab/,@list)){
 535
 536 Otherwise changing $var will clobber the values of @list.  (This most often
 537 happens when you use C<$_> for the loop variable, and call subroutines in
 538 the loop that don't properly localize C<$_>.)
 539
 540 =item * Discontinuance
 541
 542 C<split> with no arguments now behaves like C<split ' '> (which doesn't
 543 return an initial null field if $_ starts with whitespace), it used to
 544 behave like C<split /\s+/> (which does).
 545
 546     $_ = ' hi mom';
 547     print join(':', split);
 548
 549     # perl4 prints: :hi:mom
 550     # perl5 prints: hi:mom
 551
 552 =item * BugFix
 553
 554 Perl 4 would ignore any text which was attached to an C<-e> switch,
 555 always taking the code snippet from the following arg.  Additionally, it
 556 would silently accept an C<-e> switch without a following arg.  Both of
 557 these behaviors have been fixed.
 558
 559     perl -e'print "attached to -e"' 'print "separate arg"'
 560
 561     # perl4 prints: separate arg
 562     # perl5 prints: attached to -e
 563
 564     perl -e
 565
 566     # perl4 prints:
 567     # perl5 dies: No code specified for -e.
 568
 569 =item * Discontinuance
 570
 571 In Perl 4 the return value of C<push> was undocumented, but it was
 572 actually the last value being pushed onto the target list.  In Perl 5
 573 the return value of C<push> is documented, but has changed, it is the
 574 number of elements in the resulting list.
 575
 576     @x = ('existing');
 577     print push(@x, 'first new', 'second new');
 578
 579     # perl4 prints: second new
 580     # perl5 prints: 3
 581
 582 =item * Deprecation
 583
 584 Some error messages will be different.
 585
 586 =item * Discontinuance
 587
 588 Some bugs may have been inadvertently removed.  :-)
 589
 590 =back
 591
 592 =head2 Parsing Traps
 593
 594 Perl4-to-Perl5 traps from having to do with parsing.
 595
 596 =over 4
 597
 598 =item * Parsing
 599
 600 Note the space between . and =
 601
 602     $string . = "more string";
 603     print $string;
 604
 605     # perl4 prints: more string
 606     # perl5 prints: syntax error at - line 1, near ". ="
 607
 608 =item * Parsing
 609
 610 Better parsing in perl 5
 611
 612     sub foo {}
 613     &foo
 614     print("hello, world\n");
 615
 616     # perl4 prints: hello, world
 617     # perl5 prints: syntax error
 618
 619 =item * Parsing
 620
 621 "if it looks like a function, it is a function" rule.
 622
 623   print
 624     ($foo == 1) ? "is one\n" : "is zero\n";
 625
 626     # perl4 prints: is zero
 627     # perl5 warns: "Useless use of a constant in void context" if using -w
 628
 629 =back
 630
 631 =head2 Numerical Traps
 632
 633 Perl4-to-Perl5 traps having to do with numerical operators,
 634 operands, or output from same.
 635
 636 =over 5
 637
 638 =item * Numerical
 639
 640 Formatted output and significant digits
 641
 642     print 7.373504 - 0, "\n";
 643     printf "%20.18f\n", 7.373504 - 0;
 644
 645     # Perl4 prints:
 646     7.375039999999996141
 647     7.37503999999999614
 648
 649     # Perl5 prints:
 650     7.373504
 651     7.37503999999999614
 652
 653 =item * Numerical
 654
 655 This specific item has been deleted.  It demonstrated how the auto-increment
 656 operator would not catch when a number went over the signed int limit.  Fixed
 657 in 5.003_04.  But always be wary when using large integers.  If in doubt:
 658
 659    use Math::BigInt;
 660
 661 =item * Numerical
 662
 663 Assignment of return values from numeric equality tests
 664 does not work in perl5 when the test evaluates to false (0).
 665 Logical tests now return an null, instead of 0
 666
 667     $p = ($test == 1);
 668     print $p,"\n";
 669
 670     # perl4 prints: 0
 671     # perl5 prints:
 672
 673 Also see the L<General Regular Expression Traps using s///, etc.>
 674 tests for another example of this new feature...
 675
 676 =back
 677
 678 =head2 General data type traps
 679
 680 Perl4-to-Perl5 traps involving most data-types, and their usage
 681 within certain expressions and/or context.
 682
 683 =over 5
 684
 685 =item * (Arrays)
 686
 687 Negative array subscripts now count from the end of the array.
 688
 689     @a = (1, 2, 3, 4, 5);
 690     print "The third element of the array is $a[3] also expressed as $a[-2] \n";
 691
 692     # perl4 prints: The third element of the array is 4 also expressed as
 693     # perl5 prints: The third element of the array is 4 also expressed as 4
 694
 695 =item * (Arrays)
 696
 697 Setting C<$#array> lower now discards array elements, and makes them
 698 impossible to recover.
 699
 700     @a = (a,b,c,d,e);
 701     print "Before: ",join('',@a);
 702     $#a =1;
 703     print ", After: ",join('',@a);
 704     $#a =3;
 705     print ", Recovered: ",join('',@a),"\n";
 706
 707     # perl4 prints: Before: abcde, After: ab, Recovered: abcd
 708     # perl5 prints: Before: abcde, After: ab, Recovered: ab
 709
 710 =item * (Hashes)
 711
 712 Hashes get defined before use
 713
 714     local($s,@a,%h);
 715     die "scalar \$s defined" if defined($s);
 716     die "array \@a defined" if defined(@a);
 717     die "hash \%h defined" if defined(%h);
 718
 719     # perl4 prints:
 720     # perl5 dies: hash %h defined
 721
 722 =item * (Globs)
 723
 724 glob assignment from variable to variable will fail if the assigned
 725 variable is localized subsequent to the assignment
 726
 727     @a = ("This is Perl 4");
 728     *b = *a;
 729     local(@a);
 730     print @b,"\n";
 731
 732     # perl4 prints: This is Perl 4
 733     # perl5 prints:
 734
 735     # Another example
 736
 737     *fred = *barney; # fred is aliased to barney
 738     @barney = (1, 2, 4);
 739     # @fred;
 740     print "@fred";  # should print "1, 2, 4"
 741
 742     # perl4 prints: 1 2 4
 743     # perl5 prints: Literal @fred now requires backslash
 744
 745 =item * (Scalar String)
 746
 747 Changes in unary negation (of strings)
 748 This change effects both the return value and what it
 749 does to auto(magic)increment.
 750
 751     $x = "aaa";
 752     print ++$x," : ";
 753     print -$x," : ";
 754     print ++$x,"\n";
 755
 756     # perl4 prints: aab : -0 : 1
 757     # perl5 prints: aab : -aab : aac
 758
 759 =item * (Constants)
 760
 761 perl 4 lets you modify constants:
 762
 763     $foo = "x";
 764     &mod($foo);
 765     for ($x = 0; $x < 3; $x++) {
 766         &mod("a");
 767     }
 768     sub mod {
 769         print "before: $_[0]";
 770         $_[0] = "m";
 771         print "  after: $_[0]\n";
 772     }
 773
 774     # perl4:
 775     # before: x  after: m
 776     # before: a  after: m
 777     # before: m  after: m
 778     # before: m  after: m
 779
 780     # Perl5:
 781     # before: x  after: m
 782     # Modification of a read-only value attempted at foo.pl line 12.
 783     # before: a
 784
 785 =item * (Scalars)
 786
 787 The behavior is slightly different for:
 788
 789     print "$x", defined $x
 790
 791     # perl 4: 1
 792     # perl 5: <no output, $x is not called into existence>
 793
 794 =item * (Variable Suicide)
 795
 796 Variable suicide behavior is more consistent under Perl 5.
 797 Perl5 exhibits the same behavior for associative arrays and scalars,
 798 that perl4 exhibits for only scalars.
 799
 800     $aGlobal{ "aKey" } = "global value";
 801     print "MAIN:", $aGlobal{"aKey"}, "\n";
 802     $GlobalLevel = 0;
 803     &test( *aGlobal );
 804
 805     sub test {
 806         local( *theArgument ) = @_;
 807         local( %aNewLocal ); # perl 4 != 5.001l,m
 808         $aNewLocal{"aKey"} = "this should never appear";
 809         print "SUB: ", $theArgument{"aKey"}, "\n";
 810         $aNewLocal{"aKey"} = "level $GlobalLevel";   # what should print
 811         $GlobalLevel++;
 812         if( $GlobalLevel<4 ) {
 813             &test( *aNewLocal );
 814         }
 815     }
 816
 817     # Perl4:
 818     # MAIN:global value
 819     # SUB: global value
 820     # SUB: level 0
 821     # SUB: level 1
 822     # SUB: level 2
 823
 824     # Perl5:
 825     # MAIN:global value
 826     # SUB: global value
 827     # SUB: this should never appear
 828     # SUB: this should never appear
 829     # SUB: this should never appear
 830
 831 =back
 832
 833 =head2 Context Traps - scalar, list contexts
 834
 835 =over 5
 836
 837 =item * (list context)
 838
 839 The elements of argument lists for formats are now evaluated in list
 840 context.  This means you can interpolate list values now.
 841
 842     @fmt = ("foo","bar","baz");
 843     format STDOUT=
 844     @<<<<< @||||| @>>>>>
 845     @fmt;
 846     .
 847     write;
 848
 849     # perl4 errors:  Please use commas to separate fields in file
 850     # perl5 prints: foo     bar      baz
 851
 852 =item * (scalar context)
 853
 854 The C<caller()> function now returns a false value in a scalar context
 855 if there is no caller.  This lets library files determine if they're
 856 being required.
 857
 858     caller() ? (print "You rang?\n") : (print "Got a 0\n");
 859
 860     # perl4 errors: There is no caller
 861     # perl5 prints: Got a 0
 862
 863 =item * (scalar context)
 864
 865 The comma operator in a scalar context is now guaranteed to give a
 866 scalar context to its arguments.
 867
 868     @y= ('a','b','c');
 869     $x = (1, 2, @y);
 870     print "x = $x\n";
 871
 872     # Perl4 prints:  x = c   # Thinks list context interpolates list
 873     # Perl5 prints:  x = 3   # Knows scalar uses length of list
 874
 875 =item * (list, builtin)
 876
 877 C<sprintf()> funkiness (array argument converted to scalar array count)
 878 This test could be added to t/op/sprintf.t
 879
 880     @z = ('%s%s', 'foo', 'bar');
 881     $x = sprintf(@z);
 882     if ($x eq 'foobar') {print "ok 2\n";} else {print "not ok 2 '$x'\n";}
 883
 884     # perl4 prints: ok 2
 885     # perl5 prints: not ok 2
 886
 887 C<printf()> works fine, though:
 888
 889     printf STDOUT (@z);
 890     print "\n";
 891
 892     # perl4 prints: foobar
 893     # perl5 prints: foobar
 894
 895 Probably a bug.
 896
 897 =back
 898
 899 =head2 Precedence Traps
 900
 901 Perl4-to-Perl5 traps involving precedence order.
 902
 903 =over 5
 904
 905 =item * Precedence
 906
 907 LHS vs. RHS when both sides are getting an op.
 908
 909     @arr = ( 'left', 'right' );
 910     $a{shift @arr} = shift @arr;
 911     print join( ' ', keys %a );
 912
 913     # perl4 prints: left
 914     # perl5 prints: right
 915
 916 =item * Precedence
 917
 918 These are now semantic errors because of precedence:
 919
 920     @list = (1,2,3,4,5);
 921     %map = ("a",1,"b",2,"c",3,"d",4);
 922     $n = shift @list + 2;   # first item in list plus 2
 923     print "n is $n, ";
 924     $m = keys %map + 2;     # number of items in hash plus 2
 925     print "m is $m\n";
 926
 927     # perl4 prints: n is 3, m is 6
 928     # perl5 errors and fails to compile
 929
 930 =item * Precedence
 931
 932 The precedence of assignment operators is now the same as the precedence
 933 of assignment.  Perl 4 mistakenly gave them the precedence of the associated
 934 operator.  So you now must parenthesize them in expressions like
 935
 936     /foo/ ? ($a += 2) : ($a -= 2);
 937
 938 Otherwise
 939
 940     /foo/ ? $a += 2 : $a -= 2
 941
 942 would be erroneously parsed as
 943
 944     (/foo/ ? $a += 2 : $a) -= 2;
 945
 946 On the other hand,
 947
 948     $a += /foo/ ? 1 : 2;
 949
 950 now works as a C programmer would expect.
 951
 952 =item * Precedence
 953
 954     open FOO || die;
 955
 956 is now incorrect.  You need parentheses around the filehandle.
 957 Otherwise, perl5 leaves the statement as its default precedence:
 958
 959     open(FOO || die);
 960
 961     # perl4 opens or dies
 962     # perl5 errors: Precedence problem: open FOO should be open(FOO)
 963
 964 =item * Precedence
 965
 966 perl4 gives the special variable, C<$:> precedence, where perl5
 967 treats C<$::> as main C<package>
 968
 969     $a = "x"; print "$::a";
 970
 971     # perl 4 prints: -:a
 972     # perl 5 prints: x
 973
 974 =item * Precedence
 975
 976 concatenation precedence over filetest operator?
 977
 978     -e $foo .= "q"
 979
 980     # perl4 prints: no output
 981     # perl5 prints: Can't modify -e in concatenation
 982
 983 =item * Precedence
 984
 985 Assignment to value takes precedence over assignment to key in
 986 perl5 when using the shift operator on both sides.
 987
 988     @arr = ( 'left', 'right' );
 989     $a{shift @arr} = shift @arr;
 990     print join( ' ', keys %a );
 991
 992     # perl4 prints: left
 993     # perl5 prints: right
 994
 995 =back
 996
 997 =head2 General Regular Expression Traps using s///, etc.
 998
 999 All types of RE traps.
1000
1001 =over 5
1002
1003 =item * Regular Expression
1004
1005 C<s'$lhs'$rhs'> now does no interpolation on either side.  It used to
1006 interpolate C<$lhs> but not C<$rhs>.  (And still does not match a literal
1007 '$' in string)
1008
1009     $a=1;$b=2;
1010     $string = '1 2 $a $b';
1011     $string =~ s'$a'$b';
1012     print $string,"\n";
1013
1014     # perl4 prints: $b 2 $a $b
1015     # perl5 prints: 1 2 $a $b
1016
1017 =item * Regular Expression
1018
1019 C<m//g> now attaches its state to the searched string rather than the
1020 regular expression.  (Once the scope of a block is left for the sub, the
1021 state of the searched string is lost)
1022
1023     $_ = "ababab";
1024     while(m/ab/g){
1025         &doit("blah");
1026     }
1027     sub doit{local($_) = shift; print "Got $_ "}
1028
1029     # perl4 prints: blah blah blah
1030     # perl5 prints: infinite loop blah...
1031
1032 =item * Regular Expression
1033
1034 If no parentheses are used in a match, Perl4 sets C<$+> to
1035 the whole match, just like C<$&>. Perl5 does not.
1036
1037     "abcdef" =~ /b.*e/;
1038     print "\$+ = $+\n";
1039
1040     # perl4 prints: bcde
1041     # perl5 prints:
1042
1043 =item * Regular Expression
1044
1045 substitution now returns the null string if it fails
1046
1047     $string = "test";
1048     $value = ($string =~ s/foo//);
1049     print $value, "\n";
1050
1051     # perl4 prints: 0
1052     # perl5 prints:
1053
1054 Also see L<Numerical Traps> for another example of this new feature.
1055
1056 =item * Regular Expression
1057
1058 C<s`lhs`rhs`> (using back-ticks) is now a normal substitution, with no
1059 back-tick expansion
1060
1061     $string = "";
1062     $string =~ s`^`hostname`;
1063     print $string, "\n";
1064
1065     # perl4 prints: <the local hostname>
1066     # perl5 prints: hostname
1067
1068 =item * Regular Expression
1069
1070 Stricter parsing of variables used in regular expressions
1071
1072     s/^([^$grpc]*$grpc[$opt$plus$rep]?)//o;
1073
1074     # perl4: compiles w/o error
1075     # perl5: with Scalar found where operator expected ..., near "$opt$plus"
1076
1077 an added component of this example, apparently from the same script, is
1078 the actual value of the s'd string after the substitution.
1079 C<[$opt]> is a character class in perl4 and an array subscript in perl5
1080
1081     $grpc = 'a';
1082     $opt  = 'r';
1083     $_ = 'bar';
1084     s/^([^$grpc]*$grpc[$opt]?)/foo/;
1085     print ;
1086
1087     # perl4 prints: foo
1088     # perl5 prints: foobar
1089
1090 =item * Regular Expression
1091
1092 Under perl5, C<m?x?> matches only once, like C<?x?>. Under perl4, it matched
1093 repeatedly, like C</x/> or C<m!x!>.
1094
1095     $test = "once";
1096     sub match { $test =~ m?once?; }
1097     &match();
1098     if( &match() ) {
1099         # m?x? matches more then once
1100         print "perl4\n";
1101     } else {
1102         # m?x? matches only once
1103         print "perl5\n";
1104     }
1105
1106     # perl4 prints: perl4
1107     # perl5 prints: perl5
1108
1109
1110 =back
1111
1112 =head2 Subroutine, Signal, Sorting Traps
1113
1114 The general group of Perl4-to-Perl5 traps having to do with
1115 Signals, Sorting, and their related subroutines, as well as
1116 general subroutine traps.  Includes some OS-Specific traps.
1117
1118 =over 5
1119
1120 =item * (Signals)
1121
1122 Barewords that used to look like strings to Perl will now look like subroutine
1123 calls if a subroutine by that name is defined before the compiler sees them.
1124
1125     sub SeeYa { warn"Hasta la vista, baby!" }
1126     $SIG{'TERM'} = SeeYa;
1127     print "SIGTERM is now $SIG{'TERM'}\n";
1128
1129     # perl4 prints: SIGTERM is main'SeeYa
1130     # perl5 prints: SIGTERM is now main::1
1131
1132 Use B<-w> to catch this one
1133
1134 =item * (Sort Subroutine)
1135
1136 reverse is no longer allowed as the name of a sort subroutine.
1137
1138     sub reverse{ print "yup "; $a <=> $b }
1139     print sort reverse a,b,c;
1140
1141     # perl4 prints: yup yup yup yup abc
1142     # perl5 prints: abc
1143
1144 =item * warn() won't let you specify a filehandle.
1145
1146 Although it _always_ printed to STDERR, warn() would let you specify a
1147 filehandle in perl4.  With perl5 it does not.
1148
1149     warn STDERR "Foo!";
1150
1151     # perl4 prints: Foo!
1152     # perl5 prints: String found where operator expected
1153
1154 =back
1155
1156 =head2 OS Traps
1157
1158 =over 5
1159
1160 =item * (SysV)
1161
1162 Under HPUX, and some other SysV OS's, one had to reset any signal handler,
1163 within  the signal handler function, each time a signal was handled with
1164 perl4.  With perl5, the reset is now done correctly.  Any code relying
1165 on the handler _not_ being reset will have to be reworked.
1166
1167 5.002 and beyond uses sigaction() under SysV
1168
1169     sub gotit {
1170         print "Got @_... ";
1171     }
1172     $SIG{'INT'} = 'gotit';
1173
1174     $| = 1;
1175     $pid = fork;
1176     if ($pid) {
1177         kill('INT', $pid);
1178         sleep(1);
1179         kill('INT', $pid);
1180     } else {
1181         while (1) {sleep(10);}
1182     }
1183
1184     # perl4 (HPUX) prints: Got INT...
1185     # perl5 (HPUX) prints: Got INT... Got INT...
1186
1187 =item * (SysV)
1188
1189 Under SysV OS's, C<seek()> on a file opened to append C<E<gt>E<gt>> now does
1190 the right thing w.r.t. the fopen() man page. e.g., - When a file is opened
1191 for append,  it  is  impossible to overwrite information already in
1192 the file.
1193
1194     open(TEST,">>seek.test");
1195     $start = tell TEST ;
1196     foreach(1 .. 9){
1197         print TEST "$_ ";
1198     }
1199     $end = tell TEST ;
1200     seek(TEST,$start,0);
1201     print TEST "18 characters here";
1202
1203     # perl4 (solaris) seek.test has: 18 characters here
1204     # perl5 (solaris) seek.test has: 1 2 3 4 5 6 7 8 9 18 characters here
1205
1206
1207
1208 =back
1209
1210 =head2 Interpolation Traps
1211
1212 Perl4-to-Perl5 traps having to do with how things get interpolated
1213 within certain expressions, statements, contexts, or whatever.
1214
1215 =over 5
1216
1217 =item * Interpolation
1218
1219 @ now always interpolates an array in double-quotish strings.
1220
1221     print "To: someone@somewhere.com\n";
1222
1223     # perl4 prints: To:someone@somewhere.com
1224     # perl5 errors : Literal @somewhere now requires backslash
1225
1226 =item * Interpolation
1227
1228 Double-quoted strings may no longer end with an unescaped $ or @.
1229
1230     $foo = "foo$";
1231     $bar = "bar@";
1232     print "foo is $foo, bar is $bar\n";
1233
1234     # perl4 prints: foo is foo$, bar is bar@
1235     # perl5 errors: Final $ should be \$ or $name
1236
1237 Note: perl5 DOES NOT error on the terminating @ in $bar
1238
1239 =item * Interpolation
1240
1241 Perl now sometimes evaluates arbitrary expressions inside braces that occur
1242 within double quotes (usually when the opening brace is preceded by C<$>
1243 or C<@>).
1244
1245     @www = "buz";
1246     $foo = "foo";
1247     $bar = "bar";
1248     sub foo { return "bar" };
1249     print "|@{w.w.w}|${main'foo}|";
1250
1251     # perl4 prints: |@{w.w.w}|foo|
1252     # perl5 prints: |buz|bar|
1253
1254 Note that you can C<use strict;> to ward off such trappiness under perl5.
1255
1256 =item * Interpolation
1257
1258 The construct "this is $$x" used to interpolate the pid at that
1259 point, but now apparently tries to dereference C<$x>.  C<$$> by itself still
1260 works fine, however.
1261
1262     print "this is $$x\n";
1263
1264     # perl4 prints: this is XXXx   (XXX is the current pid)
1265     # perl5 prints: this is
1266
1267 =item * Interpolation
1268
1269 Creation of hashes on the fly with C<eval "EXPR"> now requires either both
1270 C<$>'s to be protected in the specification of the hash name, or both curlies
1271 to be protected.  If both curlies are protected, the result will be compatible
1272 with perl4 and perl5.  This is a very common practice, and should be changed
1273 to use the block form of C<eval{}>  if possible.
1274
1275     $hashname = "foobar";
1276     $key = "baz";
1277     $value = 1234;
1278     eval "\$$hashname{'$key'} = q|$value|";
1279     (defined($foobar{'baz'})) ?  (print "Yup") : (print "Nope");
1280
1281     # perl4 prints: Yup
1282     # perl5 prints: Nope
1283
1284 Changing
1285
1286     eval "\$$hashname{'$key'} = q|$value|";
1287
1288 to
1289
1290     eval "\$\$hashname{'$key'} = q|$value|";
1291
1292 causes the following result:
1293
1294     # perl4 prints: Nope
1295     # perl5 prints: Yup
1296
1297 or, changing to
1298
1299     eval "\$$hashname\{'$key'\} = q|$value|";
1300
1301 causes the following result:
1302
1303     # perl4 prints: Yup
1304     # perl5 prints: Yup
1305     # and is compatible for both versions
1306
1307
1308 =item * Interpolation
1309
1310 perl4 programs which unconsciously rely on the bugs in earlier perl versions.
1311
1312     perl -e '$bar=q/not/; print "This is $foo{$bar} perl5"'
1313
1314     # perl4 prints: This is not perl5
1315     # perl5 prints: This is perl5
1316
1317 =item * Interpolation
1318
1319 You also have to be careful about array references.
1320
1321     print "$foo{"
1322
1323     perl 4 prints: {
1324     perl 5 prints: syntax error
1325
1326 =item * Interpolation
1327
1328 Similarly, watch out for:
1329
1330     $foo = "array";
1331     print "\$$foo{bar}\n";
1332
1333     # perl4 prints: $array{bar}
1334     # perl5 prints: $
1335
1336 Perl 5 is looking for C<$array{bar}> which doesn't exist, but perl 4 is
1337 happy just to expand $foo to "array" by itself.  Watch out for this
1338 especially in C<eval>'s.
1339
1340 =item * Interpolation
1341
1342 C<qq()> string passed to C<eval>
1343
1344     eval qq(
1345         foreach \$y (keys %\$x\) {
1346             \$count++;
1347         }
1348     );
1349
1350     # perl4 runs this ok
1351     # perl5 prints: Can't find string terminator ")"
1352
1353 =back
1354
1355 =head2 DBM Traps
1356
1357 General DBM traps.
1358
1359 =over 5
1360
1361 =item * DBM
1362
1363 Existing dbm databases created under perl4 (or any other dbm/ndbm tool)
1364 may cause the same script, run under perl5, to fail.  The build of perl5
1365 must have been linked with the same dbm/ndbm as the default for C<dbmopen()>
1366 to function properly without C<tie>'ing to an extension dbm implementation.
1367
1368     dbmopen (%dbm, "file", undef);
1369     print "ok\n";
1370
1371     # perl4 prints: ok
1372     # perl5 prints: ok (IFF linked with -ldbm or -lndbm)
1373
1374
1375 =item * DBM
1376
1377 Existing dbm databases created under perl4 (or any other dbm/ndbm tool)
1378 may cause the same script, run under perl5, to fail.  The error generated
1379 when exceeding the limit on the key/value size will cause perl5 to exit
1380 immediately.
1381
1382     dbmopen(DB, "testdb",0600) || die "couldn't open db! $!";
1383     $DB{'trap'} = "x" x 1024;  # value too large for most dbm/ndbm
1384     print "YUP\n";
1385
1386     # perl4 prints:
1387     dbm store returned -1, errno 28, key "trap" at - line 3.
1388     YUP
1389
1390     # perl5 prints:
1391     dbm store returned -1, errno 28, key "trap" at - line 3.
1392
1393 =back
1394
1395 =head2 Unclassified Traps
1396
1397 Everything else.
1398
1399 =over 5
1400
1401 =item * Unclassified
1402
1403 C<require>/C<do> trap using returned value
1404
1405 If the file doit.pl has:
1406
1407     sub foo {
1408         $rc = do "./do.pl";
1409         return 8;
1410     }
1411     print &foo, "\n";
1412
1413 And the do.pl file has the following single line:
1414
1415     return 3;
1416
1417 Running doit.pl gives the following:
1418
1419     # perl 4 prints: 3 (aborts the subroutine early)
1420     # perl 5 prints: 8
1421
1422 Same behavior if you replace C<do> with C<require>.
1423
1424 =back
1425
1426 As always, if any of these are ever officially declared as bugs,
1427 they'll be fixed and removed.
1428