pod/perlsyn.pod

   1 =head1 NAME
   2
   3 perlsyn - Perl syntax
   4
   5 =head1 DESCRIPTION
   6
   7 A Perl script consists of a sequence of declarations and statements.
   8 The only things that need to be declared in Perl are report formats
   9 and subroutines.  See the sections below for more information on those
  10 declarations.  All uninitialized user-created objects are assumed to
  11 start with a C<null> or C<0> value until they are defined by some explicit
  12 operation such as assignment.  (Though you can get warnings about the
  13 use of undefined values if you like.)  The sequence of statements is
  14 executed just once, unlike in B<sed> and B<awk> scripts, where the
  15 sequence of statements is executed for each input line.  While this means
  16 that you must explicitly loop over the lines of your input file (or
  17 files), it also means you have much more control over which files and
  18 which lines you look at.  (Actually, I'm lying--it is possible to do an
  19 implicit loop with either the B<-n> or B<-p> switch.  It's just not the
  20 mandatory default like it is in B<sed> and B<awk>.)
  21
  22 =head2 Declarations
  23
  24 Perl is, for the most part, a free-form language.  (The only exception
  25 to this is format declarations, for obvious reasons.)  Text from a
  26 C<"#"> character until the end of the line is a comment, and is
  27 ignored.  If you attempt to use C</* */> C-style comments, it will be
  28 interpreted either as division or pattern matching, depending on the
  29 context, and C++ C<//> comments just look like a null regular
  30 expression, so don't do that.
  31
  32 A declaration can be put anywhere a statement can, but has no effect on
  33 the execution of the primary sequence of statements--declarations all
  34 take effect at compile time.  Typically all the declarations are put at
  35 the beginning or the end of the script.  However, if you're using
  36 lexically-scoped private variables created with C<my()>, you'll have to make sure
  37 your format or subroutine definition is within the same block scope
  38 as the my if you expect to be able to access those private variables.
  39
  40 Declaring a subroutine allows a subroutine name to be used as if it were a
  41 list operator from that point forward in the program.  You can declare a
  42 subroutine without defining it by saying C<sub name>, thus:
  43
  44     sub myname;
  45     $me = myname $0             or die "can't get myname";
  46
  47 Note that my() functions as a list operator, not as a unary operator; so
  48 be careful to use C<or> instead of C<||> in this case.  However, if
  49 you were to declare the subroutine as C<sub myname ($)>, then
  50 C<myname> would function as a unary operator, so either C<or> or
  51 C<||> would work.
  52
  53 Subroutines declarations can also be loaded up with the C<require> statement
  54 or both loaded and imported into your namespace with a C<use> statement.
  55 See L<perlmod> for details on this.
  56
  57 A statement sequence may contain declarations of lexically-scoped
  58 variables, but apart from declaring a variable name, the declaration acts
  59 like an ordinary statement, and is elaborated within the sequence of
  60 statements as if it were an ordinary statement.  That means it actually
  61 has both compile-time and run-time effects.
  62
  63 =head2 Simple statements
  64
  65 The only kind of simple statement is an expression evaluated for its
  66 side effects.  Every simple statement must be terminated with a
  67 semicolon, unless it is the final statement in a block, in which case
  68 the semicolon is optional.  (A semicolon is still encouraged there if the
  69 block takes up more than one line, because you may eventually add another line.)
  70 Note that there are some operators like C<eval {}> and C<do {}> that look
  71 like compound statements, but aren't (they're just TERMs in an expression),
  72 and thus need an explicit termination if used as the last item in a statement.
  73
  74 Any simple statement may optionally be followed by a I<SINGLE> modifier,
  75 just before the terminating semicolon (or block ending).  The possible
  76 modifiers are:
  77
  78     if EXPR
  79     unless EXPR
  80     while EXPR
  81     until EXPR
  82     foreach EXPR
  83
  84 The C<if> and C<unless> modifiers have the expected semantics,
  85 presuming you're a speaker of English.  The C<foreach> modifier is an
  86 iterator:  For each value in EXPR, it aliases C<$_> to the value and
  87 executes the statement.  The C<while> and C<until> modifiers have the
  88 usual "C<while> loop" semantics (conditional evaluated first), except
  89 when applied to a C<do>-BLOCK (or to the deprecated C<do>-SUBROUTINE
  90 statement), in which case the block executes once before the
  91 conditional is evaluated.  This is so that you can write loops like:
  92
  93     do {
  94         $line = <STDIN>;
  95         ...
  96     } until $line  eq ".\n";
  97
  98 See L<perlfunc/do>.  Note also that the loop control statements described
  99 later will I<NOT> work in this construct, because modifiers don't take
 100 loop labels.  Sorry.  You can always put another block inside of it
 101 (for C<next>) or around it (for C<last>) to do that sort of thing.
 102 For C<next>, just double the braces:
 103
 104     do {{
 105         next if $x == $y;
 106         # do something here
 107     }} until $x++ > $z;
 108
 109 For C<last>, you have to be more elaborate:
 110
 111     LOOP: {
 112             do {
 113                 last if $x = $y**2;
 114                 # do something here
 115             } while $x++ <= $z;
 116     }
 117
 118 =head2 Compound statements
 119
 120 In Perl, a sequence of statements that defines a scope is called a block.
 121 Sometimes a block is delimited by the file containing it (in the case
 122 of a required file, or the program as a whole), and sometimes a block
 123 is delimited by the extent of a string (in the case of an eval).
 124
 125 But generally, a block is delimited by curly brackets, also known as braces.
 126 We will call this syntactic construct a BLOCK.
 127
 128 The following compound statements may be used to control flow:
 129
 130     if (EXPR) BLOCK
 131     if (EXPR) BLOCK else BLOCK
 132     if (EXPR) BLOCK elsif (EXPR) BLOCK ... else BLOCK
 133     LABEL while (EXPR) BLOCK
 134     LABEL while (EXPR) BLOCK continue BLOCK
 135     LABEL for (EXPR; EXPR; EXPR) BLOCK
 136     LABEL foreach VAR (LIST) BLOCK
 137     LABEL BLOCK continue BLOCK
 138
 139 Note that, unlike C and Pascal, these are defined in terms of BLOCKs,
 140 not statements.  This means that the curly brackets are I<required>--no
 141 dangling statements allowed.  If you want to write conditionals without
 142 curly brackets there are several other ways to do it.  The following
 143 all do the same thing:
 144
 145     if (!open(FOO)) { die "Can't open $FOO: $!"; }
 146     die "Can't open $FOO: $!" unless open(FOO);
 147     open(FOO) or die "Can't open $FOO: $!";     # FOO or bust!
 148     open(FOO) ? 'hi mom' : die "Can't open $FOO: $!";
 149                         # a bit exotic, that last one
 150
 151 The C<if> statement is straightforward.  Because BLOCKs are always
 152 bounded by curly brackets, there is never any ambiguity about which
 153 C<if> an C<else> goes with.  If you use C<unless> in place of C<if>,
 154 the sense of the test is reversed.
 155
 156 The C<while> statement executes the block as long as the expression is
 157 true (does not evaluate to the null string (C<"">) or C<0> or C<"0")>.  The LABEL is
 158 optional, and if present, consists of an identifier followed by a colon.
 159 The LABEL identifies the loop for the loop control statements C<next>,
 160 C<last>, and C<redo>.  If the LABEL is omitted, the loop control statement
 161 refers to the innermost enclosing loop.  This may include dynamically
 162 looking back your call-stack at run time to find the LABEL.  Such
 163 desperate behavior triggers a warning if you use the B<-w> flag.
 164
 165 If there is a C<continue> BLOCK, it is always executed just before the
 166 conditional is about to be evaluated again, just like the third part of a
 167 C<for> loop in C.  Thus it can be used to increment a loop variable, even
 168 when the loop has been continued via the C<next> statement (which is
 169 similar to the C C<continue> statement).
 170
 171 =head2 Loop Control
 172
 173 The C<next> command is like the C<continue> statement in C; it starts
 174 the next iteration of the loop:
 175
 176     LINE: while (<STDIN>) {
 177         next LINE if /^#/;      # discard comments
 178         ...
 179     }
 180
 181 The C<last> command is like the C<break> statement in C (as used in
 182 loops); it immediately exits the loop in question.  The
 183 C<continue> block, if any, is not executed:
 184
 185     LINE: while (<STDIN>) {
 186         last LINE if /^$/;      # exit when done with header
 187         ...
 188     }
 189
 190 The C<redo> command restarts the loop block without evaluating the
 191 conditional again.  The C<continue> block, if any, is I<not> executed.
 192 This command is normally used by programs that want to lie to themselves
 193 about what was just input.
 194
 195 For example, when processing a file like F</etc/termcap>.
 196 If your input lines might end in backslashes to indicate continuation, you
 197 want to skip ahead and get the next record.
 198
 199     while (<>) {
 200         chomp;
 201         if (s/\\$//) {
 202             $_ .= <>;
 203             redo unless eof();
 204         }
 205         # now process $_
 206     }
 207
 208 which is Perl short-hand for the more explicitly written version:
 209
 210     LINE: while (defined($line = <ARGV>)) {
 211         chomp($line);
 212         if ($line =~ s/\\$//) {
 213             $line .= <ARGV>;
 214             redo LINE unless eof(); # not eof(ARGV)!
 215         }
 216         # now process $line
 217     }
 218
 219 Note that if there were a C<continue> block on the above code, it would get
 220 executed even on discarded lines.  This is often used to reset line counters
 221 or C<?pat?> one-time matches.
 222
 223     # inspired by :1,$g/fred/s//WILMA/
 224     while (<>) {
 225         ?(fred)?    && s//WILMA $1 WILMA/;
 226         ?(barney)?  && s//BETTY $1 BETTY/;
 227         ?(homer)?   && s//MARGE $1 MARGE/;
 228     } continue {
 229         print "$ARGV $.: $_";
 230         close ARGV  if eof();           # reset $.
 231         reset       if eof();           # reset ?pat?
 232     }
 233
 234 If the word C<while> is replaced by the word C<until>, the sense of the
 235 test is reversed, but the conditional is still tested before the first
 236 iteration.
 237
 238 The loop control statements don't work in an C<if> or C<unless>, since
 239 they aren't loops.  You can double the braces to make them such, though.
 240
 241     if (/pattern/) {{
 242         next if /fred/;
 243         next if /barney/;
 244         # so something here
 245     }}
 246
 247 The form C<while/if BLOCK BLOCK>, available in Perl 4, is no longer
 248 available.   Replace any occurrence of C<if BLOCK> by C<if (do BLOCK)>.
 249
 250 =head2 For Loops
 251
 252 Perl's C-style C<for> loop works exactly like the corresponding C<while> loop;
 253 that means that this:
 254
 255     for ($i = 1; $i < 10; $i++) {
 256         ...
 257     }
 258
 259 is the same as this:
 260
 261     $i = 1;
 262     while ($i < 10) {
 263         ...
 264     } continue {
 265         $i++;
 266     }
 267
 268 (There is one minor difference: The first form implies a lexical scope
 269 for variables declared with C<my> in the initialization expression.)
 270
 271 Besides the normal array index looping, C<for> can lend itself
 272 to many other interesting applications.  Here's one that avoids the
 273 problem you get into if you explicitly test for end-of-file on
 274 an interactive file descriptor causing your program to appear to
 275 hang.
 276
 277     $on_a_tty = -t STDIN && -t STDOUT;
 278     sub prompt { print "yes? " if $on_a_tty }
 279     for ( prompt(); <STDIN>; prompt() ) {
 280         # do something
 281     }
 282
 283 =head2 Foreach Loops
 284
 285 The C<foreach> loop iterates over a normal list value and sets the
 286 variable VAR to be each element of the list in turn.  If the variable
 287 is preceded with the keyword C<my>, then it is lexically scoped, and
 288 is therefore visible only within the loop.  Otherwise, the variable is
 289 implicitly local to the loop and regains its former value upon exiting
 290 the loop.  If the variable was previously declared with C<my>, it uses
 291 that variable instead of the global one, but it's still localized to
 292 the loop.
 293
 294 The C<foreach> keyword is actually a synonym for the C<for> keyword, so
 295 you can use C<foreach> for readability or C<for> for brevity.  (Or because
 296 the Bourne shell is more familiar to you than I<csh>, so writing C<for>
 297 comes more naturally.)  If VAR is omitted, C<$_> is set to each value.
 298 If any element of LIST is an lvalue, you can modify it by modifying VAR
 299 inside the loop.  That's because the C<foreach> loop index variable is
 300 an implicit alias for each item in the list that you're looping over.
 301
 302 If any part of LIST is an array, C<foreach> will get very confused if
 303 you add or remove elements within the loop body, for example with
 304 C<splice>.   So don't do that.
 305
 306 C<foreach> probably won't do what you expect if VAR is a tied or other
 307 special variable.   Don't do that either.
 308
 309 Examples:
 310
 311     for (@ary) { s/foo/bar/ }
 312
 313     foreach my $elem (@elements) {
 314         $elem *= 2;
 315     }
 316
 317     for $count (10,9,8,7,6,5,4,3,2,1,'BOOM') {
 318         print $count, "\n"; sleep(1);
 319     }
 320
 321     for (1..15) { print "Merry Christmas\n"; }
 322
 323     foreach $item (split(/:[\\\n:]*/, $ENV{TERMCAP})) {
 324         print "Item: $item\n";
 325     }
 326
 327 Here's how a C programmer might code up a particular algorithm in Perl:
 328
 329     for (my $i = 0; $i < @ary1; $i++) {
 330         for (my $j = 0; $j < @ary2; $j++) {
 331             if ($ary1[$i] > $ary2[$j]) {
 332                 last; # can't go to outer :-(
 333             }
 334             $ary1[$i] += $ary2[$j];
 335         }
 336         # this is where that last takes me
 337     }
 338
 339 Whereas here's how a Perl programmer more comfortable with the idiom might
 340 do it:
 341
 342     OUTER: foreach my $wid (@ary1) {
 343     INNER:   foreach my $jet (@ary2) {
 344                 next OUTER if $wid > $jet;
 345                 $wid += $jet;
 346              }
 347           }
 348
 349 See how much easier this is?  It's cleaner, safer, and faster.  It's
 350 cleaner because it's less noisy.  It's safer because if code gets added
 351 between the inner and outer loops later on, the new code won't be
 352 accidentally executed.  The C<next> explicitly iterates the other loop
 353 rather than merely terminating the inner one.  And it's faster because
 354 Perl executes a C<foreach> statement more rapidly than it would the
 355 equivalent C<for> loop.
 356
 357 =head2 Basic BLOCKs and Switch Statements
 358
 359 A BLOCK by itself (labeled or not) is semantically equivalent to a
 360 loop that executes once.  Thus you can use any of the loop control
 361 statements in it to leave or restart the block.  (Note that this is
 362 I<NOT> true in C<eval{}>, C<sub{}>, or contrary to popular belief
 363 C<do{}> blocks, which do I<NOT> count as loops.)  The C<continue>
 364 block is optional.
 365
 366 The BLOCK construct is particularly nice for doing case
 367 structures.
 368
 369     SWITCH: {
 370         if (/^abc/) { $abc = 1; last SWITCH; }
 371         if (/^def/) { $def = 1; last SWITCH; }
 372         if (/^xyz/) { $xyz = 1; last SWITCH; }
 373         $nothing = 1;
 374     }
 375
 376 There is no official C<switch> statement in Perl, because there are
 377 already several ways to write the equivalent.  In addition to the
 378 above, you could write
 379
 380     SWITCH: {
 381         $abc = 1, last SWITCH  if /^abc/;
 382         $def = 1, last SWITCH  if /^def/;
 383         $xyz = 1, last SWITCH  if /^xyz/;
 384         $nothing = 1;
 385     }
 386
 387 (That's actually not as strange as it looks once you realize that you can
 388 use loop control "operators" within an expression,  That's just the normal
 389 C comma operator.)
 390
 391 or
 392
 393     SWITCH: {
 394         /^abc/ && do { $abc = 1; last SWITCH; };
 395         /^def/ && do { $def = 1; last SWITCH; };
 396         /^xyz/ && do { $xyz = 1; last SWITCH; };
 397         $nothing = 1;
 398     }
 399
 400 or formatted so it stands out more as a "proper" C<switch> statement:
 401
 402     SWITCH: {
 403         /^abc/      && do {
 404                             $abc = 1;
 405                             last SWITCH;
 406                        };
 407
 408         /^def/      && do {
 409                             $def = 1;
 410                             last SWITCH;
 411                        };
 412
 413         /^xyz/      && do {
 414                             $xyz = 1;
 415                             last SWITCH;
 416                         };
 417         $nothing = 1;
 418     }
 419
 420 or
 421
 422     SWITCH: {
 423         /^abc/ and $abc = 1, last SWITCH;
 424         /^def/ and $def = 1, last SWITCH;
 425         /^xyz/ and $xyz = 1, last SWITCH;
 426         $nothing = 1;
 427     }
 428
 429 or even, horrors,
 430
 431     if (/^abc/)
 432         { $abc = 1 }
 433     elsif (/^def/)
 434         { $def = 1 }
 435     elsif (/^xyz/)
 436         { $xyz = 1 }
 437     else
 438         { $nothing = 1 }
 439
 440 A common idiom for a C<switch> statement is to use C<foreach>'s aliasing to make
 441 a temporary assignment to C<$_> for convenient matching:
 442
 443     SWITCH: for ($where) {
 444                 /In Card Names/     && do { push @flags, '-e'; last; };
 445                 /Anywhere/          && do { push @flags, '-h'; last; };
 446                 /In Rulings/        && do {                    last; };
 447                 die "unknown value for form variable where: `$where'";
 448             }
 449
 450 Another interesting approach to a switch statement is arrange
 451 for a C<do> block to return the proper value:
 452
 453     $amode = do {
 454         if     ($flag & O_RDONLY) { "r" }       # XXX: isn't this 0?
 455         elsif  ($flag & O_WRONLY) { ($flag & O_APPEND) ? "a" : "w" }
 456         elsif  ($flag & O_RDWR)   {
 457             if ($flag & O_CREAT)  { "w+" }
 458             else                  { ($flag & O_APPEND) ? "a+" : "r+" }
 459         }
 460     };
 461
 462 Or
 463
 464         print do {
 465             ($flags & O_WRONLY) ? "write-only"          :
 466             ($flags & O_RDWR)   ? "read-write"          :
 467                                   "read-only";
 468         };
 469
 470 Or if you are certainly that all the C<&&> clauses are true, you can use
 471 something like this, which "switches" on the value of the
 472 C<HTTP_USER_AGENT> envariable.
 473
 474     #!/usr/bin/perl
 475     # pick out jargon file page based on browser
 476     $dir = 'http://www.wins.uva.nl/~mes/jargon';
 477     for ($ENV{HTTP_USER_AGENT}) {
 478         $page  =    /Mac/            && 'm/Macintrash.html'
 479                  || /Win(dows )?NT/  && 'e/evilandrude.html'
 480                  || /Win|MSIE|WebTV/ && 'm/MicroslothWindows.html'
 481                  || /Linux/          && 'l/Linux.html'
 482                  || /HP-UX/          && 'h/HP-SUX.html'
 483                  || /SunOS/          && 's/ScumOS.html'
 484                  ||                     'a/AppendixB.html';
 485     }
 486     print "Location: $dir/$page\015\012\015\012";
 487
 488 That kind of switch statement only works when you know the C<&&> clauses
 489 will be true.  If you don't, the previous C<?:> example should be used.
 490
 491 You might also consider writing a hash of subroutine references
 492 instead of synthesizing a C<switch> statement.
 493
 494 =head2 Goto
 495
 496 Although not for the faint of heart, Perl does support a C<goto>
 497 statement.  There are three forms: C<goto>-LABEL, C<goto>-EXPR, and
 498 C<goto>-&NAME.  A loop's LABEL is not actually a valid target for
 499 a C<goto>; it's just the name of the loop.
 500
 501 The C<goto>-LABEL form finds the statement labeled with LABEL and resumes
 502 execution there.  It may not be used to go into any construct that
 503 requires initialization, such as a subroutine or a C<foreach> loop.  It
 504 also can't be used to go into a construct that is optimized away.  It
 505 can be used to go almost anywhere else within the dynamic scope,
 506 including out of subroutines, but it's usually better to use some other
 507 construct such as C<last> or C<die>.  The author of Perl has never felt the
 508 need to use this form of C<goto> (in Perl, that is--C is another matter).
 509
 510 The C<goto>-EXPR form expects a label name, whose scope will be resolved
 511 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
 512 necessarily recommended if you're optimizing for maintainability:
 513
 514     goto ("FOO", "BAR", "GLARCH")[$i];
 515
 516 The C<goto>-&NAME form is highly magical, and substitutes a call to the
 517 named subroutine for the currently running subroutine.  This is used by
 518 C<AUTOLOAD()> subroutines that wish to load another subroutine and then
 519 pretend that the other subroutine had been called in the first place
 520 (except that any modifications to C<@_> in the current subroutine are
 521 propagated to the other subroutine.)  After the C<goto>, not even C<caller()>
 522 will be able to tell that this routine was called first.
 523
 524 In almost all cases like this, it's usually a far, far better idea to use the
 525 structured control flow mechanisms of C<next>, C<last>, or C<redo> instead of
 526 resorting to a C<goto>.  For certain applications, the catch and throw pair of
 527 C<eval{}> and die() for exception processing can also be a prudent approach.
 528
 529 =head2 PODs: Embedded Documentation
 530
 531 Perl has a mechanism for intermixing documentation with source code.
 532 While it's expecting the beginning of a new statement, if the compiler
 533 encounters a line that begins with an equal sign and a word, like this
 534
 535     =head1 Here There Be Pods!
 536
 537 Then that text and all remaining text up through and including a line
 538 beginning with C<=cut> will be ignored.  The format of the intervening
 539 text is described in L<perlpod>.
 540
 541 This allows you to intermix your source code
 542 and your documentation text freely, as in
 543
 544     =item snazzle($)
 545
 546     The snazzle() function will behave in the most spectacular
 547     form that you can possibly imagine, not even excepting
 548     cybernetic pyrotechnics.
 549
 550     =cut back to the compiler, nuff of this pod stuff!
 551
 552     sub snazzle($) {
 553         my $thingie = shift;
 554         .........
 555     }
 556
 557 Note that pod translators should look at only paragraphs beginning
 558 with a pod directive (it makes parsing easier), whereas the compiler
 559 actually knows to look for pod escapes even in the middle of a
 560 paragraph.  This means that the following secret stuff will be
 561 ignored by both the compiler and the translators.
 562
 563     $a=3;
 564     =secret stuff
 565      warn "Neither POD nor CODE!?"
 566     =cut back
 567     print "got $a\n";
 568
 569 You probably shouldn't rely upon the C<warn()> being podded out forever.
 570 Not all pod translators are well-behaved in this regard, and perhaps
 571 the compiler will become pickier.
 572
 573 One may also use pod directives to quickly comment out a section
 574 of code.
 575
 576 =head2 Plain Old Comments (Not!)
 577
 578 Much like the C preprocessor, Perl can process line directives.  Using
 579 this, one can control Perl's idea of filenames and line numbers in
 580 error or warning messages (especially for strings that are processed
 581 with C<eval()>).  The syntax for this mechanism is the same as for most
 582 C preprocessors: it matches the regular expression
 583 C</^#\s*line\s+(\d+)\s*(?:\s"([^"]*)")?/> with C<$1> being the line
 584 number for the next line, and C<$2> being the optional filename
 585 (specified within quotes).
 586
 587 Here are some examples that you should be able to type into your command
 588 shell:
 589
 590     % perl
 591     # line 200 "bzzzt"
 592     # the `#' on the previous line must be the first char on line
 593     die 'foo';
 594     __END__
 595     foo at bzzzt line 201.
 596
 597     % perl
 598     # line 200 "bzzzt"
 599     eval qq[\n#line 2001 ""\ndie 'foo']; print $@;
 600     __END__
 601     foo at - line 2001.
 602
 603     % perl
 604     eval qq[\n#line 200 "foo bar"\ndie 'foo']; print $@;
 605     __END__
 606     foo at foo bar line 200.
 607
 608     % perl
 609     # line 345 "goop"
 610     eval "\n#line " . __LINE__ . ' "' . __FILE__ ."\"\ndie 'foo'";
 611     print $@;
 612     __END__
 613     foo at goop line 345.
 614
 615 =cut