pod/perltrap.pod

   1 =head1 NAME
   2
   3 perltrap - Perl traps for the unwary
   4
   5 =head1 DESCRIPTION
   6
   7 The biggest trap of all is forgetting to use the B<-w> switch; see
   8 L<perlrun>.  The second biggest trap is not making your entire program
   9 runnable under C<use strict>.  The third biggest trap is not reading
  10 the list of changes in this version of Perl; see L<perldelta>.
  11
  12 =head2 Awk Traps
  13
  14 Accustomed B<awk> users should take special note of the following:
  15
  16 =over 4
  17
  18 =item *
  19
  20 The English module, loaded via
  21
  22     use English;
  23
  24 allows you to refer to special variables (like C<$/>) with names (like
  25 $RS), as though they were in B<awk>; see L<perlvar> for details.
  26
  27 =item *
  28
  29 Semicolons are required after all simple statements in Perl (except
  30 at the end of a block).  Newline is not a statement delimiter.
  31
  32 =item *
  33
  34 Curly brackets are required on C<if>s and C<while>s.
  35
  36 =item *
  37
  38 Variables begin with "$", "@" or "%" in Perl.
  39
  40 =item *
  41
  42 Arrays index from 0.  Likewise string positions in substr() and
  43 index().
  44
  45 =item *
  46
  47 You have to decide whether your array has numeric or string indices.
  48
  49 =item *
  50
  51 Hash values do not spring into existence upon mere reference.
  52
  53 =item *
  54
  55 You have to decide whether you want to use string or numeric
  56 comparisons.
  57
  58 =item *
  59
  60 Reading an input line does not split it for you.  You get to split it
  61 to an array yourself.  And the split() operator has different
  62 arguments than B<awk>'s.
  63
  64 =item *
  65
  66 The current input line is normally in $_, not $0.  It generally does
  67 not have the newline stripped.  ($0 is the name of the program
  68 executed.)  See L<perlvar>.
  69
  70 =item *
  71
  72 $<I<digit>> does not refer to fields--it refers to substrings matched
  73 by the last match pattern.
  74
  75 =item *
  76
  77 The print() statement does not add field and record separators unless
  78 you set C<$,> and C<$\>.  You can set $OFS and $ORS if you're using
  79 the English module.
  80
  81 =item *
  82
  83 You must open your files before you print to them.
  84
  85 =item *
  86
  87 The range operator is "..", not comma.  The comma operator works as in
  88 C.
  89
  90 =item *
  91
  92 The match operator is "=~", not "~".  ("~" is the one's complement
  93 operator, as in C.)
  94
  95 =item *
  96
  97 The exponentiation operator is "**", not "^".  "^" is the XOR
  98 operator, as in C.  (You know, one could get the feeling that B<awk> is
  99 basically incompatible with C.)
 100
 101 =item *
 102
 103 The concatenation operator is ".", not the null string.  (Using the
 104 null string would render C</pat/ /pat/> unparsable, because the third slash
 105 would be interpreted as a division operator--the tokenizer is in fact
 106 slightly context sensitive for operators like "/", "?", and ">".
 107 And in fact, "." itself can be the beginning of a number.)
 108
 109 =item *
 110
 111 The C<next>, C<exit>, and C<continue> keywords work differently.
 112
 113 =item *
 114
 115
 116 The following variables work differently:
 117
 118       Awk       Perl
 119       ARGC      $#ARGV or scalar @ARGV
 120       ARGV[0]   $0
 121       FILENAME  $ARGV
 122       FNR       $. - something
 123       FS        (whatever you like)
 124       NF        $#Fld, or some such
 125       NR        $.
 126       OFMT      $#
 127       OFS       $,
 128       ORS       $\
 129       RLENGTH   length($&)
 130       RS        $/
 131       RSTART    length($`)
 132       SUBSEP    $;
 133
 134 =item *
 135
 136 You cannot set $RS to a pattern, only a string.
 137
 138 =item *
 139
 140 When in doubt, run the B<awk> construct through B<a2p> and see what it
 141 gives you.
 142
 143 =back
 144
 145 =head2 C Traps
 146
 147 Cerebral C programmers should take note of the following:
 148
 149 =over 4
 150
 151 =item *
 152
 153 Curly brackets are required on C<if>'s and C<while>'s.
 154
 155 =item *
 156
 157 You must use C<elsif> rather than C<else if>.
 158
 159 =item *
 160
 161 The C<break> and C<continue> keywords from C become in
 162 Perl C<last> and C<next>, respectively.
 163 Unlike in C, these do I<not> work within a C<do { } while> construct.
 164
 165 =item *
 166
 167 There's no switch statement.  (But it's easy to build one on the fly.)
 168
 169 =item *
 170
 171 Variables begin with "$", "@" or "%" in Perl.
 172
 173 =item *
 174
 175 C<printf()> does not implement the "*" format for interpolating
 176 field widths, but it's trivial to use interpolation of double-quoted
 177 strings to achieve the same effect.
 178
 179 =item *
 180
 181 Comments begin with "#", not "/*".
 182
 183 =item *
 184
 185 You can't take the address of anything, although a similar operator
 186 in Perl is the backslash, which creates a reference.
 187
 188 =item *
 189
 190 C<ARGV> must be capitalized.  C<$ARGV[0]> is C's C<argv[1]>, and C<argv[0]>
 191 ends up in C<$0>.
 192
 193 =item *
 194
 195 System calls such as link(), unlink(), rename(), etc. return nonzero for
 196 success, not 0.
 197
 198 =item *
 199
 200 Signal handlers deal with signal names, not numbers.  Use C<kill -l>
 201 to find their names on your system.
 202
 203 =back
 204
 205 =head2 Sed Traps
 206
 207 Seasoned B<sed> programmers should take note of the following:
 208
 209 =over 4
 210
 211 =item *
 212
 213 Backreferences in substitutions use "$" rather than "\".
 214
 215 =item *
 216
 217 The pattern matching metacharacters "(", ")", and "|" do not have backslashes
 218 in front.
 219
 220 =item *
 221
 222 The range operator is C<...>, rather than comma.
 223
 224 =back
 225
 226 =head2 Shell Traps
 227
 228 Sharp shell programmers should take note of the following:
 229
 230 =over 4
 231
 232 =item *
 233
 234 The backtick operator does variable interpolation without regard to
 235 the presence of single quotes in the command.
 236
 237 =item *
 238
 239 The backtick operator does no translation of the return value, unlike B<csh>.
 240
 241 =item *
 242
 243 Shells (especially B<csh>) do several levels of substitution on each
 244 command line.  Perl does substitution in only certain constructs
 245 such as double quotes, backticks, angle brackets, and search patterns.
 246
 247 =item *
 248
 249 Shells interpret scripts a little bit at a time.  Perl compiles the
 250 entire program before executing it (except for C<BEGIN> blocks, which
 251 execute at compile time).
 252
 253 =item *
 254
 255 The arguments are available via @ARGV, not $1, $2, etc.
 256
 257 =item *
 258
 259 The environment is not automatically made available as separate scalar
 260 variables.
 261
 262 =back
 263
 264 =head2 Perl Traps
 265
 266 Practicing Perl Programmers should take note of the following:
 267
 268 =over 4
 269
 270 =item *
 271
 272 Remember that many operations behave differently in a list
 273 context than they do in a scalar one.  See L<perldata> for details.
 274
 275 =item *
 276
 277 Avoid barewords if you can, especially all lowercase ones.
 278 You can't tell by just looking at it whether a bareword is
 279 a function or a string.  By using quotes on strings and
 280 parentheses on function calls, you won't ever get them confused.
 281
 282 =item *
 283
 284 You cannot discern from mere inspection which builtins
 285 are unary operators (like chop() and chdir())
 286 and which are list operators (like print() and unlink()).
 287 (User-defined subroutines can be B<only> list operators, never
 288 unary ones.)  See L<perlop>.
 289
 290 =item *
 291
 292 People have a hard time remembering that some functions
 293 default to $_, or @ARGV, or whatever, but that others which
 294 you might expect to do not.
 295
 296 =item *
 297
 298 The <FH> construct is not the name of the filehandle, it is a readline
 299 operation on that handle.  The data read is assigned to $_ only if the
 300 file read is the sole condition in a while loop:
 301
 302     while (<FH>)      { }
 303     while (defined($_ = <FH>)) { }..
 304     <FH>;  # data discarded!
 305
 306 =item *
 307
 308 Remember not to use C<=> when you need C<=~>;
 309 these two constructs are quite different:
 310
 311     $x =  /foo/;
 312     $x =~ /foo/;
 313
 314 =item *
 315
 316 The C<do {}> construct isn't a real loop that you can use
 317 loop control on.
 318
 319 =item *
 320
 321 Use C<my()> for local variables whenever you can get away with
 322 it (but see L<perlform> for where you can't).
 323 Using C<local()> actually gives a local value to a global
 324 variable, which leaves you open to unforeseen side-effects
 325 of dynamic scoping.
 326
 327 =item *
 328
 329 If you localize an exported variable in a module, its exported value will
 330 not change.  The local name becomes an alias to a new value but the
 331 external name is still an alias for the original.
 332
 333 =back
 334
 335 =head2 Perl4 to Perl5 Traps
 336
 337 Practicing Perl4 Programmers should take note of the following
 338 Perl4-to-Perl5 specific traps.
 339
 340 They're crudely ordered according to the following list:
 341
 342 =over 4
 343
 344 =item Discontinuance, Deprecation, and BugFix traps
 345
 346 Anything that's been fixed as a perl4 bug, removed as a perl4 feature
 347 or deprecated as a perl4 feature with the intent to encourage usage of
 348 some other perl5 feature.
 349
 350 =item Parsing Traps
 351
 352 Traps that appear to stem from the new parser.
 353
 354 =item Numerical Traps
 355
 356 Traps having to do with numerical or mathematical operators.
 357
 358 =item General data type traps
 359
 360 Traps involving perl standard data types.
 361
 362 =item Context Traps - scalar, list contexts
 363
 364 Traps related to context within lists, scalar statements/declarations.
 365
 366 =item Precedence Traps
 367
 368 Traps related to the precedence of parsing, evaluation, and execution of
 369 code.
 370
 371 =item General Regular Expression Traps using s///, etc.
 372
 373 Traps related to the use of pattern matching.
 374
 375 =item Subroutine, Signal, Sorting Traps
 376
 377 Traps related to the use of signals and signal handlers, general subroutines,
 378 and sorting, along with sorting subroutines.
 379
 380 =item OS Traps
 381
 382 OS-specific traps.
 383
 384 =item DBM Traps
 385
 386 Traps specific to the use of C<dbmopen()>, and specific dbm implementations.
 387
 388 =item Unclassified Traps
 389
 390 Everything else.
 391
 392 =back
 393
 394 If you find an example of a conversion trap that is not listed here,
 395 please submit it to Bill Middleton <F<wjm@best.com>> for inclusion.
 396 Also note that at least some of these can be caught with the
 397 C<use warnings> pragma or the B<-w> switch.
 398
 399 =head2 Discontinuance, Deprecation, and BugFix traps
 400
 401 Anything that has been discontinued, deprecated, or fixed as
 402 a bug from perl4.
 403
 404 =over 4
 405
 406 =item * Discontinuance
 407
 408 Symbols starting with "_" are no longer forced into package main, except
 409 for C<$_> itself (and C<@_>, etc.).
 410
 411     package test;
 412     $_legacy = 1;
 413
 414     package main;
 415     print "\$_legacy is ",$_legacy,"\n";
 416
 417     # perl4 prints: $_legacy is 1
 418     # perl5 prints: $_legacy is
 419
 420 =item * Deprecation
 421
 422 Double-colon is now a valid package separator in a variable name.  Thus these
 423 behave differently in perl4 vs. perl5, because the packages don't exist.
 424
 425     $a=1;$b=2;$c=3;$var=4;
 426     print "$a::$b::$c ";
 427     print "$var::abc::xyz\n";
 428
 429     # perl4 prints: 1::2::3 4::abc::xyz
 430     # perl5 prints: 3
 431
 432 Given that C<::> is now the preferred package delimiter, it is debatable
 433 whether this should be classed as a bug or not.
 434 (The older package delimiter, ' ,is used here)
 435
 436     $x = 10 ;
 437     print "x=${'x}\n" ;
 438
 439     # perl4 prints: x=10
 440     # perl5 prints: Can't find string terminator "'" anywhere before EOF
 441
 442 You can avoid this problem, and remain compatible with perl4, if you
 443 always explicitly include the package name:
 444
 445     $x = 10 ;
 446     print "x=${main'x}\n" ;
 447
 448 Also see precedence traps, for parsing C<$:>.
 449
 450 =item * BugFix
 451
 452 The second and third arguments of C<splice()> are now evaluated in scalar
 453 context (as the Camel says) rather than list context.
 454
 455     sub sub1{return(0,2) }          # return a 2-element list
 456     sub sub2{ return(1,2,3)}        # return a 3-element list
 457     @a1 = ("a","b","c","d","e");
 458     @a2 = splice(@a1,&sub1,&sub2);
 459     print join(' ',@a2),"\n";
 460
 461     # perl4 prints: a b
 462     # perl5 prints: c d e
 463
 464 =item * Discontinuance
 465
 466 You can't do a C<goto> into a block that is optimized away.  Darn.
 467
 468     goto marker1;
 469
 470     for(1){
 471     marker1:
 472         print "Here I is!\n";
 473     }
 474
 475     # perl4 prints: Here I is!
 476     # perl5 dumps core (SEGV)
 477
 478 =item * Discontinuance
 479
 480 It is no longer syntactically legal to use whitespace as the name
 481 of a variable, or as a delimiter for any kind of quote construct.
 482 Double darn.
 483
 484     $a = ("foo bar");
 485     $b = q baz ;
 486     print "a is $a, b is $b\n";
 487
 488     # perl4 prints: a is foo bar, b is baz
 489     # perl5 errors: Bareword found where operator expected
 490
 491 =item * Discontinuance
 492
 493 The archaic while/if BLOCK BLOCK syntax is no longer supported.
 494
 495     if { 1 } {
 496         print "True!";
 497     }
 498     else {
 499         print "False!";
 500     }
 501
 502     # perl4 prints: True!
 503     # perl5 errors: syntax error at test.pl line 1, near "if {"
 504
 505 =item * BugFix
 506
 507 The C<**> operator now binds more tightly than unary minus.
 508 It was documented to work this way before, but didn't.
 509
 510     print -4**2,"\n";
 511
 512     # perl4 prints: 16
 513     # perl5 prints: -16
 514
 515 =item * Discontinuance
 516
 517 The meaning of C<foreach{}> has changed slightly when it is iterating over a
 518 list which is not an array.  This used to assign the list to a
 519 temporary array, but no longer does so (for efficiency).  This means
 520 that you'll now be iterating over the actual values, not over copies of
 521 the values.  Modifications to the loop variable can change the original
 522 values.
 523
 524     @list = ('ab','abc','bcd','def');
 525     foreach $var (grep(/ab/,@list)){
 526         $var = 1;
 527     }
 528     print (join(':',@list));
 529
 530     # perl4 prints: ab:abc:bcd:def
 531     # perl5 prints: 1:1:bcd:def
 532
 533 To retain Perl4 semantics you need to assign your list
 534 explicitly to a temporary array and then iterate over that.  For
 535 example, you might need to change
 536
 537     foreach $var (grep(/ab/,@list)){
 538
 539 to
 540
 541     foreach $var (@tmp = grep(/ab/,@list)){
 542
 543 Otherwise changing $var will clobber the values of @list.  (This most often
 544 happens when you use C<$_> for the loop variable, and call subroutines in
 545 the loop that don't properly localize C<$_>.)
 546
 547 =item * Discontinuance
 548
 549 C<split> with no arguments now behaves like C<split ' '> (which doesn't
 550 return an initial null field if $_ starts with whitespace), it used to
 551 behave like C<split /\s+/> (which does).
 552
 553     $_ = ' hi mom';
 554     print join(':', split);
 555
 556     # perl4 prints: :hi:mom
 557     # perl5 prints: hi:mom
 558
 559 =item * BugFix
 560
 561 Perl 4 would ignore any text which was attached to an B<-e> switch,
 562 always taking the code snippet from the following arg.  Additionally, it
 563 would silently accept an B<-e> switch without a following arg.  Both of
 564 these behaviors have been fixed.
 565
 566     perl -e'print "attached to -e"' 'print "separate arg"'
 567
 568     # perl4 prints: separate arg
 569     # perl5 prints: attached to -e
 570
 571     perl -e
 572
 573     # perl4 prints:
 574     # perl5 dies: No code specified for -e.
 575
 576 =item * Discontinuance
 577
 578 In Perl 4 the return value of C<push> was undocumented, but it was
 579 actually the last value being pushed onto the target list.  In Perl 5
 580 the return value of C<push> is documented, but has changed, it is the
 581 number of elements in the resulting list.
 582
 583     @x = ('existing');
 584     print push(@x, 'first new', 'second new');
 585
 586     # perl4 prints: second new
 587     # perl5 prints: 3
 588
 589 =item * Deprecation
 590
 591 Some error messages will be different.
 592
 593 =item * Discontinuance
 594
 595 Some bugs may have been inadvertently removed.  :-)
 596
 597 =back
 598
 599 =head2 Parsing Traps
 600
 601 Perl4-to-Perl5 traps from having to do with parsing.
 602
 603 =over 4
 604
 605 =item * Parsing
 606
 607 Note the space between . and =
 608
 609     $string . = "more string";
 610     print $string;
 611
 612     # perl4 prints: more string
 613     # perl5 prints: syntax error at - line 1, near ". ="
 614
 615 =item * Parsing
 616
 617 Better parsing in perl 5
 618
 619     sub foo {}
 620     &foo
 621     print("hello, world\n");
 622
 623     # perl4 prints: hello, world
 624     # perl5 prints: syntax error
 625
 626 =item * Parsing
 627
 628 "if it looks like a function, it is a function" rule.
 629
 630   print
 631     ($foo == 1) ? "is one\n" : "is zero\n";
 632
 633     # perl4 prints: is zero
 634     # perl5 warns: "Useless use of a constant in void context" if using -w
 635
 636 =item * Parsing
 637
 638 String interpolation of the C<$#array> construct differs when braces
 639 are to used around the name.
 640
 641     @ = (1..3);
 642     print "${#a}";
 643
 644     # perl4 prints: 2
 645     # perl5 fails with syntax error
 646
 647     @ = (1..3);
 648     print "$#{a}";
 649
 650     # perl4 prints: {a}
 651     # perl5 prints: 2
 652
 653 =back
 654
 655 =head2 Numerical Traps
 656
 657 Perl4-to-Perl5 traps having to do with numerical operators,
 658 operands, or output from same.
 659
 660 =over 5
 661
 662 =item * Numerical
 663
 664 Formatted output and significant digits
 665
 666     print 7.373504 - 0, "\n";
 667     printf "%20.18f\n", 7.373504 - 0;
 668
 669     # Perl4 prints:
 670     7.375039999999996141
 671     7.37503999999999614
 672
 673     # Perl5 prints:
 674     7.373504
 675     7.37503999999999614
 676
 677 =item * Numerical
 678
 679 This specific item has been deleted.  It demonstrated how the auto-increment
 680 operator would not catch when a number went over the signed int limit.  Fixed
 681 in version 5.003_04.  But always be wary when using large integers.
 682 If in doubt:
 683
 684    use Math::BigInt;
 685
 686 =item * Numerical
 687
 688 Assignment of return values from numeric equality tests
 689 does not work in perl5 when the test evaluates to false (0).
 690 Logical tests now return an null, instead of 0
 691
 692     $p = ($test == 1);
 693     print $p,"\n";
 694
 695     # perl4 prints: 0
 696     # perl5 prints:
 697
 698 Also see L<"General Regular Expression Traps using s///, etc.">
 699 for another example of this new feature...
 700
 701 =item * Bitwise string ops
 702
 703 When bitwise operators which can operate upon either numbers or
 704 strings (C<& | ^ ~>) are given only strings as arguments, perl4 would
 705 treat the operands as bitstrings so long as the program contained a call
 706 to the C<vec()> function. perl5 treats the string operands as bitstrings.
 707 (See L<perlop/Bitwise String Operators> for more details.)
 708
 709     $fred = "10";
 710     $barney = "12";
 711     $betty = $fred & $barney;
 712     print "$betty\n";
 713     # Uncomment the next line to change perl4's behavior
 714     # ($dummy) = vec("dummy", 0, 0);
 715
 716     # Perl4 prints:
 717     8
 718
 719     # Perl5 prints:
 720     10
 721
 722     # If vec() is used anywhere in the program, both print:
 723     10
 724
 725 =back
 726
 727 =head2 General data type traps
 728
 729 Perl4-to-Perl5 traps involving most data-types, and their usage
 730 within certain expressions and/or context.
 731
 732 =over 5
 733
 734 =item * (Arrays)
 735
 736 Negative array subscripts now count from the end of the array.
 737
 738     @a = (1, 2, 3, 4, 5);
 739     print "The third element of the array is $a[3] also expressed as $a[-2] \n";
 740
 741     # perl4 prints: The third element of the array is 4 also expressed as
 742     # perl5 prints: The third element of the array is 4 also expressed as 4
 743
 744 =item * (Arrays)
 745
 746 Setting C<$#array> lower now discards array elements, and makes them
 747 impossible to recover.
 748
 749     @a = (a,b,c,d,e);
 750     print "Before: ",join('',@a);
 751     $#a =1;
 752     print ", After: ",join('',@a);
 753     $#a =3;
 754     print ", Recovered: ",join('',@a),"\n";
 755
 756     # perl4 prints: Before: abcde, After: ab, Recovered: abcd
 757     # perl5 prints: Before: abcde, After: ab, Recovered: ab
 758
 759 =item * (Hashes)
 760
 761 Hashes get defined before use
 762
 763     local($s,@a,%h);
 764     die "scalar \$s defined" if defined($s);
 765     die "array \@a defined" if defined(@a);
 766     die "hash \%h defined" if defined(%h);
 767
 768     # perl4 prints:
 769     # perl5 dies: hash %h defined
 770
 771 Perl will now generate a warning when it sees defined(@a) and
 772 defined(%h).
 773
 774 =item * (Globs)
 775
 776 glob assignment from variable to variable will fail if the assigned
 777 variable is localized subsequent to the assignment
 778
 779     @a = ("This is Perl 4");
 780     *b = *a;
 781     local(@a);
 782     print @b,"\n";
 783
 784     # perl4 prints: This is Perl 4
 785     # perl5 prints:
 786
 787 =item * (Globs)
 788
 789 Assigning C<undef> to a glob has no effect in Perl 5.   In Perl 4
 790 it undefines the associated scalar (but may have other side effects
 791 including SEGVs).
 792
 793 =item * (Scalar String)
 794
 795 Changes in unary negation (of strings)
 796 This change effects both the return value and what it
 797 does to auto(magic)increment.
 798
 799     $x = "aaa";
 800     print ++$x," : ";
 801     print -$x," : ";
 802     print ++$x,"\n";
 803
 804     # perl4 prints: aab : -0 : 1
 805     # perl5 prints: aab : -aab : aac
 806
 807 =item * (Constants)
 808
 809 perl 4 lets you modify constants:
 810
 811     $foo = "x";
 812     &mod($foo);
 813     for ($x = 0; $x < 3; $x++) {
 814         &mod("a");
 815     }
 816     sub mod {
 817         print "before: $_[0]";
 818         $_[0] = "m";
 819         print "  after: $_[0]\n";
 820     }
 821
 822     # perl4:
 823     # before: x  after: m
 824     # before: a  after: m
 825     # before: m  after: m
 826     # before: m  after: m
 827
 828     # Perl5:
 829     # before: x  after: m
 830     # Modification of a read-only value attempted at foo.pl line 12.
 831     # before: a
 832
 833 =item * (Scalars)
 834
 835 The behavior is slightly different for:
 836
 837     print "$x", defined $x
 838
 839     # perl 4: 1
 840     # perl 5: <no output, $x is not called into existence>
 841
 842 =item * (Variable Suicide)
 843
 844 Variable suicide behavior is more consistent under Perl 5.
 845 Perl5 exhibits the same behavior for hashes and scalars,
 846 that perl4 exhibits for only scalars.
 847
 848     $aGlobal{ "aKey" } = "global value";
 849     print "MAIN:", $aGlobal{"aKey"}, "\n";
 850     $GlobalLevel = 0;
 851     &test( *aGlobal );
 852
 853     sub test {
 854         local( *theArgument ) = @_;
 855         local( %aNewLocal ); # perl 4 != 5.001l,m
 856         $aNewLocal{"aKey"} = "this should never appear";
 857         print "SUB: ", $theArgument{"aKey"}, "\n";
 858         $aNewLocal{"aKey"} = "level $GlobalLevel";   # what should print
 859         $GlobalLevel++;
 860         if( $GlobalLevel<4 ) {
 861             &test( *aNewLocal );
 862         }
 863     }
 864
 865     # Perl4:
 866     # MAIN:global value
 867     # SUB: global value
 868     # SUB: level 0
 869     # SUB: level 1
 870     # SUB: level 2
 871
 872     # Perl5:
 873     # MAIN:global value
 874     # SUB: global value
 875     # SUB: this should never appear
 876     # SUB: this should never appear
 877     # SUB: this should never appear
 878
 879 =back
 880
 881 =head2 Context Traps - scalar, list contexts
 882
 883 =over 5
 884
 885 =item * (list context)
 886
 887 The elements of argument lists for formats are now evaluated in list
 888 context.  This means you can interpolate list values now.
 889
 890     @fmt = ("foo","bar","baz");
 891     format STDOUT=
 892     @<<<<< @||||| @>>>>>
 893     @fmt;
 894     .
 895     write;
 896
 897     # perl4 errors:  Please use commas to separate fields in file
 898     # perl5 prints: foo     bar      baz
 899
 900 =item * (scalar context)
 901
 902 The C<caller()> function now returns a false value in a scalar context
 903 if there is no caller.  This lets library files determine if they're
 904 being required.
 905
 906     caller() ? (print "You rang?\n") : (print "Got a 0\n");
 907
 908     # perl4 errors: There is no caller
 909     # perl5 prints: Got a 0
 910
 911 =item * (scalar context)
 912
 913 The comma operator in a scalar context is now guaranteed to give a
 914 scalar context to its arguments.
 915
 916     @y= ('a','b','c');
 917     $x = (1, 2, @y);
 918     print "x = $x\n";
 919
 920     # Perl4 prints:  x = c   # Thinks list context interpolates list
 921     # Perl5 prints:  x = 3   # Knows scalar uses length of list
 922
 923 =item * (list, builtin)
 924
 925 C<sprintf()> funkiness (array argument converted to scalar array count)
 926 This test could be added to t/op/sprintf.t
 927
 928     @z = ('%s%s', 'foo', 'bar');
 929     $x = sprintf(@z);
 930     if ($x eq 'foobar') {print "ok 2\n";} else {print "not ok 2 '$x'\n";}
 931
 932     # perl4 prints: ok 2
 933     # perl5 prints: not ok 2
 934
 935 C<printf()> works fine, though:
 936
 937     printf STDOUT (@z);
 938     print "\n";
 939
 940     # perl4 prints: foobar
 941     # perl5 prints: foobar
 942
 943 Probably a bug.
 944
 945 =back
 946
 947 =head2 Precedence Traps
 948
 949 Perl4-to-Perl5 traps involving precedence order.
 950
 951 Perl 4 has almost the same precedence rules as Perl 5 for the operators
 952 that they both have.  Perl 4 however, seems to have had some
 953 inconsistencies that made the behavior differ from what was documented.
 954
 955 =over 5
 956
 957 =item * Precedence
 958
 959 LHS vs. RHS of any assignment operator.  LHS is evaluated first
 960 in perl4, second in perl5; this can affect the relationship
 961 between side-effects in sub-expressions.
 962
 963     @arr = ( 'left', 'right' );
 964     $a{shift @arr} = shift @arr;
 965     print join( ' ', keys %a );
 966
 967     # perl4 prints: left
 968     # perl5 prints: right
 969
 970 =item * Precedence
 971
 972 These are now semantic errors because of precedence:
 973
 974     @list = (1,2,3,4,5);
 975     %map = ("a",1,"b",2,"c",3,"d",4);
 976     $n = shift @list + 2;   # first item in list plus 2
 977     print "n is $n, ";
 978     $m = keys %map + 2;     # number of items in hash plus 2
 979     print "m is $m\n";
 980
 981     # perl4 prints: n is 3, m is 6
 982     # perl5 errors and fails to compile
 983
 984 =item * Precedence
 985
 986 The precedence of assignment operators is now the same as the precedence
 987 of assignment.  Perl 4 mistakenly gave them the precedence of the associated
 988 operator.  So you now must parenthesize them in expressions like
 989
 990     /foo/ ? ($a += 2) : ($a -= 2);
 991
 992 Otherwise
 993
 994     /foo/ ? $a += 2 : $a -= 2
 995
 996 would be erroneously parsed as
 997
 998     (/foo/ ? $a += 2 : $a) -= 2;
 999
1000 On the other hand,
1001
1002     $a += /foo/ ? 1 : 2;
1003
1004 now works as a C programmer would expect.
1005
1006 =item * Precedence
1007
1008     open FOO || die;
1009
1010 is now incorrect.  You need parentheses around the filehandle.
1011 Otherwise, perl5 leaves the statement as its default precedence:
1012
1013     open(FOO || die);
1014
1015     # perl4 opens or dies
1016     # perl5 errors: Precedence problem: open FOO should be open(FOO)
1017
1018 =item * Precedence
1019
1020 perl4 gives the special variable, C<$:> precedence, where perl5
1021 treats C<$::> as main C<package>
1022
1023     $a = "x"; print "$::a";
1024
1025     # perl 4 prints: -:a
1026     # perl 5 prints: x
1027
1028 =item * Precedence
1029
1030 perl4 had buggy precedence for the file test operators vis-a-vis
1031 the assignment operators.  Thus, although the precedence table
1032 for perl4 leads one to believe C<-e $foo .= "q"> should parse as
1033 C<((-e $foo) .= "q")>, it actually parses as C<(-e ($foo .= "q"))>.
1034 In perl5, the precedence is as documented.
1035
1036     -e $foo .= "q"
1037
1038     # perl4 prints: no output
1039     # perl5 prints: Can't modify -e in concatenation
1040
1041 =item * Precedence
1042
1043 In perl4, keys(), each() and values() were special high-precedence operators
1044 that operated on a single hash, but in perl5, they are regular named unary
1045 operators.  As documented, named unary operators have lower precedence
1046 than the arithmetic and concatenation operators C<+ - .>, but the perl4
1047 variants of these operators actually bind tighter than C<+ - .>.
1048 Thus, for:
1049
1050     %foo = 1..10;
1051     print keys %foo - 1
1052
1053     # perl4 prints: 4
1054     # perl5 prints: Type of arg 1 to keys must be hash (not subtraction)
1055
1056 The perl4 behavior was probably more useful, if less consistent.
1057
1058 =back
1059
1060 =head2 General Regular Expression Traps using s///, etc.
1061
1062 All types of RE traps.
1063
1064 =over 5
1065
1066 =item * Regular Expression
1067
1068 C<s'$lhs'$rhs'> now does no interpolation on either side.  It used to
1069 interpolate $lhs but not $rhs.  (And still does not match a literal
1070 '$' in string)
1071
1072     $a=1;$b=2;
1073     $string = '1 2 $a $b';
1074     $string =~ s'$a'$b';
1075     print $string,"\n";
1076
1077     # perl4 prints: $b 2 $a $b
1078     # perl5 prints: 1 2 $a $b
1079
1080 =item * Regular Expression
1081
1082 C<m//g> now attaches its state to the searched string rather than the
1083 regular expression.  (Once the scope of a block is left for the sub, the
1084 state of the searched string is lost)
1085
1086     $_ = "ababab";
1087     while(m/ab/g){
1088         &doit("blah");
1089     }
1090     sub doit{local($_) = shift; print "Got $_ "}
1091
1092     # perl4 prints: blah blah blah
1093     # perl5 prints: infinite loop blah...
1094
1095 =item * Regular Expression
1096
1097 Currently, if you use the C<m//o> qualifier on a regular expression
1098 within an anonymous sub, I<all> closures generated from that anonymous
1099 sub will use the regular expression as it was compiled when it was used
1100 the very first time in any such closure.  For instance, if you say
1101
1102     sub build_match {
1103         my($left,$right) = @_;
1104         return sub { $_[0] =~ /$left stuff $right/o; };
1105     }
1106
1107 build_match() will always return a sub which matches the contents of
1108 $left and $right as they were the I<first> time that build_match()
1109 was called, not as they are in the current call.
1110
1111 This is probably a bug, and may change in future versions of Perl.
1112
1113 =item * Regular Expression
1114
1115 If no parentheses are used in a match, Perl4 sets C<$+> to
1116 the whole match, just like C<$&>. Perl5 does not.
1117
1118     "abcdef" =~ /b.*e/;
1119     print "\$+ = $+\n";
1120
1121     # perl4 prints: bcde
1122     # perl5 prints:
1123
1124 =item * Regular Expression
1125
1126 substitution now returns the null string if it fails
1127
1128     $string = "test";
1129     $value = ($string =~ s/foo//);
1130     print $value, "\n";
1131
1132     # perl4 prints: 0
1133     # perl5 prints:
1134
1135 Also see L<Numerical Traps> for another example of this new feature.
1136
1137 =item * Regular Expression
1138
1139 C<s`lhs`rhs`> (using backticks) is now a normal substitution, with no
1140 backtick expansion
1141
1142     $string = "";
1143     $string =~ s`^`hostname`;
1144     print $string, "\n";
1145
1146     # perl4 prints: <the local hostname>
1147     # perl5 prints: hostname
1148
1149 =item * Regular Expression
1150
1151 Stricter parsing of variables used in regular expressions
1152
1153     s/^([^$grpc]*$grpc[$opt$plus$rep]?)//o;
1154
1155     # perl4: compiles w/o error
1156     # perl5: with Scalar found where operator expected ..., near "$opt$plus"
1157
1158 an added component of this example, apparently from the same script, is
1159 the actual value of the s'd string after the substitution.
1160 C<[$opt]> is a character class in perl4 and an array subscript in perl5
1161
1162     $grpc = 'a';
1163     $opt  = 'r';
1164     $_ = 'bar';
1165     s/^([^$grpc]*$grpc[$opt]?)/foo/;
1166     print ;
1167
1168     # perl4 prints: foo
1169     # perl5 prints: foobar
1170
1171 =item * Regular Expression
1172
1173 Under perl5, C<m?x?> matches only once, like C<?x?>. Under perl4, it matched
1174 repeatedly, like C</x/> or C<m!x!>.
1175
1176     $test = "once";
1177     sub match { $test =~ m?once?; }
1178     &match();
1179     if( &match() ) {
1180         # m?x? matches more then once
1181         print "perl4\n";
1182     } else {
1183         # m?x? matches only once
1184         print "perl5\n";
1185     }
1186
1187     # perl4 prints: perl4
1188     # perl5 prints: perl5
1189
1190
1191 =back
1192
1193 =head2 Subroutine, Signal, Sorting Traps
1194
1195 The general group of Perl4-to-Perl5 traps having to do with
1196 Signals, Sorting, and their related subroutines, as well as
1197 general subroutine traps.  Includes some OS-Specific traps.
1198
1199 =over 5
1200
1201 =item * (Signals)
1202
1203 Barewords that used to look like strings to Perl will now look like subroutine
1204 calls if a subroutine by that name is defined before the compiler sees them.
1205
1206     sub SeeYa { warn"Hasta la vista, baby!" }
1207     $SIG{'TERM'} = SeeYa;
1208     print "SIGTERM is now $SIG{'TERM'}\n";
1209
1210     # perl4 prints: SIGTERM is main'SeeYa
1211     # perl5 prints: SIGTERM is now main::1
1212
1213 Use B<-w> to catch this one
1214
1215 =item * (Sort Subroutine)
1216
1217 reverse is no longer allowed as the name of a sort subroutine.
1218
1219     sub reverse{ print "yup "; $a <=> $b }
1220     print sort reverse a,b,c;
1221
1222     # perl4 prints: yup yup yup yup abc
1223     # perl5 prints: abc
1224
1225 =item * warn() won't let you specify a filehandle.
1226
1227 Although it _always_ printed to STDERR, warn() would let you specify a
1228 filehandle in perl4.  With perl5 it does not.
1229
1230     warn STDERR "Foo!";
1231
1232     # perl4 prints: Foo!
1233     # perl5 prints: String found where operator expected
1234
1235 =back
1236
1237 =head2 OS Traps
1238
1239 =over 5
1240
1241 =item * (SysV)
1242
1243 Under HPUX, and some other SysV OSes, one had to reset any signal handler,
1244 within  the signal handler function, each time a signal was handled with
1245 perl4.  With perl5, the reset is now done correctly.  Any code relying
1246 on the handler _not_ being reset will have to be reworked.
1247
1248 Since version 5.002, Perl uses sigaction() under SysV.
1249
1250     sub gotit {
1251         print "Got @_... ";
1252     }
1253     $SIG{'INT'} = 'gotit';
1254
1255     $| = 1;
1256     $pid = fork;
1257     if ($pid) {
1258         kill('INT', $pid);
1259         sleep(1);
1260         kill('INT', $pid);
1261     } else {
1262         while (1) {sleep(10);}
1263     }
1264
1265     # perl4 (HPUX) prints: Got INT...
1266     # perl5 (HPUX) prints: Got INT... Got INT...
1267
1268 =item * (SysV)
1269
1270 Under SysV OSes, C<seek()> on a file opened to append C<<< >> >>> now does
1271 the right thing w.r.t. the fopen() manpage. e.g., - When a file is opened
1272 for append,  it  is  impossible to overwrite information already in
1273 the file.
1274
1275     open(TEST,">>seek.test");
1276     $start = tell TEST ;
1277     foreach(1 .. 9){
1278         print TEST "$_ ";
1279     }
1280     $end = tell TEST ;
1281     seek(TEST,$start,0);
1282     print TEST "18 characters here";
1283
1284     # perl4 (solaris) seek.test has: 18 characters here
1285     # perl5 (solaris) seek.test has: 1 2 3 4 5 6 7 8 9 18 characters here
1286
1287
1288
1289 =back
1290
1291 =head2 Interpolation Traps
1292
1293 Perl4-to-Perl5 traps having to do with how things get interpolated
1294 within certain expressions, statements, contexts, or whatever.
1295
1296 =over 5
1297
1298 =item * Interpolation
1299
1300 @ now always interpolates an array in double-quotish strings.
1301
1302     print "To: someone@somewhere.com\n";
1303
1304     # perl4 prints: To:someone@somewhere.com
1305     # perl5 errors : In string, @somewhere now must be written as \@somewhere
1306
1307 =item * Interpolation
1308
1309 Double-quoted strings may no longer end with an unescaped $ or @.
1310
1311     $foo = "foo$";
1312     $bar = "bar@";
1313     print "foo is $foo, bar is $bar\n";
1314
1315     # perl4 prints: foo is foo$, bar is bar@
1316     # perl5 errors: Final $ should be \$ or $name
1317
1318 Note: perl5 DOES NOT error on the terminating @ in $bar
1319
1320 =item * Interpolation
1321
1322 Perl now sometimes evaluates arbitrary expressions inside braces that occur
1323 within double quotes (usually when the opening brace is preceded by C<$>
1324 or C<@>).
1325
1326     @www = "buz";
1327     $foo = "foo";
1328     $bar = "bar";
1329     sub foo { return "bar" };
1330     print "|@{w.w.w}|${main'foo}|";
1331
1332     # perl4 prints: |@{w.w.w}|foo|
1333     # perl5 prints: |buz|bar|
1334
1335 Note that you can C<use strict;> to ward off such trappiness under perl5.
1336
1337 =item * Interpolation
1338
1339 The construct "this is $$x" used to interpolate the pid at that
1340 point, but now apparently tries to dereference $x.  C<$$> by itself still
1341 works fine, however.
1342
1343     print "this is $$x\n";
1344
1345     # perl4 prints: this is XXXx   (XXX is the current pid)
1346     # perl5 prints: this is
1347
1348 =item * Interpolation
1349
1350 Creation of hashes on the fly with C<eval "EXPR"> now requires either both
1351 C<$>'s to be protected in the specification of the hash name, or both curlies
1352 to be protected.  If both curlies are protected, the result will be compatible
1353 with perl4 and perl5.  This is a very common practice, and should be changed
1354 to use the block form of C<eval{}>  if possible.
1355
1356     $hashname = "foobar";
1357     $key = "baz";
1358     $value = 1234;
1359     eval "\$$hashname{'$key'} = q|$value|";
1360     (defined($foobar{'baz'})) ?  (print "Yup") : (print "Nope");
1361
1362     # perl4 prints: Yup
1363     # perl5 prints: Nope
1364
1365 Changing
1366
1367     eval "\$$hashname{'$key'} = q|$value|";
1368
1369 to
1370
1371     eval "\$\$hashname{'$key'} = q|$value|";
1372
1373 causes the following result:
1374
1375     # perl4 prints: Nope
1376     # perl5 prints: Yup
1377
1378 or, changing to
1379
1380     eval "\$$hashname\{'$key'\} = q|$value|";
1381
1382 causes the following result:
1383
1384     # perl4 prints: Yup
1385     # perl5 prints: Yup
1386     # and is compatible for both versions
1387
1388
1389 =item * Interpolation
1390
1391 perl4 programs which unconsciously rely on the bugs in earlier perl versions.
1392
1393     perl -e '$bar=q/not/; print "This is $foo{$bar} perl5"'
1394
1395     # perl4 prints: This is not perl5
1396     # perl5 prints: This is perl5
1397
1398 =item * Interpolation
1399
1400 You also have to be careful about array references.
1401
1402     print "$foo{"
1403
1404     perl 4 prints: {
1405     perl 5 prints: syntax error
1406
1407 =item * Interpolation
1408
1409 Similarly, watch out for:
1410
1411     $foo = "array";
1412     print "\$$foo{bar}\n";
1413
1414     # perl4 prints: $array{bar}
1415     # perl5 prints: $
1416
1417 Perl 5 is looking for C<$array{bar}> which doesn't exist, but perl 4 is
1418 happy just to expand $foo to "array" by itself.  Watch out for this
1419 especially in C<eval>'s.
1420
1421 =item * Interpolation
1422
1423 C<qq()> string passed to C<eval>
1424
1425     eval qq(
1426         foreach \$y (keys %\$x\) {
1427             \$count++;
1428         }
1429     );
1430
1431     # perl4 runs this ok
1432     # perl5 prints: Can't find string terminator ")"
1433
1434 =back
1435
1436 =head2 DBM Traps
1437
1438 General DBM traps.
1439
1440 =over 5
1441
1442 =item * DBM
1443
1444 Existing dbm databases created under perl4 (or any other dbm/ndbm tool)
1445 may cause the same script, run under perl5, to fail.  The build of perl5
1446 must have been linked with the same dbm/ndbm as the default for C<dbmopen()>
1447 to function properly without C<tie>'ing to an extension dbm implementation.
1448
1449     dbmopen (%dbm, "file", undef);
1450     print "ok\n";
1451
1452     # perl4 prints: ok
1453     # perl5 prints: ok (IFF linked with -ldbm or -lndbm)
1454
1455
1456 =item * DBM
1457
1458 Existing dbm databases created under perl4 (or any other dbm/ndbm tool)
1459 may cause the same script, run under perl5, to fail.  The error generated
1460 when exceeding the limit on the key/value size will cause perl5 to exit
1461 immediately.
1462
1463     dbmopen(DB, "testdb",0600) || die "couldn't open db! $!";
1464     $DB{'trap'} = "x" x 1024;  # value too large for most dbm/ndbm
1465     print "YUP\n";
1466
1467     # perl4 prints:
1468     dbm store returned -1, errno 28, key "trap" at - line 3.
1469     YUP
1470
1471     # perl5 prints:
1472     dbm store returned -1, errno 28, key "trap" at - line 3.
1473
1474 =back
1475
1476 =head2 Unclassified Traps
1477
1478 Everything else.
1479
1480 =over 5
1481
1482 =item * C<require>/C<do> trap using returned value
1483
1484 If the file doit.pl has:
1485
1486     sub foo {
1487         $rc = do "./do.pl";
1488         return 8;
1489     }
1490     print &foo, "\n";
1491
1492 And the do.pl file has the following single line:
1493
1494     return 3;
1495
1496 Running doit.pl gives the following:
1497
1498     # perl 4 prints: 3 (aborts the subroutine early)
1499     # perl 5 prints: 8
1500
1501 Same behavior if you replace C<do> with C<require>.
1502
1503 =item * C<split> on empty string with LIMIT specified
1504
1505         $string = '';
1506     @list = split(/foo/, $string, 2)
1507
1508 Perl4 returns a one element list containing the empty string but Perl5
1509 returns an empty list.
1510
1511 =back
1512
1513 As always, if any of these are ever officially declared as bugs,
1514 they'll be fixed and removed.
1515