pod/perltrap.pod

   1 =head1 NAME
   2
   3 perltrap - Perl traps for the unwary
   4
   5 =head1 DESCRIPTION
   6
   7 The biggest trap of all is forgetting to C<use warnings> or use the B<-w>
   8 switch; see L<perllexwarn> and L<perlrun>. The second biggest trap is not
   9 making your entire program runnable under C<use strict>.  The third biggest
  10 trap is not reading the list of changes in this version of Perl; see
  11 L<perldelta>.
  12
  13 =head2 Awk Traps
  14
  15 Accustomed B<awk> users should take special note of the following:
  16
  17 =over 4
  18
  19 =item *
  20
  21 The English module, loaded via
  22
  23     use English;
  24
  25 allows you to refer to special variables (like C<$/>) with names (like
  26 $RS), as though they were in B<awk>; see L<perlvar> for details.
  27
  28 =item *
  29
  30 Semicolons are required after all simple statements in Perl (except
  31 at the end of a block).  Newline is not a statement delimiter.
  32
  33 =item *
  34
  35 Curly brackets are required on C<if>s and C<while>s.
  36
  37 =item *
  38
  39 Variables begin with "$", "@" or "%" in Perl.
  40
  41 =item *
  42
  43 Arrays index from 0.  Likewise string positions in substr() and
  44 index().
  45
  46 =item *
  47
  48 You have to decide whether your array has numeric or string indices.
  49
  50 =item *
  51
  52 Hash values do not spring into existence upon mere reference.
  53
  54 =item *
  55
  56 You have to decide whether you want to use string or numeric
  57 comparisons.
  58
  59 =item *
  60
  61 Reading an input line does not split it for you.  You get to split it
  62 to an array yourself.  And the split() operator has different
  63 arguments than B<awk>'s.
  64
  65 =item *
  66
  67 The current input line is normally in $_, not $0.  It generally does
  68 not have the newline stripped.  ($0 is the name of the program
  69 executed.)  See L<perlvar>.
  70
  71 =item *
  72
  73 $<I<digit>> does not refer to fields--it refers to substrings matched
  74 by the last match pattern.
  75
  76 =item *
  77
  78 The print() statement does not add field and record separators unless
  79 you set C<$,> and C<$\>.  You can set $OFS and $ORS if you're using
  80 the English module.
  81
  82 =item *
  83
  84 You must open your files before you print to them.
  85
  86 =item *
  87
  88 The range operator is "..", not comma.  The comma operator works as in
  89 C.
  90
  91 =item *
  92
  93 The match operator is "=~", not "~".  ("~" is the one's complement
  94 operator, as in C.)
  95
  96 =item *
  97
  98 The exponentiation operator is "**", not "^".  "^" is the XOR
  99 operator, as in C.  (You know, one could get the feeling that B<awk> is
 100 basically incompatible with C.)
 101
 102 =item *
 103
 104 The concatenation operator is ".", not the null string.  (Using the
 105 null string would render C</pat/ /pat/> unparsable, because the third slash
 106 would be interpreted as a division operator--the tokenizer is in fact
 107 slightly context sensitive for operators like "/", "?", and ">".
 108 And in fact, "." itself can be the beginning of a number.)
 109
 110 =item *
 111
 112 The C<next>, C<exit>, and C<continue> keywords work differently.
 113
 114 =item *
 115
 116
 117 The following variables work differently:
 118
 119       Awk       Perl
 120       ARGC      scalar @ARGV (compare with $#ARGV)
 121       ARGV[0]   $0
 122       FILENAME  $ARGV
 123       FNR       $. - something
 124       FS        (whatever you like)
 125       NF        $#Fld, or some such
 126       NR        $.
 127       OFMT      $#
 128       OFS       $,
 129       ORS       $\
 130       RLENGTH   length($&)
 131       RS        $/
 132       RSTART    length($`)
 133       SUBSEP    $;
 134
 135 =item *
 136
 137 You cannot set $RS to a pattern, only a string.
 138
 139 =item *
 140
 141 When in doubt, run the B<awk> construct through B<a2p> and see what it
 142 gives you.
 143
 144 =back
 145
 146 =head2 C/C++ Traps
 147
 148 Cerebral C and C++ programmers should take note of the following:
 149
 150 =over 4
 151
 152 =item *
 153
 154 Curly brackets are required on C<if>'s and C<while>'s.
 155
 156 =item *
 157
 158 You must use C<elsif> rather than C<else if>.
 159
 160 =item *
 161
 162 The C<break> and C<continue> keywords from C become in Perl C<last>
 163 and C<next>, respectively.  Unlike in C, these do I<not> work within a
 164 C<do { } while> construct.  See L<perlsyn/"Loop Control">.
 165
 166 =item *
 167
 168 There's no switch statement.  (But it's easy to build one on the fly,
 169 see L<perlsyn/"Basic BLOCKs and Switch Statements">)
 170
 171 =item *
 172
 173 Variables begin with "$", "@" or "%" in Perl.
 174
 175 =item *
 176
 177 Comments begin with "#", not "/*".
 178
 179 =item *
 180
 181 You can't take the address of anything, although a similar operator
 182 in Perl is the backslash, which creates a reference.
 183
 184 =item *
 185
 186 C<ARGV> must be capitalized.  C<$ARGV[0]> is C's C<argv[1]>, and C<argv[0]>
 187 ends up in C<$0>.
 188
 189 =item *
 190
 191 System calls such as link(), unlink(), rename(), etc. return nonzero for
 192 success, not 0. (system(), however, returns zero for success.)
 193
 194 =item *
 195
 196 Signal handlers deal with signal names, not numbers.  Use C<kill -l>
 197 to find their names on your system.
 198
 199 =back
 200
 201 =head2 Sed Traps
 202
 203 Seasoned B<sed> programmers should take note of the following:
 204
 205 =over 4
 206
 207 =item *
 208
 209 Backreferences in substitutions use "$" rather than "\".
 210
 211 =item *
 212
 213 The pattern matching metacharacters "(", ")", and "|" do not have backslashes
 214 in front.
 215
 216 =item *
 217
 218 The range operator is C<...>, rather than comma.
 219
 220 =back
 221
 222 =head2 Shell Traps
 223
 224 Sharp shell programmers should take note of the following:
 225
 226 =over 4
 227
 228 =item *
 229
 230 The backtick operator does variable interpolation without regard to
 231 the presence of single quotes in the command.
 232
 233 =item *
 234
 235 The backtick operator does no translation of the return value, unlike B<csh>.
 236
 237 =item *
 238
 239 Shells (especially B<csh>) do several levels of substitution on each
 240 command line.  Perl does substitution in only certain constructs
 241 such as double quotes, backticks, angle brackets, and search patterns.
 242
 243 =item *
 244
 245 Shells interpret scripts a little bit at a time.  Perl compiles the
 246 entire program before executing it (except for C<BEGIN> blocks, which
 247 execute at compile time).
 248
 249 =item *
 250
 251 The arguments are available via @ARGV, not $1, $2, etc.
 252
 253 =item *
 254
 255 The environment is not automatically made available as separate scalar
 256 variables.
 257
 258 =back
 259
 260 =head2 Perl Traps
 261
 262 Practicing Perl Programmers should take note of the following:
 263
 264 =over 4
 265
 266 =item *
 267
 268 Remember that many operations behave differently in a list
 269 context than they do in a scalar one.  See L<perldata> for details.
 270
 271 =item *
 272
 273 Avoid barewords if you can, especially all lowercase ones.
 274 You can't tell by just looking at it whether a bareword is
 275 a function or a string.  By using quotes on strings and
 276 parentheses on function calls, you won't ever get them confused.
 277
 278 =item *
 279
 280 You cannot discern from mere inspection which builtins
 281 are unary operators (like chop() and chdir())
 282 and which are list operators (like print() and unlink()).
 283 (Unless prototyped, user-defined subroutines can B<only> be list
 284 operators, never unary ones.)  See L<perlop> and L<perlsub>.
 285
 286 =item *
 287
 288 People have a hard time remembering that some functions
 289 default to $_, or @ARGV, or whatever, but that others which
 290 you might expect to do not.
 291
 292 =item *
 293
 294 The <FH> construct is not the name of the filehandle, it is a readline
 295 operation on that handle.  The data read is assigned to $_ only if the
 296 file read is the sole condition in a while loop:
 297
 298     while (<FH>)      { }
 299     while (defined($_ = <FH>)) { }..
 300     <FH>;  # data discarded!
 301
 302 =item *
 303
 304 Remember not to use C<=> when you need C<=~>;
 305 these two constructs are quite different:
 306
 307     $x =  /foo/;
 308     $x =~ /foo/;
 309
 310 =item *
 311
 312 The C<do {}> construct isn't a real loop that you can use
 313 loop control on.
 314
 315 =item *
 316
 317 Use C<my()> for local variables whenever you can get away with
 318 it (but see L<perlform> for where you can't).
 319 Using C<local()> actually gives a local value to a global
 320 variable, which leaves you open to unforeseen side-effects
 321 of dynamic scoping.
 322
 323 =item *
 324
 325 If you localize an exported variable in a module, its exported value will
 326 not change.  The local name becomes an alias to a new value but the
 327 external name is still an alias for the original.
 328
 329 =back
 330
 331 =head2 Perl4 to Perl5 Traps
 332
 333 Practicing Perl4 Programmers should take note of the following
 334 Perl4-to-Perl5 specific traps.
 335
 336 They're crudely ordered according to the following list:
 337
 338 =over 4
 339
 340 =item Discontinuance, Deprecation, and BugFix traps
 341
 342 Anything that's been fixed as a perl4 bug, removed as a perl4 feature
 343 or deprecated as a perl4 feature with the intent to encourage usage of
 344 some other perl5 feature.
 345
 346 =item Parsing Traps
 347
 348 Traps that appear to stem from the new parser.
 349
 350 =item Numerical Traps
 351
 352 Traps having to do with numerical or mathematical operators.
 353
 354 =item General data type traps
 355
 356 Traps involving perl standard data types.
 357
 358 =item Context Traps - scalar, list contexts
 359
 360 Traps related to context within lists, scalar statements/declarations.
 361
 362 =item Precedence Traps
 363
 364 Traps related to the precedence of parsing, evaluation, and execution of
 365 code.
 366
 367 =item General Regular Expression Traps using s///, etc.
 368
 369 Traps related to the use of pattern matching.
 370
 371 =item Subroutine, Signal, Sorting Traps
 372
 373 Traps related to the use of signals and signal handlers, general subroutines,
 374 and sorting, along with sorting subroutines.
 375
 376 =item OS Traps
 377
 378 OS-specific traps.
 379
 380 =item DBM Traps
 381
 382 Traps specific to the use of C<dbmopen()>, and specific dbm implementations.
 383
 384 =item Unclassified Traps
 385
 386 Everything else.
 387
 388 =back
 389
 390 If you find an example of a conversion trap that is not listed here,
 391 please submit it to <F<perlbug@perl.org>> for inclusion.
 392 Also note that at least some of these can be caught with the
 393 C<use warnings> pragma or the B<-w> switch.
 394
 395 =head2 Discontinuance, Deprecation, and BugFix traps
 396
 397 Anything that has been discontinued, deprecated, or fixed as
 398 a bug from perl4.
 399
 400 =over 4
 401
 402 =item * Discontinuance
 403
 404 Symbols starting with "_" are no longer forced into package main, except
 405 for C<$_> itself (and C<@_>, etc.).
 406
 407     package test;
 408     $_legacy = 1;
 409
 410     package main;
 411     print "\$_legacy is ",$_legacy,"\n";
 412
 413     # perl4 prints: $_legacy is 1
 414     # perl5 prints: $_legacy is
 415
 416 =item * Deprecation
 417
 418 Double-colon is now a valid package separator in a variable name.  Thus these
 419 behave differently in perl4 vs. perl5, because the packages don't exist.
 420
 421     $a=1;$b=2;$c=3;$var=4;
 422     print "$a::$b::$c ";
 423     print "$var::abc::xyz\n";
 424
 425     # perl4 prints: 1::2::3 4::abc::xyz
 426     # perl5 prints: 3
 427
 428 Given that C<::> is now the preferred package delimiter, it is debatable
 429 whether this should be classed as a bug or not.
 430 (The older package delimiter, ' ,is used here)
 431
 432     $x = 10 ;
 433     print "x=${'x}\n" ;
 434
 435     # perl4 prints: x=10
 436     # perl5 prints: Can't find string terminator "'" anywhere before EOF
 437
 438 You can avoid this problem, and remain compatible with perl4, if you
 439 always explicitly include the package name:
 440
 441     $x = 10 ;
 442     print "x=${main'x}\n" ;
 443
 444 Also see precedence traps, for parsing C<$:>.
 445
 446 =item * BugFix
 447
 448 The second and third arguments of C<splice()> are now evaluated in scalar
 449 context (as the Camel says) rather than list context.
 450
 451     sub sub1{return(0,2) }          # return a 2-element list
 452     sub sub2{ return(1,2,3)}        # return a 3-element list
 453     @a1 = ("a","b","c","d","e");
 454     @a2 = splice(@a1,&sub1,&sub2);
 455     print join(' ',@a2),"\n";
 456
 457     # perl4 prints: a b
 458     # perl5 prints: c d e
 459
 460 =item * Discontinuance
 461
 462 You can't do a C<goto> into a block that is optimized away.  Darn.
 463
 464     goto marker1;
 465
 466     for(1){
 467     marker1:
 468         print "Here I is!\n";
 469     }
 470
 471     # perl4 prints: Here I is!
 472     # perl5 errors: Can't "goto" into the middle of a foreach loop
 473
 474 =item * Discontinuance
 475
 476 It is no longer syntactically legal to use whitespace as the name
 477 of a variable, or as a delimiter for any kind of quote construct.
 478 Double darn.
 479
 480     $a = ("foo bar");
 481     $b = q baz ;
 482     print "a is $a, b is $b\n";
 483
 484     # perl4 prints: a is foo bar, b is baz
 485     # perl5 errors: Bareword found where operator expected
 486
 487 =item * Discontinuance
 488
 489 The archaic while/if BLOCK BLOCK syntax is no longer supported.
 490
 491     if { 1 } {
 492         print "True!";
 493     }
 494     else {
 495         print "False!";
 496     }
 497
 498     # perl4 prints: True!
 499     # perl5 errors: syntax error at test.pl line 1, near "if {"
 500
 501 =item * BugFix
 502
 503 The C<**> operator now binds more tightly than unary minus.
 504 It was documented to work this way before, but didn't.
 505
 506     print -4**2,"\n";
 507
 508     # perl4 prints: 16
 509     # perl5 prints: -16
 510
 511 =item * Discontinuance
 512
 513 The meaning of C<foreach{}> has changed slightly when it is iterating over a
 514 list which is not an array.  This used to assign the list to a
 515 temporary array, but no longer does so (for efficiency).  This means
 516 that you'll now be iterating over the actual values, not over copies of
 517 the values.  Modifications to the loop variable can change the original
 518 values.
 519
 520     @list = ('ab','abc','bcd','def');
 521     foreach $var (grep(/ab/,@list)){
 522         $var = 1;
 523     }
 524     print (join(':',@list));
 525
 526     # perl4 prints: ab:abc:bcd:def
 527     # perl5 prints: 1:1:bcd:def
 528
 529 To retain Perl4 semantics you need to assign your list
 530 explicitly to a temporary array and then iterate over that.  For
 531 example, you might need to change
 532
 533     foreach $var (grep(/ab/,@list)){
 534
 535 to
 536
 537     foreach $var (@tmp = grep(/ab/,@list)){
 538
 539 Otherwise changing $var will clobber the values of @list.  (This most often
 540 happens when you use C<$_> for the loop variable, and call subroutines in
 541 the loop that don't properly localize C<$_>.)
 542
 543 =item * Discontinuance
 544
 545 C<split> with no arguments now behaves like C<split ' '> (which doesn't
 546 return an initial null field if $_ starts with whitespace), it used to
 547 behave like C<split /\s+/> (which does).
 548
 549     $_ = ' hi mom';
 550     print join(':', split);
 551
 552     # perl4 prints: :hi:mom
 553     # perl5 prints: hi:mom
 554
 555 =item * BugFix
 556
 557 Perl 4 would ignore any text which was attached to an B<-e> switch,
 558 always taking the code snippet from the following arg.  Additionally, it
 559 would silently accept an B<-e> switch without a following arg.  Both of
 560 these behaviors have been fixed.
 561
 562     perl -e'print "attached to -e"' 'print "separate arg"'
 563
 564     # perl4 prints: separate arg
 565     # perl5 prints: attached to -e
 566
 567     perl -e
 568
 569     # perl4 prints:
 570     # perl5 dies: No code specified for -e.
 571
 572 =item * Discontinuance
 573
 574 In Perl 4 the return value of C<push> was undocumented, but it was
 575 actually the last value being pushed onto the target list.  In Perl 5
 576 the return value of C<push> is documented, but has changed, it is the
 577 number of elements in the resulting list.
 578
 579     @x = ('existing');
 580     print push(@x, 'first new', 'second new');
 581
 582     # perl4 prints: second new
 583     # perl5 prints: 3
 584
 585 =item * Deprecation
 586
 587 Some error messages will be different.
 588
 589 =item * Discontinuance
 590
 591 In Perl 4, if in list context the delimiters to the first argument of
 592 C<split()> were C<??>, the result would be placed in C<@_> as well as
 593 being returned.   Perl 5 has more respect for your subroutine arguments.
 594
 595 =item * Discontinuance
 596
 597 Some bugs may have been inadvertently removed.  :-)
 598
 599 =back
 600
 601 =head2 Parsing Traps
 602
 603 Perl4-to-Perl5 traps from having to do with parsing.
 604
 605 =over 4
 606
 607 =item * Parsing
 608
 609 Note the space between . and =
 610
 611     $string . = "more string";
 612     print $string;
 613
 614     # perl4 prints: more string
 615     # perl5 prints: syntax error at - line 1, near ". ="
 616
 617 =item * Parsing
 618
 619 Better parsing in perl 5
 620
 621     sub foo {}
 622     &foo
 623     print("hello, world\n");
 624
 625     # perl4 prints: hello, world
 626     # perl5 prints: syntax error
 627
 628 =item * Parsing
 629
 630 "if it looks like a function, it is a function" rule.
 631
 632   print
 633     ($foo == 1) ? "is one\n" : "is zero\n";
 634
 635     # perl4 prints: is zero
 636     # perl5 warns: "Useless use of a constant in void context" if using -w
 637
 638 =item * Parsing
 639
 640 String interpolation of the C<$#array> construct differs when braces
 641 are to used around the name.
 642
 643     @a = (1..3);
 644     print "${#a}";
 645
 646     # perl4 prints: 2
 647     # perl5 fails with syntax error
 648
 649     @ = (1..3);
 650     print "$#{a}";
 651
 652     # perl4 prints: {a}
 653     # perl5 prints: 2
 654
 655 =item * Parsing
 656
 657 When perl sees C<map {> (or C<grep {>), it has to guess whether the C<{>
 658 starts a BLOCK or a hash reference. If it guesses wrong, it will report
 659 a syntax error near the C<}> and the missing (or unexpected) comma.
 660
 661 Use unary C<+> before C<{> on a hash reference, and unary C<+> applied
 662 to the first thing in a BLOCK (after C<{>), for perl to guess right all
 663 the time. (See L<perlfunc/map>.)
 664
 665 =back
 666
 667 =head2 Numerical Traps
 668
 669 Perl4-to-Perl5 traps having to do with numerical operators,
 670 operands, or output from same.
 671
 672 =over 5
 673
 674 =item * Numerical
 675
 676 Formatted output and significant digits.  In general, Perl 5
 677 tries to be more precise.  For example, on a Solaris Sparc:
 678
 679     print 7.373504 - 0, "\n";
 680     printf "%20.18f\n", 7.373504 - 0;
 681
 682     # Perl4 prints:
 683     7.3750399999999996141
 684     7.375039999999999614
 685
 686     # Perl5 prints:
 687     7.373504
 688     7.375039999999999614
 689
 690 Notice how the first result looks better in Perl 5.
 691
 692 Your results may vary, since your floating point formatting routines
 693 and even floating point format may be slightly different.
 694
 695 =item * Numerical
 696
 697 This specific item has been deleted.  It demonstrated how the auto-increment
 698 operator would not catch when a number went over the signed int limit.  Fixed
 699 in version 5.003_04.  But always be wary when using large integers.
 700 If in doubt:
 701
 702    use Math::BigInt;
 703
 704 =item * Numerical
 705
 706 Assignment of return values from numeric equality tests
 707 does not work in perl5 when the test evaluates to false (0).
 708 Logical tests now return a null, instead of 0
 709
 710     $p = ($test == 1);
 711     print $p,"\n";
 712
 713     # perl4 prints: 0
 714     # perl5 prints:
 715
 716 Also see L<"General Regular Expression Traps using s///, etc.">
 717 for another example of this new feature...
 718
 719 =item * Bitwise string ops
 720
 721 When bitwise operators which can operate upon either numbers or
 722 strings (C<& | ^ ~>) are given only strings as arguments, perl4 would
 723 treat the operands as bitstrings so long as the program contained a call
 724 to the C<vec()> function. perl5 treats the string operands as bitstrings.
 725 (See L<perlop/Bitwise String Operators> for more details.)
 726
 727     $fred = "10";
 728     $barney = "12";
 729     $betty = $fred & $barney;
 730     print "$betty\n";
 731     # Uncomment the next line to change perl4's behavior
 732     # ($dummy) = vec("dummy", 0, 0);
 733
 734     # Perl4 prints:
 735     8
 736
 737     # Perl5 prints:
 738     10
 739
 740     # If vec() is used anywhere in the program, both print:
 741     10
 742
 743 =back
 744
 745 =head2 General data type traps
 746
 747 Perl4-to-Perl5 traps involving most data-types, and their usage
 748 within certain expressions and/or context.
 749
 750 =over 5
 751
 752 =item * (Arrays)
 753
 754 Negative array subscripts now count from the end of the array.
 755
 756     @a = (1, 2, 3, 4, 5);
 757     print "The third element of the array is $a[3] also expressed as $a[-2] \n";
 758
 759     # perl4 prints: The third element of the array is 4 also expressed as
 760     # perl5 prints: The third element of the array is 4 also expressed as 4
 761
 762 =item * (Arrays)
 763
 764 Setting C<$#array> lower now discards array elements, and makes them
 765 impossible to recover.
 766
 767     @a = (a,b,c,d,e);
 768     print "Before: ",join('',@a);
 769     $#a =1;
 770     print ", After: ",join('',@a);
 771     $#a =3;
 772     print ", Recovered: ",join('',@a),"\n";
 773
 774     # perl4 prints: Before: abcde, After: ab, Recovered: abcd
 775     # perl5 prints: Before: abcde, After: ab, Recovered: ab
 776
 777 =item * (Hashes)
 778
 779 Hashes get defined before use
 780
 781     local($s,@a,%h);
 782     die "scalar \$s defined" if defined($s);
 783     die "array \@a defined" if defined(@a);
 784     die "hash \%h defined" if defined(%h);
 785
 786     # perl4 prints:
 787     # perl5 dies: hash %h defined
 788
 789 Perl will now generate a warning when it sees defined(@a) and
 790 defined(%h).
 791
 792 =item * (Globs)
 793
 794 glob assignment from variable to variable will fail if the assigned
 795 variable is localized subsequent to the assignment
 796
 797     @a = ("This is Perl 4");
 798     *b = *a;
 799     local(@a);
 800     print @b,"\n";
 801
 802     # perl4 prints: This is Perl 4
 803     # perl5 prints:
 804
 805 =item * (Globs)
 806
 807 Assigning C<undef> to a glob has no effect in Perl 5.   In Perl 4
 808 it undefines the associated scalar (but may have other side effects
 809 including SEGVs). Perl 5 will also warn if C<undef> is assigned to a
 810 typeglob. (Note that assigning C<undef> to a typeglob is different
 811 than calling the C<undef> function on a typeglob (C<undef *foo>), which
 812 has quite a few effects.
 813
 814     $foo = "bar";
 815     *foo = undef;
 816     print $foo;
 817
 818     # perl4 prints:
 819     # perl4 warns: "Use of uninitialized variable" if using -w
 820     # perl5 prints: bar
 821     # perl5 warns: "Undefined value assigned to typeglob" if using -w
 822
 823 =item * (Scalar String)
 824
 825 Changes in unary negation (of strings)
 826 This change effects both the return value and what it
 827 does to auto(magic)increment.
 828
 829     $x = "aaa";
 830     print ++$x," : ";
 831     print -$x," : ";
 832     print ++$x,"\n";
 833
 834     # perl4 prints: aab : -0 : 1
 835     # perl5 prints: aab : -aab : aac
 836
 837 =item * (Constants)
 838
 839 perl 4 lets you modify constants:
 840
 841     $foo = "x";
 842     &mod($foo);
 843     for ($x = 0; $x < 3; $x++) {
 844         &mod("a");
 845     }
 846     sub mod {
 847         print "before: $_[0]";
 848         $_[0] = "m";
 849         print "  after: $_[0]\n";
 850     }
 851
 852     # perl4:
 853     # before: x  after: m
 854     # before: a  after: m
 855     # before: m  after: m
 856     # before: m  after: m
 857
 858     # Perl5:
 859     # before: x  after: m
 860     # Modification of a read-only value attempted at foo.pl line 12.
 861     # before: a
 862
 863 =item * (Scalars)
 864
 865 The behavior is slightly different for:
 866
 867     print "$x", defined $x
 868
 869     # perl 4: 1
 870     # perl 5: <no output, $x is not called into existence>
 871
 872 =item * (Variable Suicide)
 873
 874 Variable suicide behavior is more consistent under Perl 5.
 875 Perl5 exhibits the same behavior for hashes and scalars,
 876 that perl4 exhibits for only scalars.
 877
 878     $aGlobal{ "aKey" } = "global value";
 879     print "MAIN:", $aGlobal{"aKey"}, "\n";
 880     $GlobalLevel = 0;
 881     &test( *aGlobal );
 882
 883     sub test {
 884         local( *theArgument ) = @_;
 885         local( %aNewLocal ); # perl 4 != 5.001l,m
 886         $aNewLocal{"aKey"} = "this should never appear";
 887         print "SUB: ", $theArgument{"aKey"}, "\n";
 888         $aNewLocal{"aKey"} = "level $GlobalLevel";   # what should print
 889         $GlobalLevel++;
 890         if( $GlobalLevel<4 ) {
 891             &test( *aNewLocal );
 892         }
 893     }
 894
 895     # Perl4:
 896     # MAIN:global value
 897     # SUB: global value
 898     # SUB: level 0
 899     # SUB: level 1
 900     # SUB: level 2
 901
 902     # Perl5:
 903     # MAIN:global value
 904     # SUB: global value
 905     # SUB: this should never appear
 906     # SUB: this should never appear
 907     # SUB: this should never appear
 908
 909 =back
 910
 911 =head2 Context Traps - scalar, list contexts
 912
 913 =over 5
 914
 915 =item * (list context)
 916
 917 The elements of argument lists for formats are now evaluated in list
 918 context.  This means you can interpolate list values now.
 919
 920     @fmt = ("foo","bar","baz");
 921     format STDOUT=
 922     @<<<<< @||||| @>>>>>
 923     @fmt;
 924     .
 925     write;
 926
 927     # perl4 errors:  Please use commas to separate fields in file
 928     # perl5 prints: foo     bar      baz
 929
 930 =item * (scalar context)
 931
 932 The C<caller()> function now returns a false value in a scalar context
 933 if there is no caller.  This lets library files determine if they're
 934 being required.
 935
 936     caller() ? (print "You rang?\n") : (print "Got a 0\n");
 937
 938     # perl4 errors: There is no caller
 939     # perl5 prints: Got a 0
 940
 941 =item * (scalar context)
 942
 943 The comma operator in a scalar context is now guaranteed to give a
 944 scalar context to its arguments.
 945
 946     @y= ('a','b','c');
 947     $x = (1, 2, @y);
 948     print "x = $x\n";
 949
 950     # Perl4 prints:  x = c   # Thinks list context interpolates list
 951     # Perl5 prints:  x = 3   # Knows scalar uses length of list
 952
 953 =item * (list, builtin)
 954
 955 C<sprintf()> is prototyped as ($;@), so its first argument is given scalar
 956 context. Thus, if passed an array, it will probably not do what you want,
 957 unlike Perl 4:
 958
 959     @z = ('%s%s', 'foo', 'bar');
 960     $x = sprintf(@z);
 961     print $x;
 962
 963     # perl4 prints: foobar
 964     # perl5 prints: 3
 965
 966 C<printf()> works the same as it did in Perl 4, though:
 967
 968     @z = ('%s%s', 'foo', 'bar');
 969     printf STDOUT (@z);
 970
 971     # perl4 prints: foobar
 972     # perl5 prints: foobar
 973
 974 =back
 975
 976 =head2 Precedence Traps
 977
 978 Perl4-to-Perl5 traps involving precedence order.
 979
 980 Perl 4 has almost the same precedence rules as Perl 5 for the operators
 981 that they both have.  Perl 4 however, seems to have had some
 982 inconsistencies that made the behavior differ from what was documented.
 983
 984 =over 5
 985
 986 =item * Precedence
 987
 988 LHS vs. RHS of any assignment operator.  LHS is evaluated first
 989 in perl4, second in perl5; this can affect the relationship
 990 between side-effects in sub-expressions.
 991
 992     @arr = ( 'left', 'right' );
 993     $a{shift @arr} = shift @arr;
 994     print join( ' ', keys %a );
 995
 996     # perl4 prints: left
 997     # perl5 prints: right
 998
 999 =item * Precedence
1000
1001 These are now semantic errors because of precedence:
1002
1003     @list = (1,2,3,4,5);
1004     %map = ("a",1,"b",2,"c",3,"d",4);
1005     $n = shift @list + 2;   # first item in list plus 2
1006     print "n is $n, ";
1007     $m = keys %map + 2;     # number of items in hash plus 2
1008     print "m is $m\n";
1009
1010     # perl4 prints: n is 3, m is 6
1011     # perl5 errors and fails to compile
1012
1013 =item * Precedence
1014
1015 The precedence of assignment operators is now the same as the precedence
1016 of assignment.  Perl 4 mistakenly gave them the precedence of the associated
1017 operator.  So you now must parenthesize them in expressions like
1018
1019     /foo/ ? ($a += 2) : ($a -= 2);
1020
1021 Otherwise
1022
1023     /foo/ ? $a += 2 : $a -= 2
1024
1025 would be erroneously parsed as
1026
1027     (/foo/ ? $a += 2 : $a) -= 2;
1028
1029 On the other hand,
1030
1031     $a += /foo/ ? 1 : 2;
1032
1033 now works as a C programmer would expect.
1034
1035 =item * Precedence
1036
1037     open FOO || die;
1038
1039 is now incorrect.  You need parentheses around the filehandle.
1040 Otherwise, perl5 leaves the statement as its default precedence:
1041
1042     open(FOO || die);
1043
1044     # perl4 opens or dies
1045     # perl5 opens FOO, dying only if 'FOO' is false, i.e. never
1046
1047 =item * Precedence
1048
1049 perl4 gives the special variable, C<$:> precedence, where perl5
1050 treats C<$::> as main C<package>
1051
1052     $a = "x"; print "$::a";
1053
1054     # perl 4 prints: -:a
1055     # perl 5 prints: x
1056
1057 =item * Precedence
1058
1059 perl4 had buggy precedence for the file test operators vis-a-vis
1060 the assignment operators.  Thus, although the precedence table
1061 for perl4 leads one to believe C<-e $foo .= "q"> should parse as
1062 C<((-e $foo) .= "q")>, it actually parses as C<(-e ($foo .= "q"))>.
1063 In perl5, the precedence is as documented.
1064
1065     -e $foo .= "q"
1066
1067     # perl4 prints: no output
1068     # perl5 prints: Can't modify -e in concatenation
1069
1070 =item * Precedence
1071
1072 In perl4, keys(), each() and values() were special high-precedence operators
1073 that operated on a single hash, but in perl5, they are regular named unary
1074 operators.  As documented, named unary operators have lower precedence
1075 than the arithmetic and concatenation operators C<+ - .>, but the perl4
1076 variants of these operators actually bind tighter than C<+ - .>.
1077 Thus, for:
1078
1079     %foo = 1..10;
1080     print keys %foo - 1
1081
1082     # perl4 prints: 4
1083     # perl5 prints: Type of arg 1 to keys must be hash (not subtraction)
1084
1085 The perl4 behavior was probably more useful, if less consistent.
1086
1087 =back
1088
1089 =head2 General Regular Expression Traps using s///, etc.
1090
1091 All types of RE traps.
1092
1093 =over 5
1094
1095 =item * Regular Expression
1096
1097 C<s'$lhs'$rhs'> now does no interpolation on either side.  It used to
1098 interpolate $lhs but not $rhs.  (And still does not match a literal
1099 '$' in string)
1100
1101     $a=1;$b=2;
1102     $string = '1 2 $a $b';
1103     $string =~ s'$a'$b';
1104     print $string,"\n";
1105
1106     # perl4 prints: $b 2 $a $b
1107     # perl5 prints: 1 2 $a $b
1108
1109 =item * Regular Expression
1110
1111 C<m//g> now attaches its state to the searched string rather than the
1112 regular expression.  (Once the scope of a block is left for the sub, the
1113 state of the searched string is lost)
1114
1115     $_ = "ababab";
1116     while(m/ab/g){
1117         &doit("blah");
1118     }
1119     sub doit{local($_) = shift; print "Got $_ "}
1120
1121     # perl4 prints: Got blah Got blah Got blah Got blah
1122     # perl5 prints: infinite loop blah...
1123
1124 =item * Regular Expression
1125
1126 Currently, if you use the C<m//o> qualifier on a regular expression
1127 within an anonymous sub, I<all> closures generated from that anonymous
1128 sub will use the regular expression as it was compiled when it was used
1129 the very first time in any such closure.  For instance, if you say
1130
1131     sub build_match {
1132         my($left,$right) = @_;
1133         return sub { $_[0] =~ /$left stuff $right/o; };
1134     }
1135     $good = build_match('foo','bar');
1136     $bad = build_match('baz','blarch');
1137     print $good->('foo stuff bar') ? "ok\n" : "not ok\n";
1138     print $bad->('baz stuff blarch') ? "ok\n" : "not ok\n";
1139     print $bad->('foo stuff bar') ? "not ok\n" : "ok\n";
1140
1141 For most builds of Perl5, this will print:
1142 ok
1143 not ok
1144 not ok
1145
1146 build_match() will always return a sub which matches the contents of
1147 $left and $right as they were the I<first> time that build_match()
1148 was called, not as they are in the current call.
1149
1150 =item * Regular Expression
1151
1152 If no parentheses are used in a match, Perl4 sets C<$+> to
1153 the whole match, just like C<$&>. Perl5 does not.
1154
1155     "abcdef" =~ /b.*e/;
1156     print "\$+ = $+\n";
1157
1158     # perl4 prints: bcde
1159     # perl5 prints:
1160
1161 =item * Regular Expression
1162
1163 substitution now returns the null string if it fails
1164
1165     $string = "test";
1166     $value = ($string =~ s/foo//);
1167     print $value, "\n";
1168
1169     # perl4 prints: 0
1170     # perl5 prints:
1171
1172 Also see L<Numerical Traps> for another example of this new feature.
1173
1174 =item * Regular Expression
1175
1176 C<s`lhs`rhs`> (using backticks) is now a normal substitution, with no
1177 backtick expansion
1178
1179     $string = "";
1180     $string =~ s`^`hostname`;
1181     print $string, "\n";
1182
1183     # perl4 prints: <the local hostname>
1184     # perl5 prints: hostname
1185
1186 =item * Regular Expression
1187
1188 Stricter parsing of variables used in regular expressions
1189
1190     s/^([^$grpc]*$grpc[$opt$plus$rep]?)//o;
1191
1192     # perl4: compiles w/o error
1193     # perl5: with Scalar found where operator expected ..., near "$opt$plus"
1194
1195 an added component of this example, apparently from the same script, is
1196 the actual value of the s'd string after the substitution.
1197 C<[$opt]> is a character class in perl4 and an array subscript in perl5
1198
1199     $grpc = 'a';
1200     $opt  = 'r';
1201     $_ = 'bar';
1202     s/^([^$grpc]*$grpc[$opt]?)/foo/;
1203     print ;
1204
1205     # perl4 prints: foo
1206     # perl5 prints: foobar
1207
1208 =item * Regular Expression
1209
1210 Under perl5, C<m?x?> matches only once, like C<?x?>. Under perl4, it matched
1211 repeatedly, like C</x/> or C<m!x!>.
1212
1213     $test = "once";
1214     sub match { $test =~ m?once?; }
1215     &match();
1216     if( &match() ) {
1217         # m?x? matches more then once
1218         print "perl4\n";
1219     } else {
1220         # m?x? matches only once
1221         print "perl5\n";
1222     }
1223
1224     # perl4 prints: perl4
1225     # perl5 prints: perl5
1226
1227 =item * Regular Expression
1228
1229 Unlike in Ruby, failed matches in Perl do not reset the match variables
1230 ($1, $2, ..., C<$`>, ...).
1231
1232 =back
1233
1234 =head2 Subroutine, Signal, Sorting Traps
1235
1236 The general group of Perl4-to-Perl5 traps having to do with
1237 Signals, Sorting, and their related subroutines, as well as
1238 general subroutine traps.  Includes some OS-Specific traps.
1239
1240 =over 5
1241
1242 =item * (Signals)
1243
1244 Barewords that used to look like strings to Perl will now look like subroutine
1245 calls if a subroutine by that name is defined before the compiler sees them.
1246
1247     sub SeeYa { warn"Hasta la vista, baby!" }
1248     $SIG{'TERM'} = SeeYa;
1249     print "SIGTERM is now $SIG{'TERM'}\n";
1250
1251     # perl4 prints: SIGTERM is now main'SeeYa
1252     # perl5 prints: SIGTERM is now main::1 (and warns "Hasta la vista, baby!")
1253
1254 Use B<-w> to catch this one
1255
1256 =item * (Sort Subroutine)
1257
1258 reverse is no longer allowed as the name of a sort subroutine.
1259
1260     sub reverse{ print "yup "; $a <=> $b }
1261     print sort reverse (2,1,3);
1262
1263     # perl4 prints: yup yup 123
1264     # perl5 prints: 123
1265     # perl5 warns (if using -w): Ambiguous call resolved as CORE::reverse()
1266
1267 =item * warn() won't let you specify a filehandle.
1268
1269 Although it _always_ printed to STDERR, warn() would let you specify a
1270 filehandle in perl4.  With perl5 it does not.
1271
1272     warn STDERR "Foo!";
1273
1274     # perl4 prints: Foo!
1275     # perl5 prints: String found where operator expected
1276
1277 =back
1278
1279 =head2 OS Traps
1280
1281 =over 5
1282
1283 =item * (SysV)
1284
1285 Under HPUX, and some other SysV OSes, one had to reset any signal handler,
1286 within  the signal handler function, each time a signal was handled with
1287 perl4.  With perl5, the reset is now done correctly.  Any code relying
1288 on the handler _not_ being reset will have to be reworked.
1289
1290 Since version 5.002, Perl uses sigaction() under SysV.
1291
1292     sub gotit {
1293         print "Got @_... ";
1294     }
1295     $SIG{'INT'} = 'gotit';
1296
1297     $| = 1;
1298     $pid = fork;
1299     if ($pid) {
1300         kill('INT', $pid);
1301         sleep(1);
1302         kill('INT', $pid);
1303     } else {
1304         while (1) {sleep(10);}
1305     }
1306
1307     # perl4 (HPUX) prints: Got INT...
1308     # perl5 (HPUX) prints: Got INT... Got INT...
1309
1310 =item * (SysV)
1311
1312 Under SysV OSes, C<seek()> on a file opened to append C<<< >> >>> now does
1313 the right thing w.r.t. the fopen() manpage. e.g., - When a file is opened
1314 for append,  it  is  impossible to overwrite information already in
1315 the file.
1316
1317     open(TEST,">>seek.test");
1318     $start = tell TEST ;
1319     foreach(1 .. 9){
1320         print TEST "$_ ";
1321     }
1322     $end = tell TEST ;
1323     seek(TEST,$start,0);
1324     print TEST "18 characters here";
1325
1326     # perl4 (solaris) seek.test has: 18 characters here
1327     # perl5 (solaris) seek.test has: 1 2 3 4 5 6 7 8 9 18 characters here
1328
1329
1330
1331 =back
1332
1333 =head2 Interpolation Traps
1334
1335 Perl4-to-Perl5 traps having to do with how things get interpolated
1336 within certain expressions, statements, contexts, or whatever.
1337
1338 =over 5
1339
1340 =item * Interpolation
1341
1342 @ now always interpolates an array in double-quotish strings.
1343
1344     print "To: someone@somewhere.com\n";
1345
1346     # perl4 prints: To:someone@somewhere.com
1347     # perl < 5.6.1, error : In string, @somewhere now must be written as \@somewhere
1348     # perl >= 5.6.1, warning : Possible unintended interpolation of @somewhere in string
1349
1350 =item * Interpolation
1351
1352 Double-quoted strings may no longer end with an unescaped $.
1353
1354     $foo = "foo$";
1355     print "foo is $foo\n";
1356
1357     # perl4 prints: foo is foo$
1358     # perl5 errors: Final $ should be \$ or $name
1359
1360 Note: perl5 DOES NOT error on the terminating @ in $bar
1361
1362 =item * Interpolation
1363
1364 Perl now sometimes evaluates arbitrary expressions inside braces that occur
1365 within double quotes (usually when the opening brace is preceded by C<$>
1366 or C<@>).
1367
1368     @www = "buz";
1369     $foo = "foo";
1370     $bar = "bar";
1371     sub foo { return "bar" };
1372     print "|@{w.w.w}|${main'foo}|";
1373
1374     # perl4 prints: |@{w.w.w}|foo|
1375     # perl5 prints: |buz|bar|
1376
1377 Note that you can C<use strict;> to ward off such trappiness under perl5.
1378
1379 =item * Interpolation
1380
1381 The construct "this is $$x" used to interpolate the pid at that point, but
1382 now tries to dereference $x.  C<$$> by itself still works fine, however.
1383
1384     $s = "a reference";
1385     $x = *s;
1386     print "this is $$x\n";
1387
1388     # perl4 prints: this is XXXx   (XXX is the current pid)
1389     # perl5 prints: this is a reference
1390
1391 =item * Interpolation
1392
1393 Creation of hashes on the fly with C<eval "EXPR"> now requires either both
1394 C<$>'s to be protected in the specification of the hash name, or both curlies
1395 to be protected.  If both curlies are protected, the result will be compatible
1396 with perl4 and perl5.  This is a very common practice, and should be changed
1397 to use the block form of C<eval{}>  if possible.
1398
1399     $hashname = "foobar";
1400     $key = "baz";
1401     $value = 1234;
1402     eval "\$$hashname{'$key'} = q|$value|";
1403     (defined($foobar{'baz'})) ?  (print "Yup") : (print "Nope");
1404
1405     # perl4 prints: Yup
1406     # perl5 prints: Nope
1407
1408 Changing
1409
1410     eval "\$$hashname{'$key'} = q|$value|";
1411
1412 to
1413
1414     eval "\$\$hashname{'$key'} = q|$value|";
1415
1416 causes the following result:
1417
1418     # perl4 prints: Nope
1419     # perl5 prints: Yup
1420
1421 or, changing to
1422
1423     eval "\$$hashname\{'$key'\} = q|$value|";
1424
1425 causes the following result:
1426
1427     # perl4 prints: Yup
1428     # perl5 prints: Yup
1429     # and is compatible for both versions
1430
1431
1432 =item * Interpolation
1433
1434 perl4 programs which unconsciously rely on the bugs in earlier perl versions.
1435
1436     perl -e '$bar=q/not/; print "This is $foo{$bar} perl5"'
1437
1438     # perl4 prints: This is not perl5
1439     # perl5 prints: This is perl5
1440
1441 =item * Interpolation
1442
1443 You also have to be careful about array and hash brackets during
1444 interpolation.
1445
1446     print "$foo["
1447
1448     perl 4 prints: [
1449     perl 5 prints: syntax error
1450
1451     print "$foo{"
1452
1453     perl 4 prints: {
1454     perl 5 prints: syntax error
1455
1456 Perl 5 is expecting to find an index or key name following the respective
1457 brackets, as well as an ending bracket of the appropriate type.  In order
1458 to mimic the behavior of Perl 4, you must escape the bracket like so.
1459
1460     print "$foo\[";
1461     print "$foo\{";
1462
1463 =item * Interpolation
1464
1465 Similarly, watch out for:
1466
1467     $foo = "baz";
1468     print "\$$foo{bar}\n";
1469
1470     # perl4 prints: $baz{bar}
1471     # perl5 prints: $
1472
1473 Perl 5 is looking for C<$foo{bar}> which doesn't exist, but perl 4 is
1474 happy just to expand $foo to "baz" by itself.  Watch out for this
1475 especially in C<eval>'s.
1476
1477 =item * Interpolation
1478
1479 C<qq()> string passed to C<eval>
1480
1481     eval qq(
1482         foreach \$y (keys %\$x\) {
1483             \$count++;
1484         }
1485     );
1486
1487     # perl4 runs this ok
1488     # perl5 prints: Can't find string terminator ")"
1489
1490 =back
1491
1492 =head2 DBM Traps
1493
1494 General DBM traps.
1495
1496 =over 5
1497
1498 =item * DBM
1499
1500 Existing dbm databases created under perl4 (or any other dbm/ndbm tool)
1501 may cause the same script, run under perl5, to fail.  The build of perl5
1502 must have been linked with the same dbm/ndbm as the default for C<dbmopen()>
1503 to function properly without C<tie>'ing to an extension dbm implementation.
1504
1505     dbmopen (%dbm, "file", undef);
1506     print "ok\n";
1507
1508     # perl4 prints: ok
1509     # perl5 prints: ok (IFF linked with -ldbm or -lndbm)
1510
1511
1512 =item * DBM
1513
1514 Existing dbm databases created under perl4 (or any other dbm/ndbm tool)
1515 may cause the same script, run under perl5, to fail.  The error generated
1516 when exceeding the limit on the key/value size will cause perl5 to exit
1517 immediately.
1518
1519     dbmopen(DB, "testdb",0600) || die "couldn't open db! $!";
1520     $DB{'trap'} = "x" x 1024;  # value too large for most dbm/ndbm
1521     print "YUP\n";
1522
1523     # perl4 prints:
1524     dbm store returned -1, errno 28, key "trap" at - line 3.
1525     YUP
1526
1527     # perl5 prints:
1528     dbm store returned -1, errno 28, key "trap" at - line 3.
1529
1530 =back
1531
1532 =head2 Unclassified Traps
1533
1534 Everything else.
1535
1536 =over 5
1537
1538 =item * C<require>/C<do> trap using returned value
1539
1540 If the file doit.pl has:
1541
1542     sub foo {
1543         $rc = do "./do.pl";
1544         return 8;
1545     }
1546     print &foo, "\n";
1547
1548 And the do.pl file has the following single line:
1549
1550     return 3;
1551
1552 Running doit.pl gives the following:
1553
1554     # perl 4 prints: 3 (aborts the subroutine early)
1555     # perl 5 prints: 8
1556
1557 Same behavior if you replace C<do> with C<require>.
1558
1559 =item * C<split> on empty string with LIMIT specified
1560
1561     $string = '';
1562     @list = split(/foo/, $string, 2)
1563
1564 Perl4 returns a one element list containing the empty string but Perl5
1565 returns an empty list.
1566
1567 =back
1568
1569 As always, if any of these are ever officially declared as bugs,
1570 they'll be fixed and removed.
1571