pod/perlsyn.pod

   1 =head1 NAME
   2
   3 perlsyn - Perl syntax
   4
   5 =head1 DESCRIPTION
   6
   7 A Perl script consists of a sequence of declarations and statements.
   8 The sequence of statements is executed just once, unlike in B<sed>
   9 and B<awk> scripts, where the sequence of statements is executed
  10 for each input line.  While this means that you must explicitly
  11 loop over the lines of your input file (or files), it also means
  12 you have much more control over which files and which lines you look at.
  13 (Actually, I'm lying--it is possible to do an implicit loop with
  14 either the B<-n> or B<-p> switch.  It's just not the mandatory
  15 default like it is in B<sed> and B<awk>.)
  16
  17 Perl is, for the most part, a free-form language.  (The only exception
  18 to this is format declarations, for obvious reasons.)  Text from a
  19 C<"#"> character until the end of the line is a comment, and is
  20 ignored.  If you attempt to use C</* */> C-style comments, it will be
  21 interpreted either as division or pattern matching, depending on the
  22 context, and C++ C<//> comments just look like a null regular
  23 expression or defined-or operator, so don't do that.
  24
  25 =head2 Declarations
  26
  27 The only things you need to declare in Perl are report formats
  28 and subroutines--and even undefined subroutines can be handled
  29 through AUTOLOAD.  A variable holds the undefined value (C<undef>)
  30 until it has been assigned a defined value, which is anything
  31 other than C<undef>.  When used as a number, C<undef> is treated
  32 as C<0>; when used as a string, it is treated the empty string,
  33 C<"">; and when used as a reference that isn't being assigned
  34 to, it is treated as an error.  If you enable warnings, you'll
  35 be notified of an uninitialized value whenever you treat C<undef>
  36 as a string or a number.  Well, usually.  Boolean contexts, such as:
  37
  38     my $a;
  39     if ($a) {}
  40
  41 are exempt from warnings (because they care about truth rather than
  42 definedness).  Operators such as C<++>, C<-->, C<+=>,
  43 C<-=>, and C<.=>, that operate on undefined left values such as:
  44
  45     my $a;
  46     $a++;
  47
  48 are also always exempt from such warnings.
  49
  50 A declaration can be put anywhere a statement can, but has no effect on
  51 the execution of the primary sequence of statements--declarations all
  52 take effect at compile time.  Typically all the declarations are put at
  53 the beginning or the end of the script.  However, if you're using
  54 lexically-scoped private variables created with C<my()>, you'll
  55 have to make sure
  56 your format or subroutine definition is within the same block scope
  57 as the my if you expect to be able to access those private variables.
  58
  59 Declaring a subroutine allows a subroutine name to be used as if it were a
  60 list operator from that point forward in the program.  You can declare a
  61 subroutine without defining it by saying C<sub name>, thus:
  62
  63     sub myname;
  64     $me = myname $0             or die "can't get myname";
  65
  66 Note that myname() functions as a list operator, not as a unary operator;
  67 so be careful to use C<or> instead of C<||> in this case.  However, if
  68 you were to declare the subroutine as C<sub myname ($)>, then
  69 C<myname> would function as a unary operator, so either C<or> or
  70 C<||> would work.
  71
  72 Subroutines declarations can also be loaded up with the C<require> statement
  73 or both loaded and imported into your namespace with a C<use> statement.
  74 See L<perlmod> for details on this.
  75
  76 A statement sequence may contain declarations of lexically-scoped
  77 variables, but apart from declaring a variable name, the declaration acts
  78 like an ordinary statement, and is elaborated within the sequence of
  79 statements as if it were an ordinary statement.  That means it actually
  80 has both compile-time and run-time effects.
  81
  82 =head2 Simple Statements
  83
  84 The only kind of simple statement is an expression evaluated for its
  85 side effects.  Every simple statement must be terminated with a
  86 semicolon, unless it is the final statement in a block, in which case
  87 the semicolon is optional.  (A semicolon is still encouraged there if the
  88 block takes up more than one line, because you may eventually add another line.)
  89 Note that there are some operators like C<eval {}> and C<do {}> that look
  90 like compound statements, but aren't (they're just TERMs in an expression),
  91 and thus need an explicit termination if used as the last item in a statement.
  92
  93 Any simple statement may optionally be followed by a I<SINGLE> modifier,
  94 just before the terminating semicolon (or block ending).  The possible
  95 modifiers are:
  96
  97     if EXPR
  98     unless EXPR
  99     while EXPR
 100     until EXPR
 101     foreach EXPR
 102
 103 The C<if> and C<unless> modifiers have the expected semantics,
 104 presuming you're a speaker of English.  The C<foreach> modifier is an
 105 iterator:  For each value in EXPR, it aliases C<$_> to the value and
 106 executes the statement.  The C<while> and C<until> modifiers have the
 107 usual "C<while> loop" semantics (conditional evaluated first), except
 108 when applied to a C<do>-BLOCK (or to the deprecated C<do>-SUBROUTINE
 109 statement), in which case the block executes once before the
 110 conditional is evaluated.  This is so that you can write loops like:
 111
 112     do {
 113         $line = <STDIN>;
 114         ...
 115     } until $line  eq ".\n";
 116
 117 See L<perlfunc/do>.  Note also that the loop control statements described
 118 later will I<NOT> work in this construct, because modifiers don't take
 119 loop labels.  Sorry.  You can always put another block inside of it
 120 (for C<next>) or around it (for C<last>) to do that sort of thing.
 121 For C<next>, just double the braces:
 122
 123     do {{
 124         next if $x == $y;
 125         # do something here
 126     }} until $x++ > $z;
 127
 128 For C<last>, you have to be more elaborate:
 129
 130     LOOP: {
 131             do {
 132                 last if $x = $y**2;
 133                 # do something here
 134             } while $x++ <= $z;
 135     }
 136
 137 B<NOTE:> The behaviour of a C<my> statement modified with a statement
 138 modifier conditional or loop construct (e.g. C<my $x if ...>) is
 139 B<undefined>.  The value of the C<my> variable may be C<undef>, any
 140 previously assigned value, or possibly anything else.  Don't rely on
 141 it.  Future versions of perl might do something different from the
 142 version of perl you try it out on.  Here be dragons.
 143
 144 =head2 Compound Statements
 145
 146 In Perl, a sequence of statements that defines a scope is called a block.
 147 Sometimes a block is delimited by the file containing it (in the case
 148 of a required file, or the program as a whole), and sometimes a block
 149 is delimited by the extent of a string (in the case of an eval).
 150
 151 But generally, a block is delimited by curly brackets, also known as braces.
 152 We will call this syntactic construct a BLOCK.
 153
 154 The following compound statements may be used to control flow:
 155
 156     if (EXPR) BLOCK
 157     if (EXPR) BLOCK else BLOCK
 158     if (EXPR) BLOCK elsif (EXPR) BLOCK ... else BLOCK
 159     LABEL while (EXPR) BLOCK
 160     LABEL while (EXPR) BLOCK continue BLOCK
 161     LABEL for (EXPR; EXPR; EXPR) BLOCK
 162     LABEL foreach VAR (LIST) BLOCK
 163     LABEL foreach VAR (LIST) BLOCK continue BLOCK
 164     LABEL BLOCK continue BLOCK
 165
 166 Note that, unlike C and Pascal, these are defined in terms of BLOCKs,
 167 not statements.  This means that the curly brackets are I<required>--no
 168 dangling statements allowed.  If you want to write conditionals without
 169 curly brackets there are several other ways to do it.  The following
 170 all do the same thing:
 171
 172     if (!open(FOO)) { die "Can't open $FOO: $!"; }
 173     die "Can't open $FOO: $!" unless open(FOO);
 174     open(FOO) or die "Can't open $FOO: $!";     # FOO or bust!
 175     open(FOO) ? 'hi mom' : die "Can't open $FOO: $!";
 176                         # a bit exotic, that last one
 177
 178 The C<if> statement is straightforward.  Because BLOCKs are always
 179 bounded by curly brackets, there is never any ambiguity about which
 180 C<if> an C<else> goes with.  If you use C<unless> in place of C<if>,
 181 the sense of the test is reversed.
 182
 183 The C<while> statement executes the block as long as the expression is
 184 true (does not evaluate to the null string C<""> or C<0> or C<"0">).
 185 The LABEL is optional, and if present, consists of an identifier followed
 186 by a colon.  The LABEL identifies the loop for the loop control
 187 statements C<next>, C<last>, and C<redo>.
 188 If the LABEL is omitted, the loop control statement
 189 refers to the innermost enclosing loop.  This may include dynamically
 190 looking back your call-stack at run time to find the LABEL.  Such
 191 desperate behavior triggers a warning if you use the C<use warnings>
 192 pragma or the B<-w> flag.
 193
 194 If there is a C<continue> BLOCK, it is always executed just before the
 195 conditional is about to be evaluated again.  Thus it can be used to
 196 increment a loop variable, even when the loop has been continued via
 197 the C<next> statement.
 198
 199 =head2 Loop Control
 200
 201 The C<next> command starts the next iteration of the loop:
 202
 203     LINE: while (<STDIN>) {
 204         next LINE if /^#/;      # discard comments
 205         ...
 206     }
 207
 208 The C<last> command immediately exits the loop in question.  The
 209 C<continue> block, if any, is not executed:
 210
 211     LINE: while (<STDIN>) {
 212         last LINE if /^$/;      # exit when done with header
 213         ...
 214     }
 215
 216 The C<redo> command restarts the loop block without evaluating the
 217 conditional again.  The C<continue> block, if any, is I<not> executed.
 218 This command is normally used by programs that want to lie to themselves
 219 about what was just input.
 220
 221 For example, when processing a file like F</etc/termcap>.
 222 If your input lines might end in backslashes to indicate continuation, you
 223 want to skip ahead and get the next record.
 224
 225     while (<>) {
 226         chomp;
 227         if (s/\\$//) {
 228             $_ .= <>;
 229             redo unless eof();
 230         }
 231         # now process $_
 232     }
 233
 234 which is Perl short-hand for the more explicitly written version:
 235
 236     LINE: while (defined($line = <ARGV>)) {
 237         chomp($line);
 238         if ($line =~ s/\\$//) {
 239             $line .= <ARGV>;
 240             redo LINE unless eof(); # not eof(ARGV)!
 241         }
 242         # now process $line
 243     }
 244
 245 Note that if there were a C<continue> block on the above code, it would
 246 get executed only on lines discarded by the regex (since redo skips the
 247 continue block). A continue block is often used to reset line counters
 248 or C<?pat?> one-time matches:
 249
 250     # inspired by :1,$g/fred/s//WILMA/
 251     while (<>) {
 252         ?(fred)?    && s//WILMA $1 WILMA/;
 253         ?(barney)?  && s//BETTY $1 BETTY/;
 254         ?(homer)?   && s//MARGE $1 MARGE/;
 255     } continue {
 256         print "$ARGV $.: $_";
 257         close ARGV  if eof();           # reset $.
 258         reset       if eof();           # reset ?pat?
 259     }
 260
 261 If the word C<while> is replaced by the word C<until>, the sense of the
 262 test is reversed, but the conditional is still tested before the first
 263 iteration.
 264
 265 The loop control statements don't work in an C<if> or C<unless>, since
 266 they aren't loops.  You can double the braces to make them such, though.
 267
 268     if (/pattern/) {{
 269         last if /fred/;
 270         next if /barney/; # same effect as "last", but doesn't document as well
 271         # do something here
 272     }}
 273
 274 This is caused by the fact that a block by itself acts as a loop that
 275 executes once, see L<"Basic BLOCKs and Switch Statements">.
 276
 277 The form C<while/if BLOCK BLOCK>, available in Perl 4, is no longer
 278 available.   Replace any occurrence of C<if BLOCK> by C<if (do BLOCK)>.
 279
 280 =head2 For Loops
 281
 282 Perl's C-style C<for> loop works like the corresponding C<while> loop;
 283 that means that this:
 284
 285     for ($i = 1; $i < 10; $i++) {
 286         ...
 287     }
 288
 289 is the same as this:
 290
 291     $i = 1;
 292     while ($i < 10) {
 293         ...
 294     } continue {
 295         $i++;
 296     }
 297
 298 There is one minor difference: if variables are declared with C<my>
 299 in the initialization section of the C<for>, the lexical scope of
 300 those variables is exactly the C<for> loop (the body of the loop
 301 and the control sections).
 302
 303 Besides the normal array index looping, C<for> can lend itself
 304 to many other interesting applications.  Here's one that avoids the
 305 problem you get into if you explicitly test for end-of-file on
 306 an interactive file descriptor causing your program to appear to
 307 hang.
 308
 309     $on_a_tty = -t STDIN && -t STDOUT;
 310     sub prompt { print "yes? " if $on_a_tty }
 311     for ( prompt(); <STDIN>; prompt() ) {
 312         # do something
 313     }
 314
 315 Using C<readline> (or the operator form, C<< <EXPR> >>) as the
 316 conditional of a C<for> loop is shorthand for the following.  This
 317 behaviour is the same as a C<while> loop conditional.
 318
 319     for ( prompt(); defined( $_ = <STDIN> ); prompt() ) {
 320         # do something
 321     }
 322
 323 =head2 Foreach Loops
 324
 325 The C<foreach> loop iterates over a normal list value and sets the
 326 variable VAR to be each element of the list in turn.  If the variable
 327 is preceded with the keyword C<my>, then it is lexically scoped, and
 328 is therefore visible only within the loop.  Otherwise, the variable is
 329 implicitly local to the loop and regains its former value upon exiting
 330 the loop.  If the variable was previously declared with C<my>, it uses
 331 that variable instead of the global one, but it's still localized to
 332 the loop.  This implicit localisation occurs I<only> in a C<foreach>
 333 loop.
 334
 335 The C<foreach> keyword is actually a synonym for the C<for> keyword, so
 336 you can use C<foreach> for readability or C<for> for brevity.  (Or because
 337 the Bourne shell is more familiar to you than I<csh>, so writing C<for>
 338 comes more naturally.)  If VAR is omitted, C<$_> is set to each value.
 339
 340 If any element of LIST is an lvalue, you can modify it by modifying
 341 VAR inside the loop.  Conversely, if any element of LIST is NOT an
 342 lvalue, any attempt to modify that element will fail.  In other words,
 343 the C<foreach> loop index variable is an implicit alias for each item
 344 in the list that you're looping over.
 345
 346 If any part of LIST is an array, C<foreach> will get very confused if
 347 you add or remove elements within the loop body, for example with
 348 C<splice>.   So don't do that.
 349
 350 C<foreach> probably won't do what you expect if VAR is a tied or other
 351 special variable.   Don't do that either.
 352
 353 Examples:
 354
 355     for (@ary) { s/foo/bar/ }
 356
 357     for my $elem (@elements) {
 358         $elem *= 2;
 359     }
 360
 361     for $count (10,9,8,7,6,5,4,3,2,1,'BOOM') {
 362         print $count, "\n"; sleep(1);
 363     }
 364
 365     for (1..15) { print "Merry Christmas\n"; }
 366
 367     foreach $item (split(/:[\\\n:]*/, $ENV{TERMCAP})) {
 368         print "Item: $item\n";
 369     }
 370
 371 Here's how a C programmer might code up a particular algorithm in Perl:
 372
 373     for (my $i = 0; $i < @ary1; $i++) {
 374         for (my $j = 0; $j < @ary2; $j++) {
 375             if ($ary1[$i] > $ary2[$j]) {
 376                 last; # can't go to outer :-(
 377             }
 378             $ary1[$i] += $ary2[$j];
 379         }
 380         # this is where that last takes me
 381     }
 382
 383 Whereas here's how a Perl programmer more comfortable with the idiom might
 384 do it:
 385
 386     OUTER: for my $wid (@ary1) {
 387     INNER:   for my $jet (@ary2) {
 388                 next OUTER if $wid > $jet;
 389                 $wid += $jet;
 390              }
 391           }
 392
 393 See how much easier this is?  It's cleaner, safer, and faster.  It's
 394 cleaner because it's less noisy.  It's safer because if code gets added
 395 between the inner and outer loops later on, the new code won't be
 396 accidentally executed.  The C<next> explicitly iterates the other loop
 397 rather than merely terminating the inner one.  And it's faster because
 398 Perl executes a C<foreach> statement more rapidly than it would the
 399 equivalent C<for> loop.
 400
 401 =head2 Basic BLOCKs and Switch Statements
 402
 403 A BLOCK by itself (labeled or not) is semantically equivalent to a
 404 loop that executes once.  Thus you can use any of the loop control
 405 statements in it to leave or restart the block.  (Note that this is
 406 I<NOT> true in C<eval{}>, C<sub{}>, or contrary to popular belief
 407 C<do{}> blocks, which do I<NOT> count as loops.)  The C<continue>
 408 block is optional.
 409
 410 The BLOCK construct is particularly nice for doing case
 411 structures.
 412
 413     SWITCH: {
 414         if (/^abc/) { $abc = 1; last SWITCH; }
 415         if (/^def/) { $def = 1; last SWITCH; }
 416         if (/^xyz/) { $xyz = 1; last SWITCH; }
 417         $nothing = 1;
 418     }
 419
 420 There is no official C<switch> statement in Perl, because there are
 421 already several ways to write the equivalent.
 422
 423 However, starting from Perl 5.8 to get switch and case one can use
 424 the Switch extension and say:
 425
 426         use Switch;
 427
 428 after which one has switch and case.  It is not as fast as it could be
 429 because it's not really part of the language (it's done using source
 430 filters) but it is available, and it's very flexible.
 431
 432 In addition to the above BLOCK construct, you could write
 433
 434     SWITCH: {
 435         $abc = 1, last SWITCH  if /^abc/;
 436         $def = 1, last SWITCH  if /^def/;
 437         $xyz = 1, last SWITCH  if /^xyz/;
 438         $nothing = 1;
 439     }
 440
 441 (That's actually not as strange as it looks once you realize that you can
 442 use loop control "operators" within an expression.  That's just the binary
 443 comma operator in scalar context.  See L<perlop/"Comma Operator">.)
 444
 445 or
 446
 447     SWITCH: {
 448         /^abc/ && do { $abc = 1; last SWITCH; };
 449         /^def/ && do { $def = 1; last SWITCH; };
 450         /^xyz/ && do { $xyz = 1; last SWITCH; };
 451         $nothing = 1;
 452     }
 453
 454 or formatted so it stands out more as a "proper" C<switch> statement:
 455
 456     SWITCH: {
 457         /^abc/      && do {
 458                             $abc = 1;
 459                             last SWITCH;
 460                        };
 461
 462         /^def/      && do {
 463                             $def = 1;
 464                             last SWITCH;
 465                        };
 466
 467         /^xyz/      && do {
 468                             $xyz = 1;
 469                             last SWITCH;
 470                         };
 471         $nothing = 1;
 472     }
 473
 474 or
 475
 476     SWITCH: {
 477         /^abc/ and $abc = 1, last SWITCH;
 478         /^def/ and $def = 1, last SWITCH;
 479         /^xyz/ and $xyz = 1, last SWITCH;
 480         $nothing = 1;
 481     }
 482
 483 or even, horrors,
 484
 485     if (/^abc/)
 486         { $abc = 1 }
 487     elsif (/^def/)
 488         { $def = 1 }
 489     elsif (/^xyz/)
 490         { $xyz = 1 }
 491     else
 492         { $nothing = 1 }
 493
 494 A common idiom for a C<switch> statement is to use C<foreach>'s aliasing to make
 495 a temporary assignment to C<$_> for convenient matching:
 496
 497     SWITCH: for ($where) {
 498                 /In Card Names/     && do { push @flags, '-e'; last; };
 499                 /Anywhere/          && do { push @flags, '-h'; last; };
 500                 /In Rulings/        && do {                    last; };
 501                 die "unknown value for form variable where: `$where'";
 502             }
 503
 504 Another interesting approach to a switch statement is arrange
 505 for a C<do> block to return the proper value:
 506
 507     $amode = do {
 508         if     ($flag & O_RDONLY) { "r" }       # XXX: isn't this 0?
 509         elsif  ($flag & O_WRONLY) { ($flag & O_APPEND) ? "a" : "w" }
 510         elsif  ($flag & O_RDWR)   {
 511             if ($flag & O_CREAT)  { "w+" }
 512             else                  { ($flag & O_APPEND) ? "a+" : "r+" }
 513         }
 514     };
 515
 516 Or
 517
 518         print do {
 519             ($flags & O_WRONLY) ? "write-only"          :
 520             ($flags & O_RDWR)   ? "read-write"          :
 521                                   "read-only";
 522         };
 523
 524 Or if you are certain that all the C<&&> clauses are true, you can use
 525 something like this, which "switches" on the value of the
 526 C<HTTP_USER_AGENT> environment variable.
 527
 528     #!/usr/bin/perl
 529     # pick out jargon file page based on browser
 530     $dir = 'http://www.wins.uva.nl/~mes/jargon';
 531     for ($ENV{HTTP_USER_AGENT}) {
 532         $page  =    /Mac/            && 'm/Macintrash.html'
 533                  || /Win(dows )?NT/  && 'e/evilandrude.html'
 534                  || /Win|MSIE|WebTV/ && 'm/MicroslothWindows.html'
 535                  || /Linux/          && 'l/Linux.html'
 536                  || /HP-UX/          && 'h/HP-SUX.html'
 537                  || /SunOS/          && 's/ScumOS.html'
 538                  ||                     'a/AppendixB.html';
 539     }
 540     print "Location: $dir/$page\015\012\015\012";
 541
 542 That kind of switch statement only works when you know the C<&&> clauses
 543 will be true.  If you don't, the previous C<?:> example should be used.
 544
 545 You might also consider writing a hash of subroutine references
 546 instead of synthesizing a C<switch> statement.
 547
 548 =head2 Goto
 549
 550 Although not for the faint of heart, Perl does support a C<goto>
 551 statement.  There are three forms: C<goto>-LABEL, C<goto>-EXPR, and
 552 C<goto>-&NAME.  A loop's LABEL is not actually a valid target for
 553 a C<goto>; it's just the name of the loop.
 554
 555 The C<goto>-LABEL form finds the statement labeled with LABEL and resumes
 556 execution there.  It may not be used to go into any construct that
 557 requires initialization, such as a subroutine or a C<foreach> loop.  It
 558 also can't be used to go into a construct that is optimized away.  It
 559 can be used to go almost anywhere else within the dynamic scope,
 560 including out of subroutines, but it's usually better to use some other
 561 construct such as C<last> or C<die>.  The author of Perl has never felt the
 562 need to use this form of C<goto> (in Perl, that is--C is another matter).
 563
 564 The C<goto>-EXPR form expects a label name, whose scope will be resolved
 565 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
 566 necessarily recommended if you're optimizing for maintainability:
 567
 568     goto(("FOO", "BAR", "GLARCH")[$i]);
 569
 570 The C<goto>-&NAME form is highly magical, and substitutes a call to the
 571 named subroutine for the currently running subroutine.  This is used by
 572 C<AUTOLOAD()> subroutines that wish to load another subroutine and then
 573 pretend that the other subroutine had been called in the first place
 574 (except that any modifications to C<@_> in the current subroutine are
 575 propagated to the other subroutine.)  After the C<goto>, not even C<caller()>
 576 will be able to tell that this routine was called first.
 577
 578 In almost all cases like this, it's usually a far, far better idea to use the
 579 structured control flow mechanisms of C<next>, C<last>, or C<redo> instead of
 580 resorting to a C<goto>.  For certain applications, the catch and throw pair of
 581 C<eval{}> and die() for exception processing can also be a prudent approach.
 582
 583 =head2 PODs: Embedded Documentation
 584
 585 Perl has a mechanism for intermixing documentation with source code.
 586 While it's expecting the beginning of a new statement, if the compiler
 587 encounters a line that begins with an equal sign and a word, like this
 588
 589     =head1 Here There Be Pods!
 590
 591 Then that text and all remaining text up through and including a line
 592 beginning with C<=cut> will be ignored.  The format of the intervening
 593 text is described in L<perlpod>.
 594
 595 This allows you to intermix your source code
 596 and your documentation text freely, as in
 597
 598     =item snazzle($)
 599
 600     The snazzle() function will behave in the most spectacular
 601     form that you can possibly imagine, not even excepting
 602     cybernetic pyrotechnics.
 603
 604     =cut back to the compiler, nuff of this pod stuff!
 605
 606     sub snazzle($) {
 607         my $thingie = shift;
 608         .........
 609     }
 610
 611 Note that pod translators should look at only paragraphs beginning
 612 with a pod directive (it makes parsing easier), whereas the compiler
 613 actually knows to look for pod escapes even in the middle of a
 614 paragraph.  This means that the following secret stuff will be
 615 ignored by both the compiler and the translators.
 616
 617     $a=3;
 618     =secret stuff
 619      warn "Neither POD nor CODE!?"
 620     =cut back
 621     print "got $a\n";
 622
 623 You probably shouldn't rely upon the C<warn()> being podded out forever.
 624 Not all pod translators are well-behaved in this regard, and perhaps
 625 the compiler will become pickier.
 626
 627 One may also use pod directives to quickly comment out a section
 628 of code.
 629
 630 =head2 Plain Old Comments (Not!)
 631
 632 Perl can process line directives, much like the C preprocessor.  Using
 633 this, one can control Perl's idea of filenames and line numbers in
 634 error or warning messages (especially for strings that are processed
 635 with C<eval()>).  The syntax for this mechanism is the same as for most
 636 C preprocessors: it matches the regular expression
 637
 638     # example: '# line 42 "new_filename.plx"'
 639     /^\#   \s*
 640       line \s+ (\d+)   \s*
 641       (?:\s("?)([^"]+)\2)? \s*
 642      $/x
 643
 644 with C<$1> being the line number for the next line, and C<$3> being
 645 the optional filename (specified with or without quotes).
 646
 647 There is a fairly obvious gotcha included with the line directive:
 648 Debuggers and profilers will only show the last source line to appear
 649 at a particular line number in a given file.  Care should be taken not
 650 to cause line number collisions in code you'd like to debug later.
 651
 652 Here are some examples that you should be able to type into your command
 653 shell:
 654
 655     % perl
 656     # line 200 "bzzzt"
 657     # the `#' on the previous line must be the first char on line
 658     die 'foo';
 659     __END__
 660     foo at bzzzt line 201.
 661
 662     % perl
 663     # line 200 "bzzzt"
 664     eval qq[\n#line 2001 ""\ndie 'foo']; print $@;
 665     __END__
 666     foo at - line 2001.
 667
 668     % perl
 669     eval qq[\n#line 200 "foo bar"\ndie 'foo']; print $@;
 670     __END__
 671     foo at foo bar line 200.
 672
 673     % perl
 674     # line 345 "goop"
 675     eval "\n#line " . __LINE__ . ' "' . __FILE__ ."\"\ndie 'foo'";
 676     print $@;
 677     __END__
 678     foo at goop line 345.
 679
 680 =cut