pod/perltie.pod

   1 =head1 NAME
   2
   3 perltie - how to hide an object class in a simple variable
   4
   5 =head1 SYNOPSIS
   6
   7  tie VARIABLE, CLASSNAME, LIST
   8
   9  $object = tied VARIABLE
  10
  11  untie VARIABLE
  12
  13 =head1 DESCRIPTION
  14
  15 Prior to release 5.0 of Perl, a programmer could use dbmopen()
  16 to connect an on-disk database in the standard Unix dbm(3x)
  17 format magically to a %HASH in their program.  However, their Perl was either
  18 built with one particular dbm library or another, but not both, and
  19 you couldn't extend this mechanism to other packages or types of variables.
  20
  21 Now you can.
  22
  23 The tie() function binds a variable to a class (package) that will provide
  24 the implementation for access methods for that variable.  Once this magic
  25 has been performed, accessing a tied variable automatically triggers
  26 method calls in the proper class.  The complexity of the class is
  27 hidden behind magic methods calls.  The method names are in ALL CAPS,
  28 which is a convention that Perl uses to indicate that they're called
  29 implicitly rather than explicitly--just like the BEGIN() and END()
  30 functions.
  31
  32 In the tie() call, C<VARIABLE> is the name of the variable to be
  33 enchanted.  C<CLASSNAME> is the name of a class implementing objects of
  34 the correct type.  Any additional arguments in the C<LIST> are passed to
  35 the appropriate constructor method for that class--meaning TIESCALAR(),
  36 TIEARRAY(), TIEHASH(), or TIEHANDLE().  (Typically these are arguments
  37 such as might be passed to the dbminit() function of C.) The object
  38 returned by the "new" method is also returned by the tie() function,
  39 which would be useful if you wanted to access other methods in
  40 C<CLASSNAME>. (You don't actually have to return a reference to a right
  41 "type" (e.g., HASH or C<CLASSNAME>) so long as it's a properly blessed
  42 object.)  You can also retrieve a reference to the underlying object
  43 using the tied() function.
  44
  45 Unlike dbmopen(), the tie() function will not C<use> or C<require> a module
  46 for you--you need to do that explicitly yourself.
  47
  48 =head2 Tying Scalars
  49
  50 A class implementing a tied scalar should define the following methods:
  51 TIESCALAR, FETCH, STORE, and possibly UNTIE and/or DESTROY.
  52
  53 Let's look at each in turn, using as an example a tie class for
  54 scalars that allows the user to do something like:
  55
  56     tie $his_speed, 'Nice', getppid();
  57     tie $my_speed,  'Nice', $$;
  58
  59 And now whenever either of those variables is accessed, its current
  60 system priority is retrieved and returned.  If those variables are set,
  61 then the process's priority is changed!
  62
  63 We'll use Jarkko Hietaniemi <F<jhi@iki.fi>>'s BSD::Resource class (not
  64 included) to access the PRIO_PROCESS, PRIO_MIN, and PRIO_MAX constants
  65 from your system, as well as the getpriority() and setpriority() system
  66 calls.  Here's the preamble of the class.
  67
  68     package Nice;
  69     use Carp;
  70     use BSD::Resource;
  71     use strict;
  72     $Nice::DEBUG = 0 unless defined $Nice::DEBUG;
  73
  74 =over 4
  75
  76 =item TIESCALAR classname, LIST
  77
  78 This is the constructor for the class.  That means it is
  79 expected to return a blessed reference to a new scalar
  80 (probably anonymous) that it's creating.  For example:
  81
  82     sub TIESCALAR {
  83         my $class = shift;
  84         my $pid = shift || $$; # 0 means me
  85
  86         if ($pid !~ /^\d+$/) {
  87             carp "Nice::Tie::Scalar got non-numeric pid $pid" if $^W;
  88             return undef;
  89         }
  90
  91         unless (kill 0, $pid) { # EPERM or ERSCH, no doubt
  92             carp "Nice::Tie::Scalar got bad pid $pid: $!" if $^W;
  93             return undef;
  94         }
  95
  96         return bless \$pid, $class;
  97     }
  98
  99 This tie class has chosen to return an error rather than raising an
 100 exception if its constructor should fail.  While this is how dbmopen() works,
 101 other classes may well not wish to be so forgiving.  It checks the global
 102 variable C<$^W> to see whether to emit a bit of noise anyway.
 103
 104 =item FETCH this
 105
 106 This method will be triggered every time the tied variable is accessed
 107 (read).  It takes no arguments beyond its self reference, which is the
 108 object representing the scalar we're dealing with.  Because in this case
 109 we're using just a SCALAR ref for the tied scalar object, a simple $$self
 110 allows the method to get at the real value stored there.  In our example
 111 below, that real value is the process ID to which we've tied our variable.
 112
 113     sub FETCH {
 114         my $self = shift;
 115         confess "wrong type" unless ref $self;
 116         croak "usage error" if @_;
 117         my $nicety;
 118         local($!) = 0;
 119         $nicety = getpriority(PRIO_PROCESS, $$self);
 120         if ($!) { croak "getpriority failed: $!" }
 121         return $nicety;
 122     }
 123
 124 This time we've decided to blow up (raise an exception) if the renice
 125 fails--there's no place for us to return an error otherwise, and it's
 126 probably the right thing to do.
 127
 128 =item STORE this, value
 129
 130 This method will be triggered every time the tied variable is set
 131 (assigned).  Beyond its self reference, it also expects one (and only one)
 132 argument--the new value the user is trying to assign.
 133
 134     sub STORE {
 135         my $self = shift;
 136         confess "wrong type" unless ref $self;
 137         my $new_nicety = shift;
 138         croak "usage error" if @_;
 139
 140         if ($new_nicety < PRIO_MIN) {
 141             carp sprintf
 142               "WARNING: priority %d less than minimum system priority %d",
 143                   $new_nicety, PRIO_MIN if $^W;
 144             $new_nicety = PRIO_MIN;
 145         }
 146
 147         if ($new_nicety > PRIO_MAX) {
 148             carp sprintf
 149               "WARNING: priority %d greater than maximum system priority %d",
 150                   $new_nicety, PRIO_MAX if $^W;
 151             $new_nicety = PRIO_MAX;
 152         }
 153
 154         unless (defined setpriority(PRIO_PROCESS, $$self, $new_nicety)) {
 155             confess "setpriority failed: $!";
 156         }
 157         return $new_nicety;
 158     }
 159
 160 =item UNTIE this
 161
 162 This method will be triggered when the C<untie> occurs. This can be useful
 163 if the class needs to know when no further calls will be made. (Except DESTROY
 164 of course.) See below for more details.
 165
 166 =item DESTROY this
 167
 168 This method will be triggered when the tied variable needs to be destructed.
 169 As with other object classes, such a method is seldom necessary, because Perl
 170 deallocates its moribund object's memory for you automatically--this isn't
 171 C++, you know.  We'll use a DESTROY method here for debugging purposes only.
 172
 173     sub DESTROY {
 174         my $self = shift;
 175         confess "wrong type" unless ref $self;
 176         carp "[ Nice::DESTROY pid $$self ]" if $Nice::DEBUG;
 177     }
 178
 179 =back
 180
 181 That's about all there is to it.  Actually, it's more than all there
 182 is to it, because we've done a few nice things here for the sake
 183 of completeness, robustness, and general aesthetics.  Simpler
 184 TIESCALAR classes are certainly possible.
 185
 186 =head2 Tying Arrays
 187
 188 A class implementing a tied ordinary array should define the following
 189 methods: TIEARRAY, FETCH, STORE, FETCHSIZE, STORESIZE and perhaps UNTIE and/or DESTROY.
 190
 191 FETCHSIZE and STORESIZE are used to provide C<$#array> and
 192 equivalent C<scalar(@array)> access.
 193
 194 The methods POP, PUSH, SHIFT, UNSHIFT, SPLICE, DELETE, and EXISTS are
 195 required if the perl operator with the corresponding (but lowercase) name
 196 is to operate on the tied array. The B<Tie::Array> class can be used as a
 197 base class to implement the first five of these in terms of the basic
 198 methods above.  The default implementations of DELETE and EXISTS in
 199 B<Tie::Array> simply C<croak>.
 200
 201 In addition EXTEND will be called when perl would have pre-extended
 202 allocation in a real array.
 203
 204 For this discussion, we'll implement an array whose elements are a fixed
 205 size at creation.  If you try to create an element larger than the fixed
 206 size, you'll take an exception.  For example:
 207
 208     use FixedElem_Array;
 209     tie @array, 'FixedElem_Array', 3;
 210     $array[0] = 'cat';  # ok.
 211     $array[1] = 'dogs'; # exception, length('dogs') > 3.
 212
 213 The preamble code for the class is as follows:
 214
 215     package FixedElem_Array;
 216     use Carp;
 217     use strict;
 218
 219 =over 4
 220
 221 =item TIEARRAY classname, LIST
 222
 223 This is the constructor for the class.  That means it is expected to
 224 return a blessed reference through which the new array (probably an
 225 anonymous ARRAY ref) will be accessed.
 226
 227 In our example, just to show you that you don't I<really> have to return an
 228 ARRAY reference, we'll choose a HASH reference to represent our object.
 229 A HASH works out well as a generic record type: the C<{ELEMSIZE}> field will
 230 store the maximum element size allowed, and the C<{ARRAY}> field will hold the
 231 true ARRAY ref.  If someone outside the class tries to dereference the
 232 object returned (doubtless thinking it an ARRAY ref), they'll blow up.
 233 This just goes to show you that you should respect an object's privacy.
 234
 235     sub TIEARRAY {
 236       my $class    = shift;
 237       my $elemsize = shift;
 238       if ( @_ || $elemsize =~ /\D/ ) {
 239         croak "usage: tie ARRAY, '" . __PACKAGE__ . "', elem_size";
 240       }
 241       return bless {
 242         ELEMSIZE => $elemsize,
 243         ARRAY    => [],
 244       }, $class;
 245     }
 246
 247 =item FETCH this, index
 248
 249 This method will be triggered every time an individual element the tied array
 250 is accessed (read).  It takes one argument beyond its self reference: the
 251 index whose value we're trying to fetch.
 252
 253     sub FETCH {
 254       my $self  = shift;
 255       my $index = shift;
 256       return $self->{ARRAY}->[$index];
 257     }
 258
 259 If a negative array index is used to read from an array, the index
 260 will be translated to a positive one internally by calling FETCHSIZE
 261 before being passed to FETCH.
 262
 263 As you may have noticed, the name of the FETCH method (et al.) is the same
 264 for all accesses, even though the constructors differ in names (TIESCALAR
 265 vs TIEARRAY).  While in theory you could have the same class servicing
 266 several tied types, in practice this becomes cumbersome, and it's easiest
 267 to keep them at simply one tie type per class.
 268
 269 =item STORE this, index, value
 270
 271 This method will be triggered every time an element in the tied array is set
 272 (written).  It takes two arguments beyond its self reference: the index at
 273 which we're trying to store something and the value we're trying to put
 274 there.
 275
 276 In our example, C<undef> is really C<$self-E<gt>{ELEMSIZE}> number of
 277 spaces so we have a little more work to do here:
 278
 279     sub STORE {
 280       my $self = shift;
 281       my( $index, $value ) = @_;
 282       if ( length $value > $self->{ELEMSIZE} ) {
 283         croak "length of $value is greater than $self->{ELEMSIZE}";
 284       }
 285       # fill in the blanks
 286       $self->EXTEND( $index ) if $index > $self->FETCHSIZE();
 287       # right justify to keep element size for smaller elements
 288       $self->{ARRAY}->[$index] = sprintf "%$self->{ELEMSIZE}s", $value;
 289     }
 290
 291 Negative indexes are treated the same as with FETCH.
 292
 293 =item FETCHSIZE this
 294
 295 Returns the total number of items in the tied array associated with
 296 object I<this>. (Equivalent to C<scalar(@array)>).  For example:
 297
 298     sub FETCHSIZE {
 299       my $self = shift;
 300       return scalar @{$self->{ARRAY}};
 301     }
 302
 303 =item STORESIZE this, count
 304
 305 Sets the total number of items in the tied array associated with
 306 object I<this> to be I<count>. If this makes the array larger then
 307 class's mapping of C<undef> should be returned for new positions.
 308 If the array becomes smaller then entries beyond count should be
 309 deleted.
 310
 311 In our example, 'undef' is really an element containing
 312 C<$self-E<gt>{ELEMSIZE}> number of spaces.  Observe:
 313
 314 sub STORESIZE {
 315   my $self  = shift;
 316   my $count = shift;
 317   if ( $count > $self->FETCHSIZE() ) {
 318     $self->STORE( $_, '' ) foreach $count - $self->FETCHSIZE() + 1 .. $count;
 319   } elsif ( $count < $self->FETCHSIZE() ) {
 320     $self->POP() foreach 0 .. $self->FETCHSIZE() - $count + 1;
 321   }
 322 }
 323
 324 =item EXTEND this, count
 325
 326 Informative call that array is likely to grow to have I<count> entries.
 327 Can be used to optimize allocation. This method need do nothing.
 328
 329 In our example, we want to make sure there are no blank (C<undef>)
 330 entries, so C<EXTEND> will make use of C<STORESIZE> to fill elements
 331 as needed:
 332
 333     sub EXTEND {
 334       my $self  = shift;
 335       my $count = shift;
 336       $self->STORESIZE( $count );
 337     }
 338
 339 =item EXISTS this, key
 340
 341 Verify that the element at index I<key> exists in the tied array I<this>.
 342
 343 In our example, we will determine that if an element consists of
 344 C<$self-E<gt>{ELEMSIZE}> spaces only, it does not exist:
 345
 346     sub EXISTS {
 347       my $self  = shift;
 348       my $index = shift;
 349       return $self->{ARRAY}->[$index] eq ' ' x $self->{ELEMSIZE} ? 0 : 1;
 350     }
 351
 352 =item DELETE this, key
 353
 354 Delete the element at index I<key> from the tied array I<this>.
 355
 356 In our example, a deleted item is C<$self->{ELEMSIZE}> spaces:
 357
 358     sub DELETE {
 359       my $self  = shift;
 360       my $index = shift;
 361       return $self->STORE( $index, '' );
 362     }
 363
 364 =item CLEAR this
 365
 366 Clear (remove, delete, ...) all values from the tied array associated with
 367 object I<this>.  For example:
 368
 369     sub CLEAR {
 370       my $self = shift;
 371       return $self->{ARRAY} = [];
 372     }
 373
 374 =item PUSH this, LIST
 375
 376 Append elements of I<LIST> to the array.  For example:
 377
 378     sub PUSH {
 379       my $self = shift;
 380       my @list = @_;
 381       my $last = $self->FETCHSIZE();
 382       $self->STORE( $last + $_, $list[$_] ) foreach 0 .. $#list;
 383       return $self->FETCHSIZE();
 384     }
 385
 386 =item POP this
 387
 388 Remove last element of the array and return it.  For example:
 389
 390     sub POP {
 391       my $self = shift;
 392       return pop @{$self->{ARRAY}};
 393     }
 394
 395 =item SHIFT this
 396
 397 Remove the first element of the array (shifting other elements down)
 398 and return it.  For example:
 399
 400     sub SHIFT {
 401       my $self = shift;
 402       return shift @{$self->{ARRAY}};
 403     }
 404
 405 =item UNSHIFT this, LIST
 406
 407 Insert LIST elements at the beginning of the array, moving existing elements
 408 up to make room.  For example:
 409
 410     sub UNSHIFT {
 411       my $self = shift;
 412       my @list = @_;
 413       my $size = scalar( @list );
 414       # make room for our list
 415       @{$self->{ARRAY}}[ $size .. $#{$self->{ARRAY}} + $size ]
 416        = @{$self->{ARRAY}};
 417       $self->STORE( $_, $list[$_] ) foreach 0 .. $#list;
 418     }
 419
 420 =item SPLICE this, offset, length, LIST
 421
 422 Perform the equivalent of C<splice> on the array.
 423
 424 I<offset> is optional and defaults to zero, negative values count back
 425 from the end of the array.
 426
 427 I<length> is optional and defaults to rest of the array.
 428
 429 I<LIST> may be empty.
 430
 431 Returns a list of the original I<length> elements at I<offset>.
 432
 433 In our example, we'll use a little shortcut if there is a I<LIST>:
 434
 435     sub SPLICE {
 436       my $self   = shift;
 437       my $offset = shift || 0;
 438       my $length = shift || $self->FETCHSIZE() - $offset;
 439       my @list   = ();
 440       if ( @_ ) {
 441         tie @list, __PACKAGE__, $self->{ELEMSIZE};
 442         @list   = @_;
 443       }
 444       return splice @{$self->{ARRAY}}, $offset, $length, @list;
 445     }
 446
 447 =item UNTIE this
 448
 449 Will be called when C<untie> happens. (See below.)
 450
 451 =item DESTROY this
 452
 453 This method will be triggered when the tied variable needs to be destructed.
 454 As with the scalar tie class, this is almost never needed in a
 455 language that does its own garbage collection, so this time we'll
 456 just leave it out.
 457
 458 =back
 459
 460 The code we presented at the top of the tied array class accesses many
 461 elements of the array, far more than we've set the bounds to.  Therefore,
 462 it will blow up once they try to access beyond the 2nd element of @ary, as
 463 the following output demonstrates:
 464
 465     setting index 0: value of elt 0 now 0
 466     setting index 1: value of elt 1 now 10
 467     setting index 2: value of elt 2 now 20
 468     setting index 3: Array OOB: 3 > 2 at Bounded_Array.pm line 39
 469             Bounded_Array::FETCH called at testba line 12
 470
 471 =head2 Tying Hashes
 472
 473 Hashes were the first Perl data type to be tied (see dbmopen()).  A class
 474 implementing a tied hash should define the following methods: TIEHASH is
 475 the constructor.  FETCH and STORE access the key and value pairs.  EXISTS
 476 reports whether a key is present in the hash, and DELETE deletes one.
 477 CLEAR empties the hash by deleting all the key and value pairs.  FIRSTKEY
 478 and NEXTKEY implement the keys() and each() functions to iterate over all
 479 the keys.  UNTIE is called when C<untie> happens, and DESTROY is called when
 480 the tied variable is garbage collected.
 481
 482 If this seems like a lot, then feel free to inherit from merely the
 483 standard Tie::Hash module for most of your methods, redefining only the
 484 interesting ones.  See L<Tie::Hash> for details.
 485
 486 Remember that Perl distinguishes between a key not existing in the hash,
 487 and the key existing in the hash but having a corresponding value of
 488 C<undef>.  The two possibilities can be tested with the C<exists()> and
 489 C<defined()> functions.
 490
 491 Here's an example of a somewhat interesting tied hash class:  it gives you
 492 a hash representing a particular user's dot files.  You index into the hash
 493 with the name of the file (minus the dot) and you get back that dot file's
 494 contents.  For example:
 495
 496     use DotFiles;
 497     tie %dot, 'DotFiles';
 498     if ( $dot{profile} =~ /MANPATH/ ||
 499          $dot{login}   =~ /MANPATH/ ||
 500          $dot{cshrc}   =~ /MANPATH/    )
 501     {
 502         print "you seem to set your MANPATH\n";
 503     }
 504
 505 Or here's another sample of using our tied class:
 506
 507     tie %him, 'DotFiles', 'daemon';
 508     foreach $f ( keys %him ) {
 509         printf "daemon dot file %s is size %d\n",
 510             $f, length $him{$f};
 511     }
 512
 513 In our tied hash DotFiles example, we use a regular
 514 hash for the object containing several important
 515 fields, of which only the C<{LIST}> field will be what the
 516 user thinks of as the real hash.
 517
 518 =over 5
 519
 520 =item USER
 521
 522 whose dot files this object represents
 523
 524 =item HOME
 525
 526 where those dot files live
 527
 528 =item CLOBBER
 529
 530 whether we should try to change or remove those dot files
 531
 532 =item LIST
 533
 534 the hash of dot file names and content mappings
 535
 536 =back
 537
 538 Here's the start of F<Dotfiles.pm>:
 539
 540     package DotFiles;
 541     use Carp;
 542     sub whowasi { (caller(1))[3] . '()' }
 543     my $DEBUG = 0;
 544     sub debug { $DEBUG = @_ ? shift : 1 }
 545
 546 For our example, we want to be able to emit debugging info to help in tracing
 547 during development.  We keep also one convenience function around
 548 internally to help print out warnings; whowasi() returns the function name
 549 that calls it.
 550
 551 Here are the methods for the DotFiles tied hash.
 552
 553 =over 4
 554
 555 =item TIEHASH classname, LIST
 556
 557 This is the constructor for the class.  That means it is expected to
 558 return a blessed reference through which the new object (probably but not
 559 necessarily an anonymous hash) will be accessed.
 560
 561 Here's the constructor:
 562
 563     sub TIEHASH {
 564         my $self = shift;
 565         my $user = shift || $>;
 566         my $dotdir = shift || '';
 567         croak "usage: @{[&whowasi]} [USER [DOTDIR]]" if @_;
 568         $user = getpwuid($user) if $user =~ /^\d+$/;
 569         my $dir = (getpwnam($user))[7]
 570                 || croak "@{[&whowasi]}: no user $user";
 571         $dir .= "/$dotdir" if $dotdir;
 572
 573         my $node = {
 574             USER    => $user,
 575             HOME    => $dir,
 576             LIST    => {},
 577             CLOBBER => 0,
 578         };
 579
 580         opendir(DIR, $dir)
 581                 || croak "@{[&whowasi]}: can't opendir $dir: $!";
 582         foreach $dot ( grep /^\./ && -f "$dir/$_", readdir(DIR)) {
 583             $dot =~ s/^\.//;
 584             $node->{LIST}{$dot} = undef;
 585         }
 586         closedir DIR;
 587         return bless $node, $self;
 588     }
 589
 590 It's probably worth mentioning that if you're going to filetest the
 591 return values out of a readdir, you'd better prepend the directory
 592 in question.  Otherwise, because we didn't chdir() there, it would
 593 have been testing the wrong file.
 594
 595 =item FETCH this, key
 596
 597 This method will be triggered every time an element in the tied hash is
 598 accessed (read).  It takes one argument beyond its self reference: the key
 599 whose value we're trying to fetch.
 600
 601 Here's the fetch for our DotFiles example.
 602
 603     sub FETCH {
 604         carp &whowasi if $DEBUG;
 605         my $self = shift;
 606         my $dot = shift;
 607         my $dir = $self->{HOME};
 608         my $file = "$dir/.$dot";
 609
 610         unless (exists $self->{LIST}->{$dot} || -f $file) {
 611             carp "@{[&whowasi]}: no $dot file" if $DEBUG;
 612             return undef;
 613         }
 614
 615         if (defined $self->{LIST}->{$dot}) {
 616             return $self->{LIST}->{$dot};
 617         } else {
 618             return $self->{LIST}->{$dot} = `cat $dir/.$dot`;
 619         }
 620     }
 621
 622 It was easy to write by having it call the Unix cat(1) command, but it
 623 would probably be more portable to open the file manually (and somewhat
 624 more efficient).  Of course, because dot files are a Unixy concept, we're
 625 not that concerned.
 626
 627 =item STORE this, key, value
 628
 629 This method will be triggered every time an element in the tied hash is set
 630 (written).  It takes two arguments beyond its self reference: the index at
 631 which we're trying to store something, and the value we're trying to put
 632 there.
 633
 634 Here in our DotFiles example, we'll be careful not to let
 635 them try to overwrite the file unless they've called the clobber()
 636 method on the original object reference returned by tie().
 637
 638     sub STORE {
 639         carp &whowasi if $DEBUG;
 640         my $self = shift;
 641         my $dot = shift;
 642         my $value = shift;
 643         my $file = $self->{HOME} . "/.$dot";
 644         my $user = $self->{USER};
 645
 646         croak "@{[&whowasi]}: $file not clobberable"
 647             unless $self->{CLOBBER};
 648
 649         open(F, "> $file") || croak "can't open $file: $!";
 650         print F $value;
 651         close(F);
 652     }
 653
 654 If they wanted to clobber something, they might say:
 655
 656     $ob = tie %daemon_dots, 'daemon';
 657     $ob->clobber(1);
 658     $daemon_dots{signature} = "A true daemon\n";
 659
 660 Another way to lay hands on a reference to the underlying object is to
 661 use the tied() function, so they might alternately have set clobber
 662 using:
 663
 664     tie %daemon_dots, 'daemon';
 665     tied(%daemon_dots)->clobber(1);
 666
 667 The clobber method is simply:
 668
 669     sub clobber {
 670         my $self = shift;
 671         $self->{CLOBBER} = @_ ? shift : 1;
 672     }
 673
 674 =item DELETE this, key
 675
 676 This method is triggered when we remove an element from the hash,
 677 typically by using the delete() function.  Again, we'll
 678 be careful to check whether they really want to clobber files.
 679
 680     sub DELETE   {
 681         carp &whowasi if $DEBUG;
 682
 683         my $self = shift;
 684         my $dot = shift;
 685         my $file = $self->{HOME} . "/.$dot";
 686         croak "@{[&whowasi]}: won't remove file $file"
 687             unless $self->{CLOBBER};
 688         delete $self->{LIST}->{$dot};
 689         my $success = unlink($file);
 690         carp "@{[&whowasi]}: can't unlink $file: $!" unless $success;
 691         $success;
 692     }
 693
 694 The value returned by DELETE becomes the return value of the call
 695 to delete().  If you want to emulate the normal behavior of delete(),
 696 you should return whatever FETCH would have returned for this key.
 697 In this example, we have chosen instead to return a value which tells
 698 the caller whether the file was successfully deleted.
 699
 700 =item CLEAR this
 701
 702 This method is triggered when the whole hash is to be cleared, usually by
 703 assigning the empty list to it.
 704
 705 In our example, that would remove all the user's dot files!  It's such a
 706 dangerous thing that they'll have to set CLOBBER to something higher than
 707 1 to make it happen.
 708
 709     sub CLEAR    {
 710         carp &whowasi if $DEBUG;
 711         my $self = shift;
 712         croak "@{[&whowasi]}: won't remove all dot files for $self->{USER}"
 713             unless $self->{CLOBBER} > 1;
 714         my $dot;
 715         foreach $dot ( keys %{$self->{LIST}}) {
 716             $self->DELETE($dot);
 717         }
 718     }
 719
 720 =item EXISTS this, key
 721
 722 This method is triggered when the user uses the exists() function
 723 on a particular hash.  In our example, we'll look at the C<{LIST}>
 724 hash element for this:
 725
 726     sub EXISTS   {
 727         carp &whowasi if $DEBUG;
 728         my $self = shift;
 729         my $dot = shift;
 730         return exists $self->{LIST}->{$dot};
 731     }
 732
 733 =item FIRSTKEY this
 734
 735 This method will be triggered when the user is going
 736 to iterate through the hash, such as via a keys() or each()
 737 call.
 738
 739     sub FIRSTKEY {
 740         carp &whowasi if $DEBUG;
 741         my $self = shift;
 742         my $a = keys %{$self->{LIST}};          # reset each() iterator
 743         each %{$self->{LIST}}
 744     }
 745
 746 =item NEXTKEY this, lastkey
 747
 748 This method gets triggered during a keys() or each() iteration.  It has a
 749 second argument which is the last key that had been accessed.  This is
 750 useful if you're carrying about ordering or calling the iterator from more
 751 than one sequence, or not really storing things in a hash anywhere.
 752
 753 For our example, we're using a real hash so we'll do just the simple
 754 thing, but we'll have to go through the LIST field indirectly.
 755
 756     sub NEXTKEY  {
 757         carp &whowasi if $DEBUG;
 758         my $self = shift;
 759         return each %{ $self->{LIST} }
 760     }
 761
 762 =item UNTIE this
 763
 764 This is called when C<untie> occurs.
 765
 766 =item DESTROY this
 767
 768 This method is triggered when a tied hash is about to go out of
 769 scope.  You don't really need it unless you're trying to add debugging
 770 or have auxiliary state to clean up.  Here's a very simple function:
 771
 772     sub DESTROY  {
 773         carp &whowasi if $DEBUG;
 774     }
 775
 776 =back
 777
 778 Note that functions such as keys() and values() may return huge lists
 779 when used on large objects, like DBM files.  You may prefer to use the
 780 each() function to iterate over such.  Example:
 781
 782     # print out history file offsets
 783     use NDBM_File;
 784     tie(%HIST, 'NDBM_File', '/usr/lib/news/history', 1, 0);
 785     while (($key,$val) = each %HIST) {
 786         print $key, ' = ', unpack('L',$val), "\n";
 787     }
 788     untie(%HIST);
 789
 790 =head2 Tying FileHandles
 791
 792 This is partially implemented now.
 793
 794 A class implementing a tied filehandle should define the following
 795 methods: TIEHANDLE, at least one of PRINT, PRINTF, WRITE, READLINE, GETC,
 796 READ, and possibly CLOSE, UNTIE and DESTROY.  The class can also provide: BINMODE,
 797 OPEN, EOF, FILENO, SEEK, TELL - if the corresponding perl operators are
 798 used on the handle.
 799
 800 It is especially useful when perl is embedded in some other program,
 801 where output to STDOUT and STDERR may have to be redirected in some
 802 special way. See nvi and the Apache module for examples.
 803
 804 In our example we're going to create a shouting handle.
 805
 806     package Shout;
 807
 808 =over 4
 809
 810 =item TIEHANDLE classname, LIST
 811
 812 This is the constructor for the class.  That means it is expected to
 813 return a blessed reference of some sort. The reference can be used to
 814 hold some internal information.
 815
 816     sub TIEHANDLE { print "<shout>\n"; my $i; bless \$i, shift }
 817
 818 =item WRITE this, LIST
 819
 820 This method will be called when the handle is written to via the
 821 C<syswrite> function.
 822
 823     sub WRITE {
 824         $r = shift;
 825         my($buf,$len,$offset) = @_;
 826         print "WRITE called, \$buf=$buf, \$len=$len, \$offset=$offset";
 827     }
 828
 829 =item PRINT this, LIST
 830
 831 This method will be triggered every time the tied handle is printed to
 832 with the C<print()> function.
 833 Beyond its self reference it also expects the list that was passed to
 834 the print function.
 835
 836     sub PRINT { $r = shift; $$r++; print join($,,map(uc($_),@_)),$\ }
 837
 838 =item PRINTF this, LIST
 839
 840 This method will be triggered every time the tied handle is printed to
 841 with the C<printf()> function.
 842 Beyond its self reference it also expects the format and list that was
 843 passed to the printf function.
 844
 845     sub PRINTF {
 846         shift;
 847         my $fmt = shift;
 848         print sprintf($fmt, @_)."\n";
 849     }
 850
 851 =item READ this, LIST
 852
 853 This method will be called when the handle is read from via the C<read>
 854 or C<sysread> functions.
 855
 856     sub READ {
 857         my $self = shift;
 858         my $$bufref = \$_[0];
 859         my(undef,$len,$offset) = @_;
 860         print "READ called, \$buf=$bufref, \$len=$len, \$offset=$offset";
 861         # add to $$bufref, set $len to number of characters read
 862         $len;
 863     }
 864
 865 =item READLINE this
 866
 867 This method will be called when the handle is read from via <HANDLE>.
 868 The method should return undef when there is no more data.
 869
 870     sub READLINE { $r = shift; "READLINE called $$r times\n"; }
 871
 872 =item GETC this
 873
 874 This method will be called when the C<getc> function is called.
 875
 876     sub GETC { print "Don't GETC, Get Perl"; return "a"; }
 877
 878 =item CLOSE this
 879
 880 This method will be called when the handle is closed via the C<close>
 881 function.
 882
 883     sub CLOSE { print "CLOSE called.\n" }
 884
 885 =item UNTIE this
 886
 887 As with the other types of ties, this method will be called when C<untie> happens.
 888 It may be appropriate to "auto CLOSE" when this occurs.
 889
 890 =item DESTROY this
 891
 892 As with the other types of ties, this method will be called when the
 893 tied handle is about to be destroyed. This is useful for debugging and
 894 possibly cleaning up.
 895
 896     sub DESTROY { print "</shout>\n" }
 897
 898 =back
 899
 900 Here's how to use our little example:
 901
 902     tie(*FOO,'Shout');
 903     print FOO "hello\n";
 904     $a = 4; $b = 6;
 905     print FOO $a, " plus ", $b, " equals ", $a + $b, "\n";
 906     print <FOO>;
 907
 908 =head2 UNTIE this
 909
 910 You can define for all tie types an UNTIE method that will be called
 911 at untie().
 912
 913 =head2 The C<untie> Gotcha
 914
 915 If you intend making use of the object returned from either tie() or
 916 tied(), and if the tie's target class defines a destructor, there is a
 917 subtle gotcha you I<must> guard against.
 918
 919 As setup, consider this (admittedly rather contrived) example of a
 920 tie; all it does is use a file to keep a log of the values assigned to
 921 a scalar.
 922
 923     package Remember;
 924
 925     use strict;
 926     use warnings;
 927     use IO::File;
 928
 929     sub TIESCALAR {
 930         my $class = shift;
 931         my $filename = shift;
 932         my $handle = new IO::File "> $filename"
 933                          or die "Cannot open $filename: $!\n";
 934
 935         print $handle "The Start\n";
 936         bless {FH => $handle, Value => 0}, $class;
 937     }
 938
 939     sub FETCH {
 940         my $self = shift;
 941         return $self->{Value};
 942     }
 943
 944     sub STORE {
 945         my $self = shift;
 946         my $value = shift;
 947         my $handle = $self->{FH};
 948         print $handle "$value\n";
 949         $self->{Value} = $value;
 950     }
 951
 952     sub DESTROY {
 953         my $self = shift;
 954         my $handle = $self->{FH};
 955         print $handle "The End\n";
 956         close $handle;
 957     }
 958
 959     1;
 960
 961 Here is an example that makes use of this tie:
 962
 963     use strict;
 964     use Remember;
 965
 966     my $fred;
 967     tie $fred, 'Remember', 'myfile.txt';
 968     $fred = 1;
 969     $fred = 4;
 970     $fred = 5;
 971     untie $fred;
 972     system "cat myfile.txt";
 973
 974 This is the output when it is executed:
 975
 976     The Start
 977     1
 978     4
 979     5
 980     The End
 981
 982 So far so good.  Those of you who have been paying attention will have
 983 spotted that the tied object hasn't been used so far.  So lets add an
 984 extra method to the Remember class to allow comments to be included in
 985 the file -- say, something like this:
 986
 987     sub comment {
 988         my $self = shift;
 989         my $text = shift;
 990         my $handle = $self->{FH};
 991         print $handle $text, "\n";
 992     }
 993
 994 And here is the previous example modified to use the C<comment> method
 995 (which requires the tied object):
 996
 997     use strict;
 998     use Remember;
 999
1000     my ($fred, $x);
1001     $x = tie $fred, 'Remember', 'myfile.txt';
1002     $fred = 1;
1003     $fred = 4;
1004     comment $x "changing...";
1005     $fred = 5;
1006     untie $fred;
1007     system "cat myfile.txt";
1008
1009 When this code is executed there is no output.  Here's why:
1010
1011 When a variable is tied, it is associated with the object which is the
1012 return value of the TIESCALAR, TIEARRAY, or TIEHASH function.  This
1013 object normally has only one reference, namely, the implicit reference
1014 from the tied variable.  When untie() is called, that reference is
1015 destroyed.  Then, as in the first example above, the object's
1016 destructor (DESTROY) is called, which is normal for objects that have
1017 no more valid references; and thus the file is closed.
1018
1019 In the second example, however, we have stored another reference to
1020 the tied object in $x.  That means that when untie() gets called
1021 there will still be a valid reference to the object in existence, so
1022 the destructor is not called at that time, and thus the file is not
1023 closed.  The reason there is no output is because the file buffers
1024 have not been flushed to disk.
1025
1026 Now that you know what the problem is, what can you do to avoid it?
1027 Prior to the introduction of the optional UNTIE method the only way
1028 was the good old C<-w> flag. Which will spot any instances where you call
1029 untie() and there are still valid references to the tied object.  If
1030 the second script above this near the top C<use warnings 'untie'>
1031 or was run with the C<-w> flag, Perl prints this
1032 warning message:
1033
1034     untie attempted while 1 inner references still exist
1035
1036 To get the script to work properly and silence the warning make sure
1037 there are no valid references to the tied object I<before> untie() is
1038 called:
1039
1040     undef $x;
1041     untie $fred;
1042
1043 Now that UNTIE exists the class designer can decide which parts of the
1044 class functionality are really associated with C<untie> and which with
1045 the object being destroyed. What makes sense for a given class depends
1046 on whether the inner references are being kept so that non-tie-related
1047 methods can be called on the object. But in most cases it probably makes
1048 sense to move the functionality that would have been in DESTROY to the UNTIE
1049 method.
1050
1051 If the UNTIE method exists then the warning above does not occur. Instead the
1052 UNTIE method is passed the count of "extra" references and can issue its own
1053 warning if appropriate. e.g. to replicate the no UNTIE case this method can
1054 be used:
1055
1056     sub UNTIE
1057     {
1058      my ($obj,$count) = @_;
1059      carp "untie attempted while $count inner references still exist" if $count;
1060     }
1061
1062 =head1 SEE ALSO
1063
1064 See L<DB_File> or L<Config> for some interesting tie() implementations.
1065 A good starting point for many tie() implementations is with one of the
1066 modules L<Tie::Scalar>, L<Tie::Array>, L<Tie::Hash>, or L<Tie::Handle>.
1067
1068 =head1 BUGS
1069
1070 You cannot easily tie a multilevel data structure (such as a hash of
1071 hashes) to a dbm file.  The first problem is that all but GDBM and
1072 Berkeley DB have size limitations, but beyond that, you also have problems
1073 with how references are to be represented on disk.  One experimental
1074 module that does attempt to address this need partially is the MLDBM
1075 module.  Check your nearest CPAN site as described in L<perlmodlib> for
1076 source code to MLDBM.
1077
1078 Tied filehandles are still incomplete.  sysopen(), truncate(),
1079 flock(), fcntl(), stat() and -X can't currently be trapped.
1080
1081 =head1 AUTHOR
1082
1083 Tom Christiansen
1084
1085 TIEHANDLE by Sven Verdoolaege <F<skimo@dns.ufsia.ac.be>> and Doug MacEachern <F<dougm@osf.org>>
1086
1087 UNTIE by Nick Ing-Simmons <F<nick@ing-simmons.net>>
1088
1089 Tying Arrays by Casey Tweten <F<crt@kiski.net>>