pod/perlsyn.pod

   1 =head1 NAME
   2
   3 perlsyn - Perl syntax
   4
   5 =head1 DESCRIPTION
   6
   7 A Perl script consists of a sequence of declarations and statements.
   8 The only things that need to be declared in Perl are report formats
   9 and subroutines.  See the sections below for more information on those
  10 declarations.  All uninitialized user-created objects are assumed to
  11 start with a C<null> or C<0> value until they are defined by some explicit
  12 operation such as assignment.  (Though you can get warnings about the
  13 use of undefined values if you like.)  The sequence of statements is
  14 executed just once, unlike in B<sed> and B<awk> scripts, where the
  15 sequence of statements is executed for each input line.  While this means
  16 that you must explicitly loop over the lines of your input file (or
  17 files), it also means you have much more control over which files and
  18 which lines you look at.  (Actually, I'm lying--it is possible to do an
  19 implicit loop with either the B<-n> or B<-p> switch.  It's just not the
  20 mandatory default like it is in B<sed> and B<awk>.)
  21
  22 =head2 Declarations
  23
  24 Perl is, for the most part, a free-form language.  (The only exception
  25 to this is format declarations, for obvious reasons.)  Text from a
  26 C<"#"> character until the end of the line is a comment, and is
  27 ignored.  If you attempt to use C</* */> C-style comments, it will be
  28 interpreted either as division or pattern matching, depending on the
  29 context, and C++ C<//> comments just look like a null regular
  30 expression, so don't do that.
  31
  32 A declaration can be put anywhere a statement can, but has no effect on
  33 the execution of the primary sequence of statements--declarations all
  34 take effect at compile time.  Typically all the declarations are put at
  35 the beginning or the end of the script.  However, if you're using
  36 lexically-scoped private variables created with C<my()>, you'll have to make sure
  37 your format or subroutine definition is within the same block scope
  38 as the my if you expect to be able to access those private variables.
  39
  40 Declaring a subroutine allows a subroutine name to be used as if it were a
  41 list operator from that point forward in the program.  You can declare a
  42 subroutine without defining it by saying C<sub name>, thus:
  43
  44     sub myname;
  45     $me = myname $0             or die "can't get myname";
  46
  47 Note that my() functions as a list operator, not as a unary operator; so
  48 be careful to use C<or> instead of C<||> in this case.  However, if
  49 you were to declare the subroutine as C<sub myname ($)>, then
  50 C<myname> would function as a unary operator, so either C<or> or
  51 C<||> would work.
  52
  53 Subroutines declarations can also be loaded up with the C<require> statement
  54 or both loaded and imported into your namespace with a C<use> statement.
  55 See L<perlmod> for details on this.
  56
  57 A statement sequence may contain declarations of lexically-scoped
  58 variables, but apart from declaring a variable name, the declaration acts
  59 like an ordinary statement, and is elaborated within the sequence of
  60 statements as if it were an ordinary statement.  That means it actually
  61 has both compile-time and run-time effects.
  62
  63 =head2 Simple statements
  64
  65 The only kind of simple statement is an expression evaluated for its
  66 side effects.  Every simple statement must be terminated with a
  67 semicolon, unless it is the final statement in a block, in which case
  68 the semicolon is optional.  (A semicolon is still encouraged there if the
  69 block takes up more than one line, because you may eventually add another line.)
  70 Note that there are some operators like C<eval {}> and C<do {}> that look
  71 like compound statements, but aren't (they're just TERMs in an expression),
  72 and thus need an explicit termination if used as the last item in a statement.
  73
  74 Any simple statement may optionally be followed by a I<SINGLE> modifier,
  75 just before the terminating semicolon (or block ending).  The possible
  76 modifiers are:
  77
  78     if EXPR
  79     unless EXPR
  80     while EXPR
  81     until EXPR
  82     foreach EXPR
  83
  84 The C<if> and C<unless> modifiers have the expected semantics,
  85 presuming you're a speaker of English.  The C<foreach> modifier is an
  86 iterator:  For each value in EXPR, it aliases C<$_> to the value and
  87 executes the statement.  The C<while> and C<until> modifiers have the
  88 usual "C<while> loop" semantics (conditional evaluated first), except
  89 when applied to a C<do>-BLOCK (or to the deprecated C<do>-SUBROUTINE
  90 statement), in which case the block executes once before the
  91 conditional is evaluated.  This is so that you can write loops like:
  92
  93     do {
  94         $line = <STDIN>;
  95         ...
  96     } until $line  eq ".\n";
  97
  98 See L<perlfunc/do>.  Note also that the loop control statements described
  99 later will I<NOT> work in this construct, because modifiers don't take
 100 loop labels.  Sorry.  You can always put another block inside of it
 101 (for C<next>) or around it (for C<last>) to do that sort of thing.
 102 For C<next>, just double the braces:
 103
 104     do {{
 105         next if $x == $y;
 106         # do something here
 107     }} until $x++ > $z;
 108
 109 For C<last>, you have to be more elaborate:
 110
 111     LOOP: {
 112             do {
 113                 last if $x = $y**2;
 114                 # do something here
 115             } while $x++ <= $z;
 116     }
 117
 118 =head2 Compound statements
 119
 120 In Perl, a sequence of statements that defines a scope is called a block.
 121 Sometimes a block is delimited by the file containing it (in the case
 122 of a required file, or the program as a whole), and sometimes a block
 123 is delimited by the extent of a string (in the case of an eval).
 124
 125 But generally, a block is delimited by curly brackets, also known as braces.
 126 We will call this syntactic construct a BLOCK.
 127
 128 The following compound statements may be used to control flow:
 129
 130     if (EXPR) BLOCK
 131     if (EXPR) BLOCK else BLOCK
 132     if (EXPR) BLOCK elsif (EXPR) BLOCK ... else BLOCK
 133     LABEL while (EXPR) BLOCK
 134     LABEL while (EXPR) BLOCK continue BLOCK
 135     LABEL for (EXPR; EXPR; EXPR) BLOCK
 136     LABEL foreach VAR (LIST) BLOCK
 137     LABEL foreach VAR (LIST) BLOCK continue BLOCK
 138     LABEL BLOCK continue BLOCK
 139
 140 Note that, unlike C and Pascal, these are defined in terms of BLOCKs,
 141 not statements.  This means that the curly brackets are I<required>--no
 142 dangling statements allowed.  If you want to write conditionals without
 143 curly brackets there are several other ways to do it.  The following
 144 all do the same thing:
 145
 146     if (!open(FOO)) { die "Can't open $FOO: $!"; }
 147     die "Can't open $FOO: $!" unless open(FOO);
 148     open(FOO) or die "Can't open $FOO: $!";     # FOO or bust!
 149     open(FOO) ? 'hi mom' : die "Can't open $FOO: $!";
 150                         # a bit exotic, that last one
 151
 152 The C<if> statement is straightforward.  Because BLOCKs are always
 153 bounded by curly brackets, there is never any ambiguity about which
 154 C<if> an C<else> goes with.  If you use C<unless> in place of C<if>,
 155 the sense of the test is reversed.
 156
 157 The C<while> statement executes the block as long as the expression is
 158 true (does not evaluate to the null string C<""> or C<0> or C<"0">).
 159 The LABEL is optional, and if present, consists of an identifier followed
 160 by a colon.  The LABEL identifies the loop for the loop control
 161 statements C<next>, C<last>, and C<redo>.
 162 If the LABEL is omitted, the loop control statement
 163 refers to the innermost enclosing loop.  This may include dynamically
 164 looking back your call-stack at run time to find the LABEL.  Such
 165 desperate behavior triggers a warning if you use the B<-w> flag.
 166 Unlike a C<foreach> statement, a C<while> statement never implicitly
 167 localises any variables.
 168
 169 If there is a C<continue> BLOCK, it is always executed just before the
 170 conditional is about to be evaluated again, just like the third part of a
 171 C<for> loop in C.  Thus it can be used to increment a loop variable, even
 172 when the loop has been continued via the C<next> statement (which is
 173 similar to the C C<continue> statement).
 174
 175 =head2 Loop Control
 176
 177 The C<next> command is like the C<continue> statement in C; it starts
 178 the next iteration of the loop:
 179
 180     LINE: while (<STDIN>) {
 181         next LINE if /^#/;      # discard comments
 182         ...
 183     }
 184
 185 The C<last> command is like the C<break> statement in C (as used in
 186 loops); it immediately exits the loop in question.  The
 187 C<continue> block, if any, is not executed:
 188
 189     LINE: while (<STDIN>) {
 190         last LINE if /^$/;      # exit when done with header
 191         ...
 192     }
 193
 194 The C<redo> command restarts the loop block without evaluating the
 195 conditional again.  The C<continue> block, if any, is I<not> executed.
 196 This command is normally used by programs that want to lie to themselves
 197 about what was just input.
 198
 199 For example, when processing a file like F</etc/termcap>.
 200 If your input lines might end in backslashes to indicate continuation, you
 201 want to skip ahead and get the next record.
 202
 203     while (<>) {
 204         chomp;
 205         if (s/\\$//) {
 206             $_ .= <>;
 207             redo unless eof();
 208         }
 209         # now process $_
 210     }
 211
 212 which is Perl short-hand for the more explicitly written version:
 213
 214     LINE: while (defined($line = <ARGV>)) {
 215         chomp($line);
 216         if ($line =~ s/\\$//) {
 217             $line .= <ARGV>;
 218             redo LINE unless eof(); # not eof(ARGV)!
 219         }
 220         # now process $line
 221     }
 222
 223 Note that if there were a C<continue> block on the above code, it would get
 224 executed even on discarded lines.  This is often used to reset line counters
 225 or C<?pat?> one-time matches.
 226
 227     # inspired by :1,$g/fred/s//WILMA/
 228     while (<>) {
 229         ?(fred)?    && s//WILMA $1 WILMA/;
 230         ?(barney)?  && s//BETTY $1 BETTY/;
 231         ?(homer)?   && s//MARGE $1 MARGE/;
 232     } continue {
 233         print "$ARGV $.: $_";
 234         close ARGV  if eof();           # reset $.
 235         reset       if eof();           # reset ?pat?
 236     }
 237
 238 If the word C<while> is replaced by the word C<until>, the sense of the
 239 test is reversed, but the conditional is still tested before the first
 240 iteration.
 241
 242 The loop control statements don't work in an C<if> or C<unless>, since
 243 they aren't loops.  You can double the braces to make them such, though.
 244
 245     if (/pattern/) {{
 246         next if /fred/;
 247         next if /barney/;
 248         # so something here
 249     }}
 250
 251 The form C<while/if BLOCK BLOCK>, available in Perl 4, is no longer
 252 available.   Replace any occurrence of C<if BLOCK> by C<if (do BLOCK)>.
 253
 254 =head2 For Loops
 255
 256 Perl's C-style C<for> loop works exactly like the corresponding C<while> loop;
 257 that means that this:
 258
 259     for ($i = 1; $i < 10; $i++) {
 260         ...
 261     }
 262
 263 is the same as this:
 264
 265     $i = 1;
 266     while ($i < 10) {
 267         ...
 268     } continue {
 269         $i++;
 270     }
 271
 272 (There is one minor difference: The first form implies a lexical scope
 273 for variables declared with C<my> in the initialization expression.)
 274
 275 Besides the normal array index looping, C<for> can lend itself
 276 to many other interesting applications.  Here's one that avoids the
 277 problem you get into if you explicitly test for end-of-file on
 278 an interactive file descriptor causing your program to appear to
 279 hang.
 280
 281     $on_a_tty = -t STDIN && -t STDOUT;
 282     sub prompt { print "yes? " if $on_a_tty }
 283     for ( prompt(); <STDIN>; prompt() ) {
 284         # do something
 285     }
 286
 287 =head2 Foreach Loops
 288
 289 The C<foreach> loop iterates over a normal list value and sets the
 290 variable VAR to be each element of the list in turn.  If the variable
 291 is preceded with the keyword C<my>, then it is lexically scoped, and
 292 is therefore visible only within the loop.  Otherwise, the variable is
 293 implicitly local to the loop and regains its former value upon exiting
 294 the loop.  If the variable was previously declared with C<my>, it uses
 295 that variable instead of the global one, but it's still localized to
 296 the loop.
 297
 298 The C<foreach> keyword is actually a synonym for the C<for> keyword, so
 299 you can use C<foreach> for readability or C<for> for brevity.  (Or because
 300 the Bourne shell is more familiar to you than I<csh>, so writing C<for>
 301 comes more naturally.)  If VAR is omitted, C<$_> is set to each value.
 302 If any element of LIST is an lvalue, you can modify it by modifying VAR
 303 inside the loop.  That's because the C<foreach> loop index variable is
 304 an implicit alias for each item in the list that you're looping over.
 305
 306 If any part of LIST is an array, C<foreach> will get very confused if
 307 you add or remove elements within the loop body, for example with
 308 C<splice>.   So don't do that.
 309
 310 C<foreach> probably won't do what you expect if VAR is a tied or other
 311 special variable.   Don't do that either.
 312
 313 Examples:
 314
 315     for (@ary) { s/foo/bar/ }
 316
 317     foreach my $elem (@elements) {
 318         $elem *= 2;
 319     }
 320
 321     for $count (10,9,8,7,6,5,4,3,2,1,'BOOM') {
 322         print $count, "\n"; sleep(1);
 323     }
 324
 325     for (1..15) { print "Merry Christmas\n"; }
 326
 327     foreach $item (split(/:[\\\n:]*/, $ENV{TERMCAP})) {
 328         print "Item: $item\n";
 329     }
 330
 331 Here's how a C programmer might code up a particular algorithm in Perl:
 332
 333     for (my $i = 0; $i < @ary1; $i++) {
 334         for (my $j = 0; $j < @ary2; $j++) {
 335             if ($ary1[$i] > $ary2[$j]) {
 336                 last; # can't go to outer :-(
 337             }
 338             $ary1[$i] += $ary2[$j];
 339         }
 340         # this is where that last takes me
 341     }
 342
 343 Whereas here's how a Perl programmer more comfortable with the idiom might
 344 do it:
 345
 346     OUTER: foreach my $wid (@ary1) {
 347     INNER:   foreach my $jet (@ary2) {
 348                 next OUTER if $wid > $jet;
 349                 $wid += $jet;
 350              }
 351           }
 352
 353 See how much easier this is?  It's cleaner, safer, and faster.  It's
 354 cleaner because it's less noisy.  It's safer because if code gets added
 355 between the inner and outer loops later on, the new code won't be
 356 accidentally executed.  The C<next> explicitly iterates the other loop
 357 rather than merely terminating the inner one.  And it's faster because
 358 Perl executes a C<foreach> statement more rapidly than it would the
 359 equivalent C<for> loop.
 360
 361 =head2 Basic BLOCKs and Switch Statements
 362
 363 A BLOCK by itself (labeled or not) is semantically equivalent to a
 364 loop that executes once.  Thus you can use any of the loop control
 365 statements in it to leave or restart the block.  (Note that this is
 366 I<NOT> true in C<eval{}>, C<sub{}>, or contrary to popular belief
 367 C<do{}> blocks, which do I<NOT> count as loops.)  The C<continue>
 368 block is optional.
 369
 370 The BLOCK construct is particularly nice for doing case
 371 structures.
 372
 373     SWITCH: {
 374         if (/^abc/) { $abc = 1; last SWITCH; }
 375         if (/^def/) { $def = 1; last SWITCH; }
 376         if (/^xyz/) { $xyz = 1; last SWITCH; }
 377         $nothing = 1;
 378     }
 379
 380 There is no official C<switch> statement in Perl, because there are
 381 already several ways to write the equivalent.  In addition to the
 382 above, you could write
 383
 384     SWITCH: {
 385         $abc = 1, last SWITCH  if /^abc/;
 386         $def = 1, last SWITCH  if /^def/;
 387         $xyz = 1, last SWITCH  if /^xyz/;
 388         $nothing = 1;
 389     }
 390
 391 (That's actually not as strange as it looks once you realize that you can
 392 use loop control "operators" within an expression,  That's just the normal
 393 C comma operator.)
 394
 395 or
 396
 397     SWITCH: {
 398         /^abc/ && do { $abc = 1; last SWITCH; };
 399         /^def/ && do { $def = 1; last SWITCH; };
 400         /^xyz/ && do { $xyz = 1; last SWITCH; };
 401         $nothing = 1;
 402     }
 403
 404 or formatted so it stands out more as a "proper" C<switch> statement:
 405
 406     SWITCH: {
 407         /^abc/      && do {
 408                             $abc = 1;
 409                             last SWITCH;
 410                        };
 411
 412         /^def/      && do {
 413                             $def = 1;
 414                             last SWITCH;
 415                        };
 416
 417         /^xyz/      && do {
 418                             $xyz = 1;
 419                             last SWITCH;
 420                         };
 421         $nothing = 1;
 422     }
 423
 424 or
 425
 426     SWITCH: {
 427         /^abc/ and $abc = 1, last SWITCH;
 428         /^def/ and $def = 1, last SWITCH;
 429         /^xyz/ and $xyz = 1, last SWITCH;
 430         $nothing = 1;
 431     }
 432
 433 or even, horrors,
 434
 435     if (/^abc/)
 436         { $abc = 1 }
 437     elsif (/^def/)
 438         { $def = 1 }
 439     elsif (/^xyz/)
 440         { $xyz = 1 }
 441     else
 442         { $nothing = 1 }
 443
 444 A common idiom for a C<switch> statement is to use C<foreach>'s aliasing to make
 445 a temporary assignment to C<$_> for convenient matching:
 446
 447     SWITCH: for ($where) {
 448                 /In Card Names/     && do { push @flags, '-e'; last; };
 449                 /Anywhere/          && do { push @flags, '-h'; last; };
 450                 /In Rulings/        && do {                    last; };
 451                 die "unknown value for form variable where: `$where'";
 452             }
 453
 454 Another interesting approach to a switch statement is arrange
 455 for a C<do> block to return the proper value:
 456
 457     $amode = do {
 458         if     ($flag & O_RDONLY) { "r" }       # XXX: isn't this 0?
 459         elsif  ($flag & O_WRONLY) { ($flag & O_APPEND) ? "a" : "w" }
 460         elsif  ($flag & O_RDWR)   {
 461             if ($flag & O_CREAT)  { "w+" }
 462             else                  { ($flag & O_APPEND) ? "a+" : "r+" }
 463         }
 464     };
 465
 466 Or
 467
 468         print do {
 469             ($flags & O_WRONLY) ? "write-only"          :
 470             ($flags & O_RDWR)   ? "read-write"          :
 471                                   "read-only";
 472         };
 473
 474 Or if you are certainly that all the C<&&> clauses are true, you can use
 475 something like this, which "switches" on the value of the
 476 C<HTTP_USER_AGENT> envariable.
 477
 478     #!/usr/bin/perl
 479     # pick out jargon file page based on browser
 480     $dir = 'http://www.wins.uva.nl/~mes/jargon';
 481     for ($ENV{HTTP_USER_AGENT}) {
 482         $page  =    /Mac/            && 'm/Macintrash.html'
 483                  || /Win(dows )?NT/  && 'e/evilandrude.html'
 484                  || /Win|MSIE|WebTV/ && 'm/MicroslothWindows.html'
 485                  || /Linux/          && 'l/Linux.html'
 486                  || /HP-UX/          && 'h/HP-SUX.html'
 487                  || /SunOS/          && 's/ScumOS.html'
 488                  ||                     'a/AppendixB.html';
 489     }
 490     print "Location: $dir/$page\015\012\015\012";
 491
 492 That kind of switch statement only works when you know the C<&&> clauses
 493 will be true.  If you don't, the previous C<?:> example should be used.
 494
 495 You might also consider writing a hash of subroutine references
 496 instead of synthesizing a C<switch> statement.
 497
 498 =head2 Goto
 499
 500 Although not for the faint of heart, Perl does support a C<goto>
 501 statement.  There are three forms: C<goto>-LABEL, C<goto>-EXPR, and
 502 C<goto>-&NAME.  A loop's LABEL is not actually a valid target for
 503 a C<goto>; it's just the name of the loop.
 504
 505 The C<goto>-LABEL form finds the statement labeled with LABEL and resumes
 506 execution there.  It may not be used to go into any construct that
 507 requires initialization, such as a subroutine or a C<foreach> loop.  It
 508 also can't be used to go into a construct that is optimized away.  It
 509 can be used to go almost anywhere else within the dynamic scope,
 510 including out of subroutines, but it's usually better to use some other
 511 construct such as C<last> or C<die>.  The author of Perl has never felt the
 512 need to use this form of C<goto> (in Perl, that is--C is another matter).
 513
 514 The C<goto>-EXPR form expects a label name, whose scope will be resolved
 515 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
 516 necessarily recommended if you're optimizing for maintainability:
 517
 518     goto ("FOO", "BAR", "GLARCH")[$i];
 519
 520 The C<goto>-&NAME form is highly magical, and substitutes a call to the
 521 named subroutine for the currently running subroutine.  This is used by
 522 C<AUTOLOAD()> subroutines that wish to load another subroutine and then
 523 pretend that the other subroutine had been called in the first place
 524 (except that any modifications to C<@_> in the current subroutine are
 525 propagated to the other subroutine.)  After the C<goto>, not even C<caller()>
 526 will be able to tell that this routine was called first.
 527
 528 In almost all cases like this, it's usually a far, far better idea to use the
 529 structured control flow mechanisms of C<next>, C<last>, or C<redo> instead of
 530 resorting to a C<goto>.  For certain applications, the catch and throw pair of
 531 C<eval{}> and die() for exception processing can also be a prudent approach.
 532
 533 =head2 PODs: Embedded Documentation
 534
 535 Perl has a mechanism for intermixing documentation with source code.
 536 While it's expecting the beginning of a new statement, if the compiler
 537 encounters a line that begins with an equal sign and a word, like this
 538
 539     =head1 Here There Be Pods!
 540
 541 Then that text and all remaining text up through and including a line
 542 beginning with C<=cut> will be ignored.  The format of the intervening
 543 text is described in L<perlpod>.
 544
 545 This allows you to intermix your source code
 546 and your documentation text freely, as in
 547
 548     =item snazzle($)
 549
 550     The snazzle() function will behave in the most spectacular
 551     form that you can possibly imagine, not even excepting
 552     cybernetic pyrotechnics.
 553
 554     =cut back to the compiler, nuff of this pod stuff!
 555
 556     sub snazzle($) {
 557         my $thingie = shift;
 558         .........
 559     }
 560
 561 Note that pod translators should look at only paragraphs beginning
 562 with a pod directive (it makes parsing easier), whereas the compiler
 563 actually knows to look for pod escapes even in the middle of a
 564 paragraph.  This means that the following secret stuff will be
 565 ignored by both the compiler and the translators.
 566
 567     $a=3;
 568     =secret stuff
 569      warn "Neither POD nor CODE!?"
 570     =cut back
 571     print "got $a\n";
 572
 573 You probably shouldn't rely upon the C<warn()> being podded out forever.
 574 Not all pod translators are well-behaved in this regard, and perhaps
 575 the compiler will become pickier.
 576
 577 One may also use pod directives to quickly comment out a section
 578 of code.
 579
 580 =head2 Plain Old Comments (Not!)
 581
 582 Much like the C preprocessor, Perl can process line directives.  Using
 583 this, one can control Perl's idea of filenames and line numbers in
 584 error or warning messages (especially for strings that are processed
 585 with C<eval()>).  The syntax for this mechanism is the same as for most
 586 C preprocessors: it matches the regular expression
 587 C</^#\s*line\s+(\d+)\s*(?:\s"([^"]*)")?/> with C<$1> being the line
 588 number for the next line, and C<$2> being the optional filename
 589 (specified within quotes).
 590
 591 Here are some examples that you should be able to type into your command
 592 shell:
 593
 594     % perl
 595     # line 200 "bzzzt"
 596     # the `#' on the previous line must be the first char on line
 597     die 'foo';
 598     __END__
 599     foo at bzzzt line 201.
 600
 601     % perl
 602     # line 200 "bzzzt"
 603     eval qq[\n#line 2001 ""\ndie 'foo']; print $@;
 604     __END__
 605     foo at - line 2001.
 606
 607     % perl
 608     eval qq[\n#line 200 "foo bar"\ndie 'foo']; print $@;
 609     __END__
 610     foo at foo bar line 200.
 611
 612     % perl
 613     # line 345 "goop"
 614     eval "\n#line " . __LINE__ . ' "' . __FILE__ ."\"\ndie 'foo'";
 615     print $@;
 616     __END__
 617     foo at goop line 345.
 618
 619 =cut