pod/perltrap.pod

   1 =head1 NAME
   2
   3 perltrap - Perl traps for the unwary
   4
   5 =head1 DESCRIPTION
   6
   7 The biggest trap of all is forgetting to use the B<-w> switch; see
   8 L<perlrun>.  The second biggest trap is not making your entire program
   9 runnable under C<use strict>.  The third biggest trap is not reading
  10 the list of changes in this version of Perl; see L<perldelta>.
  11
  12 =head2 Awk Traps
  13
  14 Accustomed B<awk> users should take special note of the following:
  15
  16 =over 4
  17
  18 =item *
  19
  20 The English module, loaded via
  21
  22     use English;
  23
  24 allows you to refer to special variables (like C<$/>) with names (like
  25 $RS), as though they were in B<awk>; see L<perlvar> for details.
  26
  27 =item *
  28
  29 Semicolons are required after all simple statements in Perl (except
  30 at the end of a block).  Newline is not a statement delimiter.
  31
  32 =item *
  33
  34 Curly brackets are required on C<if>s and C<while>s.
  35
  36 =item *
  37
  38 Variables begin with "$", "@" or "%" in Perl.
  39
  40 =item *
  41
  42 Arrays index from 0.  Likewise string positions in substr() and
  43 index().
  44
  45 =item *
  46
  47 You have to decide whether your array has numeric or string indices.
  48
  49 =item *
  50
  51 Hash values do not spring into existence upon mere reference.
  52
  53 =item *
  54
  55 You have to decide whether you want to use string or numeric
  56 comparisons.
  57
  58 =item *
  59
  60 Reading an input line does not split it for you.  You get to split it
  61 to an array yourself.  And the split() operator has different
  62 arguments than B<awk>'s.
  63
  64 =item *
  65
  66 The current input line is normally in $_, not $0.  It generally does
  67 not have the newline stripped.  ($0 is the name of the program
  68 executed.)  See L<perlvar>.
  69
  70 =item *
  71
  72 $E<lt>I<digit>E<gt> does not refer to fields--it refers to substrings matched
  73 by the last match pattern.
  74
  75 =item *
  76
  77 The print() statement does not add field and record separators unless
  78 you set C<$,> and C<$\>.  You can set $OFS and $ORS if you're using
  79 the English module.
  80
  81 =item *
  82
  83 You must open your files before you print to them.
  84
  85 =item *
  86
  87 The range operator is "..", not comma.  The comma operator works as in
  88 C.
  89
  90 =item *
  91
  92 The match operator is "=~", not "~".  ("~" is the one's complement
  93 operator, as in C.)
  94
  95 =item *
  96
  97 The exponentiation operator is "**", not "^".  "^" is the XOR
  98 operator, as in C.  (You know, one could get the feeling that B<awk> is
  99 basically incompatible with C.)
 100
 101 =item *
 102
 103 The concatenation operator is ".", not the null string.  (Using the
 104 null string would render C</pat/ /pat/> unparsable, because the third slash
 105 would be interpreted as a division operator--the tokenizer is in fact
 106 slightly context sensitive for operators like "/", "?", and "E<gt>".
 107 And in fact, "." itself can be the beginning of a number.)
 108
 109 =item *
 110
 111 The C<next>, C<exit>, and C<continue> keywords work differently.
 112
 113 =item *
 114
 115
 116 The following variables work differently:
 117
 118       Awk       Perl
 119       ARGC      $#ARGV or scalar @ARGV
 120       ARGV[0]   $0
 121       FILENAME  $ARGV
 122       FNR       $. - something
 123       FS        (whatever you like)
 124       NF        $#Fld, or some such
 125       NR        $.
 126       OFMT      $#
 127       OFS       $,
 128       ORS       $\
 129       RLENGTH   length($&)
 130       RS        $/
 131       RSTART    length($`)
 132       SUBSEP    $;
 133
 134 =item *
 135
 136 You cannot set $RS to a pattern, only a string.
 137
 138 =item *
 139
 140 When in doubt, run the B<awk> construct through B<a2p> and see what it
 141 gives you.
 142
 143 =back
 144
 145 =head2 C Traps
 146
 147 Cerebral C programmers should take note of the following:
 148
 149 =over 4
 150
 151 =item *
 152
 153 Curly brackets are required on C<if>'s and C<while>'s.
 154
 155 =item *
 156
 157 You must use C<elsif> rather than C<else if>.
 158
 159 =item *
 160
 161 The C<break> and C<continue> keywords from C become in
 162 Perl C<last> and C<next>, respectively.
 163 Unlike in C, these do I<not> work within a C<do { } while> construct.
 164
 165 =item *
 166
 167 There's no switch statement.  (But it's easy to build one on the fly.)
 168
 169 =item *
 170
 171 Variables begin with "$", "@" or "%" in Perl.
 172
 173 =item *
 174
 175 C<printf()> does not implement the "*" format for interpolating
 176 field widths, but it's trivial to use interpolation of double-quoted
 177 strings to achieve the same effect.
 178
 179 =item *
 180
 181 Comments begin with "#", not "/*".
 182
 183 =item *
 184
 185 You can't take the address of anything, although a similar operator
 186 in Perl is the backslash, which creates a reference.
 187
 188 =item *
 189
 190 C<ARGV> must be capitalized.  C<$ARGV[0]> is C's C<argv[1]>, and C<argv[0]>
 191 ends up in C<$0>.
 192
 193 =item *
 194
 195 System calls such as link(), unlink(), rename(), etc. return nonzero for
 196 success, not 0.
 197
 198 =item *
 199
 200 Signal handlers deal with signal names, not numbers.  Use C<kill -l>
 201 to find their names on your system.
 202
 203 =back
 204
 205 =head2 Sed Traps
 206
 207 Seasoned B<sed> programmers should take note of the following:
 208
 209 =over 4
 210
 211 =item *
 212
 213 Backreferences in substitutions use "$" rather than "\".
 214
 215 =item *
 216
 217 The pattern matching metacharacters "(", ")", and "|" do not have backslashes
 218 in front.
 219
 220 =item *
 221
 222 The range operator is C<...>, rather than comma.
 223
 224 =back
 225
 226 =head2 Shell Traps
 227
 228 Sharp shell programmers should take note of the following:
 229
 230 =over 4
 231
 232 =item *
 233
 234 The backtick operator does variable interpolation without regard to
 235 the presence of single quotes in the command.
 236
 237 =item *
 238
 239 The backtick operator does no translation of the return value, unlike B<csh>.
 240
 241 =item *
 242
 243 Shells (especially B<csh>) do several levels of substitution on each
 244 command line.  Perl does substitution in only certain constructs
 245 such as double quotes, backticks, angle brackets, and search patterns.
 246
 247 =item *
 248
 249 Shells interpret scripts a little bit at a time.  Perl compiles the
 250 entire program before executing it (except for C<BEGIN> blocks, which
 251 execute at compile time).
 252
 253 =item *
 254
 255 The arguments are available via @ARGV, not $1, $2, etc.
 256
 257 =item *
 258
 259 The environment is not automatically made available as separate scalar
 260 variables.
 261
 262 =back
 263
 264 =head2 Perl Traps
 265
 266 Practicing Perl Programmers should take note of the following:
 267
 268 =over 4
 269
 270 =item *
 271
 272 Remember that many operations behave differently in a list
 273 context than they do in a scalar one.  See L<perldata> for details.
 274
 275 =item *
 276
 277 Avoid barewords if you can, especially all lowercase ones.
 278 You can't tell by just looking at it whether a bareword is
 279 a function or a string.  By using quotes on strings and
 280 parentheses on function calls, you won't ever get them confused.
 281
 282 =item *
 283
 284 You cannot discern from mere inspection which builtins
 285 are unary operators (like chop() and chdir())
 286 and which are list operators (like print() and unlink()).
 287 (User-defined subroutines can be B<only> list operators, never
 288 unary ones.)  See L<perlop>.
 289
 290 =item *
 291
 292 People have a hard time remembering that some functions
 293 default to $_, or @ARGV, or whatever, but that others which
 294 you might expect to do not.
 295
 296 =item *
 297
 298 The E<lt>FHE<gt> construct is not the name of the filehandle, it is a readline
 299 operation on that handle.  The data read is assigned to $_ only if the
 300 file read is the sole condition in a while loop:
 301
 302     while (<FH>)      { }
 303     while (defined($_ = <FH>)) { }..
 304     <FH>;  # data discarded!
 305
 306 =item *
 307
 308 Remember not to use C<=> when you need C<=~>;
 309 these two constructs are quite different:
 310
 311     $x =  /foo/;
 312     $x =~ /foo/;
 313
 314 =item *
 315
 316 The C<do {}> construct isn't a real loop that you can use
 317 loop control on.
 318
 319 =item *
 320
 321 Use C<my()> for local variables whenever you can get away with
 322 it (but see L<perlform> for where you can't).
 323 Using C<local()> actually gives a local value to a global
 324 variable, which leaves you open to unforeseen side-effects
 325 of dynamic scoping.
 326
 327 =item *
 328
 329 If you localize an exported variable in a module, its exported value will
 330 not change.  The local name becomes an alias to a new value but the
 331 external name is still an alias for the original.
 332
 333 =back
 334
 335 =head2 Perl4 to Perl5 Traps
 336
 337 Practicing Perl4 Programmers should take note of the following
 338 Perl4-to-Perl5 specific traps.
 339
 340 They're crudely ordered according to the following list:
 341
 342 =over 4
 343
 344 =item Discontinuance, Deprecation, and BugFix traps
 345
 346 Anything that's been fixed as a perl4 bug, removed as a perl4 feature
 347 or deprecated as a perl4 feature with the intent to encourage usage of
 348 some other perl5 feature.
 349
 350 =item Parsing Traps
 351
 352 Traps that appear to stem from the new parser.
 353
 354 =item Numerical Traps
 355
 356 Traps having to do with numerical or mathematical operators.
 357
 358 =item General data type traps
 359
 360 Traps involving perl standard data types.
 361
 362 =item Context Traps - scalar, list contexts
 363
 364 Traps related to context within lists, scalar statements/declarations.
 365
 366 =item Precedence Traps
 367
 368 Traps related to the precedence of parsing, evaluation, and execution of
 369 code.
 370
 371 =item General Regular Expression Traps using s///, etc.
 372
 373 Traps related to the use of pattern matching.
 374
 375 =item Subroutine, Signal, Sorting Traps
 376
 377 Traps related to the use of signals and signal handlers, general subroutines,
 378 and sorting, along with sorting subroutines.
 379
 380 =item OS Traps
 381
 382 OS-specific traps.
 383
 384 =item DBM Traps
 385
 386 Traps specific to the use of C<dbmopen()>, and specific dbm implementations.
 387
 388 =item Unclassified Traps
 389
 390 Everything else.
 391
 392 =back
 393
 394 If you find an example of a conversion trap that is not listed here,
 395 please submit it to Bill Middleton <F<wjm@best.com>> for inclusion.
 396 Also note that at least some of these can be caught with B<-w>.
 397
 398 =head2 Discontinuance, Deprecation, and BugFix traps
 399
 400 Anything that has been discontinued, deprecated, or fixed as
 401 a bug from perl4.
 402
 403 =over 4
 404
 405 =item * Discontinuance
 406
 407 Symbols starting with "_" are no longer forced into package main, except
 408 for C<$_> itself (and C<@_>, etc.).
 409
 410     package test;
 411     $_legacy = 1;
 412
 413     package main;
 414     print "\$_legacy is ",$_legacy,"\n";
 415
 416     # perl4 prints: $_legacy is 1
 417     # perl5 prints: $_legacy is
 418
 419 =item * Deprecation
 420
 421 Double-colon is now a valid package separator in a variable name.  Thus these
 422 behave differently in perl4 vs. perl5, because the packages don't exist.
 423
 424     $a=1;$b=2;$c=3;$var=4;
 425     print "$a::$b::$c ";
 426     print "$var::abc::xyz\n";
 427
 428     # perl4 prints: 1::2::3 4::abc::xyz
 429     # perl5 prints: 3
 430
 431 Given that C<::> is now the preferred package delimiter, it is debatable
 432 whether this should be classed as a bug or not.
 433 (The older package delimiter, ' ,is used here)
 434
 435     $x = 10 ;
 436     print "x=${'x}\n" ;
 437
 438     # perl4 prints: x=10
 439     # perl5 prints: Can't find string terminator "'" anywhere before EOF
 440
 441 You can avoid this problem, and remain compatible with perl4, if you
 442 always explicitly include the package name:
 443
 444     $x = 10 ;
 445     print "x=${main'x}\n" ;
 446
 447 Also see precedence traps, for parsing C<$:>.
 448
 449 =item * BugFix
 450
 451 The second and third arguments of C<splice()> are now evaluated in scalar
 452 context (as the Camel says) rather than list context.
 453
 454     sub sub1{return(0,2) }          # return a 2-element list
 455     sub sub2{ return(1,2,3)}        # return a 3-element list
 456     @a1 = ("a","b","c","d","e");
 457     @a2 = splice(@a1,&sub1,&sub2);
 458     print join(' ',@a2),"\n";
 459
 460     # perl4 prints: a b
 461     # perl5 prints: c d e
 462
 463 =item * Discontinuance
 464
 465 You can't do a C<goto> into a block that is optimized away.  Darn.
 466
 467     goto marker1;
 468
 469     for(1){
 470     marker1:
 471         print "Here I is!\n";
 472     }
 473
 474     # perl4 prints: Here I is!
 475     # perl5 dumps core (SEGV)
 476
 477 =item * Discontinuance
 478
 479 It is no longer syntactically legal to use whitespace as the name
 480 of a variable, or as a delimiter for any kind of quote construct.
 481 Double darn.
 482
 483     $a = ("foo bar");
 484     $b = q baz ;
 485     print "a is $a, b is $b\n";
 486
 487     # perl4 prints: a is foo bar, b is baz
 488     # perl5 errors: Bareword found where operator expected
 489
 490 =item * Discontinuance
 491
 492 The archaic while/if BLOCK BLOCK syntax is no longer supported.
 493
 494     if { 1 } {
 495         print "True!";
 496     }
 497     else {
 498         print "False!";
 499     }
 500
 501     # perl4 prints: True!
 502     # perl5 errors: syntax error at test.pl line 1, near "if {"
 503
 504 =item * BugFix
 505
 506 The C<**> operator now binds more tightly than unary minus.
 507 It was documented to work this way before, but didn't.
 508
 509     print -4**2,"\n";
 510
 511     # perl4 prints: 16
 512     # perl5 prints: -16
 513
 514 =item * Discontinuance
 515
 516 The meaning of C<foreach{}> has changed slightly when it is iterating over a
 517 list which is not an array.  This used to assign the list to a
 518 temporary array, but no longer does so (for efficiency).  This means
 519 that you'll now be iterating over the actual values, not over copies of
 520 the values.  Modifications to the loop variable can change the original
 521 values.
 522
 523     @list = ('ab','abc','bcd','def');
 524     foreach $var (grep(/ab/,@list)){
 525         $var = 1;
 526     }
 527     print (join(':',@list));
 528
 529     # perl4 prints: ab:abc:bcd:def
 530     # perl5 prints: 1:1:bcd:def
 531
 532 To retain Perl4 semantics you need to assign your list
 533 explicitly to a temporary array and then iterate over that.  For
 534 example, you might need to change
 535
 536     foreach $var (grep(/ab/,@list)){
 537
 538 to
 539
 540     foreach $var (@tmp = grep(/ab/,@list)){
 541
 542 Otherwise changing $var will clobber the values of @list.  (This most often
 543 happens when you use C<$_> for the loop variable, and call subroutines in
 544 the loop that don't properly localize C<$_>.)
 545
 546 =item * Discontinuance
 547
 548 C<split> with no arguments now behaves like C<split ' '> (which doesn't
 549 return an initial null field if $_ starts with whitespace), it used to
 550 behave like C<split /\s+/> (which does).
 551
 552     $_ = ' hi mom';
 553     print join(':', split);
 554
 555     # perl4 prints: :hi:mom
 556     # perl5 prints: hi:mom
 557
 558 =item * BugFix
 559
 560 Perl 4 would ignore any text which was attached to an B<-e> switch,
 561 always taking the code snippet from the following arg.  Additionally, it
 562 would silently accept an B<-e> switch without a following arg.  Both of
 563 these behaviors have been fixed.
 564
 565     perl -e'print "attached to -e"' 'print "separate arg"'
 566
 567     # perl4 prints: separate arg
 568     # perl5 prints: attached to -e
 569
 570     perl -e
 571
 572     # perl4 prints:
 573     # perl5 dies: No code specified for -e.
 574
 575 =item * Discontinuance
 576
 577 In Perl 4 the return value of C<push> was undocumented, but it was
 578 actually the last value being pushed onto the target list.  In Perl 5
 579 the return value of C<push> is documented, but has changed, it is the
 580 number of elements in the resulting list.
 581
 582     @x = ('existing');
 583     print push(@x, 'first new', 'second new');
 584
 585     # perl4 prints: second new
 586     # perl5 prints: 3
 587
 588 =item * Deprecation
 589
 590 Some error messages will be different.
 591
 592 =item * Discontinuance
 593
 594 Some bugs may have been inadvertently removed.  :-)
 595
 596 =back
 597
 598 =head2 Parsing Traps
 599
 600 Perl4-to-Perl5 traps from having to do with parsing.
 601
 602 =over 4
 603
 604 =item * Parsing
 605
 606 Note the space between . and =
 607
 608     $string . = "more string";
 609     print $string;
 610
 611     # perl4 prints: more string
 612     # perl5 prints: syntax error at - line 1, near ". ="
 613
 614 =item * Parsing
 615
 616 Better parsing in perl 5
 617
 618     sub foo {}
 619     &foo
 620     print("hello, world\n");
 621
 622     # perl4 prints: hello, world
 623     # perl5 prints: syntax error
 624
 625 =item * Parsing
 626
 627 "if it looks like a function, it is a function" rule.
 628
 629   print
 630     ($foo == 1) ? "is one\n" : "is zero\n";
 631
 632     # perl4 prints: is zero
 633     # perl5 warns: "Useless use of a constant in void context" if using -w
 634
 635 =item * Parsing
 636
 637 String interpolation of the C<$#array> construct differs when braces
 638 are to used around the name.
 639
 640     @ = (1..3);
 641     print "${#a}";
 642
 643     # perl4 prints: 2
 644     # perl5 fails with syntax error
 645
 646     @ = (1..3);
 647     print "$#{a}";
 648
 649     # perl4 prints: {a}
 650     # perl5 prints: 2
 651
 652 =back
 653
 654 =head2 Numerical Traps
 655
 656 Perl4-to-Perl5 traps having to do with numerical operators,
 657 operands, or output from same.
 658
 659 =over 5
 660
 661 =item * Numerical
 662
 663 Formatted output and significant digits
 664
 665     print 7.373504 - 0, "\n";
 666     printf "%20.18f\n", 7.373504 - 0;
 667
 668     # Perl4 prints:
 669     7.375039999999996141
 670     7.37503999999999614
 671
 672     # Perl5 prints:
 673     7.373504
 674     7.37503999999999614
 675
 676 =item * Numerical
 677
 678 This specific item has been deleted.  It demonstrated how the auto-increment
 679 operator would not catch when a number went over the signed int limit.  Fixed
 680 in version 5.003_04.  But always be wary when using large integers.
 681 If in doubt:
 682
 683    use Math::BigInt;
 684
 685 =item * Numerical
 686
 687 Assignment of return values from numeric equality tests
 688 does not work in perl5 when the test evaluates to false (0).
 689 Logical tests now return an null, instead of 0
 690
 691     $p = ($test == 1);
 692     print $p,"\n";
 693
 694     # perl4 prints: 0
 695     # perl5 prints:
 696
 697 Also see L<"General Regular Expression Traps using s///, etc.">
 698 for another example of this new feature...
 699
 700 =item * Bitwise string ops
 701
 702 When bitwise operators which can operate upon either numbers or
 703 strings (C<& | ^ ~>) are given only strings as arguments, perl4 would
 704 treat the operands as bitstrings so long as the program contained a call
 705 to the C<vec()> function. perl5 treats the string operands as bitstrings.
 706 (See L<perlop/Bitwise String Operators> for more details.)
 707
 708     $fred = "10";
 709     $barney = "12";
 710     $betty = $fred & $barney;
 711     print "$betty\n";
 712     # Uncomment the next line to change perl4's behavior
 713     # ($dummy) = vec("dummy", 0, 0);
 714
 715     # Perl4 prints:
 716     8
 717
 718     # Perl5 prints:
 719     10
 720
 721     # If vec() is used anywhere in the program, both print:
 722     10
 723
 724 =back
 725
 726 =head2 General data type traps
 727
 728 Perl4-to-Perl5 traps involving most data-types, and their usage
 729 within certain expressions and/or context.
 730
 731 =over 5
 732
 733 =item * (Arrays)
 734
 735 Negative array subscripts now count from the end of the array.
 736
 737     @a = (1, 2, 3, 4, 5);
 738     print "The third element of the array is $a[3] also expressed as $a[-2] \n";
 739
 740     # perl4 prints: The third element of the array is 4 also expressed as
 741     # perl5 prints: The third element of the array is 4 also expressed as 4
 742
 743 =item * (Arrays)
 744
 745 Setting C<$#array> lower now discards array elements, and makes them
 746 impossible to recover.
 747
 748     @a = (a,b,c,d,e);
 749     print "Before: ",join('',@a);
 750     $#a =1;
 751     print ", After: ",join('',@a);
 752     $#a =3;
 753     print ", Recovered: ",join('',@a),"\n";
 754
 755     # perl4 prints: Before: abcde, After: ab, Recovered: abcd
 756     # perl5 prints: Before: abcde, After: ab, Recovered: ab
 757
 758 =item * (Hashes)
 759
 760 Hashes get defined before use
 761
 762     local($s,@a,%h);
 763     die "scalar \$s defined" if defined($s);
 764     die "array \@a defined" if defined(@a);
 765     die "hash \%h defined" if defined(%h);
 766
 767     # perl4 prints:
 768     # perl5 dies: hash %h defined
 769
 770 Perl will now generate a warning when it sees defined(@a) and
 771 defined(%h).
 772
 773 =item * (Globs)
 774
 775 glob assignment from variable to variable will fail if the assigned
 776 variable is localized subsequent to the assignment
 777
 778     @a = ("This is Perl 4");
 779     *b = *a;
 780     local(@a);
 781     print @b,"\n";
 782
 783     # perl4 prints: This is Perl 4
 784     # perl5 prints:
 785
 786 =item * (Globs)
 787
 788 Assigning C<undef> to a glob has no effect in Perl 5.   In Perl 4
 789 it undefines the associated scalar (but may have other side effects
 790 including SEGVs).
 791
 792 =item * (Scalar String)
 793
 794 Changes in unary negation (of strings)
 795 This change effects both the return value and what it
 796 does to auto(magic)increment.
 797
 798     $x = "aaa";
 799     print ++$x," : ";
 800     print -$x," : ";
 801     print ++$x,"\n";
 802
 803     # perl4 prints: aab : -0 : 1
 804     # perl5 prints: aab : -aab : aac
 805
 806 =item * (Constants)
 807
 808 perl 4 lets you modify constants:
 809
 810     $foo = "x";
 811     &mod($foo);
 812     for ($x = 0; $x < 3; $x++) {
 813         &mod("a");
 814     }
 815     sub mod {
 816         print "before: $_[0]";
 817         $_[0] = "m";
 818         print "  after: $_[0]\n";
 819     }
 820
 821     # perl4:
 822     # before: x  after: m
 823     # before: a  after: m
 824     # before: m  after: m
 825     # before: m  after: m
 826
 827     # Perl5:
 828     # before: x  after: m
 829     # Modification of a read-only value attempted at foo.pl line 12.
 830     # before: a
 831
 832 =item * (Scalars)
 833
 834 The behavior is slightly different for:
 835
 836     print "$x", defined $x
 837
 838     # perl 4: 1
 839     # perl 5: <no output, $x is not called into existence>
 840
 841 =item * (Variable Suicide)
 842
 843 Variable suicide behavior is more consistent under Perl 5.
 844 Perl5 exhibits the same behavior for hashes and scalars,
 845 that perl4 exhibits for only scalars.
 846
 847     $aGlobal{ "aKey" } = "global value";
 848     print "MAIN:", $aGlobal{"aKey"}, "\n";
 849     $GlobalLevel = 0;
 850     &test( *aGlobal );
 851
 852     sub test {
 853         local( *theArgument ) = @_;
 854         local( %aNewLocal ); # perl 4 != 5.001l,m
 855         $aNewLocal{"aKey"} = "this should never appear";
 856         print "SUB: ", $theArgument{"aKey"}, "\n";
 857         $aNewLocal{"aKey"} = "level $GlobalLevel";   # what should print
 858         $GlobalLevel++;
 859         if( $GlobalLevel<4 ) {
 860             &test( *aNewLocal );
 861         }
 862     }
 863
 864     # Perl4:
 865     # MAIN:global value
 866     # SUB: global value
 867     # SUB: level 0
 868     # SUB: level 1
 869     # SUB: level 2
 870
 871     # Perl5:
 872     # MAIN:global value
 873     # SUB: global value
 874     # SUB: this should never appear
 875     # SUB: this should never appear
 876     # SUB: this should never appear
 877
 878 =back
 879
 880 =head2 Context Traps - scalar, list contexts
 881
 882 =over 5
 883
 884 =item * (list context)
 885
 886 The elements of argument lists for formats are now evaluated in list
 887 context.  This means you can interpolate list values now.
 888
 889     @fmt = ("foo","bar","baz");
 890     format STDOUT=
 891     @<<<<< @||||| @>>>>>
 892     @fmt;
 893     .
 894     write;
 895
 896     # perl4 errors:  Please use commas to separate fields in file
 897     # perl5 prints: foo     bar      baz
 898
 899 =item * (scalar context)
 900
 901 The C<caller()> function now returns a false value in a scalar context
 902 if there is no caller.  This lets library files determine if they're
 903 being required.
 904
 905     caller() ? (print "You rang?\n") : (print "Got a 0\n");
 906
 907     # perl4 errors: There is no caller
 908     # perl5 prints: Got a 0
 909
 910 =item * (scalar context)
 911
 912 The comma operator in a scalar context is now guaranteed to give a
 913 scalar context to its arguments.
 914
 915     @y= ('a','b','c');
 916     $x = (1, 2, @y);
 917     print "x = $x\n";
 918
 919     # Perl4 prints:  x = c   # Thinks list context interpolates list
 920     # Perl5 prints:  x = 3   # Knows scalar uses length of list
 921
 922 =item * (list, builtin)
 923
 924 C<sprintf()> funkiness (array argument converted to scalar array count)
 925 This test could be added to t/op/sprintf.t
 926
 927     @z = ('%s%s', 'foo', 'bar');
 928     $x = sprintf(@z);
 929     if ($x eq 'foobar') {print "ok 2\n";} else {print "not ok 2 '$x'\n";}
 930
 931     # perl4 prints: ok 2
 932     # perl5 prints: not ok 2
 933
 934 C<printf()> works fine, though:
 935
 936     printf STDOUT (@z);
 937     print "\n";
 938
 939     # perl4 prints: foobar
 940     # perl5 prints: foobar
 941
 942 Probably a bug.
 943
 944 =back
 945
 946 =head2 Precedence Traps
 947
 948 Perl4-to-Perl5 traps involving precedence order.
 949
 950 Perl 4 has almost the same precedence rules as Perl 5 for the operators
 951 that they both have.  Perl 4 however, seems to have had some
 952 inconsistencies that made the behavior differ from what was documented.
 953
 954 =over 5
 955
 956 =item * Precedence
 957
 958 LHS vs. RHS of any assignment operator.  LHS is evaluated first
 959 in perl4, second in perl5; this can affect the relationship
 960 between side-effects in sub-expressions.
 961
 962     @arr = ( 'left', 'right' );
 963     $a{shift @arr} = shift @arr;
 964     print join( ' ', keys %a );
 965
 966     # perl4 prints: left
 967     # perl5 prints: right
 968
 969 =item * Precedence
 970
 971 These are now semantic errors because of precedence:
 972
 973     @list = (1,2,3,4,5);
 974     %map = ("a",1,"b",2,"c",3,"d",4);
 975     $n = shift @list + 2;   # first item in list plus 2
 976     print "n is $n, ";
 977     $m = keys %map + 2;     # number of items in hash plus 2
 978     print "m is $m\n";
 979
 980     # perl4 prints: n is 3, m is 6
 981     # perl5 errors and fails to compile
 982
 983 =item * Precedence
 984
 985 The precedence of assignment operators is now the same as the precedence
 986 of assignment.  Perl 4 mistakenly gave them the precedence of the associated
 987 operator.  So you now must parenthesize them in expressions like
 988
 989     /foo/ ? ($a += 2) : ($a -= 2);
 990
 991 Otherwise
 992
 993     /foo/ ? $a += 2 : $a -= 2
 994
 995 would be erroneously parsed as
 996
 997     (/foo/ ? $a += 2 : $a) -= 2;
 998
 999 On the other hand,
1000
1001     $a += /foo/ ? 1 : 2;
1002
1003 now works as a C programmer would expect.
1004
1005 =item * Precedence
1006
1007     open FOO || die;
1008
1009 is now incorrect.  You need parentheses around the filehandle.
1010 Otherwise, perl5 leaves the statement as its default precedence:
1011
1012     open(FOO || die);
1013
1014     # perl4 opens or dies
1015     # perl5 errors: Precedence problem: open FOO should be open(FOO)
1016
1017 =item * Precedence
1018
1019 perl4 gives the special variable, C<$:> precedence, where perl5
1020 treats C<$::> as main C<package>
1021
1022     $a = "x"; print "$::a";
1023
1024     # perl 4 prints: -:a
1025     # perl 5 prints: x
1026
1027 =item * Precedence
1028
1029 perl4 had buggy precedence for the file test operators vis-a-vis
1030 the assignment operators.  Thus, although the precedence table
1031 for perl4 leads one to believe C<-e $foo .= "q"> should parse as
1032 C<((-e $foo) .= "q")>, it actually parses as C<(-e ($foo .= "q"))>.
1033 In perl5, the precedence is as documented.
1034
1035     -e $foo .= "q"
1036
1037     # perl4 prints: no output
1038     # perl5 prints: Can't modify -e in concatenation
1039
1040 =item * Precedence
1041
1042 In perl4, keys(), each() and values() were special high-precedence operators
1043 that operated on a single hash, but in perl5, they are regular named unary
1044 operators.  As documented, named unary operators have lower precedence
1045 than the arithmetic and concatenation operators C<+ - .>, but the perl4
1046 variants of these operators actually bind tighter than C<+ - .>.
1047 Thus, for:
1048
1049     %foo = 1..10;
1050     print keys %foo - 1
1051
1052     # perl4 prints: 4
1053     # perl5 prints: Type of arg 1 to keys must be hash (not subtraction)
1054
1055 The perl4 behavior was probably more useful, if less consistent.
1056
1057 =back
1058
1059 =head2 General Regular Expression Traps using s///, etc.
1060
1061 All types of RE traps.
1062
1063 =over 5
1064
1065 =item * Regular Expression
1066
1067 C<s'$lhs'$rhs'> now does no interpolation on either side.  It used to
1068 interpolate $lhs but not $rhs.  (And still does not match a literal
1069 '$' in string)
1070
1071     $a=1;$b=2;
1072     $string = '1 2 $a $b';
1073     $string =~ s'$a'$b';
1074     print $string,"\n";
1075
1076     # perl4 prints: $b 2 $a $b
1077     # perl5 prints: 1 2 $a $b
1078
1079 =item * Regular Expression
1080
1081 C<m//g> now attaches its state to the searched string rather than the
1082 regular expression.  (Once the scope of a block is left for the sub, the
1083 state of the searched string is lost)
1084
1085     $_ = "ababab";
1086     while(m/ab/g){
1087         &doit("blah");
1088     }
1089     sub doit{local($_) = shift; print "Got $_ "}
1090
1091     # perl4 prints: blah blah blah
1092     # perl5 prints: infinite loop blah...
1093
1094 =item * Regular Expression
1095
1096 Currently, if you use the C<m//o> qualifier on a regular expression
1097 within an anonymous sub, I<all> closures generated from that anonymous
1098 sub will use the regular expression as it was compiled when it was used
1099 the very first time in any such closure.  For instance, if you say
1100
1101     sub build_match {
1102         my($left,$right) = @_;
1103         return sub { $_[0] =~ /$left stuff $right/o; };
1104     }
1105
1106 build_match() will always return a sub which matches the contents of
1107 $left and $right as they were the I<first> time that build_match()
1108 was called, not as they are in the current call.
1109
1110 This is probably a bug, and may change in future versions of Perl.
1111
1112 =item * Regular Expression
1113
1114 If no parentheses are used in a match, Perl4 sets C<$+> to
1115 the whole match, just like C<$&>. Perl5 does not.
1116
1117     "abcdef" =~ /b.*e/;
1118     print "\$+ = $+\n";
1119
1120     # perl4 prints: bcde
1121     # perl5 prints:
1122
1123 =item * Regular Expression
1124
1125 substitution now returns the null string if it fails
1126
1127     $string = "test";
1128     $value = ($string =~ s/foo//);
1129     print $value, "\n";
1130
1131     # perl4 prints: 0
1132     # perl5 prints:
1133
1134 Also see L<Numerical Traps> for another example of this new feature.
1135
1136 =item * Regular Expression
1137
1138 C<s`lhs`rhs`> (using backticks) is now a normal substitution, with no
1139 backtick expansion
1140
1141     $string = "";
1142     $string =~ s`^`hostname`;
1143     print $string, "\n";
1144
1145     # perl4 prints: <the local hostname>
1146     # perl5 prints: hostname
1147
1148 =item * Regular Expression
1149
1150 Stricter parsing of variables used in regular expressions
1151
1152     s/^([^$grpc]*$grpc[$opt$plus$rep]?)//o;
1153
1154     # perl4: compiles w/o error
1155     # perl5: with Scalar found where operator expected ..., near "$opt$plus"
1156
1157 an added component of this example, apparently from the same script, is
1158 the actual value of the s'd string after the substitution.
1159 C<[$opt]> is a character class in perl4 and an array subscript in perl5
1160
1161     $grpc = 'a';
1162     $opt  = 'r';
1163     $_ = 'bar';
1164     s/^([^$grpc]*$grpc[$opt]?)/foo/;
1165     print ;
1166
1167     # perl4 prints: foo
1168     # perl5 prints: foobar
1169
1170 =item * Regular Expression
1171
1172 Under perl5, C<m?x?> matches only once, like C<?x?>. Under perl4, it matched
1173 repeatedly, like C</x/> or C<m!x!>.
1174
1175     $test = "once";
1176     sub match { $test =~ m?once?; }
1177     &match();
1178     if( &match() ) {
1179         # m?x? matches more then once
1180         print "perl4\n";
1181     } else {
1182         # m?x? matches only once
1183         print "perl5\n";
1184     }
1185
1186     # perl4 prints: perl4
1187     # perl5 prints: perl5
1188
1189
1190 =back
1191
1192 =head2 Subroutine, Signal, Sorting Traps
1193
1194 The general group of Perl4-to-Perl5 traps having to do with
1195 Signals, Sorting, and their related subroutines, as well as
1196 general subroutine traps.  Includes some OS-Specific traps.
1197
1198 =over 5
1199
1200 =item * (Signals)
1201
1202 Barewords that used to look like strings to Perl will now look like subroutine
1203 calls if a subroutine by that name is defined before the compiler sees them.
1204
1205     sub SeeYa { warn"Hasta la vista, baby!" }
1206     $SIG{'TERM'} = SeeYa;
1207     print "SIGTERM is now $SIG{'TERM'}\n";
1208
1209     # perl4 prints: SIGTERM is main'SeeYa
1210     # perl5 prints: SIGTERM is now main::1
1211
1212 Use B<-w> to catch this one
1213
1214 =item * (Sort Subroutine)
1215
1216 reverse is no longer allowed as the name of a sort subroutine.
1217
1218     sub reverse{ print "yup "; $a <=> $b }
1219     print sort reverse a,b,c;
1220
1221     # perl4 prints: yup yup yup yup abc
1222     # perl5 prints: abc
1223
1224 =item * warn() won't let you specify a filehandle.
1225
1226 Although it _always_ printed to STDERR, warn() would let you specify a
1227 filehandle in perl4.  With perl5 it does not.
1228
1229     warn STDERR "Foo!";
1230
1231     # perl4 prints: Foo!
1232     # perl5 prints: String found where operator expected
1233
1234 =back
1235
1236 =head2 OS Traps
1237
1238 =over 5
1239
1240 =item * (SysV)
1241
1242 Under HPUX, and some other SysV OSes, one had to reset any signal handler,
1243 within  the signal handler function, each time a signal was handled with
1244 perl4.  With perl5, the reset is now done correctly.  Any code relying
1245 on the handler _not_ being reset will have to be reworked.
1246
1247 Since version 5.002, Perl uses sigaction() under SysV.
1248
1249     sub gotit {
1250         print "Got @_... ";
1251     }
1252     $SIG{'INT'} = 'gotit';
1253
1254     $| = 1;
1255     $pid = fork;
1256     if ($pid) {
1257         kill('INT', $pid);
1258         sleep(1);
1259         kill('INT', $pid);
1260     } else {
1261         while (1) {sleep(10);}
1262     }
1263
1264     # perl4 (HPUX) prints: Got INT...
1265     # perl5 (HPUX) prints: Got INT... Got INT...
1266
1267 =item * (SysV)
1268
1269 Under SysV OSes, C<seek()> on a file opened to append C<E<gt>E<gt>> now does
1270 the right thing w.r.t. the fopen() manpage. e.g., - When a file is opened
1271 for append,  it  is  impossible to overwrite information already in
1272 the file.
1273
1274     open(TEST,">>seek.test");
1275     $start = tell TEST ;
1276     foreach(1 .. 9){
1277         print TEST "$_ ";
1278     }
1279     $end = tell TEST ;
1280     seek(TEST,$start,0);
1281     print TEST "18 characters here";
1282
1283     # perl4 (solaris) seek.test has: 18 characters here
1284     # perl5 (solaris) seek.test has: 1 2 3 4 5 6 7 8 9 18 characters here
1285
1286
1287
1288 =back
1289
1290 =head2 Interpolation Traps
1291
1292 Perl4-to-Perl5 traps having to do with how things get interpolated
1293 within certain expressions, statements, contexts, or whatever.
1294
1295 =over 5
1296
1297 =item * Interpolation
1298
1299 @ now always interpolates an array in double-quotish strings.
1300
1301     print "To: someone@somewhere.com\n";
1302
1303     # perl4 prints: To:someone@somewhere.com
1304     # perl5 errors : In string, @somewhere now must be written as \@somewhere
1305
1306 =item * Interpolation
1307
1308 Double-quoted strings may no longer end with an unescaped $ or @.
1309
1310     $foo = "foo$";
1311     $bar = "bar@";
1312     print "foo is $foo, bar is $bar\n";
1313
1314     # perl4 prints: foo is foo$, bar is bar@
1315     # perl5 errors: Final $ should be \$ or $name
1316
1317 Note: perl5 DOES NOT error on the terminating @ in $bar
1318
1319 =item * Interpolation
1320
1321 Perl now sometimes evaluates arbitrary expressions inside braces that occur
1322 within double quotes (usually when the opening brace is preceded by C<$>
1323 or C<@>).
1324
1325     @www = "buz";
1326     $foo = "foo";
1327     $bar = "bar";
1328     sub foo { return "bar" };
1329     print "|@{w.w.w}|${main'foo}|";
1330
1331     # perl4 prints: |@{w.w.w}|foo|
1332     # perl5 prints: |buz|bar|
1333
1334 Note that you can C<use strict;> to ward off such trappiness under perl5.
1335
1336 =item * Interpolation
1337
1338 The construct "this is $$x" used to interpolate the pid at that
1339 point, but now apparently tries to dereference $x.  C<$$> by itself still
1340 works fine, however.
1341
1342     print "this is $$x\n";
1343
1344     # perl4 prints: this is XXXx   (XXX is the current pid)
1345     # perl5 prints: this is
1346
1347 =item * Interpolation
1348
1349 Creation of hashes on the fly with C<eval "EXPR"> now requires either both
1350 C<$>'s to be protected in the specification of the hash name, or both curlies
1351 to be protected.  If both curlies are protected, the result will be compatible
1352 with perl4 and perl5.  This is a very common practice, and should be changed
1353 to use the block form of C<eval{}>  if possible.
1354
1355     $hashname = "foobar";
1356     $key = "baz";
1357     $value = 1234;
1358     eval "\$$hashname{'$key'} = q|$value|";
1359     (defined($foobar{'baz'})) ?  (print "Yup") : (print "Nope");
1360
1361     # perl4 prints: Yup
1362     # perl5 prints: Nope
1363
1364 Changing
1365
1366     eval "\$$hashname{'$key'} = q|$value|";
1367
1368 to
1369
1370     eval "\$\$hashname{'$key'} = q|$value|";
1371
1372 causes the following result:
1373
1374     # perl4 prints: Nope
1375     # perl5 prints: Yup
1376
1377 or, changing to
1378
1379     eval "\$$hashname\{'$key'\} = q|$value|";
1380
1381 causes the following result:
1382
1383     # perl4 prints: Yup
1384     # perl5 prints: Yup
1385     # and is compatible for both versions
1386
1387
1388 =item * Interpolation
1389
1390 perl4 programs which unconsciously rely on the bugs in earlier perl versions.
1391
1392     perl -e '$bar=q/not/; print "This is $foo{$bar} perl5"'
1393
1394     # perl4 prints: This is not perl5
1395     # perl5 prints: This is perl5
1396
1397 =item * Interpolation
1398
1399 You also have to be careful about array references.
1400
1401     print "$foo{"
1402
1403     perl 4 prints: {
1404     perl 5 prints: syntax error
1405
1406 =item * Interpolation
1407
1408 Similarly, watch out for:
1409
1410     $foo = "array";
1411     print "\$$foo{bar}\n";
1412
1413     # perl4 prints: $array{bar}
1414     # perl5 prints: $
1415
1416 Perl 5 is looking for C<$array{bar}> which doesn't exist, but perl 4 is
1417 happy just to expand $foo to "array" by itself.  Watch out for this
1418 especially in C<eval>'s.
1419
1420 =item * Interpolation
1421
1422 C<qq()> string passed to C<eval>
1423
1424     eval qq(
1425         foreach \$y (keys %\$x\) {
1426             \$count++;
1427         }
1428     );
1429
1430     # perl4 runs this ok
1431     # perl5 prints: Can't find string terminator ")"
1432
1433 =back
1434
1435 =head2 DBM Traps
1436
1437 General DBM traps.
1438
1439 =over 5
1440
1441 =item * DBM
1442
1443 Existing dbm databases created under perl4 (or any other dbm/ndbm tool)
1444 may cause the same script, run under perl5, to fail.  The build of perl5
1445 must have been linked with the same dbm/ndbm as the default for C<dbmopen()>
1446 to function properly without C<tie>'ing to an extension dbm implementation.
1447
1448     dbmopen (%dbm, "file", undef);
1449     print "ok\n";
1450
1451     # perl4 prints: ok
1452     # perl5 prints: ok (IFF linked with -ldbm or -lndbm)
1453
1454
1455 =item * DBM
1456
1457 Existing dbm databases created under perl4 (or any other dbm/ndbm tool)
1458 may cause the same script, run under perl5, to fail.  The error generated
1459 when exceeding the limit on the key/value size will cause perl5 to exit
1460 immediately.
1461
1462     dbmopen(DB, "testdb",0600) || die "couldn't open db! $!";
1463     $DB{'trap'} = "x" x 1024;  # value too large for most dbm/ndbm
1464     print "YUP\n";
1465
1466     # perl4 prints:
1467     dbm store returned -1, errno 28, key "trap" at - line 3.
1468     YUP
1469
1470     # perl5 prints:
1471     dbm store returned -1, errno 28, key "trap" at - line 3.
1472
1473 =back
1474
1475 =head2 Unclassified Traps
1476
1477 Everything else.
1478
1479 =over 5
1480
1481 =item * C<require>/C<do> trap using returned value
1482
1483 If the file doit.pl has:
1484
1485     sub foo {
1486         $rc = do "./do.pl";
1487         return 8;
1488     }
1489     print &foo, "\n";
1490
1491 And the do.pl file has the following single line:
1492
1493     return 3;
1494
1495 Running doit.pl gives the following:
1496
1497     # perl 4 prints: 3 (aborts the subroutine early)
1498     # perl 5 prints: 8
1499
1500 Same behavior if you replace C<do> with C<require>.
1501
1502 =item * C<split> on empty string with LIMIT specified
1503
1504         $string = '';
1505     @list = split(/foo/, $string, 2)
1506
1507 Perl4 returns a one element list containing the empty string but Perl5
1508 returns an empty list.
1509
1510 =back
1511
1512 As always, if any of these are ever officially declared as bugs,
1513 they'll be fixed and removed.
1514