pod/perlsyn.pod

   1 =head1 NAME
   2
   3 perlsyn - Perl syntax
   4
   5 =head1 DESCRIPTION
   6
   7 A Perl script consists of a sequence of declarations and statements.
   8 The sequence of statements is executed just once, unlike in B<sed>
   9 and B<awk> scripts, where the sequence of statements is executed
  10 for each input line.  While this means that you must explicitly
  11 loop over the lines of your input file (or files), it also means
  12 you have much more control over which files and which lines you look at.
  13 (Actually, I'm lying--it is possible to do an implicit loop with
  14 either the B<-n> or B<-p> switch.  It's just not the mandatory
  15 default like it is in B<sed> and B<awk>.)
  16
  17 Perl is, for the most part, a free-form language.  (The only exception
  18 to this is format declarations, for obvious reasons.)  Text from a
  19 C<"#"> character until the end of the line is a comment, and is
  20 ignored.  If you attempt to use C</* */> C-style comments, it will be
  21 interpreted either as division or pattern matching, depending on the
  22 context, and C++ C<//> comments just look like a null regular
  23 expression, so don't do that.
  24
  25 =head2 Declarations
  26
  27 The only things you need to declare in Perl are report formats
  28 and subroutines--and even undefined subroutines can be handled
  29 through AUTOLOAD.  A variable holds the undefined value (C<undef>)
  30 until it has been assigned a defined value, which is anything
  31 other than C<undef>.  When used as a number, C<undef> is treated
  32 as C<0>; when used as a string, it is treated the empty string,
  33 C<"">; and when used as a reference that isn't being assigned
  34 to, it is treated as an error.  If you enable warnings, you'll
  35 be notified of an uninitialized value whenever you treat C<undef>
  36 as a string or a number.  Well, usually.  Boolean contexts, such as:
  37
  38     my $a;
  39     if ($a) {}
  40
  41 are exempt from warnings (because they care about truth rather than
  42 definedness).  Operators such as C<++>, C<-->, C<+=>,
  43 C<-=>, and C<.=>, that operate on undefined left values such as:
  44
  45     my $a;
  46     $a++;
  47
  48 are also always exempt from such warnings.
  49
  50 A declaration can be put anywhere a statement can, but has no effect on
  51 the execution of the primary sequence of statements--declarations all
  52 take effect at compile time.  Typically all the declarations are put at
  53 the beginning or the end of the script.  However, if you're using
  54 lexically-scoped private variables created with C<my()>, you'll
  55 have to make sure
  56 your format or subroutine definition is within the same block scope
  57 as the my if you expect to be able to access those private variables.
  58
  59 Declaring a subroutine allows a subroutine name to be used as if it were a
  60 list operator from that point forward in the program.  You can declare a
  61 subroutine without defining it by saying C<sub name>, thus:
  62
  63     sub myname;
  64     $me = myname $0             or die "can't get myname";
  65
  66 Note that myname() functions as a list operator, not as a unary operator;
  67 so be careful to use C<or> instead of C<||> in this case.  However, if
  68 you were to declare the subroutine as C<sub myname ($)>, then
  69 C<myname> would function as a unary operator, so either C<or> or
  70 C<||> would work.
  71
  72 Subroutines declarations can also be loaded up with the C<require> statement
  73 or both loaded and imported into your namespace with a C<use> statement.
  74 See L<perlmod> for details on this.
  75
  76 A statement sequence may contain declarations of lexically-scoped
  77 variables, but apart from declaring a variable name, the declaration acts
  78 like an ordinary statement, and is elaborated within the sequence of
  79 statements as if it were an ordinary statement.  That means it actually
  80 has both compile-time and run-time effects.
  81
  82 =head2 Simple statements
  83
  84 The only kind of simple statement is an expression evaluated for its
  85 side effects.  Every simple statement must be terminated with a
  86 semicolon, unless it is the final statement in a block, in which case
  87 the semicolon is optional.  (A semicolon is still encouraged there if the
  88 block takes up more than one line, because you may eventually add another line.)
  89 Note that there are some operators like C<eval {}> and C<do {}> that look
  90 like compound statements, but aren't (they're just TERMs in an expression),
  91 and thus need an explicit termination if used as the last item in a statement.
  92
  93 Any simple statement may optionally be followed by a I<SINGLE> modifier,
  94 just before the terminating semicolon (or block ending).  The possible
  95 modifiers are:
  96
  97     if EXPR
  98     unless EXPR
  99     while EXPR
 100     until EXPR
 101     foreach EXPR
 102
 103 The C<if> and C<unless> modifiers have the expected semantics,
 104 presuming you're a speaker of English.  The C<foreach> modifier is an
 105 iterator:  For each value in EXPR, it aliases C<$_> to the value and
 106 executes the statement.  The C<while> and C<until> modifiers have the
 107 usual "C<while> loop" semantics (conditional evaluated first), except
 108 when applied to a C<do>-BLOCK (or to the deprecated C<do>-SUBROUTINE
 109 statement), in which case the block executes once before the
 110 conditional is evaluated.  This is so that you can write loops like:
 111
 112     do {
 113         $line = <STDIN>;
 114         ...
 115     } until $line  eq ".\n";
 116
 117 See L<perlfunc/do>.  Note also that the loop control statements described
 118 later will I<NOT> work in this construct, because modifiers don't take
 119 loop labels.  Sorry.  You can always put another block inside of it
 120 (for C<next>) or around it (for C<last>) to do that sort of thing.
 121 For C<next>, just double the braces:
 122
 123     do {{
 124         next if $x == $y;
 125         # do something here
 126     }} until $x++ > $z;
 127
 128 For C<last>, you have to be more elaborate:
 129
 130     LOOP: {
 131             do {
 132                 last if $x = $y**2;
 133                 # do something here
 134             } while $x++ <= $z;
 135     }
 136
 137 B<NOTE:> The behaviour of a C<my> statement modified with a statement
 138 modifier conditional or loop construct (e.g. C<my $x if ...>) is
 139 B<undefined>.  The value of the C<my> variable may be C<undef>, any
 140 previously assigned value, or possibly anything else.  Don't rely on
 141 it.  Future versions of perl might do something different from the
 142 version of perl you try it out on.  Here be dragons.
 143
 144 =head2 Compound statements
 145
 146 In Perl, a sequence of statements that defines a scope is called a block.
 147 Sometimes a block is delimited by the file containing it (in the case
 148 of a required file, or the program as a whole), and sometimes a block
 149 is delimited by the extent of a string (in the case of an eval).
 150
 151 But generally, a block is delimited by curly brackets, also known as braces.
 152 We will call this syntactic construct a BLOCK.
 153
 154 The following compound statements may be used to control flow:
 155
 156     if (EXPR) BLOCK
 157     if (EXPR) BLOCK else BLOCK
 158     if (EXPR) BLOCK elsif (EXPR) BLOCK ... else BLOCK
 159     LABEL while (EXPR) BLOCK
 160     LABEL while (EXPR) BLOCK continue BLOCK
 161     LABEL for (EXPR; EXPR; EXPR) BLOCK
 162     LABEL foreach VAR (LIST) BLOCK
 163     LABEL foreach VAR (LIST) BLOCK continue BLOCK
 164     LABEL BLOCK continue BLOCK
 165
 166 Note that, unlike C and Pascal, these are defined in terms of BLOCKs,
 167 not statements.  This means that the curly brackets are I<required>--no
 168 dangling statements allowed.  If you want to write conditionals without
 169 curly brackets there are several other ways to do it.  The following
 170 all do the same thing:
 171
 172     if (!open(FOO)) { die "Can't open $FOO: $!"; }
 173     die "Can't open $FOO: $!" unless open(FOO);
 174     open(FOO) or die "Can't open $FOO: $!";     # FOO or bust!
 175     open(FOO) ? 'hi mom' : die "Can't open $FOO: $!";
 176                         # a bit exotic, that last one
 177
 178 The C<if> statement is straightforward.  Because BLOCKs are always
 179 bounded by curly brackets, there is never any ambiguity about which
 180 C<if> an C<else> goes with.  If you use C<unless> in place of C<if>,
 181 the sense of the test is reversed.
 182
 183 The C<while> statement executes the block as long as the expression is
 184 true (does not evaluate to the null string C<""> or C<0> or C<"0">).
 185 The LABEL is optional, and if present, consists of an identifier followed
 186 by a colon.  The LABEL identifies the loop for the loop control
 187 statements C<next>, C<last>, and C<redo>.
 188 If the LABEL is omitted, the loop control statement
 189 refers to the innermost enclosing loop.  This may include dynamically
 190 looking back your call-stack at run time to find the LABEL.  Such
 191 desperate behavior triggers a warning if you use the C<use warnings>
 192 pragma or the B<-w> flag.
 193
 194 If there is a C<continue> BLOCK, it is always executed just before the
 195 conditional is about to be evaluated again, just like the third part of a
 196 C<for> loop in C.  Thus it can be used to increment a loop variable, even
 197 when the loop has been continued via the C<next> statement (which is
 198 similar to the C C<continue> statement).
 199
 200 =head2 Loop Control
 201
 202 The C<next> command is like the C<continue> statement in C; it starts
 203 the next iteration of the loop:
 204
 205     LINE: while (<STDIN>) {
 206         next LINE if /^#/;      # discard comments
 207         ...
 208     }
 209
 210 The C<last> command is like the C<break> statement in C (as used in
 211 loops); it immediately exits the loop in question.  The
 212 C<continue> block, if any, is not executed:
 213
 214     LINE: while (<STDIN>) {
 215         last LINE if /^$/;      # exit when done with header
 216         ...
 217     }
 218
 219 The C<redo> command restarts the loop block without evaluating the
 220 conditional again.  The C<continue> block, if any, is I<not> executed.
 221 This command is normally used by programs that want to lie to themselves
 222 about what was just input.
 223
 224 For example, when processing a file like F</etc/termcap>.
 225 If your input lines might end in backslashes to indicate continuation, you
 226 want to skip ahead and get the next record.
 227
 228     while (<>) {
 229         chomp;
 230         if (s/\\$//) {
 231             $_ .= <>;
 232             redo unless eof();
 233         }
 234         # now process $_
 235     }
 236
 237 which is Perl short-hand for the more explicitly written version:
 238
 239     LINE: while (defined($line = <ARGV>)) {
 240         chomp($line);
 241         if ($line =~ s/\\$//) {
 242             $line .= <ARGV>;
 243             redo LINE unless eof(); # not eof(ARGV)!
 244         }
 245         # now process $line
 246     }
 247
 248 Note that if there were a C<continue> block on the above code, it would
 249 get executed only on lines discarded by the regex (since redo skips the
 250 continue block). A continue block is often used to reset line counters
 251 or C<?pat?> one-time matches:
 252
 253     # inspired by :1,$g/fred/s//WILMA/
 254     while (<>) {
 255         ?(fred)?    && s//WILMA $1 WILMA/;
 256         ?(barney)?  && s//BETTY $1 BETTY/;
 257         ?(homer)?   && s//MARGE $1 MARGE/;
 258     } continue {
 259         print "$ARGV $.: $_";
 260         close ARGV  if eof();           # reset $.
 261         reset       if eof();           # reset ?pat?
 262     }
 263
 264 If the word C<while> is replaced by the word C<until>, the sense of the
 265 test is reversed, but the conditional is still tested before the first
 266 iteration.
 267
 268 The loop control statements don't work in an C<if> or C<unless>, since
 269 they aren't loops.  You can double the braces to make them such, though.
 270
 271     if (/pattern/) {{
 272         last if /fred/;
 273         next if /barney/; # same effect as "last", but doesn't document as well
 274         # do something here
 275     }}
 276
 277 This is caused by the fact that a block by itself acts as a loop that
 278 executes once, see L<"Basic BLOCKs and Switch Statements">.
 279
 280 The form C<while/if BLOCK BLOCK>, available in Perl 4, is no longer
 281 available.   Replace any occurrence of C<if BLOCK> by C<if (do BLOCK)>.
 282
 283 =head2 For Loops
 284
 285 Perl's C-style C<for> loop works like the corresponding C<while> loop;
 286 that means that this:
 287
 288     for ($i = 1; $i < 10; $i++) {
 289         ...
 290     }
 291
 292 is the same as this:
 293
 294     $i = 1;
 295     while ($i < 10) {
 296         ...
 297     } continue {
 298         $i++;
 299     }
 300
 301 There is one minor difference: if variables are declared with C<my>
 302 in the initialization section of the C<for>, the lexical scope of
 303 those variables is exactly the C<for> loop (the body of the loop
 304 and the control sections).
 305
 306 Besides the normal array index looping, C<for> can lend itself
 307 to many other interesting applications.  Here's one that avoids the
 308 problem you get into if you explicitly test for end-of-file on
 309 an interactive file descriptor causing your program to appear to
 310 hang.
 311
 312     $on_a_tty = -t STDIN && -t STDOUT;
 313     sub prompt { print "yes? " if $on_a_tty }
 314     for ( prompt(); <STDIN>; prompt() ) {
 315         # do something
 316     }
 317
 318 =head2 Foreach Loops
 319
 320 The C<foreach> loop iterates over a normal list value and sets the
 321 variable VAR to be each element of the list in turn.  If the variable
 322 is preceded with the keyword C<my>, then it is lexically scoped, and
 323 is therefore visible only within the loop.  Otherwise, the variable is
 324 implicitly local to the loop and regains its former value upon exiting
 325 the loop.  If the variable was previously declared with C<my>, it uses
 326 that variable instead of the global one, but it's still localized to
 327 the loop.  This implicit localisation occurs I<only> in a C<foreach>
 328 loop.
 329
 330 The C<foreach> keyword is actually a synonym for the C<for> keyword, so
 331 you can use C<foreach> for readability or C<for> for brevity.  (Or because
 332 the Bourne shell is more familiar to you than I<csh>, so writing C<for>
 333 comes more naturally.)  If VAR is omitted, C<$_> is set to each value.
 334
 335 If any element of LIST is an lvalue, you can modify it by modifying
 336 VAR inside the loop.  Conversely, if any element of LIST is NOT an
 337 lvalue, any attempt to modify that element will fail.  In other words,
 338 the C<foreach> loop index variable is an implicit alias for each item
 339 in the list that you're looping over.
 340
 341 If any part of LIST is an array, C<foreach> will get very confused if
 342 you add or remove elements within the loop body, for example with
 343 C<splice>.   So don't do that.
 344
 345 C<foreach> probably won't do what you expect if VAR is a tied or other
 346 special variable.   Don't do that either.
 347
 348 Examples:
 349
 350     for (@ary) { s/foo/bar/ }
 351
 352     for my $elem (@elements) {
 353         $elem *= 2;
 354     }
 355
 356     for $count (10,9,8,7,6,5,4,3,2,1,'BOOM') {
 357         print $count, "\n"; sleep(1);
 358     }
 359
 360     for (1..15) { print "Merry Christmas\n"; }
 361
 362     foreach $item (split(/:[\\\n:]*/, $ENV{TERMCAP})) {
 363         print "Item: $item\n";
 364     }
 365
 366 Here's how a C programmer might code up a particular algorithm in Perl:
 367
 368     for (my $i = 0; $i < @ary1; $i++) {
 369         for (my $j = 0; $j < @ary2; $j++) {
 370             if ($ary1[$i] > $ary2[$j]) {
 371                 last; # can't go to outer :-(
 372             }
 373             $ary1[$i] += $ary2[$j];
 374         }
 375         # this is where that last takes me
 376     }
 377
 378 Whereas here's how a Perl programmer more comfortable with the idiom might
 379 do it:
 380
 381     OUTER: for my $wid (@ary1) {
 382     INNER:   for my $jet (@ary2) {
 383                 next OUTER if $wid > $jet;
 384                 $wid += $jet;
 385              }
 386           }
 387
 388 See how much easier this is?  It's cleaner, safer, and faster.  It's
 389 cleaner because it's less noisy.  It's safer because if code gets added
 390 between the inner and outer loops later on, the new code won't be
 391 accidentally executed.  The C<next> explicitly iterates the other loop
 392 rather than merely terminating the inner one.  And it's faster because
 393 Perl executes a C<foreach> statement more rapidly than it would the
 394 equivalent C<for> loop.
 395
 396 =head2 Basic BLOCKs and Switch Statements
 397
 398 A BLOCK by itself (labeled or not) is semantically equivalent to a
 399 loop that executes once.  Thus you can use any of the loop control
 400 statements in it to leave or restart the block.  (Note that this is
 401 I<NOT> true in C<eval{}>, C<sub{}>, or contrary to popular belief
 402 C<do{}> blocks, which do I<NOT> count as loops.)  The C<continue>
 403 block is optional.
 404
 405 The BLOCK construct is particularly nice for doing case
 406 structures.
 407
 408     SWITCH: {
 409         if (/^abc/) { $abc = 1; last SWITCH; }
 410         if (/^def/) { $def = 1; last SWITCH; }
 411         if (/^xyz/) { $xyz = 1; last SWITCH; }
 412         $nothing = 1;
 413     }
 414
 415 There is no official C<switch> statement in Perl, because there are
 416 already several ways to write the equivalent.
 417
 418 However, starting from Perl 5.8 to get switch and case one can use
 419 the Switch extension and say:
 420
 421         use Switch;
 422
 423 after which one has switch and case.  It is not as fast as it could be
 424 because it's not really part of the language (it's done using source
 425 filters) but it is available, and it's very flexible.
 426
 427 In addition to the above BLOCK construct, you could write
 428
 429     SWITCH: {
 430         $abc = 1, last SWITCH  if /^abc/;
 431         $def = 1, last SWITCH  if /^def/;
 432         $xyz = 1, last SWITCH  if /^xyz/;
 433         $nothing = 1;
 434     }
 435
 436 (That's actually not as strange as it looks once you realize that you can
 437 use loop control "operators" within an expression,  That's just the normal
 438 C comma operator.)
 439
 440 or
 441
 442     SWITCH: {
 443         /^abc/ && do { $abc = 1; last SWITCH; };
 444         /^def/ && do { $def = 1; last SWITCH; };
 445         /^xyz/ && do { $xyz = 1; last SWITCH; };
 446         $nothing = 1;
 447     }
 448
 449 or formatted so it stands out more as a "proper" C<switch> statement:
 450
 451     SWITCH: {
 452         /^abc/      && do {
 453                             $abc = 1;
 454                             last SWITCH;
 455                        };
 456
 457         /^def/      && do {
 458                             $def = 1;
 459                             last SWITCH;
 460                        };
 461
 462         /^xyz/      && do {
 463                             $xyz = 1;
 464                             last SWITCH;
 465                         };
 466         $nothing = 1;
 467     }
 468
 469 or
 470
 471     SWITCH: {
 472         /^abc/ and $abc = 1, last SWITCH;
 473         /^def/ and $def = 1, last SWITCH;
 474         /^xyz/ and $xyz = 1, last SWITCH;
 475         $nothing = 1;
 476     }
 477
 478 or even, horrors,
 479
 480     if (/^abc/)
 481         { $abc = 1 }
 482     elsif (/^def/)
 483         { $def = 1 }
 484     elsif (/^xyz/)
 485         { $xyz = 1 }
 486     else
 487         { $nothing = 1 }
 488
 489 A common idiom for a C<switch> statement is to use C<foreach>'s aliasing to make
 490 a temporary assignment to C<$_> for convenient matching:
 491
 492     SWITCH: for ($where) {
 493                 /In Card Names/     && do { push @flags, '-e'; last; };
 494                 /Anywhere/          && do { push @flags, '-h'; last; };
 495                 /In Rulings/        && do {                    last; };
 496                 die "unknown value for form variable where: `$where'";
 497             }
 498
 499 Another interesting approach to a switch statement is arrange
 500 for a C<do> block to return the proper value:
 501
 502     $amode = do {
 503         if     ($flag & O_RDONLY) { "r" }       # XXX: isn't this 0?
 504         elsif  ($flag & O_WRONLY) { ($flag & O_APPEND) ? "a" : "w" }
 505         elsif  ($flag & O_RDWR)   {
 506             if ($flag & O_CREAT)  { "w+" }
 507             else                  { ($flag & O_APPEND) ? "a+" : "r+" }
 508         }
 509     };
 510
 511 Or
 512
 513         print do {
 514             ($flags & O_WRONLY) ? "write-only"          :
 515             ($flags & O_RDWR)   ? "read-write"          :
 516                                   "read-only";
 517         };
 518
 519 Or if you are certain that all the C<&&> clauses are true, you can use
 520 something like this, which "switches" on the value of the
 521 C<HTTP_USER_AGENT> environment variable.
 522
 523     #!/usr/bin/perl
 524     # pick out jargon file page based on browser
 525     $dir = 'http://www.wins.uva.nl/~mes/jargon';
 526     for ($ENV{HTTP_USER_AGENT}) {
 527         $page  =    /Mac/            && 'm/Macintrash.html'
 528                  || /Win(dows )?NT/  && 'e/evilandrude.html'
 529                  || /Win|MSIE|WebTV/ && 'm/MicroslothWindows.html'
 530                  || /Linux/          && 'l/Linux.html'
 531                  || /HP-UX/          && 'h/HP-SUX.html'
 532                  || /SunOS/          && 's/ScumOS.html'
 533                  ||                     'a/AppendixB.html';
 534     }
 535     print "Location: $dir/$page\015\012\015\012";
 536
 537 That kind of switch statement only works when you know the C<&&> clauses
 538 will be true.  If you don't, the previous C<?:> example should be used.
 539
 540 You might also consider writing a hash of subroutine references
 541 instead of synthesizing a C<switch> statement.
 542
 543 =head2 Goto
 544
 545 Although not for the faint of heart, Perl does support a C<goto>
 546 statement.  There are three forms: C<goto>-LABEL, C<goto>-EXPR, and
 547 C<goto>-&NAME.  A loop's LABEL is not actually a valid target for
 548 a C<goto>; it's just the name of the loop.
 549
 550 The C<goto>-LABEL form finds the statement labeled with LABEL and resumes
 551 execution there.  It may not be used to go into any construct that
 552 requires initialization, such as a subroutine or a C<foreach> loop.  It
 553 also can't be used to go into a construct that is optimized away.  It
 554 can be used to go almost anywhere else within the dynamic scope,
 555 including out of subroutines, but it's usually better to use some other
 556 construct such as C<last> or C<die>.  The author of Perl has never felt the
 557 need to use this form of C<goto> (in Perl, that is--C is another matter).
 558
 559 The C<goto>-EXPR form expects a label name, whose scope will be resolved
 560 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
 561 necessarily recommended if you're optimizing for maintainability:
 562
 563     goto(("FOO", "BAR", "GLARCH")[$i]);
 564
 565 The C<goto>-&NAME form is highly magical, and substitutes a call to the
 566 named subroutine for the currently running subroutine.  This is used by
 567 C<AUTOLOAD()> subroutines that wish to load another subroutine and then
 568 pretend that the other subroutine had been called in the first place
 569 (except that any modifications to C<@_> in the current subroutine are
 570 propagated to the other subroutine.)  After the C<goto>, not even C<caller()>
 571 will be able to tell that this routine was called first.
 572
 573 In almost all cases like this, it's usually a far, far better idea to use the
 574 structured control flow mechanisms of C<next>, C<last>, or C<redo> instead of
 575 resorting to a C<goto>.  For certain applications, the catch and throw pair of
 576 C<eval{}> and die() for exception processing can also be a prudent approach.
 577
 578 =head2 PODs: Embedded Documentation
 579
 580 Perl has a mechanism for intermixing documentation with source code.
 581 While it's expecting the beginning of a new statement, if the compiler
 582 encounters a line that begins with an equal sign and a word, like this
 583
 584     =head1 Here There Be Pods!
 585
 586 Then that text and all remaining text up through and including a line
 587 beginning with C<=cut> will be ignored.  The format of the intervening
 588 text is described in L<perlpod>.
 589
 590 This allows you to intermix your source code
 591 and your documentation text freely, as in
 592
 593     =item snazzle($)
 594
 595     The snazzle() function will behave in the most spectacular
 596     form that you can possibly imagine, not even excepting
 597     cybernetic pyrotechnics.
 598
 599     =cut back to the compiler, nuff of this pod stuff!
 600
 601     sub snazzle($) {
 602         my $thingie = shift;
 603         .........
 604     }
 605
 606 Note that pod translators should look at only paragraphs beginning
 607 with a pod directive (it makes parsing easier), whereas the compiler
 608 actually knows to look for pod escapes even in the middle of a
 609 paragraph.  This means that the following secret stuff will be
 610 ignored by both the compiler and the translators.
 611
 612     $a=3;
 613     =secret stuff
 614      warn "Neither POD nor CODE!?"
 615     =cut back
 616     print "got $a\n";
 617
 618 You probably shouldn't rely upon the C<warn()> being podded out forever.
 619 Not all pod translators are well-behaved in this regard, and perhaps
 620 the compiler will become pickier.
 621
 622 One may also use pod directives to quickly comment out a section
 623 of code.
 624
 625 =head2 Plain Old Comments (Not!)
 626
 627 Much like the C preprocessor, Perl can process line directives.  Using
 628 this, one can control Perl's idea of filenames and line numbers in
 629 error or warning messages (especially for strings that are processed
 630 with C<eval()>).  The syntax for this mechanism is the same as for most
 631 C preprocessors: it matches the regular expression
 632 C</^#\s*line\s+(\d+)\s*(?:\s"([^"]+)")?\s*$/> with C<$1> being the line
 633 number for the next line, and C<$2> being the optional filename
 634 (specified within quotes).
 635
 636 There is a fairly obvious gotcha included with the line directive:
 637 Debuggers and profilers will only show the last source line to appear
 638 at a particular line number in a given file.  Care should be taken not
 639 to cause line number collisions in code you'd like to debug later.
 640
 641 Here are some examples that you should be able to type into your command
 642 shell:
 643
 644     % perl
 645     # line 200 "bzzzt"
 646     # the `#' on the previous line must be the first char on line
 647     die 'foo';
 648     __END__
 649     foo at bzzzt line 201.
 650
 651     % perl
 652     # line 200 "bzzzt"
 653     eval qq[\n#line 2001 ""\ndie 'foo']; print $@;
 654     __END__
 655     foo at - line 2001.
 656
 657     % perl
 658     eval qq[\n#line 200 "foo bar"\ndie 'foo']; print $@;
 659     __END__
 660     foo at foo bar line 200.
 661
 662     % perl
 663     # line 345 "goop"
 664     eval "\n#line " . __LINE__ . ' "' . __FILE__ ."\"\ndie 'foo'";
 665     print $@;
 666     __END__
 667     foo at goop line 345.
 668
 669 =cut