pod/perltrap.pod

   1 =head1 NAME
   2
   3 perltrap - Perl traps for the unwary
   4
   5 =head1 DESCRIPTION
   6
   7 The biggest trap of all is forgetting to use the B<-w> switch; see
   8 L<perlrun>.  The second biggest trap is not making your entire program
   9 runnable under C<use strict>.
  10
  11 =head2 Awk Traps
  12
  13 Accustomed B<awk> users should take special note of the following:
  14
  15 =over 4
  16
  17 =item *
  18
  19 The English module, loaded via
  20
  21     use English;
  22
  23 allows you to refer to special variables (like $RS) as
  24 though they were in B<awk>; see L<perlvar> for details.
  25
  26 =item *
  27
  28 Semicolons are required after all simple statements in Perl (except
  29 at the end of a block).  Newline is not a statement delimiter.
  30
  31 =item *
  32
  33 Curly brackets are required on C<if>s and C<while>s.
  34
  35 =item *
  36
  37 Variables begin with "$" or "@" in Perl.
  38
  39 =item *
  40
  41 Arrays index from 0.  Likewise string positions in substr() and
  42 index().
  43
  44 =item *
  45
  46 You have to decide whether your array has numeric or string indices.
  47
  48 =item *
  49
  50 Hash values do not spring into existence upon mere reference.
  51
  52 =item *
  53
  54 You have to decide whether you want to use string or numeric
  55 comparisons.
  56
  57 =item *
  58
  59 Reading an input line does not split it for you.  You get to split it
  60 yourself to an array.  And the split() operator has different
  61 arguments.
  62
  63 =item *
  64
  65 The current input line is normally in $_, not $0.  It generally does
  66 not have the newline stripped.  ($0 is the name of the program
  67 executed.)  See L<perlvar>.
  68
  69 =item *
  70
  71 $E<lt>I<digit>E<gt> does not refer to fields--it refers to substrings matched
  72 by the last match pattern.
  73
  74 =item *
  75
  76 The print() statement does not add field and record separators unless
  77 you set C<$,> and C<$\>.  You can set $OFS and $ORS if you're using
  78 the English module.
  79
  80 =item *
  81
  82 You must open your files before you print to them.
  83
  84 =item *
  85
  86 The range operator is "..", not comma.  The comma operator works as in
  87 C.
  88
  89 =item *
  90
  91 The match operator is "=~", not "~".  ("~" is the one's complement
  92 operator, as in C.)
  93
  94 =item *
  95
  96 The exponentiation operator is "**", not "^".  "^" is the XOR
  97 operator, as in C.  (You know, one could get the feeling that B<awk> is
  98 basically incompatible with C.)
  99
 100 =item *
 101
 102 The concatenation operator is ".", not the null string.  (Using the
 103 null string would render C</pat/ /pat/> unparsable, because the third slash
 104 would be interpreted as a division operator--the tokenizer is in fact
 105 slightly context sensitive for operators like "/", "?", and "E<gt>".
 106 And in fact, "." itself can be the beginning of a number.)
 107
 108 =item *
 109
 110 The C<next>, C<exit>, and C<continue> keywords work differently.
 111
 112 =item *
 113
 114
 115 The following variables work differently:
 116
 117       Awk       Perl
 118       ARGC      $#ARGV or scalar @ARGV
 119       ARGV[0]   $0
 120       FILENAME  $ARGV
 121       FNR       $. - something
 122       FS        (whatever you like)
 123       NF        $#Fld, or some such
 124       NR        $.
 125       OFMT      $#
 126       OFS       $,
 127       ORS       $\
 128       RLENGTH   length($&)
 129       RS        $/
 130       RSTART    length($`)
 131       SUBSEP    $;
 132
 133 =item *
 134
 135 You cannot set $RS to a pattern, only a string.
 136
 137 =item *
 138
 139 When in doubt, run the B<awk> construct through B<a2p> and see what it
 140 gives you.
 141
 142 =back
 143
 144 =head2 C Traps
 145
 146 Cerebral C programmers should take note of the following:
 147
 148 =over 4
 149
 150 =item *
 151
 152 Curly brackets are required on C<if>'s and C<while>'s.
 153
 154 =item *
 155
 156 You must use C<elsif> rather than C<else if>.
 157
 158 =item *
 159
 160 The C<break> and C<continue> keywords from C become in
 161 Perl C<last> and C<next>, respectively.
 162 Unlike in C, these do I<NOT> work within a C<do { } while> construct.
 163
 164 =item *
 165
 166 There's no switch statement.  (But it's easy to build one on the fly.)
 167
 168 =item *
 169
 170 Variables begin with "$" or "@" in Perl.
 171
 172 =item *
 173
 174 C<printf()> does not implement the "*" format for interpolating
 175 field widths, but it's trivial to use interpolation of double-quoted
 176 strings to achieve the same effect.
 177
 178 =item *
 179
 180 Comments begin with "#", not "/*".
 181
 182 =item *
 183
 184 You can't take the address of anything, although a similar operator
 185 in Perl is the backslash, which creates a reference.
 186
 187 =item *
 188
 189 C<ARGV> must be capitalized.  C<$ARGV[0]> is C's C<argv[1]>, and C<argv[0]>
 190 ends up in C<$0>.
 191
 192 =item *
 193
 194 System calls such as link(), unlink(), rename(), etc. return nonzero for
 195 success, not 0.
 196
 197 =item *
 198
 199 Signal handlers deal with signal names, not numbers.  Use C<kill -l>
 200 to find their names on your system.
 201
 202 =back
 203
 204 =head2 Sed Traps
 205
 206 Seasoned B<sed> programmers should take note of the following:
 207
 208 =over 4
 209
 210 =item *
 211
 212 Backreferences in substitutions use "$" rather than "\".
 213
 214 =item *
 215
 216 The pattern matching metacharacters "(", ")", and "|" do not have backslashes
 217 in front.
 218
 219 =item *
 220
 221 The range operator is C<...>, rather than comma.
 222
 223 =back
 224
 225 =head2 Shell Traps
 226
 227 Sharp shell programmers should take note of the following:
 228
 229 =over 4
 230
 231 =item *
 232
 233 The back-tick operator does variable interpolation without regard to
 234 the presence of single quotes in the command.
 235
 236 =item *
 237
 238 The back-tick operator does no translation of the return value, unlike B<csh>.
 239
 240 =item *
 241
 242 Shells (especially B<csh>) do several levels of substitution on each
 243 command line.  Perl does substitution in only certain constructs
 244 such as double quotes, back-ticks, angle brackets, and search patterns.
 245
 246 =item *
 247
 248 Shells interpret scripts a little bit at a time.  Perl compiles the
 249 entire program before executing it (except for C<BEGIN> blocks, which
 250 execute at compile time).
 251
 252 =item *
 253
 254 The arguments are available via @ARGV, not $1, $2, etc.
 255
 256 =item *
 257
 258 The environment is not automatically made available as separate scalar
 259 variables.
 260
 261 =back
 262
 263 =head2 Perl Traps
 264
 265 Practicing Perl Programmers should take note of the following:
 266
 267 =over 4
 268
 269 =item *
 270
 271 Remember that many operations behave differently in a list
 272 context than they do in a scalar one.  See L<perldata> for details.
 273
 274 =item *
 275
 276 Avoid barewords if you can, especially all lower-case ones.
 277 You can't tell by just looking at it whether a bareword is
 278 a function or a string.  By using quotes on strings and
 279 parentheses on function calls, you won't ever get them confused.
 280
 281 =item *
 282
 283 You cannot discern from mere inspection which built-ins
 284 are unary operators (like chop() and chdir())
 285 and which are list operators (like print() and unlink()).
 286 (User-defined subroutines can be B<only> list operators, never
 287 unary ones.)  See L<perlop>.
 288
 289 =item *
 290
 291 People have a hard time remembering that some functions
 292 default to $_, or @ARGV, or whatever, but that others which
 293 you might expect to do not.
 294
 295 =item *
 296
 297 The E<lt>FHE<gt> construct is not the name of the filehandle, it is a readline
 298 operation on that handle.  The data read is assigned to $_ only if the
 299 file read is the sole condition in a while loop:
 300
 301     while (<FH>)      { }
 302     while ($_ = <FH>) { }..
 303     <FH>;  # data discarded!
 304
 305 =item *
 306
 307 Remember not to use "C<=>" when you need "C<=~>";
 308 these two constructs are quite different:
 309
 310     $x =  /foo/;
 311     $x =~ /foo/;
 312
 313 =item *
 314
 315 The C<do {}> construct isn't a real loop that you can use
 316 loop control on.
 317
 318 =item *
 319
 320 Use C<my()> for local variables whenever you can get away with
 321 it (but see L<perlform> for where you can't).
 322 Using C<local()> actually gives a local value to a global
 323 variable, which leaves you open to unforeseen side-effects
 324 of dynamic scoping.
 325
 326 =item *
 327
 328 If you localize an exported variable in a module, its exported value will
 329 not change.  The local name becomes an alias to a new value but the
 330 external name is still an alias for the original.
 331
 332 =back
 333
 334 =head2 Perl4 to Perl5 Traps
 335
 336 Practicing Perl4 Programmers should take note of the following
 337 Perl4-to-Perl5 specific traps.
 338
 339 They're crudely ordered according to the following list:
 340
 341 =over 4
 342
 343 =item Discontinuance, Deprecation, and BugFix traps
 344
 345 Anything that's been fixed as a perl4 bug, removed as a perl4 feature
 346 or deprecated as a perl4 feature with the intent to encourage usage of
 347 some other perl5 feature.
 348
 349 =item Parsing Traps
 350
 351 Traps that appear to stem from the new parser.
 352
 353 =item Numerical Traps
 354
 355 Traps having to do with numerical or mathematical operators.
 356
 357 =item General data type traps
 358
 359 Traps involving perl standard data types.
 360
 361 =item Context Traps - scalar, list contexts
 362
 363 Traps related to context within lists, scalar statements/declarations.
 364
 365 =item Precedence Traps
 366
 367 Traps related to the precedence of parsing, evaluation, and execution of
 368 code.
 369
 370 =item General Regular Expression Traps using s///, etc.
 371
 372 Traps related to the use of pattern matching.
 373
 374 =item Subroutine, Signal, Sorting Traps
 375
 376 Traps related to the use of signals and signal handlers, general subroutines,
 377 and sorting, along with sorting subroutines.
 378
 379 =item OS Traps
 380
 381 OS-specific traps.
 382
 383 =item DBM Traps
 384
 385 Traps specific to the use of C<dbmopen()>, and specific dbm implementations.
 386
 387 =item Unclassified Traps
 388
 389 Everything else.
 390
 391 =back
 392
 393 If you find an example of a conversion trap that is not listed here,
 394 please submit it to Bill Middleton <F<wjm@best.com>> for inclusion.
 395 Also note that at least some of these can be caught with B<-w>.
 396
 397 =head2 Discontinuance, Deprecation, and BugFix traps
 398
 399 Anything that has been discontinued, deprecated, or fixed as
 400 a bug from perl4.
 401
 402 =over 4
 403
 404 =item * Discontinuance
 405
 406 Symbols starting with "_" are no longer forced into package main, except
 407 for C<$_> itself (and C<@_>, etc.).
 408
 409     package test;
 410     $_legacy = 1;
 411
 412     package main;
 413     print "\$_legacy is ",$_legacy,"\n";
 414
 415     # perl4 prints: $_legacy is 1
 416     # perl5 prints: $_legacy is
 417
 418 =item * Deprecation
 419
 420 Double-colon is now a valid package separator in a variable name.  Thus these
 421 behave differently in perl4 vs. perl5, because the packages don't exist.
 422
 423     $a=1;$b=2;$c=3;$var=4;
 424     print "$a::$b::$c ";
 425     print "$var::abc::xyz\n";
 426
 427     # perl4 prints: 1::2::3 4::abc::xyz
 428     # perl5 prints: 3
 429
 430 Given that C<::> is now the preferred package delimiter, it is debatable
 431 whether this should be classed as a bug or not.
 432 (The older package delimiter, ' ,is used here)
 433
 434     $x = 10 ;
 435     print "x=${'x}\n" ;
 436
 437     # perl4 prints: x=10
 438     # perl5 prints: Can't find string terminator "'" anywhere before EOF
 439
 440 Also see precedence traps, for parsing C<$:>.
 441
 442 =item * BugFix
 443
 444 The second and third arguments of C<splice()> are now evaluated in scalar
 445 context (as the Camel says) rather than list context.
 446
 447     sub sub1{return(0,2) }          # return a 2-elem array
 448     sub sub2{ return(1,2,3)}        # return a 3-elem array
 449     @a1 = ("a","b","c","d","e");
 450     @a2 = splice(@a1,&sub1,&sub2);
 451     print join(' ',@a2),"\n";
 452
 453     # perl4 prints: a b
 454     # perl5 prints: c d e
 455
 456 =item * Discontinuance
 457
 458 You can't do a C<goto> into a block that is optimized away.  Darn.
 459
 460     goto marker1;
 461
 462     for(1){
 463     marker1:
 464         print "Here I is!\n";
 465     }
 466
 467     # perl4 prints: Here I is!
 468     # perl5 dumps core (SEGV)
 469
 470 =item * Discontinuance
 471
 472 It is no longer syntactically legal to use whitespace as the name
 473 of a variable, or as a delimiter for any kind of quote construct.
 474 Double darn.
 475
 476     $a = ("foo bar");
 477     $b = q baz ;
 478     print "a is $a, b is $b\n";
 479
 480     # perl4 prints: a is foo bar, b is baz
 481     # perl5 errors: Bare word found where operator expected
 482
 483 =item * Discontinuance
 484
 485 The archaic while/if BLOCK BLOCK syntax is no longer supported.
 486
 487     if { 1 } {
 488         print "True!";
 489     }
 490     else {
 491         print "False!";
 492     }
 493
 494     # perl4 prints: True!
 495     # perl5 errors: syntax error at test.pl line 1, near "if {"
 496
 497 =item * BugFix
 498
 499 The C<**> operator now binds more tightly than unary minus.
 500 It was documented to work this way before, but didn't.
 501
 502     print -4**2,"\n";
 503
 504     # perl4 prints: 16
 505     # perl5 prints: -16
 506
 507 =item * Discontinuance
 508
 509 The meaning of C<foreach{}> has changed slightly when it is iterating over a
 510 list which is not an array.  This used to assign the list to a
 511 temporary array, but no longer does so (for efficiency).  This means
 512 that you'll now be iterating over the actual values, not over copies of
 513 the values.  Modifications to the loop variable can change the original
 514 values.
 515
 516     @list = ('ab','abc','bcd','def');
 517     foreach $var (grep(/ab/,@list)){
 518         $var = 1;
 519     }
 520     print (join(':',@list));
 521
 522     # perl4 prints: ab:abc:bcd:def
 523     # perl5 prints: 1:1:bcd:def
 524
 525 To retain Perl4 semantics you need to assign your list
 526 explicitly to a temporary array and then iterate over that.  For
 527 example, you might need to change
 528
 529     foreach $var (grep(/ab/,@list)){
 530
 531 to
 532
 533     foreach $var (@tmp = grep(/ab/,@list)){
 534
 535 Otherwise changing $var will clobber the values of @list.  (This most often
 536 happens when you use C<$_> for the loop variable, and call subroutines in
 537 the loop that don't properly localize C<$_>.)
 538
 539 =item * Discontinuance
 540
 541 C<split> with no arguments now behaves like C<split ' '> (which doesn't
 542 return an initial null field if $_ starts with whitespace), it used to
 543 behave like C<split /\s+/> (which does).
 544
 545     $_ = ' hi mom';
 546     print join(':', split);
 547
 548     # perl4 prints: :hi:mom
 549     # perl5 prints: hi:mom
 550
 551 =item * BugFix
 552
 553 Perl 4 would ignore any text which was attached to an B<-e> switch,
 554 always taking the code snippet from the following arg.  Additionally, it
 555 would silently accept an B<-e> switch without a following arg.  Both of
 556 these behaviors have been fixed.
 557
 558     perl -e'print "attached to -e"' 'print "separate arg"'
 559
 560     # perl4 prints: separate arg
 561     # perl5 prints: attached to -e
 562
 563     perl -e
 564
 565     # perl4 prints:
 566     # perl5 dies: No code specified for -e.
 567
 568 =item * Discontinuance
 569
 570 In Perl 4 the return value of C<push> was undocumented, but it was
 571 actually the last value being pushed onto the target list.  In Perl 5
 572 the return value of C<push> is documented, but has changed, it is the
 573 number of elements in the resulting list.
 574
 575     @x = ('existing');
 576     print push(@x, 'first new', 'second new');
 577
 578     # perl4 prints: second new
 579     # perl5 prints: 3
 580
 581 =item * Deprecation
 582
 583 Some error messages will be different.
 584
 585 =item * Discontinuance
 586
 587 Some bugs may have been inadvertently removed.  :-)
 588
 589 =back
 590
 591 =head2 Parsing Traps
 592
 593 Perl4-to-Perl5 traps from having to do with parsing.
 594
 595 =over 4
 596
 597 =item * Parsing
 598
 599 Note the space between . and =
 600
 601     $string . = "more string";
 602     print $string;
 603
 604     # perl4 prints: more string
 605     # perl5 prints: syntax error at - line 1, near ". ="
 606
 607 =item * Parsing
 608
 609 Better parsing in perl 5
 610
 611     sub foo {}
 612     &foo
 613     print("hello, world\n");
 614
 615     # perl4 prints: hello, world
 616     # perl5 prints: syntax error
 617
 618 =item * Parsing
 619
 620 "if it looks like a function, it is a function" rule.
 621
 622   print
 623     ($foo == 1) ? "is one\n" : "is zero\n";
 624
 625     # perl4 prints: is zero
 626     # perl5 warns: "Useless use of a constant in void context" if using -w
 627
 628 =back
 629
 630 =head2 Numerical Traps
 631
 632 Perl4-to-Perl5 traps having to do with numerical operators,
 633 operands, or output from same.
 634
 635 =over 5
 636
 637 =item * Numerical
 638
 639 Formatted output and significant digits
 640
 641     print 7.373504 - 0, "\n";
 642     printf "%20.18f\n", 7.373504 - 0;
 643
 644     # Perl4 prints:
 645     7.375039999999996141
 646     7.37503999999999614
 647
 648     # Perl5 prints:
 649     7.373504
 650     7.37503999999999614
 651
 652 =item * Numerical
 653
 654 This specific item has been deleted.  It demonstrated how the auto-increment
 655 operator would not catch when a number went over the signed int limit.  Fixed
 656 in version 5.003_04.  But always be wary when using large integers.
 657 If in doubt:
 658
 659    use Math::BigInt;
 660
 661 =item * Numerical
 662
 663 Assignment of return values from numeric equality tests
 664 does not work in perl5 when the test evaluates to false (0).
 665 Logical tests now return an null, instead of 0
 666
 667     $p = ($test == 1);
 668     print $p,"\n";
 669
 670     # perl4 prints: 0
 671     # perl5 prints:
 672
 673 Also see the L<General Regular Expression Traps using s///, etc.>
 674 tests for another example of this new feature...
 675
 676 =back
 677
 678 =head2 General data type traps
 679
 680 Perl4-to-Perl5 traps involving most data-types, and their usage
 681 within certain expressions and/or context.
 682
 683 =over 5
 684
 685 =item * (Arrays)
 686
 687 Negative array subscripts now count from the end of the array.
 688
 689     @a = (1, 2, 3, 4, 5);
 690     print "The third element of the array is $a[3] also expressed as $a[-2] \n";
 691
 692     # perl4 prints: The third element of the array is 4 also expressed as
 693     # perl5 prints: The third element of the array is 4 also expressed as 4
 694
 695 =item * (Arrays)
 696
 697 Setting C<$#array> lower now discards array elements, and makes them
 698 impossible to recover.
 699
 700     @a = (a,b,c,d,e);
 701     print "Before: ",join('',@a);
 702     $#a =1;
 703     print ", After: ",join('',@a);
 704     $#a =3;
 705     print ", Recovered: ",join('',@a),"\n";
 706
 707     # perl4 prints: Before: abcde, After: ab, Recovered: abcd
 708     # perl5 prints: Before: abcde, After: ab, Recovered: ab
 709
 710 =item * (Hashes)
 711
 712 Hashes get defined before use
 713
 714     local($s,@a,%h);
 715     die "scalar \$s defined" if defined($s);
 716     die "array \@a defined" if defined(@a);
 717     die "hash \%h defined" if defined(%h);
 718
 719     # perl4 prints:
 720     # perl5 dies: hash %h defined
 721
 722 =item * (Globs)
 723
 724 glob assignment from variable to variable will fail if the assigned
 725 variable is localized subsequent to the assignment
 726
 727     @a = ("This is Perl 4");
 728     *b = *a;
 729     local(@a);
 730     print @b,"\n";
 731
 732     # perl4 prints: This is Perl 4
 733     # perl5 prints:
 734
 735     # Another example
 736
 737     *fred = *barney; # fred is aliased to barney
 738     @barney = (1, 2, 4);
 739     # @fred;
 740     print "@fred";  # should print "1, 2, 4"
 741
 742     # perl4 prints: 1 2 4
 743     # perl5 prints: In string, @fred now must be written as \@fred
 744
 745 =item * (Scalar String)
 746
 747 Changes in unary negation (of strings)
 748 This change effects both the return value and what it
 749 does to auto(magic)increment.
 750
 751     $x = "aaa";
 752     print ++$x," : ";
 753     print -$x," : ";
 754     print ++$x,"\n";
 755
 756     # perl4 prints: aab : -0 : 1
 757     # perl5 prints: aab : -aab : aac
 758
 759 =item * (Constants)
 760
 761 perl 4 lets you modify constants:
 762
 763     $foo = "x";
 764     &mod($foo);
 765     for ($x = 0; $x < 3; $x++) {
 766         &mod("a");
 767     }
 768     sub mod {
 769         print "before: $_[0]";
 770         $_[0] = "m";
 771         print "  after: $_[0]\n";
 772     }
 773
 774     # perl4:
 775     # before: x  after: m
 776     # before: a  after: m
 777     # before: m  after: m
 778     # before: m  after: m
 779
 780     # Perl5:
 781     # before: x  after: m
 782     # Modification of a read-only value attempted at foo.pl line 12.
 783     # before: a
 784
 785 =item * (Scalars)
 786
 787 The behavior is slightly different for:
 788
 789     print "$x", defined $x
 790
 791     # perl 4: 1
 792     # perl 5: <no output, $x is not called into existence>
 793
 794 =item * (Variable Suicide)
 795
 796 Variable suicide behavior is more consistent under Perl 5.
 797 Perl5 exhibits the same behavior for hashes and scalars,
 798 that perl4 exhibits for only scalars.
 799
 800     $aGlobal{ "aKey" } = "global value";
 801     print "MAIN:", $aGlobal{"aKey"}, "\n";
 802     $GlobalLevel = 0;
 803     &test( *aGlobal );
 804
 805     sub test {
 806         local( *theArgument ) = @_;
 807         local( %aNewLocal ); # perl 4 != 5.001l,m
 808         $aNewLocal{"aKey"} = "this should never appear";
 809         print "SUB: ", $theArgument{"aKey"}, "\n";
 810         $aNewLocal{"aKey"} = "level $GlobalLevel";   # what should print
 811         $GlobalLevel++;
 812         if( $GlobalLevel<4 ) {
 813             &test( *aNewLocal );
 814         }
 815     }
 816
 817     # Perl4:
 818     # MAIN:global value
 819     # SUB: global value
 820     # SUB: level 0
 821     # SUB: level 1
 822     # SUB: level 2
 823
 824     # Perl5:
 825     # MAIN:global value
 826     # SUB: global value
 827     # SUB: this should never appear
 828     # SUB: this should never appear
 829     # SUB: this should never appear
 830
 831 =back
 832
 833 =head2 Context Traps - scalar, list contexts
 834
 835 =over 5
 836
 837 =item * (list context)
 838
 839 The elements of argument lists for formats are now evaluated in list
 840 context.  This means you can interpolate list values now.
 841
 842     @fmt = ("foo","bar","baz");
 843     format STDOUT=
 844     @<<<<< @||||| @>>>>>
 845     @fmt;
 846     .
 847     write;
 848
 849     # perl4 errors:  Please use commas to separate fields in file
 850     # perl5 prints: foo     bar      baz
 851
 852 =item * (scalar context)
 853
 854 The C<caller()> function now returns a false value in a scalar context
 855 if there is no caller.  This lets library files determine if they're
 856 being required.
 857
 858     caller() ? (print "You rang?\n") : (print "Got a 0\n");
 859
 860     # perl4 errors: There is no caller
 861     # perl5 prints: Got a 0
 862
 863 =item * (scalar context)
 864
 865 The comma operator in a scalar context is now guaranteed to give a
 866 scalar context to its arguments.
 867
 868     @y= ('a','b','c');
 869     $x = (1, 2, @y);
 870     print "x = $x\n";
 871
 872     # Perl4 prints:  x = c   # Thinks list context interpolates list
 873     # Perl5 prints:  x = 3   # Knows scalar uses length of list
 874
 875 =item * (list, builtin)
 876
 877 C<sprintf()> funkiness (array argument converted to scalar array count)
 878 This test could be added to t/op/sprintf.t
 879
 880     @z = ('%s%s', 'foo', 'bar');
 881     $x = sprintf(@z);
 882     if ($x eq 'foobar') {print "ok 2\n";} else {print "not ok 2 '$x'\n";}
 883
 884     # perl4 prints: ok 2
 885     # perl5 prints: not ok 2
 886
 887 C<printf()> works fine, though:
 888
 889     printf STDOUT (@z);
 890     print "\n";
 891
 892     # perl4 prints: foobar
 893     # perl5 prints: foobar
 894
 895 Probably a bug.
 896
 897 =back
 898
 899 =head2 Precedence Traps
 900
 901 Perl4-to-Perl5 traps involving precedence order.
 902
 903 =over 5
 904
 905 =item * Precedence
 906
 907 LHS vs. RHS when both sides are getting an op.
 908
 909     @arr = ( 'left', 'right' );
 910     $a{shift @arr} = shift @arr;
 911     print join( ' ', keys %a );
 912
 913     # perl4 prints: left
 914     # perl5 prints: right
 915
 916 =item * Precedence
 917
 918 These are now semantic errors because of precedence:
 919
 920     @list = (1,2,3,4,5);
 921     %map = ("a",1,"b",2,"c",3,"d",4);
 922     $n = shift @list + 2;   # first item in list plus 2
 923     print "n is $n, ";
 924     $m = keys %map + 2;     # number of items in hash plus 2
 925     print "m is $m\n";
 926
 927     # perl4 prints: n is 3, m is 6
 928     # perl5 errors and fails to compile
 929
 930 =item * Precedence
 931
 932 The precedence of assignment operators is now the same as the precedence
 933 of assignment.  Perl 4 mistakenly gave them the precedence of the associated
 934 operator.  So you now must parenthesize them in expressions like
 935
 936     /foo/ ? ($a += 2) : ($a -= 2);
 937
 938 Otherwise
 939
 940     /foo/ ? $a += 2 : $a -= 2
 941
 942 would be erroneously parsed as
 943
 944     (/foo/ ? $a += 2 : $a) -= 2;
 945
 946 On the other hand,
 947
 948     $a += /foo/ ? 1 : 2;
 949
 950 now works as a C programmer would expect.
 951
 952 =item * Precedence
 953
 954     open FOO || die;
 955
 956 is now incorrect.  You need parentheses around the filehandle.
 957 Otherwise, perl5 leaves the statement as its default precedence:
 958
 959     open(FOO || die);
 960
 961     # perl4 opens or dies
 962     # perl5 errors: Precedence problem: open FOO should be open(FOO)
 963
 964 =item * Precedence
 965
 966 perl4 gives the special variable, C<$:> precedence, where perl5
 967 treats C<$::> as main C<package>
 968
 969     $a = "x"; print "$::a";
 970
 971     # perl 4 prints: -:a
 972     # perl 5 prints: x
 973
 974 =item * Precedence
 975
 976 concatenation precedence over filetest operator?
 977
 978     -e $foo .= "q"
 979
 980     # perl4 prints: no output
 981     # perl5 prints: Can't modify -e in concatenation
 982
 983 =item * Precedence
 984
 985 Assignment to value takes precedence over assignment to key in
 986 perl5 when using the shift operator on both sides.
 987
 988     @arr = ( 'left', 'right' );
 989     $a{shift @arr} = shift @arr;
 990     print join( ' ', keys %a );
 991
 992     # perl4 prints: left
 993     # perl5 prints: right
 994
 995 =back
 996
 997 =head2 General Regular Expression Traps using s///, etc.
 998
 999 All types of RE traps.
1000
1001 =over 5
1002
1003 =item * Regular Expression
1004
1005 C<s'$lhs'$rhs'> now does no interpolation on either side.  It used to
1006 interpolate C<$lhs> but not C<$rhs>.  (And still does not match a literal
1007 '$' in string)
1008
1009     $a=1;$b=2;
1010     $string = '1 2 $a $b';
1011     $string =~ s'$a'$b';
1012     print $string,"\n";
1013
1014     # perl4 prints: $b 2 $a $b
1015     # perl5 prints: 1 2 $a $b
1016
1017 =item * Regular Expression
1018
1019 C<m//g> now attaches its state to the searched string rather than the
1020 regular expression.  (Once the scope of a block is left for the sub, the
1021 state of the searched string is lost)
1022
1023     $_ = "ababab";
1024     while(m/ab/g){
1025         &doit("blah");
1026     }
1027     sub doit{local($_) = shift; print "Got $_ "}
1028
1029     # perl4 prints: blah blah blah
1030     # perl5 prints: infinite loop blah...
1031
1032 =item * Regular Expression
1033
1034 If no parentheses are used in a match, Perl4 sets C<$+> to
1035 the whole match, just like C<$&>. Perl5 does not.
1036
1037     "abcdef" =~ /b.*e/;
1038     print "\$+ = $+\n";
1039
1040     # perl4 prints: bcde
1041     # perl5 prints:
1042
1043 =item * Regular Expression
1044
1045 substitution now returns the null string if it fails
1046
1047     $string = "test";
1048     $value = ($string =~ s/foo//);
1049     print $value, "\n";
1050
1051     # perl4 prints: 0
1052     # perl5 prints:
1053
1054 Also see L<Numerical Traps> for another example of this new feature.
1055
1056 =item * Regular Expression
1057
1058 C<s`lhs`rhs`> (using back-ticks) is now a normal substitution, with no
1059 back-tick expansion
1060
1061     $string = "";
1062     $string =~ s`^`hostname`;
1063     print $string, "\n";
1064
1065     # perl4 prints: <the local hostname>
1066     # perl5 prints: hostname
1067
1068 =item * Regular Expression
1069
1070 Stricter parsing of variables used in regular expressions
1071
1072     s/^([^$grpc]*$grpc[$opt$plus$rep]?)//o;
1073
1074     # perl4: compiles w/o error
1075     # perl5: with Scalar found where operator expected ..., near "$opt$plus"
1076
1077 an added component of this example, apparently from the same script, is
1078 the actual value of the s'd string after the substitution.
1079 C<[$opt]> is a character class in perl4 and an array subscript in perl5
1080
1081     $grpc = 'a';
1082     $opt  = 'r';
1083     $_ = 'bar';
1084     s/^([^$grpc]*$grpc[$opt]?)/foo/;
1085     print ;
1086
1087     # perl4 prints: foo
1088     # perl5 prints: foobar
1089
1090 =item * Regular Expression
1091
1092 Under perl5, C<m?x?> matches only once, like C<?x?>. Under perl4, it matched
1093 repeatedly, like C</x/> or C<m!x!>.
1094
1095     $test = "once";
1096     sub match { $test =~ m?once?; }
1097     &match();
1098     if( &match() ) {
1099         # m?x? matches more then once
1100         print "perl4\n";
1101     } else {
1102         # m?x? matches only once
1103         print "perl5\n";
1104     }
1105
1106     # perl4 prints: perl4
1107     # perl5 prints: perl5
1108
1109
1110 =item * Regular Expression
1111
1112 Under perl4 and upto version 5.003, a failed C<m//g> match used to
1113 reset the internal iterator, so that subsequent C<m//g> match attempts
1114 began from the beginning of the string.  In perl version 5.004 and later,
1115 failed C<m//g> matches do not reset the iterator position (which can be
1116 found using the C<pos()> function--see L<perlfunc/pos>).
1117
1118     $test = "foop";
1119     for (1..3) {
1120         print $1 while ($test =~ /(o)/g);
1121         # pos $test = 0;     # to get old behavior
1122     }
1123
1124     # perl4     prints: oooooo
1125     # perl5.004 prints: oo
1126
1127 You may always reset the iterator yourself as shown in the commented line
1128 to get the old behavior.
1129
1130 =item * Regular Expression
1131
1132 Currently, if you use the /o qualifier on a regular expression within
1133 an anonymous subroutine, I<all> closures generated from that anonymous
1134 sub constructor will use the regular expression compiled the very
1135 first time the constructor was called.  For instance, if you say
1136
1137     sub build_match {
1138        my($left,$right) = @_;
1139        return sub { $_[0] =~ /$left stuff $right/o; };
1140     }
1141
1142 build_match will always return a sub which matches the contents of
1143 C<$left> and <$right> from the first time it was called, not from
1144 the current call.  This is probably a bug, and may change in future
1145 versions of Perl.
1146
1147 =back
1148
1149 =head2 Subroutine, Signal, Sorting Traps
1150
1151 The general group of Perl4-to-Perl5 traps having to do with
1152 Signals, Sorting, and their related subroutines, as well as
1153 general subroutine traps.  Includes some OS-Specific traps.
1154
1155 =over 5
1156
1157 =item * (Signals)
1158
1159 Barewords that used to look like strings to Perl will now look like subroutine
1160 calls if a subroutine by that name is defined before the compiler sees them.
1161
1162     sub SeeYa { warn"Hasta la vista, baby!" }
1163     $SIG{'TERM'} = SeeYa;
1164     print "SIGTERM is now $SIG{'TERM'}\n";
1165
1166     # perl4 prints: SIGTERM is main'SeeYa
1167     # perl5 prints: SIGTERM is now main::1
1168
1169 Use B<-w> to catch this one
1170
1171 =item * (Sort Subroutine)
1172
1173 reverse is no longer allowed as the name of a sort subroutine.
1174
1175     sub reverse{ print "yup "; $a <=> $b }
1176     print sort reverse a,b,c;
1177
1178     # perl4 prints: yup yup yup yup abc
1179     # perl5 prints: abc
1180
1181 =item * warn() won't let you specify a filehandle.
1182
1183 Although it _always_ printed to STDERR, warn() would let you specify a
1184 filehandle in perl4.  With perl5 it does not.
1185
1186     warn STDERR "Foo!";
1187
1188     # perl4 prints: Foo!
1189     # perl5 prints: String found where operator expected
1190
1191 =back
1192
1193 =head2 OS Traps
1194
1195 =over 5
1196
1197 =item * (SysV)
1198
1199 Under HPUX, and some other SysV OS's, one had to reset any signal handler,
1200 within  the signal handler function, each time a signal was handled with
1201 perl4.  With perl5, the reset is now done correctly.  Any code relying
1202 on the handler _not_ being reset will have to be reworked.
1203
1204 Since version 5.002, Perl uses sigaction() under SysV.
1205
1206     sub gotit {
1207         print "Got @_... ";
1208     }
1209     $SIG{'INT'} = 'gotit';
1210
1211     $| = 1;
1212     $pid = fork;
1213     if ($pid) {
1214         kill('INT', $pid);
1215         sleep(1);
1216         kill('INT', $pid);
1217     } else {
1218         while (1) {sleep(10);}
1219     }
1220
1221     # perl4 (HPUX) prints: Got INT...
1222     # perl5 (HPUX) prints: Got INT... Got INT...
1223
1224 =item * (SysV)
1225
1226 Under SysV OS's, C<seek()> on a file opened to append C<E<gt>E<gt>> now does
1227 the right thing w.r.t. the fopen() man page. e.g., - When a file is opened
1228 for append,  it  is  impossible to overwrite information already in
1229 the file.
1230
1231     open(TEST,">>seek.test");
1232     $start = tell TEST ;
1233     foreach(1 .. 9){
1234         print TEST "$_ ";
1235     }
1236     $end = tell TEST ;
1237     seek(TEST,$start,0);
1238     print TEST "18 characters here";
1239
1240     # perl4 (solaris) seek.test has: 18 characters here
1241     # perl5 (solaris) seek.test has: 1 2 3 4 5 6 7 8 9 18 characters here
1242
1243
1244
1245 =back
1246
1247 =head2 Interpolation Traps
1248
1249 Perl4-to-Perl5 traps having to do with how things get interpolated
1250 within certain expressions, statements, contexts, or whatever.
1251
1252 =over 5
1253
1254 =item * Interpolation
1255
1256 @ now always interpolates an array in double-quotish strings.
1257
1258     print "To: someone@somewhere.com\n";
1259
1260     # perl4 prints: To:someone@somewhere.com
1261     # perl5 errors : In string, @somewhere now must be written as \@somewhere
1262
1263 =item * Interpolation
1264
1265 Double-quoted strings may no longer end with an unescaped $ or @.
1266
1267     $foo = "foo$";
1268     $bar = "bar@";
1269     print "foo is $foo, bar is $bar\n";
1270
1271     # perl4 prints: foo is foo$, bar is bar@
1272     # perl5 errors: Final $ should be \$ or $name
1273
1274 Note: perl5 DOES NOT error on the terminating @ in $bar
1275
1276 =item * Interpolation
1277
1278 Perl now sometimes evaluates arbitrary expressions inside braces that occur
1279 within double quotes (usually when the opening brace is preceded by C<$>
1280 or C<@>).
1281
1282     @www = "buz";
1283     $foo = "foo";
1284     $bar = "bar";
1285     sub foo { return "bar" };
1286     print "|@{w.w.w}|${main'foo}|";
1287
1288     # perl4 prints: |@{w.w.w}|foo|
1289     # perl5 prints: |buz|bar|
1290
1291 Note that you can C<use strict;> to ward off such trappiness under perl5.
1292
1293 =item * Interpolation
1294
1295 The construct "this is $$x" used to interpolate the pid at that
1296 point, but now apparently tries to dereference C<$x>.  C<$$> by itself still
1297 works fine, however.
1298
1299     print "this is $$x\n";
1300
1301     # perl4 prints: this is XXXx   (XXX is the current pid)
1302     # perl5 prints: this is
1303
1304 =item * Interpolation
1305
1306 Creation of hashes on the fly with C<eval "EXPR"> now requires either both
1307 C<$>'s to be protected in the specification of the hash name, or both curlies
1308 to be protected.  If both curlies are protected, the result will be compatible
1309 with perl4 and perl5.  This is a very common practice, and should be changed
1310 to use the block form of C<eval{}>  if possible.
1311
1312     $hashname = "foobar";
1313     $key = "baz";
1314     $value = 1234;
1315     eval "\$$hashname{'$key'} = q|$value|";
1316     (defined($foobar{'baz'})) ?  (print "Yup") : (print "Nope");
1317
1318     # perl4 prints: Yup
1319     # perl5 prints: Nope
1320
1321 Changing
1322
1323     eval "\$$hashname{'$key'} = q|$value|";
1324
1325 to
1326
1327     eval "\$\$hashname{'$key'} = q|$value|";
1328
1329 causes the following result:
1330
1331     # perl4 prints: Nope
1332     # perl5 prints: Yup
1333
1334 or, changing to
1335
1336     eval "\$$hashname\{'$key'\} = q|$value|";
1337
1338 causes the following result:
1339
1340     # perl4 prints: Yup
1341     # perl5 prints: Yup
1342     # and is compatible for both versions
1343
1344
1345 =item * Interpolation
1346
1347 perl4 programs which unconsciously rely on the bugs in earlier perl versions.
1348
1349     perl -e '$bar=q/not/; print "This is $foo{$bar} perl5"'
1350
1351     # perl4 prints: This is not perl5
1352     # perl5 prints: This is perl5
1353
1354 =item * Interpolation
1355
1356 You also have to be careful about array references.
1357
1358     print "$foo{"
1359
1360     perl 4 prints: {
1361     perl 5 prints: syntax error
1362
1363 =item * Interpolation
1364
1365 Similarly, watch out for:
1366
1367     $foo = "array";
1368     print "\$$foo{bar}\n";
1369
1370     # perl4 prints: $array{bar}
1371     # perl5 prints: $
1372
1373 Perl 5 is looking for C<$array{bar}> which doesn't exist, but perl 4 is
1374 happy just to expand $foo to "array" by itself.  Watch out for this
1375 especially in C<eval>'s.
1376
1377 =item * Interpolation
1378
1379 C<qq()> string passed to C<eval>
1380
1381     eval qq(
1382         foreach \$y (keys %\$x\) {
1383             \$count++;
1384         }
1385     );
1386
1387     # perl4 runs this ok
1388     # perl5 prints: Can't find string terminator ")"
1389
1390 =back
1391
1392 =head2 DBM Traps
1393
1394 General DBM traps.
1395
1396 =over 5
1397
1398 =item * DBM
1399
1400 Existing dbm databases created under perl4 (or any other dbm/ndbm tool)
1401 may cause the same script, run under perl5, to fail.  The build of perl5
1402 must have been linked with the same dbm/ndbm as the default for C<dbmopen()>
1403 to function properly without C<tie>'ing to an extension dbm implementation.
1404
1405     dbmopen (%dbm, "file", undef);
1406     print "ok\n";
1407
1408     # perl4 prints: ok
1409     # perl5 prints: ok (IFF linked with -ldbm or -lndbm)
1410
1411
1412 =item * DBM
1413
1414 Existing dbm databases created under perl4 (or any other dbm/ndbm tool)
1415 may cause the same script, run under perl5, to fail.  The error generated
1416 when exceeding the limit on the key/value size will cause perl5 to exit
1417 immediately.
1418
1419     dbmopen(DB, "testdb",0600) || die "couldn't open db! $!";
1420     $DB{'trap'} = "x" x 1024;  # value too large for most dbm/ndbm
1421     print "YUP\n";
1422
1423     # perl4 prints:
1424     dbm store returned -1, errno 28, key "trap" at - line 3.
1425     YUP
1426
1427     # perl5 prints:
1428     dbm store returned -1, errno 28, key "trap" at - line 3.
1429
1430 =back
1431
1432 =head2 Unclassified Traps
1433
1434 Everything else.
1435
1436 =over 5
1437
1438 =item * Unclassified
1439
1440 C<require>/C<do> trap using returned value
1441
1442 If the file doit.pl has:
1443
1444     sub foo {
1445         $rc = do "./do.pl";
1446         return 8;
1447     }
1448     print &foo, "\n";
1449
1450 And the do.pl file has the following single line:
1451
1452     return 3;
1453
1454 Running doit.pl gives the following:
1455
1456     # perl 4 prints: 3 (aborts the subroutine early)
1457     # perl 5 prints: 8
1458
1459 Same behavior if you replace C<do> with C<require>.
1460
1461 =back
1462
1463 As always, if any of these are ever officially declared as bugs,
1464 they'll be fixed and removed.
1465