3 perlthrtut - Tutorial on threads in Perl
7 This tutorial describes the use of Perl interpreter threads (sometimes
8 referred to as I<ithreads>) that was first introduced in Perl 5.6.0. In this
9 model, each thread runs in its own Perl interpreter, and any data sharing
10 between threads must be explicit. The user-level interface for I<ithreads>
11 uses the L<threads> class.
13 B<NOTE>: There is another older Perl threading flavor called the 5.005 model
14 that used the L<Threads> class. This old model is known to have problems, is
15 deprecated, and support for it will be removed in release 5.10. You are
16 strongly encouraged to migrate any existing 5.005 threads code to the new
17 model as soon as possible.
19 You can see which (or neither) threading flavour you have by
20 running C<perl -V> and looking at the C<Platform> section.
21 If you have C<useithreads=define> you have ithreads, if you
22 have C<use5005threads=define> you have 5.005 threads.
23 If you have neither, you don't have any thread support built in.
24 If you have both, you are in trouble.
26 The L<threads> and L<threads::shared> modules are included in the core Perl
27 distribution. Additionally, they are maintained as a separate modules on
28 CPAN, so you can check there for any updates.
30 =head1 What Is A Thread Anyway?
32 A thread is a flow of control through a program with a single
35 Sounds an awful lot like a process, doesn't it? Well, it should.
36 Threads are one of the pieces of a process. Every process has at least
37 one thread and, up until now, every process running Perl had only one
38 thread. With 5.8, though, you can create extra threads. We're going
39 to show you how, when, and why.
41 =head1 Threaded Program Models
43 There are three basic ways that you can structure a threaded
44 program. Which model you choose depends on what you need your program
45 to do. For many non-trivial threaded programs, you'll need to choose
46 different models for different pieces of your program.
50 The boss/worker model usually has one I<boss> thread and one or more
51 I<worker> threads. The boss thread gathers or generates tasks that need
52 to be done, then parcels those tasks out to the appropriate worker
55 This model is common in GUI and server programs, where a main thread
56 waits for some event and then passes that event to the appropriate
57 worker threads for processing. Once the event has been passed on, the
58 boss thread goes back to waiting for another event.
60 The boss thread does relatively little work. While tasks aren't
61 necessarily performed faster than with any other method, it tends to
62 have the best user-response times.
66 In the work crew model, several threads are created that do
67 essentially the same thing to different pieces of data. It closely
68 mirrors classical parallel processing and vector processors, where a
69 large array of processors do the exact same thing to many pieces of
72 This model is particularly useful if the system running the program
73 will distribute multiple threads across different processors. It can
74 also be useful in ray tracing or rendering engines, where the
75 individual threads can pass on interim results to give the user visual
80 The pipeline model divides up a task into a series of steps, and
81 passes the results of one step on to the thread processing the
82 next. Each thread does one thing to each piece of data and passes the
83 results to the next thread in line.
85 This model makes the most sense if you have multiple processors so two
86 or more threads will be executing in parallel, though it can often
87 make sense in other contexts as well. It tends to keep the individual
88 tasks small and simple, as well as allowing some parts of the pipeline
89 to block (on I/O or system calls, for example) while other parts keep
90 going. If you're running different parts of the pipeline on different
91 processors you may also take advantage of the caches on each
94 This model is also handy for a form of recursive programming where,
95 rather than having a subroutine call itself, it instead creates
96 another thread. Prime and Fibonacci generators both map well to this
97 form of the pipeline model. (A version of a prime number generator is
100 =head1 What kind of threads are Perl threads?
102 If you have experience with other thread implementations, you might
103 find that things aren't quite what you expect. It's very important to
104 remember when dealing with Perl threads that I<Perl Threads Are Not X
105 Threads> for all values of X. They aren't POSIX threads, or
106 DecThreads, or Java's Green threads, or Win32 threads. There are
107 similarities, and the broad concepts are the same, but if you start
108 looking for implementation details you're going to be either
109 disappointed or confused. Possibly both.
111 This is not to say that Perl threads are completely different from
112 everything that's ever come before -- they're not. Perl's threading
113 model owes a lot to other thread models, especially POSIX. Just as
114 Perl is not C, though, Perl threads are not POSIX threads. So if you
115 find yourself looking for mutexes, or thread priorities, it's time to
116 step back a bit and think about what you want to do and how Perl can
119 However, it is important to remember that Perl threads cannot magically
120 do things unless your operating system's threads allows it. So if your
121 system blocks the entire process on C<sleep()>, Perl usually will, as well.
123 B<Perl Threads Are Different.>
125 =head1 Thread-Safe Modules
127 The addition of threads has changed Perl's internals
128 substantially. There are implications for people who write
129 modules with XS code or external libraries. However, since Perl data is
130 not shared among threads by default, Perl modules stand a high chance of
131 being thread-safe or can be made thread-safe easily. Modules that are not
132 tagged as thread-safe should be tested or code reviewed before being used
135 Not all modules that you might use are thread-safe, and you should
136 always assume a module is unsafe unless the documentation says
137 otherwise. This includes modules that are distributed as part of the
138 core. Threads are a relatively new feature, and even some of the standard
139 modules aren't thread-safe.
141 Even if a module is thread-safe, it doesn't mean that the module is optimized
142 to work well with threads. A module could possibly be rewritten to utilize
143 the new features in threaded Perl to increase performance in a threaded
146 If you're using a module that's not thread-safe for some reason, you
147 can protect yourself by using it from one, and only one thread at all.
148 If you need multiple threads to access such a module, you can use semaphores and
149 lots of programming discipline to control access to it. Semaphores
150 are covered in L</"Basic semaphores">.
152 See also L</"Thread-Safety of System Libraries">.
156 The L<threads> module provides the basic functions you need to write
157 threaded programs. In the following sections, we'll cover the basics,
158 showing you what you need to do to create a threaded program. After
159 that, we'll go over some of the features of the L<threads> module that
160 make threaded programming easier.
162 =head2 Basic Thread Support
164 Thread support is a Perl compile-time option -- it's something that's
165 turned on or off when Perl is built at your site, rather than when
166 your programs are compiled. If your Perl wasn't compiled with thread
167 support enabled, then any attempt to use threads will fail.
169 Your programs can use the Config module to check whether threads are
170 enabled. If your program can't run without them, you can say something
174 $Config{useithreads} or die('Recompile Perl with threads to run this program.');
176 A possibly-threaded program using a possibly-threaded module might
183 if ($Config{useithreads}) {
185 require MyMod_threaded;
186 import MyMod_threaded;
188 require MyMod_unthreaded;
189 import MyMod_unthreaded;
193 Since code that runs both with and without threads is usually pretty
194 messy, it's best to isolate the thread-specific code in its own
195 module. In our example above, that's what C<MyMod_threaded> is, and it's
196 only imported if we're running on a threaded Perl.
198 =head2 A Note about the Examples
200 In a real situation, care should be taken that all threads are finished
201 executing before the program exits. That care has B<not> been taken in these
202 examples in the interest of simplicity. Running these examples I<as is> will
203 produce error messages, usually caused by the fact that there are still
204 threads running when the program exits. You should not be alarmed by this.
206 =head2 Creating Threads
208 The L<threads> module provides the tools you need to create new
209 threads. Like any other module, you need to tell Perl that you want to use
210 it; C<use threads;> imports all the pieces you need to create basic
213 The simplest, most straightforward way to create a thread is with C<create()>:
217 my $thr = threads->create(\&sub1);
220 print("In the thread\n");
223 The C<create()> method takes a reference to a subroutine and creates a new
224 thread that starts executing in the referenced subroutine. Control
225 then passes both to the subroutine and the caller.
227 If you need to, your program can pass parameters to the subroutine as
228 part of the thread startup. Just include the list of parameters as
229 part of the C<threads-E<gt>create()> call, like this:
234 my $thr1 = threads->create(\&sub1, 'Param 1', 'Param 2', $Param3);
235 my @ParamList = (42, 'Hello', 3.14);
236 my $thr2 = threads->create(\&sub1, @ParamList);
237 my $thr3 = threads->create(\&sub1, qw(Param1 Param2 Param3));
240 my @InboundParameters = @_;
241 print("In the thread\n");
242 print('Got parameters >', join('<>', @InboundParameters), "<\n");
245 The last example illustrates another feature of threads. You can spawn
246 off several threads using the same subroutine. Each thread executes
247 the same subroutine, but in a separate thread with a separate
248 environment and potentially separate arguments.
250 C<new()> is a synonym for C<create()>.
252 =head2 Waiting For A Thread To Exit
254 Since threads are also subroutines, they can return values. To wait
255 for a thread to exit and extract any values it might return, you can
256 use the C<join()> method:
260 my ($thr) = threads->create(\&sub1);
262 my @ReturnData = $thr->join();
263 print('Thread returned ', join(', ', @ReturnData), "\n");
265 sub sub1 { return ('Fifty-six', 'foo', 2); }
267 In the example above, the C<join()> method returns as soon as the thread
268 ends. In addition to waiting for a thread to finish and gathering up
269 any values that the thread might have returned, C<join()> also performs
270 any OS cleanup necessary for the thread. That cleanup might be
271 important, especially for long-running programs that spawn lots of
272 threads. If you don't want the return values and don't want to wait
273 for the thread to finish, you should call the C<detach()> method
274 instead, as described next.
276 NOTE: In the example above, the thread returns a list, thus necessitating
277 that the thread creation call be made in list context (i.e., C<my ($thr)>).
278 See L<threads/"$thr->join()"> and L<threads/"THREAD CONTEXT"> for more
279 details on thread context and return values.
281 =head2 Ignoring A Thread
283 C<join()> does three things: it waits for a thread to exit, cleans up
284 after it, and returns any data the thread may have produced. But what
285 if you're not interested in the thread's return values, and you don't
286 really care when the thread finishes? All you want is for the thread
287 to get cleaned up after when it's done.
289 In this case, you use the C<detach()> method. Once a thread is detached,
290 it'll run until it's finished; then Perl will clean up after it
295 my $thr = threads->create(\&sub1); # Spawn the thread
297 $thr->detach(); # Now we officially don't care any more
299 sleep(15); # Let thread run for awhile
305 print("\$a is $a\n");
310 Once a thread is detached, it may not be joined, and any return data
311 that it might have produced (if it was done and waiting for a join) is
314 C<detach()> can also be called as a class method to allow a thread to
319 my $thr = threads->create(\&sub1);
326 =head1 Threads And Data
328 Now that we've covered the basics of threads, it's time for our next
329 topic: Data. Threading introduces a couple of complications to data
330 access that non-threaded programs never need to worry about.
332 =head2 Shared And Unshared Data
334 The biggest difference between Perl I<ithreads> and the old 5.005 style
335 threading, or for that matter, to most other threading systems out there,
336 is that by default, no data is shared. When a new Perl thread is created,
337 all the data associated with the current thread is copied to the new
338 thread, and is subsequently private to that new thread!
339 This is similar in feel to what happens when a UNIX process forks,
340 except that in this case, the data is just copied to a different part of
341 memory within the same process rather than a real fork taking place.
343 To make use of threading, however, one usually wants the threads to share
344 at least some data between themselves. This is done with the
345 L<threads::shared> module and the C<:shared> attribute:
352 threads->create(sub { $foo++; $bar++; })->join();
354 print("$foo\n"); # Prints 2 since $foo is shared
355 print("$bar\n"); # Prints 1 since $bar is not shared
357 In the case of a shared array, all the array's elements are shared, and for
358 a shared hash, all the keys and values are shared. This places
359 restrictions on what may be assigned to shared array and hash elements: only
360 simple values or references to shared variables are allowed - this is
361 so that a private variable can't accidentally become shared. A bad
362 assignment will cause the thread to die. For example:
368 my $svar :shared = 2;
371 ... create some threads ...
373 $hash{a} = 1; # All threads see exists($hash{a}) and $hash{a} == 1
374 $hash{a} = $var; # okay - copy-by-value: same effect as previous
375 $hash{a} = $svar; # okay - copy-by-value: same effect as previous
376 $hash{a} = \$svar; # okay - a reference to a shared variable
377 $hash{a} = \$var; # This will die
378 delete($hash{a}); # okay - all threads will see !exists($hash{a})
380 Note that a shared variable guarantees that if two or more threads try to
381 modify it at the same time, the internal state of the variable will not
382 become corrupted. However, there are no guarantees beyond this, as
383 explained in the next section.
385 =head2 Thread Pitfalls: Races
387 While threads bring a new set of useful tools, they also bring a
388 number of pitfalls. One pitfall is the race condition:
394 my $thr1 = threads->create(\&sub1);
395 my $thr2 = threads->create(\&sub2);
401 sub sub1 { my $foo = $a; $a = $foo + 1; }
402 sub sub2 { my $bar = $a; $a = $bar + 1; }
404 What do you think C<$a> will be? The answer, unfortunately, is I<it
405 depends>. Both C<sub1()> and C<sub2()> access the global variable C<$a>, once
406 to read and once to write. Depending on factors ranging from your
407 thread implementation's scheduling algorithm to the phase of the moon,
410 Race conditions are caused by unsynchronized access to shared
411 data. Without explicit synchronization, there's no way to be sure that
412 nothing has happened to the shared data between the time you access it
413 and the time you update it. Even this simple code fragment has the
414 possibility of error:
420 my $thr1 = threads->create(sub { $b = $a; $a = $b + 1; });
421 my $thr2 = threads->create(sub { $c = $a; $a = $c + 1; });
425 Two threads both access C<$a>. Each thread can potentially be interrupted
426 at any point, or be executed in any order. At the end, C<$a> could be 3
427 or 4, and both C<$b> and C<$c> could be 2 or 3.
429 Even C<$a += 5> or C<$a++> are not guaranteed to be atomic.
431 Whenever your program accesses data or resources that can be accessed
432 by other threads, you must take steps to coordinate access or risk
433 data inconsistency and race conditions. Note that Perl will protect its
434 internals from your race conditions, but it won't protect you from you.
436 =head1 Synchronization and control
438 Perl provides a number of mechanisms to coordinate the interactions
439 between themselves and their data, to avoid race conditions and the like.
440 Some of these are designed to resemble the common techniques used in thread
441 libraries such as C<pthreads>; others are Perl-specific. Often, the
442 standard techniques are clumsy and difficult to get right (such as
443 condition waits). Where possible, it is usually easier to use Perlish
444 techniques such as queues, which remove some of the hard work involved.
446 =head2 Controlling access: lock()
448 The C<lock()> function takes a shared variable and puts a lock on it.
449 No other thread may lock the variable until the variable is unlocked
450 by the thread holding the lock. Unlocking happens automatically
451 when the locking thread exits the block that contains the call to the
452 C<lock()> function. Using C<lock()> is straightforward: This example has
453 several threads doing some calculations in parallel, and occasionally
454 updating a running total:
459 my $total :shared = 0;
464 # (... do some calculations and set $result ...)
466 lock($total); # Block until we obtain the lock
468 } # Lock implicitly released at end of scope
469 last if $result == 0;
473 my $thr1 = threads->create(\&calc);
474 my $thr2 = threads->create(\&calc);
475 my $thr3 = threads->create(\&calc);
479 print("total=$total\n");
481 C<lock()> blocks the thread until the variable being locked is
482 available. When C<lock()> returns, your thread can be sure that no other
483 thread can lock that variable until the block containing the
486 It's important to note that locks don't prevent access to the variable
487 in question, only lock attempts. This is in keeping with Perl's
488 longstanding tradition of courteous programming, and the advisory file
489 locking that C<flock()> gives you.
491 You may lock arrays and hashes as well as scalars. Locking an array,
492 though, will not block subsequent locks on array elements, just lock
493 attempts on the array itself.
495 Locks are recursive, which means it's okay for a thread to
496 lock a variable more than once. The lock will last until the outermost
497 C<lock()> on the variable goes out of scope. For example:
505 lock($x); # Wait for lock
506 lock($x); # NOOP - we already have the lock
514 } # *** Implicit unlock here ***
518 sub lockit_some_more {
520 } # Nothing happens here
522 Note that there is no C<unlock()> function - the only way to unlock a
523 variable is to allow it to go out of scope.
525 A lock can either be used to guard the data contained within the variable
526 being locked, or it can be used to guard something else, like a section
527 of code. In this latter case, the variable in question does not hold any
528 useful data, and exists only for the purpose of being locked. In this
529 respect, the variable behaves like the mutexes and basic semaphores of
530 traditional thread libraries.
532 =head2 A Thread Pitfall: Deadlocks
534 Locks are a handy tool to synchronize access to data, and using them
535 properly is the key to safe shared data. Unfortunately, locks aren't
536 without their dangers, especially when multiple locks are involved.
537 Consider the following code:
542 my $b :shared = 'foo';
543 my $thr1 = threads->create(sub {
548 my $thr2 = threads->create(sub {
554 This program will probably hang until you kill it. The only way it
555 won't hang is if one of the two threads acquires both locks
556 first. A guaranteed-to-hang version is more complicated, but the
557 principle is the same.
559 The first thread will grab a lock on C<$a>, then, after a pause during which
560 the second thread has probably had time to do some work, try to grab a
561 lock on C<$b>. Meanwhile, the second thread grabs a lock on C<$b>, then later
562 tries to grab a lock on C<$a>. The second lock attempt for both threads will
563 block, each waiting for the other to release its lock.
565 This condition is called a deadlock, and it occurs whenever two or
566 more threads are trying to get locks on resources that the others
567 own. Each thread will block, waiting for the other to release a lock
568 on a resource. That never happens, though, since the thread with the
569 resource is itself waiting for a lock to be released.
571 There are a number of ways to handle this sort of problem. The best
572 way is to always have all threads acquire locks in the exact same
573 order. If, for example, you lock variables C<$a>, C<$b>, and C<$c>, always lock
574 C<$a> before C<$b>, and C<$b> before C<$c>. It's also best to hold on to locks for
575 as short a period of time to minimize the risks of deadlock.
577 The other synchronization primitives described below can suffer from
580 =head2 Queues: Passing Data Around
582 A queue is a special thread-safe object that lets you put data in one
583 end and take it out the other without having to worry about
584 synchronization issues. They're pretty straightforward, and look like
590 my $DataQueue = Thread::Queue->new();
591 my $thr = threads->create(sub {
592 while (my $DataElement = $DataQueue->dequeue()) {
593 print("Popped $DataElement off the queue\n");
597 $DataQueue->enqueue(12);
598 $DataQueue->enqueue("A", "B", "C");
599 $DataQueue->enqueue(\$thr);
601 $DataQueue->enqueue(undef);
604 You create the queue with C<Thread::Queue-E<gt>new()>. Then you can
605 add lists of scalars onto the end with C<enqueue()>, and pop scalars off
606 the front of it with C<dequeue()>. A queue has no fixed size, and can grow
607 as needed to hold everything pushed on to it.
609 If a queue is empty, C<dequeue()> blocks until another thread enqueues
610 something. This makes queues ideal for event loops and other
611 communications between threads.
613 =head2 Semaphores: Synchronizing Data Access
615 Semaphores are a kind of generic locking mechanism. In their most basic
616 form, they behave very much like lockable scalars, except that they
617 can't hold data, and that they must be explicitly unlocked. In their
618 advanced form, they act like a kind of counter, and can allow multiple
619 threads to have the I<lock> at any one time.
621 =head2 Basic semaphores
623 Semaphores have two methods, C<down()> and C<up()>: C<down()> decrements the resource
624 count, while up() increments it. Calls to C<down()> will block if the
625 semaphore's current count would decrement below zero. This program
626 gives a quick demonstration:
629 use Thread::Semaphore;
631 my $semaphore = Thread::Semaphore->new();
632 my $GlobalVariable :shared = 0;
634 $thr1 = threads->create(\&sample_sub, 1);
635 $thr2 = threads->create(\&sample_sub, 2);
636 $thr3 = threads->create(\&sample_sub, 3);
639 my $SubNumber = shift(@_);
643 while ($TryCount--) {
645 $LocalCopy = $GlobalVariable;
646 print("$TryCount tries left for sub $SubNumber (\$GlobalVariable is $GlobalVariable)\n");
649 $GlobalVariable = $LocalCopy;
658 The three invocations of the subroutine all operate in sync. The
659 semaphore, though, makes sure that only one thread is accessing the
660 global variable at once.
662 =head2 Advanced Semaphores
664 By default, semaphores behave like locks, letting only one thread
665 C<down()> them at a time. However, there are other uses for semaphores.
667 Each semaphore has a counter attached to it. By default, semaphores are
668 created with the counter set to one, C<down()> decrements the counter by
669 one, and C<up()> increments by one. However, we can override any or all
670 of these defaults simply by passing in different values:
673 use Thread::Semaphore;
675 my $semaphore = Thread::Semaphore->new(5);
676 # Creates a semaphore with the counter set to five
678 my $thr1 = threads->create(\&sub1);
679 my $thr2 = threads->create(\&sub1);
682 $semaphore->down(5); # Decrements the counter by five
684 $semaphore->up(5); # Increment the counter by five
690 If C<down()> attempts to decrement the counter below zero, it blocks until
691 the counter is large enough. Note that while a semaphore can be created
692 with a starting count of zero, any C<up()> or C<down()> always changes the
693 counter by at least one, and so C<$semaphore->down(0)> is the same as
694 C<$semaphore->down(1)>.
696 The question, of course, is why would you do something like this? Why
697 create a semaphore with a starting count that's not one, or why
698 decrement or increment it by more than one? The answer is resource
699 availability. Many resources that you want to manage access for can be
700 safely used by more than one thread at once.
702 For example, let's take a GUI driven program. It has a semaphore that
703 it uses to synchronize access to the display, so only one thread is
704 ever drawing at once. Handy, but of course you don't want any thread
705 to start drawing until things are properly set up. In this case, you
706 can create a semaphore with a counter set to zero, and up it when
707 things are ready for drawing.
709 Semaphores with counters greater than one are also useful for
710 establishing quotas. Say, for example, that you have a number of
711 threads that can do I/O at once. You don't want all the threads
712 reading or writing at once though, since that can potentially swamp
713 your I/O channels, or deplete your process' quota of filehandles. You
714 can use a semaphore initialized to the number of concurrent I/O
715 requests (or open files) that you want at any one time, and have your
716 threads quietly block and unblock themselves.
718 Larger increments or decrements are handy in those cases where a
719 thread needs to check out or return a number of resources at once.
721 =head2 cond_wait() and cond_signal()
723 These two functions can be used in conjunction with locks to notify
724 co-operating threads that a resource has become available. They are
725 very similar in use to the functions found in C<pthreads>. However
726 for most purposes, queues are simpler to use and more intuitive. See
727 L<threads::shared> for more details.
729 =head2 Giving up control
731 There are times when you may find it useful to have a thread
732 explicitly give up the CPU to another thread. You may be doing something
733 processor-intensive and want to make sure that the user-interface thread
734 gets called frequently. Regardless, there are times that you might want
735 a thread to give up the processor.
737 Perl's threading package provides the C<yield()> function that does
738 this. C<yield()> is pretty straightforward, and works like this:
745 while($foo--) { print("In thread $thread\n"); }
748 while($foo--) { print("In thread $thread\n"); }
751 my $thr1 = threads->create(\&loop, 'first');
752 my $thr2 = threads->create(\&loop, 'second');
753 my $thr3 = threads->create(\&loop, 'third');
755 It is important to remember that C<yield()> is only a hint to give up the CPU,
756 it depends on your hardware, OS and threading libraries what actually happens.
757 B<On many operating systems, yield() is a no-op.> Therefore it is important
758 to note that one should not build the scheduling of the threads around
759 C<yield()> calls. It might work on your platform but it won't work on another
762 =head1 General Thread Utility Routines
764 We've covered the workhorse parts of Perl's threading package, and
765 with these tools you should be well on your way to writing threaded
766 code and packages. There are a few useful little pieces that didn't
767 really fit in anyplace else.
769 =head2 What Thread Am I In?
771 The C<threads-E<gt>self()> class method provides your program with a way to
772 get an object representing the thread it's currently in. You can use this
773 object in the same way as the ones returned from thread creation.
777 C<tid()> is a thread object method that returns the thread ID of the
778 thread the object represents. Thread IDs are integers, with the main
779 thread in a program being 0. Currently Perl assigns a unique TID to
780 every thread ever created in your program, assigning the first thread
781 to be created a tid of 1, and increasing the tid by 1 for each new
782 thread that's created. When used as a class method, C<threads-E<gt>tid()>
783 can be used by a thread to get its own TID.
785 =head2 Are These Threads The Same?
787 The C<equal()> method takes two thread objects and returns true
788 if the objects represent the same thread, and false if they don't.
790 Thread objects also have an overloaded C<==> comparison so that you can do
791 comparison on them as you would with normal objects.
793 =head2 What Threads Are Running?
795 C<threads-E<gt>list()> returns a list of thread objects, one for each thread
796 that's currently running and not detached. Handy for a number of things,
797 including cleaning up at the end of your program (from the main Perl thread,
800 # Loop through all the threads
801 foreach my $thr (threads->list()) {
805 If some threads have not finished running when the main Perl thread
806 ends, Perl will warn you about it and die, since it is impossible for Perl
807 to clean up itself while other threads are running.
809 NOTE: The main Perl thread (thread 0) is in a I<detached> state, and so
810 does not appear in the list returned by C<threads-E<gt>list()>.
812 =head1 A Complete Example
814 Confused yet? It's time for an example program to show some of the
815 things we've covered. This program finds prime numbers using threads.
818 2 # prime-pthread, courtesy of Tom Christiansen
826 10 my $stream = Thread::Queue->new();
827 11 for my $i ( 3 .. 1000 ) {
828 12 $stream->enqueue($i);
830 14 $stream->enqueue(undef);
832 16 threads->create(\&check_num, $stream, 2);
836 20 my ($upstream, $cur_prime) = @_;
838 22 my $downstream = Thread::Queue->new();
839 23 while (my $num = $upstream->dequeue()) {
840 24 next unless ($num % $cur_prime);
842 26 $downstream->enqueue($num);
844 28 print("Found prime $num\n");
845 29 $kid = threads->create(\&check_num, $downstream, $num);
849 33 $downstream->enqueue(undef);
854 This program uses the pipeline model to generate prime numbers. Each
855 thread in the pipeline has an input queue that feeds numbers to be
856 checked, a prime number that it's responsible for, and an output queue
857 into which it funnels numbers that have failed the check. If the thread
858 has a number that's failed its check and there's no child thread, then
859 the thread must have found a new prime number. In that case, a new
860 child thread is created for that prime and stuck on the end of the
863 This probably sounds a bit more confusing than it really is, so let's
864 go through this program piece by piece and see what it does. (For
865 those of you who might be trying to remember exactly what a prime
866 number is, it's a number that's only evenly divisible by itself and 1.)
868 The bulk of the work is done by the C<check_num()> subroutine, which
869 takes a reference to its input queue and a prime number that it's
870 responsible for. After pulling in the input queue and the prime that
871 the subroutine is checking (line 20), we create a new queue (line 22)
872 and reserve a scalar for the thread that we're likely to create later
875 The while loop from lines 23 to line 31 grabs a scalar off the input
876 queue and checks against the prime this thread is responsible
877 for. Line 24 checks to see if there's a remainder when we divide the
878 number to be checked by our prime. If there is one, the number
879 must not be evenly divisible by our prime, so we need to either pass
880 it on to the next thread if we've created one (line 26) or create a
881 new thread if we haven't.
883 The new thread creation is line 29. We pass on to it a reference to
884 the queue we've created, and the prime number we've found.
886 Finally, once the loop terminates (because we got a 0 or C<undef> in the
887 queue, which serves as a note to terminate), we pass on the notice to our
888 child and wait for it to exit if we've created a child (lines 32 and
891 Meanwhile, back in the main thread, we first create a queue (line 10) and
892 queue up all the numbers from 3 to 1000 for checking (lines 11-13),
893 plus a termination notice (line 14). Then we create the initial child
894 threads (line 16), passing it the queue and the first prime: 2. Finally,
895 we wait for the first child thread to terminate (line 17). Because a
896 child won't terminate until its child has terminated, we know that we're
897 done once we return from the C<join()>.
899 That's how it works. It's pretty simple; as with many Perl programs,
900 the explanation is much longer than the program.
902 =head1 Different implementations of threads
904 Some background on thread implementations from the operating system
905 viewpoint. There are three basic categories of threads: user-mode threads,
906 kernel threads, and multiprocessor kernel threads.
908 User-mode threads are threads that live entirely within a program and
909 its libraries. In this model, the OS knows nothing about threads. As
910 far as it's concerned, your process is just a process.
912 This is the easiest way to implement threads, and the way most OSes
913 start. The big disadvantage is that, since the OS knows nothing about
914 threads, if one thread blocks they all do. Typical blocking activities
915 include most system calls, most I/O, and things like C<sleep()>.
917 Kernel threads are the next step in thread evolution. The OS knows
918 about kernel threads, and makes allowances for them. The main
919 difference between a kernel thread and a user-mode thread is
920 blocking. With kernel threads, things that block a single thread don't
921 block other threads. This is not the case with user-mode threads,
922 where the kernel blocks at the process level and not the thread level.
924 This is a big step forward, and can give a threaded program quite a
925 performance boost over non-threaded programs. Threads that block
926 performing I/O, for example, won't block threads that are doing other
927 things. Each process still has only one thread running at once,
928 though, regardless of how many CPUs a system might have.
930 Since kernel threading can interrupt a thread at any time, they will
931 uncover some of the implicit locking assumptions you may make in your
932 program. For example, something as simple as C<$a = $a + 2> can behave
933 unpredictably with kernel threads if C<$a> is visible to other
934 threads, as another thread may have changed C<$a> between the time it
935 was fetched on the right hand side and the time the new value is
938 Multiprocessor kernel threads are the final step in thread
939 support. With multiprocessor kernel threads on a machine with multiple
940 CPUs, the OS may schedule two or more threads to run simultaneously on
943 This can give a serious performance boost to your threaded program,
944 since more than one thread will be executing at the same time. As a
945 tradeoff, though, any of those nagging synchronization issues that
946 might not have shown with basic kernel threads will appear with a
949 In addition to the different levels of OS involvement in threads,
950 different OSes (and different thread implementations for a particular
951 OS) allocate CPU cycles to threads in different ways.
953 Cooperative multitasking systems have running threads give up control
954 if one of two things happen. If a thread calls a yield function, it
955 gives up control. It also gives up control if the thread does
956 something that would cause it to block, such as perform I/O. In a
957 cooperative multitasking implementation, one thread can starve all the
958 others for CPU time if it so chooses.
960 Preemptive multitasking systems interrupt threads at regular intervals
961 while the system decides which thread should run next. In a preemptive
962 multitasking system, one thread usually won't monopolize the CPU.
964 On some systems, there can be cooperative and preemptive threads
965 running simultaneously. (Threads running with realtime priorities
966 often behave cooperatively, for example, while threads running at
967 normal priorities behave preemptively.)
969 Most modern operating systems support preemptive multitasking nowadays.
971 =head1 Performance considerations
973 The main thing to bear in mind when comparing Perl's I<ithreads> to other threading
974 models is the fact that for each new thread created, a complete copy of
975 all the variables and data of the parent thread has to be taken. Thus,
976 thread creation can be quite expensive, both in terms of memory usage and
977 time spent in creation. The ideal way to reduce these costs is to have a
978 relatively short number of long-lived threads, all created fairly early
979 on -- before the base thread has accumulated too much data. Of course, this
980 may not always be possible, so compromises have to be made. However, after
981 a thread has been created, its performance and extra memory usage should
982 be little different than ordinary code.
984 Also note that under the current implementation, shared variables
985 use a little more memory and are a little slower than ordinary variables.
987 =head1 Process-scope Changes
989 Note that while threads themselves are separate execution threads and
990 Perl data is thread-private unless explicitly shared, the threads can
991 affect process-scope state, affecting all the threads.
993 The most common example of this is changing the current working
994 directory using C<chdir()>. One thread calls C<chdir()>, and the working
995 directory of all the threads changes.
997 Even more drastic example of a process-scope change is C<chroot()>:
998 the root directory of all the threads changes, and no thread can
999 undo it (as opposed to C<chdir()>).
1001 Further examples of process-scope changes include C<umask()> and
1002 changing uids and gids.
1004 Thinking of mixing C<fork()> and threads? Please lie down and wait
1005 until the feeling passes. Be aware that the semantics of C<fork()> vary
1006 between platforms. For example, some UNIX systems copy all the current
1007 threads into the child process, while others only copy the thread that
1008 called C<fork()>. You have been warned!
1010 Similarly, mixing signals and threads may be problematic.
1011 Implementations are platform-dependent, and even the POSIX
1012 semantics may not be what you expect (and Perl doesn't even
1013 give you the full POSIX API). For example, there is no way to
1014 guarantee that a signal sent to a multi-threaded Perl application
1015 will get intercepted by any particular thread. (However, a recently
1016 added feature does provide the capability to send signals between
1017 threads. See L<threads/"THREAD SIGNALLING> for more details.)
1019 =head1 Thread-Safety of System Libraries
1021 Whether various library calls are thread-safe is outside the control
1022 of Perl. Calls often suffering from not being thread-safe include:
1023 C<localtime()>, C<gmtime()>, C<get{gr,host,net,proto,serv,pw}*()>, C<readdir()>,
1024 C<rand()>, and C<srand()> -- in general, calls that depend on some global
1027 If the system Perl is compiled in has thread-safe variants of such
1028 calls, they will be used. Beyond that, Perl is at the mercy of
1029 the thread-safety or -unsafety of the calls. Please consult your
1030 C library call documentation.
1032 On some platforms the thread-safe library interfaces may fail if the
1033 result buffer is too small (for example the user group databases may
1034 be rather large, and the reentrant interfaces may have to carry around
1035 a full snapshot of those databases). Perl will start with a small
1036 buffer, but keep retrying and growing the result buffer
1037 until the result fits. If this limitless growing sounds bad for
1038 security or memory consumption reasons you can recompile Perl with
1039 C<PERL_REENTRANT_MAXSIZE> defined to the maximum number of bytes you will
1044 A complete thread tutorial could fill a book (and has, many times),
1045 but with what we've covered in this introduction, you should be well
1046 on your way to becoming a threaded Perl expert.
1050 Annotated POD for L<threads>:
1051 L<http://annocpan.org/?mode=search&field=Module&name=threads>
1053 Lastest version of L<threads> on CPAN:
1054 L<http://search.cpan.org/search?module=threads>
1056 Annotated POD for L<threads::shared>:
1057 L<http://annocpan.org/?mode=search&field=Module&name=threads%3A%3Ashared>
1059 Lastest version of L<threads::shared> on CPAN:
1060 L<http://search.cpan.org/search?module=threads%3A%3Ashared>
1062 Perl threads mailing list:
1063 L<http://lists.cpan.org/showlist.cgi?name=iThreads>
1067 Here's a short bibliography courtesy of Jürgen Christoffel:
1069 =head2 Introductory Texts
1071 Birrell, Andrew D. An Introduction to Programming with
1072 Threads. Digital Equipment Corporation, 1989, DEC-SRC Research Report
1074 http://gatekeeper.dec.com/pub/DEC/SRC/research-reports/abstracts/src-rr-035.html
1075 (highly recommended)
1077 Robbins, Kay. A., and Steven Robbins. Practical Unix Programming: A
1078 Guide to Concurrency, Communication, and
1079 Multithreading. Prentice-Hall, 1996.
1081 Lewis, Bill, and Daniel J. Berg. Multithreaded Programming with
1082 Pthreads. Prentice Hall, 1997, ISBN 0-13-443698-9 (a well-written
1083 introduction to threads).
1085 Nelson, Greg (editor). Systems Programming with Modula-3. Prentice
1086 Hall, 1991, ISBN 0-13-590464-1.
1088 Nichols, Bradford, Dick Buttlar, and Jacqueline Proulx Farrell.
1089 Pthreads Programming. O'Reilly & Associates, 1996, ISBN 156592-115-1
1090 (covers POSIX threads).
1092 =head2 OS-Related References
1094 Boykin, Joseph, David Kirschen, Alan Langerman, and Susan
1095 LoVerso. Programming under Mach. Addison-Wesley, 1994, ISBN
1098 Tanenbaum, Andrew S. Distributed Operating Systems. Prentice Hall,
1099 1995, ISBN 0-13-219908-4 (great textbook).
1101 Silberschatz, Abraham, and Peter B. Galvin. Operating System Concepts,
1102 4th ed. Addison-Wesley, 1995, ISBN 0-201-59292-4
1104 =head2 Other References
1106 Arnold, Ken and James Gosling. The Java Programming Language, 2nd
1107 ed. Addison-Wesley, 1998, ISBN 0-201-31006-6.
1109 comp.programming.threads FAQ,
1110 L<http://www.serpentine.com/~bos/threads-faq/>
1112 Le Sergent, T. and B. Berthomieu. "Incremental MultiThreaded Garbage
1113 Collection on Virtually Shared Memory Architectures" in Memory
1114 Management: Proc. of the International Workshop IWMM 92, St. Malo,
1115 France, September 1992, Yves Bekkers and Jacques Cohen, eds. Springer,
1116 1992, ISBN 3540-55940-X (real-life thread applications).
1118 Artur Bergman, "Where Wizards Fear To Tread", June 11, 2002,
1119 L<http://www.perl.com/pub/a/2002/06/11/threads.html>
1121 =head1 Acknowledgements
1123 Thanks (in no particular order) to Chaim Frenkel, Steve Fink, Gurusamy
1124 Sarathy, Ilya Zakharevich, Benjamin Sugars, Jürgen Christoffel, Joshua
1125 Pritikin, and Alan Burlison, for their help in reality-checking and
1126 polishing this article. Big thanks to Tom Christiansen for his rewrite
1127 of the prime number generator.
1131 Dan Sugalski E<lt>dan@sidhe.org<gt>
1133 Slightly modified by Arthur Bergman to fit the new thread model/module.
1135 Reworked slightly by Jörg Walter E<lt>jwalt@cpan.org<gt> to be more concise
1136 about thread-safety of Perl code.
1138 Rearranged slightly by Elizabeth Mattijsen E<lt>liz@dijkmat.nl<gt> to put
1139 less emphasis on yield().
1143 The original version of this article originally appeared in The Perl
1144 Journal #10, and is copyright 1998 The Perl Journal. It appears courtesy
1145 of Jon Orwant and The Perl Journal. This document may be distributed
1146 under the same terms as Perl itself.