3 perlrebackslash - Perl Regular Expression Backslash Sequences and Escapes
7 The top level documentation about Perl regular expressions
10 This document describes all backslash and escape sequences. After
11 explaining the role of the backslash, it lists all the sequences that have
12 a special meaning in Perl regular expressions (in alphabetical order),
13 then describes each of them.
15 Most sequences are described in detail in different documents; the primary
16 purpose of this document is to have a quick reference guide describing all
17 backslash and escape sequences.
22 In a regular expression, the backslash can perform one of two tasks:
23 it either takes away the special meaning of the character following it
24 (for instance, C<\|> matches a vertical bar, it's not an alternation),
25 or it is the start of a backslash or escape sequence.
27 The rules determining what it is are quite simple: if the character
28 following the backslash is an ASCII punctuation (non-word) character (that is,
29 anything that is not a letter, digit or underscore), then the backslash just
30 takes away the special meaning (if any) of the character following it.
32 If the character following the backslash is an ASCII letter or an ASCII digit,
33 then the sequence may be special; if so, it's listed below. A few letters have
34 not been used yet, and escaping them with a backslash is safe for now, but a
35 future version of Perl may assign a special meaning to it. However, if you
36 have warnings turned on, Perl will issue a warning if you use such a sequence.
39 It is however guaranteed that backslash or escape sequences never have a
40 punctuation character following the backslash, not now, and not in a future
41 version of Perl 5. So it is safe to put a backslash in front of a non-word
44 Note that the backslash itself is special; if you want to match a backslash,
45 you have to escape the backslash with a backslash: C</\\/> matches a single
52 There is one exception. If you use an alphanumerical character as the
53 delimiter of your pattern (which you probably shouldn't do for readability
54 reasons), you will have to escape the delimiter if you want to match
55 it. Perl won't warn then. See also L<perlop/Gory details of parsing
61 =head2 All the sequences and escapes
63 Those not usable within a bracketed character class (like C<[\da-z]>) are marked
66 \000 Octal escape sequence.
67 \1 Absolute backreference. Not in [].
69 \A Beginning of string. Not in [].
70 \b Word/non-word boundary. (Backspace in []).
71 \B Not a word/non-word boundary. Not in [].
72 \cX Control-X (X can be any ASCII character).
73 \C Single octet, even under UTF-8. Not in [].
74 \d Character class for digits.
75 \D Character class for non-digits.
77 \E Turn off \Q, \L and \U processing. Not in [].
79 \g{}, \g1 Named, absolute or relative backreference. Not in [].
80 \G Pos assertion. Not in [].
81 \h Character class for horizontal white space.
82 \H Character class for non horizontal white space.
83 \k{}, \k<>, \k'' Named backreference. Not in [].
84 \K Keep the stuff left of \K. Not in [].
85 \l Lowercase next character. Not in [].
86 \L Lowercase till \E. Not in [].
87 \n (Logical) newline character.
88 \N Any character but newline. Not in [].
89 \N{} Named (Unicode) character.
90 \p{}, \pP Character with the given Unicode property.
91 \P{}, \PP Character without the given Unicode property.
92 \Q Quotemeta till \E. Not in [].
94 \R Generic new line. Not in [].
95 \s Character class for white space.
96 \S Character class for non white space.
98 \u Titlecase next character. Not in [].
99 \U Uppercase till \E. Not in [].
100 \v Character class for vertical white space.
101 \V Character class for non vertical white space.
102 \w Character class for word characters.
103 \W Character class for non-word characters.
104 \x{}, \x00 Hexadecimal escape sequence.
105 \X Unicode "extended grapheme cluster". Not in [].
106 \z End of string. Not in [].
107 \Z End of string. Not in [].
109 =head2 Character Escapes
111 =head3 Fixed characters
113 A handful of characters have a dedicated I<character escape>. The following
114 table shows them, along with their code points (in decimal and hex), their
115 ASCII name, the control escape (see below) and a short description.
117 Seq. Code Point ASCII Cntr Description.
119 \a 7 07 BEL \cG alarm or bell
120 \b 8 08 BS \cH backspace [1]
121 \e 27 1B ESC \c[ escape character
122 \f 12 0C FF \cL form feed
123 \n 10 0A LF \cJ line feed [2]
124 \r 13 0D CR \cM carriage return
131 C<\b> is only the backspace character inside a character class. Outside a
132 character class, C<\b> is a word/non-word boundary.
136 C<\n> matches a logical newline. Perl will convert between C<\n> and your
137 OSses native newline character when reading from or writing to text files.
143 $str =~ /\t/; # Matches if $str contains a (horizontal) tab.
145 =head3 Control characters
147 C<\c> is used to denote a control character; the character following C<\c>
148 is the name of the control character. For instance, C</\cM/> matches the
149 character I<control-M> (a carriage return, code point 13). The case of the
150 character following C<\c> doesn't matter: C<\cM> and C<\cm> match the same
153 Mnemonic: I<c>ontrol character.
157 $str =~ /\cK/; # Matches if $str contains a vertical tab (control-K).
159 =head3 Named characters
161 All Unicode characters have a Unicode name. It is even possible to give your
162 own names to characters, even to short sequences of characters. You can use a
163 character by name by using the C<\N{}> construct; the name of the character
164 goes between the curly braces. You do have to C<use charnames> to load the
165 Unicode names of the characters, otherwise Perl will complain. (If you instead
166 have your own names, a C<use> statement will be required for your translator.)
167 For more details, see L<charnames>.
169 Mnemonic: I<N>amed character.
171 Note that a character that is expressed as a named character is considered
172 as a character without special meaning by the regex engine, and will match
177 use charnames ':full'; # Loads the Unicode names.
178 $str =~ /\N{THAI CHARACTER SO SO}/; # Matches the Thai SO SO character
180 use charnames 'Cyrillic'; # Loads Cyrillic names.
181 $str =~ /\N{ZHE}\N{KA}/; # Match "ZHE" followed by "KA".
185 Octal escapes consist of a backslash followed by two or three octal digits
186 matching the code point of the character you want to use. This allows for
187 512 characters (C<\00> up to C<\777>) that can be expressed this way (but
188 anything above C<\377> is deprecated).
189 Enough in pre-Unicode days, but most Unicode characters cannot be escaped
192 Note that a character that is expressed as an octal escape is considered
193 as a character without special meaning by the regex engine, and will match
199 $str =~ /\120/; # Match, "\120" is "P".
200 $str =~ /\120+/; # Match, "\120" is "P", it is repeated at least once.
201 $str =~ /P\053/; # No match, "\053" is "+" and taken literally.
205 Octal escapes potentially clash with backreferences. They both consist
206 of a backslash followed by numbers. So Perl has to use heuristics to
207 determine whether it is a backreference or an octal escape. Perl uses
214 If the backslash is followed by a single digit, it's a backreference.
218 If the first digit following the backslash is a 0, it's an octal escape.
222 If the number following the backslash is N (decimal), and Perl already has
223 seen N capture groups, Perl will consider this to be a backreference.
224 Otherwise, it will consider it to be an octal escape. Note that if N > 999,
225 Perl only takes the first three digits for the octal escape; the rest is
231 /^($pat)\1000$/; # Matches 'aa'; there are 1000 capture groups.
232 /^$pat\1000$/; # Matches 'a@0'; there are 999 capture groups
233 # and \1000 is seen as \100 (a '@') and a '0'.
237 =head3 Hexadecimal escapes
239 Hexadecimal escapes start with C<\x> and are then either followed by
240 two digit hexadecimal number, or a hexadecimal number of arbitrary length
241 surrounded by curly braces. The hexadecimal number is the code point of
242 the character you want to express.
244 Note that a character that is expressed as a hexadecimal escape is considered
245 as a character without special meaning by the regex engine, and will match
248 Mnemonic: heI<x>adecimal.
253 $str =~ /\x50/; # Match, "\x50" is "P".
254 $str =~ /\x50+/; # Match, "\x50" is "P", it is repeated at least once.
255 $str =~ /P\x2B/; # No match, "\x2B" is "+" and taken literally.
257 /\x{2603}\x{2602}/ # Snowman with an umbrella.
258 # The Unicode character 2603 is a snowman,
259 # the Unicode character 2602 is an umbrella.
260 /\x{263B}/ # Black smiling face.
261 /\x{263b}/ # Same, the hex digits A - F are case insensitive.
265 A number of backslash sequences have to do with changing the character,
266 or characters following them. C<\l> will lowercase the character following
267 it, while C<\u> will uppercase (or, more accurately, titlecase) the
268 character following it. (They perform similar functionality as the
269 functions C<lcfirst> and C<ucfirst>).
271 To uppercase or lowercase several characters, one might want to use
272 C<\L> or C<\U>, which will lowercase/uppercase all characters following
273 them, until either the end of the pattern, or the next occurrence of
274 C<\E>, whatever comes first. They perform similar functionality as the
275 functions C<lc> and C<uc> do.
277 C<\Q> is used to escape all characters following, up to the next C<\E>
278 or the end of the pattern. C<\Q> adds a backslash to any character that
279 isn't a letter, digit or underscore. This will ensure that any character
280 between C<\Q> and C<\E> is matched literally, and will not be interpreted
281 by the regexp engine.
283 Mnemonic: I<L>owercase, I<U>ppercase, I<Q>uotemeta, I<E>nd.
289 $miranda = "(Miranda)";
290 $str =~ /\u$sid/; # Matches 'Sid'
291 $str =~ /\L$greg/; # Matches 'greg'
292 $str =~ /\Q$miranda\E/; # Matches '(Miranda)', as if the pattern
293 # had been written as /\(Miranda\)/
295 =head2 Character classes
297 Perl regular expressions have a large range of character classes. Some of
298 the character classes are written as a backslash sequence. We will briefly
299 discuss those here; full details of character classes can be found in
302 C<\w> is a character class that matches any I<word> character (letters,
303 digits, underscore). C<\d> is a character class that matches any digit,
304 while the character class C<\s> matches any white space character.
305 New in perl 5.10.0 are the classes C<\h> and C<\v> which match horizontal
306 and vertical white space characters.
308 The uppercase variants (C<\W>, C<\D>, C<\S>, C<\H>, and C<\V>) are
309 character classes that match any character that isn't a word character,
310 digit, white space, horizontal white space or vertical white space.
312 Mnemonics: I<w>ord, I<d>igit, I<s>pace, I<h>orizontal, I<v>ertical.
314 =head3 Unicode classes
316 C<\pP> (where C<P> is a single letter) and C<\p{Property}> are used to
317 match a character that matches the given Unicode property; properties
318 include things like "letter", or "thai character". Capitalizing the
319 sequence to C<\PP> and C<\P{Property}> make the sequence match a character
320 that doesn't match the given Unicode property. For more details, see
321 L<perlrecharclass/Backslashed sequences> and
322 L<perlunicode/Unicode Character Properties>.
324 Mnemonic: I<p>roperty.
329 If capturing parenthesis are used in a regular expression, we can refer
330 to the part of the source string that was matched, and match exactly the
331 same thing. There are three ways of referring to such I<backreference>:
332 absolutely, relatively, and by name.
334 =for later add link to perlrecapture
336 =head3 Absolute referencing
338 A backslash sequence that starts with a backslash and is followed by a
339 number is an absolute reference (but be aware of the caveat mentioned above).
340 If the number is I<N>, it refers to the Nth set of parentheses - whatever
341 has been matched by that set of parenthesis has to be matched by the C<\N>
346 /(\w+) \1/; # Finds a duplicated word, (e.g. "cat cat").
347 /(.)(.)\2\1/; # Match a four letter palindrome (e.g. "ABBA").
350 =head3 Relative referencing
352 New in perl 5.10.0 is a different way of referring to capture buffers: C<\g>.
353 C<\g> takes a number as argument, with the number in curly braces (the
354 braces are optional). If the number (N) does not have a sign, it's a reference
355 to the Nth capture group (so C<\g{2}> is equivalent to C<\2> - except that
356 C<\g> always refers to a capture group and will never be seen as an octal
357 escape). If the number is negative, the reference is relative, referring to
358 the Nth group before the C<\g{-N}>.
360 The big advantage of C<\g{-N}> is that it makes it much easier to write
361 patterns with references that can be interpolated in larger patterns,
362 even if the larger pattern also contains capture groups.
371 \g{-1} # Refers to buffer 3 (B)
372 \g{-3} # Refers to buffer 1 (A)
374 /x; # Matches "ABBA".
376 my $qr = qr /(.)(.)\g{-2}\g{-1}/; # Matches 'abab', 'cdcd', etc.
377 /$qr$qr/ # Matches 'ababcdcd'.
379 =head3 Named referencing
381 Also new in perl 5.10.0 is the use of named capture buffers, which can be
382 referred to by name. This is done with C<\g{name}>, which is a
383 backreference to the capture buffer with the name I<name>.
385 To be compatible with .Net regular expressions, C<\g{name}> may also be
386 written as C<\k{name}>, C<< \k<name> >> or C<\k'name'>.
388 Note that C<\g{}> has the potential to be ambiguous, as it could be a named
389 reference, or an absolute or relative reference (if its argument is numeric).
390 However, names are not allowed to start with digits, nor are they allowed to
391 contain a hyphen, so there is no ambiguity.
395 /(?<word>\w+) \g{word}/ # Finds duplicated word, (e.g. "cat cat")
396 /(?<word>\w+) \k{word}/ # Same.
397 /(?<word>\w+) \k<word>/ # Same.
398 /(?<letter1>.)(?<letter2>.)\g{letter2}\g{letter1}/
399 # Match a four letter palindrome (e.g. "ABBA")
403 Assertions are conditions that have to be true; they don't actually
404 match parts of the substring. There are six assertions that are written as
411 C<\A> only matches at the beginning of the string. If the C</m> modifier
412 isn't used, then C</\A/> is equivalent with C</^/>. However, if the C</m>
413 modifier is used, then C</^/> matches internal newlines, but the meaning
414 of C</\A/> isn't changed by the C</m> modifier. C<\A> matches at the beginning
415 of the string regardless whether the C</m> modifier is used.
419 C<\z> and C<\Z> match at the end of the string. If the C</m> modifier isn't
420 used, then C</\Z/> is equivalent with C</$/>, that is, it matches at the
421 end of the string, or before the newline at the end of the string. If the
422 C</m> modifier is used, then C</$/> matches at internal newlines, but the
423 meaning of C</\Z/> isn't changed by the C</m> modifier. C<\Z> matches at
424 the end of the string (or just before a trailing newline) regardless whether
425 the C</m> modifier is used.
427 C<\z> is just like C<\Z>, except that it will not match before a trailing
428 newline. C<\z> will only match at the end of the string - regardless of the
429 modifiers used, and not before a newline.
433 C<\G> is usually only used in combination with the C</g> modifier. If the
434 C</g> modifier is used (and the match is done in scalar context), Perl will
435 remember where in the source string the last match ended, and the next time,
436 it will start the match from where it ended the previous time.
438 C<\G> matches the point where the previous match ended, or the beginning
439 of the string if there was no previous match.
441 =for later add link to perlremodifiers
447 C<\b> matches at any place between a word and a non-word character; C<\B>
448 matches at any place between characters where C<\b> doesn't match. C<\b>
449 and C<\B> assume there's a non-word character before the beginning and after
450 the end of the source string; so C<\b> will match at the beginning (or end)
451 of the source string if the source string begins (or ends) with a word
452 character. Otherwise, C<\B> will match.
454 Mnemonic: I<b>oundary.
460 "cat" =~ /\Acat/; # Match.
461 "cat" =~ /cat\Z/; # Match.
462 "cat\n" =~ /cat\Z/; # Match.
463 "cat\n" =~ /cat\z/; # No match.
465 "cat" =~ /\bcat\b/; # Matches.
466 "cats" =~ /\bcat\b/; # No match.
467 "cat" =~ /\bcat\B/; # No match.
468 "cats" =~ /\bcat\B/; # Match.
470 while ("cat dog" =~ /(\w+)/g) {
471 print $1; # Prints 'catdog'
473 while ("cat dog" =~ /\G(\w+)/g) {
474 print $1; # Prints 'cat'
479 Here we document the backslash sequences that don't fall in one of the
480 categories above. They are:
486 C<\C> always matches a single octet, even if the source string is encoded
487 in UTF-8 format, and the character to be matched is a multi-octet character.
488 C<\C> was introduced in perl 5.6.
494 This is new in perl 5.10.0. Anything that is matched left of C<\K> is
495 not included in C<$&> - and will not be replaced if the pattern is
496 used in a substitution. This will allow you to write C<s/PAT1 \K PAT2/REPL/x>
497 instead of C<s/(PAT1) PAT2/${1}REPL/x> or C<s/(?<=PAT1) PAT2/REPL/x>.
503 This is new in perl 5.12.0. It matches any character that is not a newline.
504 It is a short-hand for writing C<[^\n]>, and is identical to the C<.>
505 metasymbol, except under the C</s> flag, which changes the meaning of C<.>, but
508 Note that C<\N{...}> can mean a L<named character|/Named characters>.
510 Mnemonic: Complement of I<\n>.
514 C<\R> matches a I<generic newline>, that is, anything that is considered
515 a newline by Unicode. This includes all characters matched by C<\v>
516 (vertical white space), and the multi character sequence C<"\x0D\x0A">
517 (carriage return followed by a line feed, aka the network newline, or
518 the newline used in Windows text files). C<\R> is equivalent with
519 C<< (?>\x0D\x0A)|\v) >>. Since C<\R> can match a more than one character,
520 it cannot be put inside a bracketed character class; C</[\R]/> is an error.
521 C<\R> was introduced in perl 5.10.0.
523 Mnemonic: none really. C<\R> was picked because PCRE already uses C<\R>,
524 and more importantly because Unicode recommends such a regular expression
525 metacharacter, and suggests C<\R> as the notation.
529 This matches a Unicode I<extended grapheme cluster>.
531 C<\X> matches quite well what normal (non-Unicode-programmer) usage
532 would consider a single character. As an example, consider a G with some sort
533 of diacritic mark, such as an arrow. There is no such single character in
534 Unicode, but one can be composed by using a G followed by a Unicode "COMBINING
535 UPWARDS ARROW BELOW", and would be displayed by Unicode-aware software as if it
536 were a single character.
538 Mnemonic: eI<X>tended Unicode character.
544 "\x{256}" =~ /^\C\C$/; # Match as chr (256) takes 2 octets in UTF-8.
546 $str =~ s/foo\Kbar/baz/g; # Change any 'bar' following a 'foo' to 'baz'.
547 $str =~ s/(.)\K\1//g; # Delete duplicated characters.
549 "\n" =~ /^\R$/; # Match, \n is a generic newline.
550 "\r" =~ /^\R$/; # Match, \r is a generic newline.
551 "\r\n" =~ /^\R$/; # Match, \r\n is a generic newline.
553 "P\x{0307}" =~ /^\X$/ # \X matches a P with a dot above.