Updates to perlfunc.pod
[p5sagit/p5-mst-13.2.git] / pod / perlsec.pod
1 =head1 NAME
2
3 perlsec - Perl security
4
5 =head1 DESCRIPTION
6
7 Perl is designed to make it easy to program securely even when running
8 with extra privileges, like setuid or setgid programs.  Unlike most
9 command-line shells, which are based on multiple substitution passes on
10 each line of the script, Perl uses a more conventional evaluation scheme
11 with fewer hidden snags.  Additionally, because the language has more
12 built-in functionality, it can rely less upon external (and possibly
13 untrustworthy) programs to accomplish its purposes.
14
15 Perl automatically enables a set of special security checks, called I<taint
16 mode>, when it detects its program running with differing real and effective
17 user or group IDs.  The setuid bit in Unix permissions is mode 04000, the
18 setgid bit mode 02000; either or both may be set.  You can also enable taint
19 mode explicitly by using the B<-T> command line flag. This flag is
20 I<strongly> suggested for server programs and any program run on behalf of
21 someone else, such as a CGI script.
22
23 While in this mode, Perl takes special precautions called I<taint checks> to
24 prevent both obvious and subtle traps.  Some of these checks are reasonably
25 simple, such as not blindly using the PATH inherited from one's parent
26 process.  Other checks, however, are best supported by the language itself,
27 and it is these checks especially that contribute to making a setuid Perl
28 program more secure than the corresponding C program.
29
30 You may not use data derived from outside your program to affect something
31 else outside your program--at least, not by accident.  All command-line
32 arguments, environment variables, locale information (see L<perllocale>),
33 and file input are marked as "tainted".  Tainted data may not be used
34 directly or indirectly in any command that invokes a sub-shell, nor in any
35 command that modifies files, directories, or processes.  Any variable set
36 within an expression that has previously referenced a tainted value itself
37 becomes tainted, even if it is logically impossible for the tainted value
38 to influence the variable.  Because taintedness is associated with each
39 scalar value, some elements of an array can be tainted and others not.
40
41 For example:
42
43     $arg = shift;               # $arg is tainted
44     $hid = $arg, 'bar';         # $hid is also tainted
45     $line = <>;                 # Tainted
46     $line = <STDIN>;            # Also tainted
47     open FOO, "/home/me/bar" or die $!;
48     $line = <FOO>;              # Still tainted
49     $path = $ENV{'PATH'};       # Tainted, but see below
50     $data = 'abc';              # Not tainted
51
52     system "echo $arg";         # Insecure
53     system "/bin/echo", $arg;   # Secure (doesn't use sh)
54     system "echo $hid";         # Insecure
55     system "echo $data";        # Insecure until PATH set
56
57     $path = $ENV{'PATH'};       # $path now tainted
58
59     $ENV{'PATH'} = '/bin:/usr/bin'; 
60     $ENV{'IFS'} = '' if $ENV{'IFS'} ne '';
61
62     $path = $ENV{'PATH'};       # $path now NOT tainted
63     system "echo $data";        # Is secure now!
64
65     open(FOO, "< $arg");        # OK - read-only file
66     open(FOO, "> $arg");        # Not OK - trying to write
67
68     open(FOO,"echo $arg|");     # Not OK, but...
69     open(FOO,"-|")
70         or exec 'echo', $arg;   # OK
71
72     $shout = `echo $arg`;       # Insecure, $shout now tainted
73
74     unlink $data, $arg;         # Insecure
75     umask $arg;                 # Insecure
76
77     exec "echo $arg";           # Insecure
78     exec "echo", $arg;          # Secure (doesn't use the shell)
79     exec "sh", '-c', $arg;      # Considered secure, alas!
80
81 If you try to do something insecure, you will get a fatal error saying
82 something like "Insecure dependency" or "Insecure PATH".  Note that you
83 can still write an insecure B<system> or B<exec>, but only by explicitly
84 doing something like the last example above.  
85
86 =head2 Laundering and Detecting Tainted Data
87
88 To test whether a variable contains tainted data, and whose use would thus
89 trigger an "Insecure dependency" message, you can use the following
90 I<is_tainted()> function.
91
92     sub is_tainted {
93         return ! eval { 
94             join('',@_), kill 0; 
95             1;  
96         };
97     }
98
99 This function makes use of the fact that the presence of tainted data
100 anywhere within an expression renders the entire expression tainted.  It
101 would be inefficient for every operator to test every argument for
102 taintedness.  Instead, the slightly more efficient and conservative
103 approach is used that if any tainted value has been accessed within the
104 same expression, the whole expression is considered tainted.
105
106 But testing for taintedness gets you only so far.  Sometimes you have just
107 to clear your data's taintedness.  The only way to bypass the tainting
108 mechanism is by referencing sub-patterns from a regular expression match.
109 Perl presumes that if you reference a substring using $1, $2, etc., that
110 you knew what you were doing when you wrote the pattern.  That means using
111 a bit of thought--don't just blindly untaint anything, or you defeat the
112 entire mechanism.  It's better to verify that the variable has only good
113 characters (for certain values of "good") rather than checking whether it
114 has any bad characters.  That's because it's far too easy to miss bad
115 characters that you never thought of.
116
117 Here's a test to make sure that the data contains nothing but "word"
118 characters (alphabetics, numerics, and underscores), a hyphen, an at sign,
119 or a dot.
120
121     if ($data =~ /^([-\@\w.]+)$/) {     
122         $data = $1;                     # $data now untainted
123     } else {
124         die "Bad data in $data";        # log this somewhere
125     }
126
127 This is fairly secure because C</\w+/> doesn't normally match shell
128 metacharacters, nor are dot, dash, or at going to mean something special
129 to the shell.  Use of C</.+/> would have been insecure in theory because
130 it lets everything through, but Perl doesn't check for that.  The lesson
131 is that when untainting, you must be exceedingly careful with your patterns.
132 Laundering data using regular expression is the I<ONLY> mechanism for
133 untainting dirty data, unless you use the strategy detailed below to fork
134 a child of lesser privilege.
135
136 The example does not untaint $data if C<use locale> is in effect,
137 because the characters matched by C<\w> are determined by the locale.
138 Perl considers that locale definitions are untrustworthy because they
139 contain data from outside the program.  If you are writing a
140 locale-aware program, and want to launder data with a regular expression
141 containing C<\w>, put C<no locale> ahead of the expression in the same
142 block.  See L<perllocale/SECURITY> for further discussion and examples.
143
144 =head2 Switches On the "#!" Line
145
146 When you make a script executable, in order to make it usable as a
147 command, the system will pass switches to perl from the script's #!
148 line.  Perl checks that any command-line switches given to a setuid
149 (or setgid) script actually match the ones set on the #! line.  Some
150 UNIX and UNIX-like environments impose a one-switch limit on the #!
151 line, so you may need to use something like C<-wU> instead of C<-w -U>
152 under such systems.  (This issue should arise only in UNIX or
153 UNIX-like environments that support #! and setuid or setgid scripts.)
154
155 =head2 Cleaning Up Your Path
156
157 For "Insecure C<$ENV{PATH}>" messages, you need to set C<$ENV{'PATH'}> to a
158 known value.  You may be surprised to get this message even if the pathname
159 to your executable is fully qualified.  This is I<not> generated because you
160 didn't supply a full path to the program; instead, it's generated because
161 you never set your PATH environment variable.  Because Perl can't guarantee
162 that the executable in question isn't itself going to turn around and
163 execute some other program that is dependent on your PATH, it makes sure you
164 set the PATH.
165
166 It's also possible to get into trouble with other operations that don't
167 care whether they use tainted values.  Make judicious use of the file
168 tests in dealing with any user-supplied filenames.  When possible, do
169 opens and such after setting C<$E<gt> = $E<lt>>.  (Remember group IDs,
170 too!)  Perl doesn't prevent you from opening tainted filenames for reading,
171 so be careful what you print out.  The tainting mechanism is intended to
172 prevent stupid mistakes, not to remove the need for thought.
173
174 Perl does not call the shell to expand wild cards when you pass B<system>
175 and B<exec> explicit parameter lists instead of strings with possible shell
176 wildcards in them.  Unfortunately, the B<open>, B<glob>, and
177 back-tick functions provide no such alternate calling convention, so more
178 subterfuge will be required.  
179
180 Perl provides a reasonably safe way to open a file or pipe from a setuid
181 or setgid program: just create a child process with reduced privilege who
182 does the dirty work for you.  First, fork a child using the special
183 B<open> syntax that connects the parent and child by a pipe.  Now the
184 child resets its ID set and any other per-process attributes, like
185 environment variables, umasks, current working directories, back to the
186 originals or known safe values.  Then the child process, which no longer
187 has any special permissions, does the B<open> or other system call.
188 Finally, the child passes the data it managed to access back to the
189 parent.  Because the file or pipe was opened in the child while running
190 under less privilege than the parent, it's not apt to be tricked into
191 doing something it shouldn't.
192
193 Here's a way to do back-ticks reasonably safely.  Notice how the B<exec> is
194 not called with a string that the shell could expand.  This is by far the
195 best way to call something that might be subjected to shell escapes: just
196 never call the shell at all.  By the time we get to the B<exec>, tainting
197 is turned off, however, so be careful what you call and what you pass it.
198
199     use English;  
200     die unless defined $pid = open(KID, "-|");
201     if ($pid) {           # parent
202         while (<KID>) {
203             # do something
204         }
205         close KID;
206     } else {
207         $EUID = $UID;
208         $EGID = $GID;    # XXX: initgroups() not called
209         $ENV{PATH} = "/bin:/usr/bin";
210         exec 'myprog', 'arg1', 'arg2';
211         die "can't exec myprog: $!";
212     }
213
214 A similar strategy would work for wildcard expansion via C<glob>.
215
216 Taint checking is most useful when although you trust yourself not to have
217 written a program to give away the farm, you don't necessarily trust those
218 who end up using it not to try to trick it into doing something bad.  This
219 is the kind of security checking that's useful for setuid programs and
220 programs launched on someone else's behalf, like CGI programs.
221
222 This is quite different, however, from not even trusting the writer of the
223 code not to try to do something evil.  That's the kind of trust needed
224 when someone hands you a program you've never seen before and says, "Here,
225 run this."  For that kind of safety, check out the Safe module,
226 included standard in the Perl distribution.  This module allows the
227 programmer to set up special compartments in which all system operations
228 are trapped and namespace access is carefully controlled.
229
230 =head2 Security Bugs
231
232 Beyond the obvious problems that stem from giving special privileges to
233 systems as flexible as scripts, on many versions of Unix, setuid scripts
234 are inherently insecure right from the start.  The problem is a race
235 condition in the kernel.  Between the time the kernel opens the file to
236 see which interpreter to run and when the (now-setuid) interpreter turns
237 around and reopens the file to interpret it, the file in question may have
238 changed, especially if you have symbolic links on your system.
239
240 Fortunately, sometimes this kernel "feature" can be disabled.
241 Unfortunately, there are two ways to disable it.  The system can simply
242 outlaw scripts with the setuid bit set, which doesn't help much.
243 Alternately, it can simply ignore the setuid bit on scripts.  If the
244 latter is true, Perl can emulate the setuid and setgid mechanism when it
245 notices the otherwise useless setuid/gid bits on Perl scripts.  It does
246 this via a special executable called B<suidperl> that is automatically
247 invoked for you if it's needed.  
248
249 However, if the kernel setuid script feature isn't disabled, Perl will
250 complain loudly that your setuid script is insecure.  You'll need to
251 either disable the kernel setuid script feature, or put a C wrapper around
252 the script.  A C wrapper is just a compiled program that does nothing
253 except call your Perl program.   Compiled programs are not subject to the
254 kernel bug that plagues setuid scripts.  Here's a simple wrapper, written
255 in C:
256
257     #define REAL_PATH "/path/to/script"
258     main(ac, av) 
259         char **av;
260     {
261         execv(REAL_PATH, av);
262     } 
263
264 Compile this wrapper into a binary executable and then make I<it> rather 
265 than your script setuid or setgid.  
266
267 See the program B<wrapsuid> in the F<eg> directory of your Perl
268 distribution for a convenient way to do this automatically for all your
269 setuid Perl programs.  It moves setuid scripts into files with the same
270 name plus a leading dot, and then compiles a wrapper like the one above
271 for each of them.
272
273 In recent years, vendors have begun to supply systems free of this
274 inherent security bug.  On such systems, when the kernel passes the name
275 of the setuid script to open to the interpreter, rather than using a
276 pathname subject to meddling, it instead passes I</dev/fd/3>.  This is a
277 special file already opened on the script, so that there can be no race
278 condition for evil scripts to exploit.  On these systems, Perl should be
279 compiled with C<-DSETUID_SCRIPTS_ARE_SECURE_NOW>.  The B<Configure>
280 program that builds Perl tries to figure this out for itself, so you
281 should never have to specify this yourself.  Most modern releases of
282 SysVr4 and BSD 4.4 use this approach to avoid the kernel race condition.
283
284 Prior to release 5.003 of Perl, a bug in the code of B<suidperl> could
285 introduce a security hole in systems compiled with strict POSIX
286 compliance.