pod/perlrebackslash.pod

   1 =head1 NAME
   2
   3 perlrebackslash - Perl Regular Expression Backslash Sequences and Escapes
   4
   5 =head1 DESCRIPTION
   6
   7 The top level documentation about Perl regular expressions
   8 is found in L<perlre>.
   9
  10 This document describes all backslash and escape sequences. After
  11 explaining the role of the backslash, it lists all the sequences that have
  12 a special meaning in Perl regular expressions (in alphabetical order),
  13 then describes each of them.
  14
  15 Most sequences are described in detail in different documents; the primary
  16 purpose of this document is to have a quick reference guide describing all
  17 backslash and escape sequences.
  18
  19
  20 =head2 The backslash
  21
  22 In a regular expression, the backslash can perform one of two tasks:
  23 it either takes away the special meaning of the character following it
  24 (for instance, C<\|> matches a vertical bar, it's not an alternation),
  25 or it is the start of a backslash or escape sequence.
  26
  27 The rules determining what it is are quite simple: if the character
  28 following the backslash is a punctuation (non-word) character (that is,
  29 anything that is not a letter, digit or underscore), then the backslash
  30 just takes away the special meaning (if any) of the character following
  31 it.
  32
  33 If the character following the backslash is a letter or a digit, then the
  34 sequence may be special; if so, it's listed below. A few letters have not
  35 been used yet, and escaping them with a backslash is safe for now, but a
  36 future version of Perl may assign a special meaning to it. However, if you
  37 have warnings turned on, Perl will issue a warning if you use such a sequence.
  38 [1].
  39
  40 It is however garanteed that backslash or escape sequences never have a
  41 punctuation character following the backslash, not now, and not in a future
  42 version of Perl 5. So it is safe to put a backslash in front of a non-word
  43 character.
  44
  45 Note that the backslash itself is special; if you want to match a backslash,
  46 you have to escape the backslash with a backslash: C</\\/> matches a single
  47 backslash.
  48
  49 =over 4
  50
  51 =item [1]
  52
  53 There is one exception. If you use an alphanumerical character as the
  54 delimiter of your pattern (which you probably shouldn't do for readability
  55 reasons), you will have to escape the delimiter if you want to match
  56 it. Perl won't warn then. See also L<perlop/Gory details of parsing
  57 quoted constructs>.
  58
  59 =back
  60
  61
  62 =head2 All the sequences and escapes
  63
  64  \000              Octal escape sequence.
  65  \1                Absolute backreference.
  66  \a                Alarm or bell.
  67  \A                Beginning of string.
  68  \b                Word/non-word boundary. (Backspace in a char class).
  69  \B                Not a word/non-word boundary.
  70  \cX               Control-X (X can be any ASCII character).
  71  \C                Single octet, even under UTF-8.
  72  \d                Character class for digits.
  73  \D                Character class for non-digits.
  74  \e                Escape character.
  75  \E                Turn off \Q, \L and \U processing.
  76  \f                Form feed.
  77  \g{}, \g1         Named, absolute or relative backreference.
  78  \G                Pos assertion.
  79  \h                Character class for horizontal white space.
  80  \H                Character class for non horizontal white space.
  81  \k{}, \k<>, \k''  Named backreference.
  82  \K                Keep the stuff left of \K.
  83  \l                Lowercase next character.
  84  \L                Lowercase till \E.
  85  \n                (Logical) newline character.
  86  \N{}              Named (Unicode) character.
  87  \p{}, \pP         Character with a Unicode property.
  88  \P{}, \PP         Character without a Unicode property.
  89  \Q                Quotemeta till \E.
  90  \r                Return character.
  91  \R                Generic new line.
  92  \s                Character class for white space.
  93  \S                Character class for non white space.
  94  \t                Tab character.
  95  \u                Uppercase next character.
  96  \U                Uppercase till \E.
  97  \v                Character class for vertical white space.
  98  \V                Character class for non vertical white space.
  99  \w                Character class for word characters.
 100  \W                Character class for non-word characters.
 101  \x{}, \x00        Hexadecimal escape sequence.
 102  \X                Extended Unicode "combining character sequence".
 103  \z                End of string.
 104  \Z                End of string.
 105
 106 =head2 Character Escapes
 107
 108 =head3  Fixed characters
 109
 110 A handful of characters have a dedidated I<character escape>. The following
 111 table shows them, along with their code points (in decimal and hex), their
 112 ASCII name, the control escape (see below) and a short description.
 113
 114  Seq.  Code Point  ASCII   Cntr    Description.
 115        Dec    Hex
 116   \a     7     07    BEL    \cG    alarm or bell
 117   \b     8     08     BS    \cH    backspace [1]
 118   \e    27     1B    ESC    \c[    escape character
 119   \f    12     0C     FF    \cL    form feed
 120   \n    10     0A     LF    \cJ    line feed [2]
 121   \r    13     0D     CR    \cM    carriage return
 122   \t     9     09    TAB    \cI    tab
 123
 124 =over 4
 125
 126 =item [1]
 127
 128 C<\b> is only the backspace character inside a character class. Outside a
 129 character class, C<\b> is a word/non-word boundary.
 130
 131 =item [2]
 132
 133 C<\n> matches a logical newline. Perl will convert between C<\n> and your
 134 OSses native newline character when reading from or writing to text files.
 135
 136 =back
 137
 138 =head4 Example
 139
 140  $str =~ /\t/;   # Matches if $str contains a (horizontal) tab.
 141
 142 =head3 Control characters
 143
 144 C<\c> is used to denote a control character; the character following C<\c>
 145 is the name of the control character. For instance, C</\cM/> matches the
 146 character I<control-M> (a carriage return, code point 13). The case of the
 147 character following C<\c> doesn't matter: C<\cM> and C<\cm> match the same
 148 character.
 149
 150 Mnemonic: I<c>ontrol character.
 151
 152 =head4 Example
 153
 154  $str =~ /\cK/;  # Matches if $str contains a vertical tab (control-K).
 155
 156 =head3 Named characters
 157
 158 All Unicode characters have a Unicode name, and characters in various scripts
 159 have names as well. It is even possible to give your own names to characters.
 160 You can use a character by name by using the C<\N{}> construct; the name of
 161 the character goes between the curly braces. You do have to C<use charnames>
 162 to load the names of the characters, otherwise Perl will complain you use
 163 a name it doesn't know about. For more details, see L<charnames>.
 164
 165 Mnemonic: I<N>amed character.
 166
 167 =head4 Example
 168
 169  use charnames ':full';               # Loads the Unicode names.
 170  $str =~ /\N{THAI CHARACTER SO SO}/;  # Matches the Thai SO SO character
 171
 172  use charnames 'Cyrillic';            # Loads Cyrillic names.
 173  $str =~ /\N{ZHE}\N{KA}/;             # Match "ZHE" followed by "KA".
 174
 175 =head3 Octal escapes
 176
 177 Octal escapes consist of a backslash followed by two or three octal digits
 178 matching the code point of the character you want to use. This allows for
 179 522 characters (C<\00> up to C<\777>) that can be expressed this way.
 180 Enough in pre-Unicode days, but most Unicode characters cannot be escaped
 181 this way.
 182
 183 Note that a character that is expressed as an octal escape is considered
 184 as a character without special meaning by the regex engine, and will match
 185 "as is".
 186
 187 =head4 Examples
 188
 189  $str = "Perl";
 190  $str =~ /\120/;    # Match, "\120" is "P".
 191  $str =~ /\120+/;   # Match, "\120" is "P", it is repeated at least once.
 192  $str =~ /P\053/;   # No match, "\053" is "+" and taken literally.
 193
 194 =head4 Caveat
 195
 196 Octal escapes potentially clash with backreferences. They both consist
 197 of a backslash followed by numbers. So Perl has to use heuristics to
 198 determine whether it is a backreference or an octal escape. Perl uses
 199 the following rules:
 200
 201 =over 4
 202
 203 =item 1
 204
 205 If the backslash is followed by a single digit, it's a backrefence.
 206
 207 =item 2
 208
 209 If the first digit following the backslash is a 0, it's an octal escape.
 210
 211 =item 3
 212
 213 If the number following the backslash is N (decimal), and Perl already has
 214 seen N capture groups, Perl will consider this to be a backreference.
 215 Otherwise, it will consider it to be an octal escape. Note that if N > 999,
 216 Perl only takes the first three digits for the octal escape; the rest is
 217 matched as is.
 218
 219  my $pat  = "(" x 999;
 220     $pat .= "a";
 221     $pat .= ")" x 999;
 222  /^($pat)\1000$/;   #  Matches 'aa'; there are 1000 capture groups.
 223  /^$pat\1000$/;     #  Matches 'a@0'; there are 999 capture groups
 224                     #    and \1000 is seen as \100 (a '@') and a '0'.
 225
 226 =back
 227
 228 =head3 Hexadecimal escapes
 229
 230 Hexadecimal escapes start with C<\x> and are then either followed by
 231 two digit hexadecimal number, or a hexadecimal number of arbitrary length
 232 surrounded by curly braces. The hexadecimal number is the code point of
 233 the character you want to express.
 234
 235 Note that a character that is expressed as a hexadecimal escape is considered
 236 as a character without special meaning by the regex engine, and will match
 237 "as is".
 238
 239 Mnemonic: heI<x>adecimal.
 240
 241 =head4 Examples
 242
 243  $str = "Perl";
 244  $str =~ /\x50/;    # Match, "\x50" is "P".
 245  $str =~ /\x50+/;   # Match, "\x50" is "P", it is repeated at least once.
 246  $str =~ /P\x2B/;   # No match, "\x2B" is "+" and taken literally.
 247
 248  /\x{2603}\x{2602}/ # Snowman with an umbrella.
 249                     # The Unicode character 2603 is a snowman,
 250                     # the Unicode character 2602 is an umbrella.
 251  /\x{263B}/         # Black smiling face.
 252  /\x{263b}/         # Same, the hex digits A - F are case insensitive.
 253
 254 =head2 Modifiers
 255
 256 A number of backslash sequences have to do with changing the character,
 257 or characters following them. C<\l> will lowercase the character following
 258 it, while C<\u> will uppercase the character following it. (They perform
 259 similar functionality as the functions C<lcfirst> and C<ucfirst>).
 260
 261 To uppercase or lowercase several characters, one might want to use
 262 C<\L> or C<\U>, which will lowercase/uppercase all characters following
 263 them, until either the end of the pattern, or the next occurance of
 264 C<\E>, whatever comes first. They perform similar functionality as the
 265 functions C<lc> and C<uc> do.
 266
 267 C<\Q> is used to escape all characters following, up to the next C<\E>
 268 or the end of the pattern. C<\Q> adds a backslash to any character that
 269 isn't a letter, digit or underscore. This will ensure that any character
 270 between C<\Q> and C<\E> is matched literally, and will not be interpreted
 271 by the regexp engine.
 272
 273 Mnemonic: I<L>owercase, I<U>ppercase, I<Q>uotemeta, I<E>nd.
 274
 275 =head4 Examples
 276
 277  $sid     = "sid";
 278  $greg    = "GrEg";
 279  $miranda = "(Miranda)";
 280  $str     =~ /\u$sid/;        # Matches 'Sid'
 281  $str     =~ /\L$greg/;       # Matches 'greg'
 282  $str     =~ /\Q$miranda\E/;  # Matches '(Miranda)', as if the pattern
 283                               #   had been written as /\(Miranda\)/
 284
 285 =head2 Character classes
 286
 287 Perl regular expressions have a large range of character classes. Some of
 288 the character classes are written as a backslash sequence. We will briefly
 289 discuss those here; full details of character classes can be found in
 290 L<perlrecharclass>.
 291
 292 C<\w> is a character class that matches any I<word> character (letters,
 293 digits, underscore). C<\d> is a character class that matches any digit,
 294 while the character class C<\s> matches any white space character.
 295 New in perl 5.10 are the classes C<\h> and C<\v> which match horizontal
 296 and vertical white space characters.
 297
 298 The uppercase variants (C<\W>, C<\D>, C<\S>, C<\H>, and C<\V>) are
 299 character classes that match any character that isn't a word character,
 300 digit, white space, horizontal white space or vertical white space.
 301
 302 Mnemonics: I<w>ord, I<d>igit, I<s>pace, I<h>orizontal, I<v>ertical.
 303
 304 =head3 Unicode classes
 305
 306 C<\pP> (where C<P> is a single letter) and C<\p{Property}> are used to
 307 match a character that matches the given Unicode property; properties
 308 include things like "letter", or "thai character". Capitalizing the
 309 sequence to C<\PP> and C<\P{Property}> make the sequence match a character
 310 that doesn't match the given Unicode property. For more details, see
 311 L<perlrecharclass/Backslashed sequences> and
 312 L<perlunicode/Unicode Character Properties>.
 313
 314 Mnemonic: I<p>roperty.
 315
 316
 317 =head2 Referencing
 318
 319 If capturing parenthesis are used in a regular expression, we can refer
 320 to the part of the source string that was matched, and match exactly the
 321 same thing. (Full details are discussed in L<perlrecapture>). There are
 322 three ways of refering to such I<backreference>: absolutely, relatively,
 323 and by name.
 324
 325 =head3 Absolute referencing
 326
 327 A backslash sequence that starts with a backslash and is followed by a
 328 number is an absolute reference (but be aware of the caveat mentioned above).
 329 If the number is I<N>, it refers to the Nth set of parenthesis - whatever
 330 has been matched by that set of parenthesis has to be matched by the C<\N>
 331 as well.
 332
 333 =head4 Examples
 334
 335  /(\w+) \1/;    # Finds a duplicated word, (e.g. "cat cat").
 336  /(.)(.)\2\1/;  # Match a four letter palindrome (e.g. "ABBA").
 337
 338
 339 =head3 Relative referencing
 340
 341 New in perl 5.10 is different way of refering to capture buffers: C<\g>.
 342 C<\g> takes a number as argument, with the number in curly braces (the
 343 braces are optional). If the number (N) does not have a sign, it's a reference
 344 to the Nth capture group (so C<\g{2}> is equivalent to C<\2> - except that
 345 C<\g> always refers to a capture group and will never be seen as an octal
 346 escape). If the number is negative, the reference is relative, refering to
 347 the Nth group before the C<\g{-N}>.
 348
 349 The big advantage of C<\g{-N}> is that it makes it much easier to write
 350 patterns with references that can be interpolated in larger patterns,
 351 even if the larger pattern also contains capture groups.
 352
 353 Mnemonic: I<g>roup.
 354
 355 =head4 Examples
 356
 357  /(A)        # Buffer 1
 358   (          # Buffer 2
 359     (B)      # Buffer 3
 360     \g{-1}   # Refers to buffer 3 (B)
 361     \g{-3}   # Refers to buffer 1 (A)
 362   )
 363  /x;         # Matches "ABBA".
 364
 365  my $qr = qr /(.)(.)\g{-2}\g{-1}/;  # Matches 'abab', 'cdcd', etc.
 366  /$qr$qr/                           # Matches 'ababcdcd'.
 367
 368 =head3 Named referencing
 369
 370 Also new in perl 5.10 is the use of named capture buffers, which can be
 371 referred to by name. This is done with C<\g{name}>, which is a
 372 backreference to the capture buffer with the name I<name>.
 373
 374 To be compatible with .Net regular expressions, C<\g{name}> may also be
 375 written as C<\k{name}>, C<< \k<name> >> or C<\k'name'>.
 376
 377 Note that C<\g{}> has the potential to be ambiguous, as it could be a named
 378 reference, or an absolute or relative reference (if its argument is numeric).
 379 However, names are not allowed to start with digits, nor are allowed to
 380 contain a hyphen, so there is no ambiguity.
 381
 382 =head4 Examples
 383
 384  /(?<word>\w+) \g{word}/ # Finds duplicated word, (e.g. "cat cat")
 385  /(?<word>\w+) \k{word}/ # Same.
 386  /(?<word>\w+) \k<word>/ # Same.
 387  /(?<letter1>.)(?<letter2>.)\g{letter2}\g{letter1}/
 388                          # Match a four letter palindrome (e.g. "ABBA")
 389
 390 =head2 Assertions
 391
 392 Assertions are conditions that have to be true -- they don't actually
 393 match parts of the substring. There are six assertions that are written as
 394 backslash sequences.
 395
 396 =over 4
 397
 398 =item \A
 399
 400 C<\A> only matches at the beginning of the string. If the C</m> modifier
 401 isn't used, then C</\A/> is equivalent with C</^/>. However, if the C</m>
 402 modifier is used, then C</^/> matches internal newlines, but the meaning
 403 of C</\A/> isn't changed by the C</m> modifier. C<\A> matches at the beginning
 404 of the string regardless whether the C</m> modifier is used.
 405
 406 =item \z, \Z
 407
 408 C<\z> and C<\Z> match at the end of the string. If the C</m> modifier isn't
 409 used, then C</\Z/> is equivalent with C</$/>, that is, it matches at the
 410 end of the string, or before the newline at the end of the string. If the
 411 C</m> modifier is used, then C</$/> matches at internal newlines, but the
 412 meaning of C</\Z/> isn't changed by the C</m> modifier. C<\Z> matches at
 413 the end of the string (or just before a trailing newline) regardless whether
 414 the C</m> modifier is used.
 415
 416 C<\z> is just like C<\Z>, except that it will not match before a trailing
 417 newline. C<\z> will only match at the end of the string - regardless of the
 418 modifiers used, and not before a newline.
 419
 420 =item \G
 421
 422 C<\G> is usually only used in combination with the C</g> modifier. If the
 423 C</g> modifier is used (and the match is done in scalar context), Perl will
 424 remember where in the source string the last match ended, and the next time,
 425 it will start the match from where it ended the previous time.
 426
 427 C<\G> matches the point where the previous match ended, or the beginning
 428 of the string if there was no previous match. See also L<perlremodifiers>.
 429
 430 Mnemonic: I<G>lobal.
 431
 432 =item \b, \B
 433
 434 C<\b> matches at any place between a word and a non-word character; C<\B>
 435 matches at any place between characters where C<\b> doesn't match. C<\b>
 436 and C<\B> assume there's a non-word character before the beginning and after
 437 the end of the source string; so C<\b> will match at the beginning (or end)
 438 of the source string if the source string begins (or ends) with a word
 439 character. Otherwise, C<\B> will match.
 440
 441 Mnemonic: I<b>oundary.
 442
 443 =back
 444
 445 =head4 Examples
 446
 447   "cat"   =~ /\Acat/;     # Match.
 448   "cat"   =~ /cat\Z/;     # Match.
 449   "cat\n" =~ /cat\Z/;     # Match.
 450   "cat\n" =~ /cat\z/;     # No match.
 451
 452   "cat"   =~ /\bcat\b/;   # Matches.
 453   "cats"  =~ /\bcat\b/;   # No match.
 454   "cat"   =~ /\bcat\B/;   # No match.
 455   "cats"  =~ /\bcat\B/;   # Match.
 456
 457   while ("cat dog" =~ /(\w+)/g) {
 458       print $1;           # Prints 'catdog'
 459   }
 460   while ("cat dog" =~ /\G(\w+)/g) {
 461       print $1;           # Prints 'cat'
 462   }
 463
 464 =head2 Misc
 465
 466 Here we document the backslash sequences that don't fall in one of the
 467 categories above. They are:
 468
 469 =over 4
 470
 471 =item \C
 472
 473 C<\C> always matches a single octet, even if the source string is encoded
 474 in UTF-8 format, and the character to be matched is a multi-octet character.
 475 C<\C> was introduced in perl 5.6.
 476
 477 Mnemonic: oI<C>tet.
 478
 479 =item \K
 480
 481 This is new in perl 5.10. Anything that is matched left of C<\K> is
 482 not included in C<$&> - and will not be replaced if the pattern is
 483 used in a substitution. This will allow you to write C<s/PAT1 \K PAT2/REPL/x>
 484 instead of C<s/(PAT1) PAT2/${1}REPL/x> or C<s/(?<=PAT1) PAT2/REPL/x>.
 485
 486 Mnemonic: I<K>eep.
 487
 488 =item \R
 489
 490 C<\R> matches a I<generic newline>, that is, anything that is considered
 491 a newline by Unicode. This includes all characters matched by C<\v>
 492 (vertical white space), and the multi character sequence C<"\x0D\x0A">
 493 (carriage return followed by a line feed, aka the network newline, or
 494 the newline used in Windows text files). C<\R> is equivalent with
 495 C<(?>\x0D\x0A)|\v)>. Since C<\R> can match a more than one character,
 496 it cannot be put inside a bracketed character class; C</[\R]/> is an error.
 497 C<\R> is introduced in perl 5.10.
 498
 499 Mnemonic: none really. C<\R> was picked because PCRE already uses C<\R>.
 500
 501 =item \X
 502
 503 This matches an extended Unicode I<combining character sequence>, and
 504 is equivalent to C<< (?>\PM\pM*) >>. C<\PM> matches any character that is
 505 not considered a Unicode mark character, while C<\pM> matches any character
 506 that is considered a Unicode mark character; so C<\X> matches any non
 507 mark character followed by zero or more mark characters. Mark characters
 508 include (but are not restricted to) I<combining characters> and
 509 I<vowel signs>.
 510
 511 Mnemonic: eI<X>tended Unicode character.
 512
 513 =back
 514
 515 =head4 Examples
 516
 517  "\x{256}" =~ /^\C\C$/;    # Match as chr (256) takes 2 octets in UTF-8.
 518
 519  $str =~ s/foo\Kbar/baz/g; # Change any 'bar' following a 'foo' to 'baz'.
 520  $str =~ s/(.)\K\1//g;     # Delete duplicated characters.
 521
 522  "\n"   =~ /^\R$/;         # Match, \n   is a generic newline.
 523  "\r"   =~ /^\R$/;         # Match, \r   is a generic newline.
 524  "\r\n" =~ /^\R$/;         # Match, \r\n is a generic newline.
 525
 526  "P\x{0307}" =~ /^\X$/     # \X matches a P with a dot above.
 527
 528 =cut