3 perlre - Perl regular expressions
7 This page describes the syntax of regular expressions in Perl.
9 If you haven't used regular expressions before, a quick-start
10 introduction is available in L<perlrequick>, and a longer tutorial
11 introduction is available in L<perlretut>.
13 For reference on how regular expressions are used in matching
14 operations, plus various examples of the same, see discussions of
15 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
18 Matching operations can have various modifiers. Modifiers
19 that relate to the interpretation of the regular expression inside
20 are listed below. Modifiers that alter the way a regular expression
21 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
22 L<perlop/"Gory details of parsing quoted constructs">.
28 Do case-insensitive pattern matching.
30 If C<use locale> is in effect, the case map is taken from the current
31 locale. See L<perllocale>.
35 Treat string as multiple lines. That is, change "^" and "$" from matching
36 the start or end of the string to matching the start or end of any
37 line anywhere within the string.
41 Treat string as single line. That is, change "." to match any character
42 whatsoever, even a newline, which normally it would not match.
44 Used together, as /ms, they let the "." match any character whatsoever,
45 while still allowing "^" and "$" to match, respectively, just after
46 and just before newlines within the string.
50 Extend your pattern's legibility by permitting whitespace and comments.
54 These are usually written as "the C</x> modifier", even though the delimiter
55 in question might not really be a slash. Any of these
56 modifiers may also be embedded within the regular expression itself using
57 the C<(?...)> construct. See below.
59 The C</x> modifier itself needs a little more explanation. It tells
60 the regular expression parser to ignore whitespace that is neither
61 backslashed nor within a character class. You can use this to break up
62 your regular expression into (slightly) more readable parts. The C<#>
63 character is also treated as a metacharacter introducing a comment,
64 just as in ordinary Perl code. This also means that if you want real
65 whitespace or C<#> characters in the pattern (outside a character
66 class, where they are unaffected by C</x>), that you'll either have to
67 escape them or encode them using octal or hex escapes. Taken together,
68 these features go a long way towards making Perl's regular expressions
69 more readable. Note that you have to be careful not to include the
70 pattern delimiter in the comment--perl has no way of knowing you did
71 not intend to close the pattern early. See the C-comment deletion code
74 =head2 Regular Expressions
76 The patterns used in Perl pattern matching derive from supplied in
77 the Version 8 regex routines. (The routines are derived
78 (distantly) from Henry Spencer's freely redistributable reimplementation
79 of the V8 routines.) See L<Version 8 Regular Expressions> for
82 In particular the following metacharacters have their standard I<egrep>-ish
85 \ Quote the next metacharacter
86 ^ Match the beginning of the line
87 . Match any character (except newline)
88 $ Match the end of the line (or before newline at the end)
93 By default, the "^" character is guaranteed to match only the
94 beginning of the string, the "$" character only the end (or before the
95 newline at the end), and Perl does certain optimizations with the
96 assumption that the string contains only one line. Embedded newlines
97 will not be matched by "^" or "$". You may, however, wish to treat a
98 string as a multi-line buffer, such that the "^" will match after any
99 newline within the string, and "$" will match before any newline. At the
100 cost of a little more overhead, you can do this by using the /m modifier
101 on the pattern match operator. (Older programs did this by setting C<$*>,
102 but this practice has been removed in perl 5.9.)
104 To simplify multi-line substitutions, the "." character never matches a
105 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
106 the string is a single line--even if it isn't.
108 The following standard quantifiers are recognized:
110 * Match 0 or more times
111 + Match 1 or more times
113 {n} Match exactly n times
114 {n,} Match at least n times
115 {n,m} Match at least n but not more than m times
117 (If a curly bracket occurs in any other context, it is treated
118 as a regular character. In particular, the lower bound
119 is not optional.) The "*" modifier is equivalent to C<{0,}>, the "+"
120 modifier to C<{1,}>, and the "?" modifier to C<{0,1}>. n and m are limited
121 to integral values less than a preset limit defined when perl is built.
122 This is usually 32766 on the most common platforms. The actual limit can
123 be seen in the error message generated by code such as this:
125 $_ **= $_ , / {$_} / for 2 .. 42;
127 By default, a quantified subpattern is "greedy", that is, it will match as
128 many times as possible (given a particular starting location) while still
129 allowing the rest of the pattern to match. If you want it to match the
130 minimum number of times possible, follow the quantifier with a "?". Note
131 that the meanings don't change, just the "greediness":
133 *? Match 0 or more times
134 +? Match 1 or more times
136 {n}? Match exactly n times
137 {n,}? Match at least n times
138 {n,m}? Match at least n but not more than m times
140 Because patterns are processed as double quoted strings, the following
147 \a alarm (bell) (BEL)
148 \e escape (think troff) (ESC)
149 \033 octal char (think of a PDP-11)
151 \x{263a} wide hex char (Unicode SMILEY)
154 \l lowercase next char (think vi)
155 \u uppercase next char (think vi)
156 \L lowercase till \E (think vi)
157 \U uppercase till \E (think vi)
158 \E end case modification (think vi)
159 \Q quote (disable) pattern metacharacters till \E
161 If C<use locale> is in effect, the case map used by C<\l>, C<\L>, C<\u>
162 and C<\U> is taken from the current locale. See L<perllocale>. For
163 documentation of C<\N{name}>, see L<charnames>.
165 You cannot include a literal C<$> or C<@> within a C<\Q> sequence.
166 An unescaped C<$> or C<@> interpolates the corresponding variable,
167 while escaping will cause the literal string C<\$> to be matched.
168 You'll need to write something like C<m/\Quser\E\@\Qhost/>.
170 In addition, Perl defines the following:
172 \w Match a "word" character (alphanumeric plus "_")
173 \W Match a non-"word" character
174 \s Match a whitespace character
175 \S Match a non-whitespace character
176 \d Match a digit character
177 \D Match a non-digit character
178 \pP Match P, named property. Use \p{Prop} for longer names.
180 \X Match eXtended Unicode "combining character sequence",
181 equivalent to (?:\PM\pM*)
182 \C Match a single C char (octet) even under Unicode.
183 NOTE: breaks up characters into their UTF-8 bytes,
184 so you may end up with malformed pieces of UTF-8.
185 Unsupported in lookbehind.
187 A C<\w> matches a single alphanumeric character (an alphabetic
188 character, or a decimal digit) or C<_>, not a whole word. Use C<\w+>
189 to match a string of Perl-identifier characters (which isn't the same
190 as matching an English word). If C<use locale> is in effect, the list
191 of alphabetic characters generated by C<\w> is taken from the current
192 locale. See L<perllocale>. You may use C<\w>, C<\W>, C<\s>, C<\S>,
193 C<\d>, and C<\D> within character classes, but if you try to use them
194 as endpoints of a range, that's not a range, the "-" is understood
195 literally. If Unicode is in effect, C<\s> matches also "\x{85}",
196 "\x{2028}, and "\x{2029}", see L<perlunicode> for more details about
197 C<\pP>, C<\PP>, and C<\X>, and L<perluniintro> about Unicode in general.
198 You can define your own C<\p> and C<\P> propreties, see L<perlunicode>.
200 The POSIX character class syntax
204 is also available. The available classes and their backslash
205 equivalents (if available) are as follows:
226 A GNU extension equivalent to C<[ \t]>, `all horizontal whitespace'.
230 Not exactly equivalent to C<\s> since the C<[[:space:]]> includes
231 also the (very rare) `vertical tabulator', "\ck", chr(11).
235 A Perl extension, see above.
239 For example use C<[:upper:]> to match all the uppercase characters.
240 Note that the C<[]> are part of the C<[::]> construct, not part of the
241 whole character class. For example:
245 matches zero, one, any alphabetic character, and the percentage sign.
247 The following equivalences to Unicode \p{} constructs and equivalent
248 backslash character classes (if available), will hold:
250 [:...:] \p{...} backslash
268 For example C<[:lower:]> and C<\p{IsLower}> are equivalent.
270 If the C<utf8> pragma is not used but the C<locale> pragma is, the
271 classes correlate with the usual isalpha(3) interface (except for
274 The assumedly non-obviously named classes are:
280 Any control character. Usually characters that don't produce output as
281 such but instead control the terminal somehow: for example newline and
282 backspace are control characters. All characters with ord() less than
283 32 are most often classified as control characters (assuming ASCII,
284 the ISO Latin character sets, and Unicode), as is the character with
285 the ord() value of 127 (C<DEL>).
289 Any alphanumeric or punctuation (special) character.
293 Any alphanumeric or punctuation (special) character or the space character.
297 Any punctuation (special) character.
301 Any hexadecimal digit. Though this may feel silly ([0-9A-Fa-f] would
302 work just fine) it is included for completeness.
306 You can negate the [::] character classes by prefixing the class name
307 with a '^'. This is a Perl extension. For example:
309 POSIX traditional Unicode
311 [:^digit:] \D \P{IsDigit}
312 [:^space:] \S \P{IsSpace}
313 [:^word:] \W \P{IsWord}
315 Perl respects the POSIX standard in that POSIX character classes are
316 only supported within a character class. The POSIX character classes
317 [.cc.] and [=cc=] are recognized but B<not> supported and trying to
318 use them will cause an error.
320 Perl defines the following zero-width assertions:
322 \b Match a word boundary
323 \B Match a non-(word boundary)
324 \A Match only at beginning of string
325 \Z Match only at end of string, or before newline at the end
326 \z Match only at end of string
327 \G Match only at pos() (e.g. at the end-of-match position
330 A word boundary (C<\b>) is a spot between two characters
331 that has a C<\w> on one side of it and a C<\W> on the other side
332 of it (in either order), counting the imaginary characters off the
333 beginning and end of the string as matching a C<\W>. (Within
334 character classes C<\b> represents backspace rather than a word
335 boundary, just as it normally does in any double-quoted string.)
336 The C<\A> and C<\Z> are just like "^" and "$", except that they
337 won't match multiple times when the C</m> modifier is used, while
338 "^" and "$" will match at every internal line boundary. To match
339 the actual end of the string and not ignore an optional trailing
342 The C<\G> assertion can be used to chain global matches (using
343 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
344 It is also useful when writing C<lex>-like scanners, when you have
345 several patterns that you want to match against consequent substrings
346 of your string, see the previous reference. The actual location
347 where C<\G> will match can also be influenced by using C<pos()> as
348 an lvalue: see L<perlfunc/pos>. Currently C<\G> is only fully
349 supported when anchored to the start of the pattern; while it
350 is permitted to use it elsewhere, as in C</(?<=\G..)./g>, some
351 such uses (C</.\G/g>, for example) currently cause problems, and
352 it is recommended that you avoid such usage for now.
354 The bracketing construct C<( ... )> creates capture buffers. To
355 refer to the digit'th buffer use \<digit> within the
356 match. Outside the match use "$" instead of "\". (The
357 \<digit> notation works in certain circumstances outside
358 the match. See the warning below about \1 vs $1 for details.)
359 Referring back to another part of the match is called a
362 There is no limit to the number of captured substrings that you may
363 use. However Perl also uses \10, \11, etc. as aliases for \010,
364 \011, etc. (Recall that 0 means octal, so \011 is the character at
365 number 9 in your coded character set; which would be the 10th character,
366 a horizontal tab under ASCII.) Perl resolves this
367 ambiguity by interpreting \10 as a backreference only if at least 10
368 left parentheses have opened before it. Likewise \11 is a
369 backreference only if at least 11 left parentheses have opened
370 before it. And so on. \1 through \9 are always interpreted as
375 s/^([^ ]*) *([^ ]*)/$2 $1/; # swap first two words
377 if (/(.)\1/) { # find first doubled char
378 print "'$1' is the first doubled character\n";
381 if (/Time: (..):(..):(..)/) { # parse out values
387 Several special variables also refer back to portions of the previous
388 match. C<$+> returns whatever the last bracket match matched.
389 C<$&> returns the entire matched string. (At one point C<$0> did
390 also, but now it returns the name of the program.) C<$`> returns
391 everything before the matched string. C<$'> returns everything
392 after the matched string. And C<$^N> contains whatever was matched by
393 the most-recently closed group (submatch). C<$^N> can be used in
394 extended patterns (see below), for example to assign a submatch to a
397 The numbered variables ($1, $2, $3, etc.) and the related punctuation
398 set (C<$+>, C<$&>, C<$`>, C<$'>, and C<$^N>) are all dynamically scoped
399 until the end of the enclosing block or until the next successful
400 match, whichever comes first. (See L<perlsyn/"Compound Statements">.)
402 B<WARNING>: Once Perl sees that you need one of C<$&>, C<$`>, or
403 C<$'> anywhere in the program, it has to provide them for every
404 pattern match. This may substantially slow your program. Perl
405 uses the same mechanism to produce $1, $2, etc, so you also pay a
406 price for each pattern that contains capturing parentheses. (To
407 avoid this cost while retaining the grouping behaviour, use the
408 extended regular expression C<(?: ... )> instead.) But if you never
409 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
410 parentheses will not be penalized. So avoid C<$&>, C<$'>, and C<$`>
411 if you can, but if you can't (and some algorithms really appreciate
412 them), once you've used them once, use them at will, because you've
413 already paid the price. As of 5.005, C<$&> is not so costly as the
416 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
417 C<\w>, C<\n>. Unlike some other regular expression languages, there
418 are no backslashed symbols that aren't alphanumeric. So anything
419 that looks like \\, \(, \), \<, \>, \{, or \} is always
420 interpreted as a literal character, not a metacharacter. This was
421 once used in a common idiom to disable or quote the special meanings
422 of regular expression metacharacters in a string that you want to
423 use for a pattern. Simply quote all non-"word" characters:
425 $pattern =~ s/(\W)/\\$1/g;
427 (If C<use locale> is set, then this depends on the current locale.)
428 Today it is more common to use the quotemeta() function or the C<\Q>
429 metaquoting escape sequence to disable all metacharacters' special
432 /$unquoted\Q$quoted\E$unquoted/
434 Beware that if you put literal backslashes (those not inside
435 interpolated variables) between C<\Q> and C<\E>, double-quotish
436 backslash interpolation may lead to confusing results. If you
437 I<need> to use literal backslashes within C<\Q...\E>,
438 consult L<perlop/"Gory details of parsing quoted constructs">.
440 =head2 Extended Patterns
442 Perl also defines a consistent extension syntax for features not
443 found in standard tools like B<awk> and B<lex>. The syntax is a
444 pair of parentheses with a question mark as the first thing within
445 the parentheses. The character after the question mark indicates
448 The stability of these extensions varies widely. Some have been
449 part of the core language for many years. Others are experimental
450 and may change without warning or be completely removed. Check
451 the documentation on an individual feature to verify its current
454 A question mark was chosen for this and for the minimal-matching
455 construct because 1) question marks are rare in older regular
456 expressions, and 2) whenever you see one, you should stop and
457 "question" exactly what is going on. That's psychology...
463 A comment. The text is ignored. If the C</x> modifier enables
464 whitespace formatting, a simple C<#> will suffice. Note that Perl closes
465 the comment as soon as it sees a C<)>, so there is no way to put a literal
468 =item C<(?imsx-imsx)>
470 One or more embedded pattern-match modifiers, to be turned on (or
471 turned off, if preceded by C<->) for the remainder of the pattern or
472 the remainder of the enclosing pattern group (if any). This is
473 particularly useful for dynamic patterns, such as those read in from a
474 configuration file, read in as an argument, are specified in a table
475 somewhere, etc. Consider the case that some of which want to be case
476 sensitive and some do not. The case insensitive ones need to include
477 merely C<(?i)> at the front of the pattern. For example:
480 if ( /$pattern/i ) { }
484 $pattern = "(?i)foobar";
485 if ( /$pattern/ ) { }
487 These modifiers are restored at the end of the enclosing group. For example,
491 will match a repeated (I<including the case>!) word C<blah> in any
492 case, assuming C<x> modifier, and no C<i> modifier outside this
497 =item C<(?imsx-imsx:pattern)>
499 This is for clustering, not capturing; it groups subexpressions like
500 "()", but doesn't make backreferences as "()" does. So
502 @fields = split(/\b(?:a|b|c)\b/)
506 @fields = split(/\b(a|b|c)\b/)
508 but doesn't spit out extra fields. It's also cheaper not to capture
509 characters if you don't need to.
511 Any letters between C<?> and C<:> act as flags modifiers as with
512 C<(?imsx-imsx)>. For example,
514 /(?s-i:more.*than).*million/i
516 is equivalent to the more verbose
518 /(?:(?s-i)more.*than).*million/i
522 A zero-width positive look-ahead assertion. For example, C</\w+(?=\t)/>
523 matches a word followed by a tab, without including the tab in C<$&>.
527 A zero-width negative look-ahead assertion. For example C</foo(?!bar)/>
528 matches any occurrence of "foo" that isn't followed by "bar". Note
529 however that look-ahead and look-behind are NOT the same thing. You cannot
530 use this for look-behind.
532 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
533 will not do what you want. That's because the C<(?!foo)> is just saying that
534 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
535 match. You would have to do something like C</(?!foo)...bar/> for that. We
536 say "like" because there's the case of your "bar" not having three characters
537 before it. You could cover that this way: C</(?:(?!foo)...|^.{0,2})bar/>.
538 Sometimes it's still easier just to say:
540 if (/bar/ && $` !~ /foo$/)
542 For look-behind see below.
544 =item C<(?<=pattern)>
546 A zero-width positive look-behind assertion. For example, C</(?<=\t)\w+/>
547 matches a word that follows a tab, without including the tab in C<$&>.
548 Works only for fixed-width look-behind.
550 =item C<(?<!pattern)>
552 A zero-width negative look-behind assertion. For example C</(?<!bar)foo/>
553 matches any occurrence of "foo" that does not follow "bar". Works
554 only for fixed-width look-behind.
558 B<WARNING>: This extended regular expression feature is considered
559 highly experimental, and may be changed or deleted without notice.
561 This zero-width assertion evaluates any embedded Perl code. It
562 always succeeds, and its C<code> is not interpolated. Currently,
563 the rules to determine where the C<code> ends are somewhat convoluted.
565 This feature can be used together with the special variable C<$^N> to
566 capture the results of submatches in variables without having to keep
567 track of the number of nested parentheses. For example:
569 $_ = "The brown fox jumps over the lazy dog";
570 /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
571 print "color = $color, animal = $animal\n";
573 The C<code> is properly scoped in the following sense: If the assertion
574 is backtracked (compare L<"Backtracking">), all changes introduced after
575 C<local>ization are undone, so that
579 (?{ $cnt = 0 }) # Initialize $cnt.
583 local $cnt = $cnt + 1; # Update $cnt, backtracking-safe.
587 (?{ $res = $cnt }) # On success copy to non-localized
591 will set C<$res = 4>. Note that after the match, $cnt returns to the globally
592 introduced value, because the scopes that restrict C<local> operators
595 This assertion may be used as a C<(?(condition)yes-pattern|no-pattern)>
596 switch. If I<not> used in this way, the result of evaluation of
597 C<code> is put into the special variable C<$^R>. This happens
598 immediately, so C<$^R> can be used from other C<(?{ code })> assertions
599 inside the same regular expression.
601 The assignment to C<$^R> above is properly localized, so the old
602 value of C<$^R> is restored if the assertion is backtracked; compare
605 For reasons of security, this construct is forbidden if the regular
606 expression involves run-time interpolation of variables, unless the
607 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
608 variables contain results of C<qr//> operator (see
609 L<perlop/"qr/STRING/imosx">).
611 This restriction is because of the wide-spread and remarkably convenient
612 custom of using run-time determined strings as patterns. For example:
618 Before Perl knew how to execute interpolated code within a pattern,
619 this operation was completely safe from a security point of view,
620 although it could raise an exception from an illegal pattern. If
621 you turn on the C<use re 'eval'>, though, it is no longer secure,
622 so you should only do so if you are also using taint checking.
623 Better yet, use the carefully constrained evaluation within a Safe
624 compartment. See L<perlsec> for details about both these mechanisms.
626 =item C<(??{ code })>
628 B<WARNING>: This extended regular expression feature is considered
629 highly experimental, and may be changed or deleted without notice.
630 A simplified version of the syntax may be introduced for commonly
633 This is a "postponed" regular subexpression. The C<code> is evaluated
634 at run time, at the moment this subexpression may match. The result
635 of evaluation is considered as a regular expression and matched as
636 if it were inserted instead of this construct.
638 The C<code> is not interpolated. As before, the rules to determine
639 where the C<code> ends are currently somewhat convoluted.
641 The following pattern matches a parenthesized group:
646 (?> [^()]+ ) # Non-parens without backtracking
648 (??{ $re }) # Group with matching parens
653 =item C<< (?>pattern) >>
655 B<WARNING>: This extended regular expression feature is considered
656 highly experimental, and may be changed or deleted without notice.
658 An "independent" subexpression, one which matches the substring
659 that a I<standalone> C<pattern> would match if anchored at the given
660 position, and it matches I<nothing other than this substring>. This
661 construct is useful for optimizations of what would otherwise be
662 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
663 It may also be useful in places where the "grab all you can, and do not
664 give anything back" semantic is desirable.
666 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
667 (anchored at the beginning of string, as above) will match I<all>
668 characters C<a> at the beginning of string, leaving no C<a> for
669 C<ab> to match. In contrast, C<a*ab> will match the same as C<a+b>,
670 since the match of the subgroup C<a*> is influenced by the following
671 group C<ab> (see L<"Backtracking">). In particular, C<a*> inside
672 C<a*ab> will match fewer characters than a standalone C<a*>, since
673 this makes the tail match.
675 An effect similar to C<< (?>pattern) >> may be achieved by writing
676 C<(?=(pattern))\1>. This matches the same substring as a standalone
677 C<a+>, and the following C<\1> eats the matched string; it therefore
678 makes a zero-length assertion into an analogue of C<< (?>...) >>.
679 (The difference between these two constructs is that the second one
680 uses a capturing group, thus shifting ordinals of backreferences
681 in the rest of a regular expression.)
683 Consider this pattern:
694 That will efficiently match a nonempty group with matching parentheses
695 two levels deep or less. However, if there is no such group, it
696 will take virtually forever on a long string. That's because there
697 are so many different ways to split a long string into several
698 substrings. This is what C<(.+)+> is doing, and C<(.+)+> is similar
699 to a subpattern of the above pattern. Consider how the pattern
700 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
701 seconds, but that each extra letter doubles this time. This
702 exponential performance will make it appear that your program has
703 hung. However, a tiny change to this pattern
707 (?> [^()]+ ) # change x+ above to (?> x+ )
714 which uses C<< (?>...) >> matches exactly when the one above does (verifying
715 this yourself would be a productive exercise), but finishes in a fourth
716 the time when used on a similar string with 1000000 C<a>s. Be aware,
717 however, that this pattern currently triggers a warning message under
718 the C<use warnings> pragma or B<-w> switch saying it
719 C<"matches null string many times in regex">.
721 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
722 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
723 This was only 4 times slower on a string with 1000000 C<a>s.
725 The "grab all you can, and do not give anything back" semantic is desirable
726 in many situations where on the first sight a simple C<()*> looks like
727 the correct solution. Suppose we parse text with comments being delimited
728 by C<#> followed by some optional (horizontal) whitespace. Contrary to
729 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
730 the comment delimiter, because it may "give up" some whitespace if
731 the remainder of the pattern can be made to match that way. The correct
732 answer is either one of these:
737 For example, to grab non-empty comments into $1, one should use either
740 / (?> \# [ \t]* ) ( .+ ) /x;
741 / \# [ \t]* ( [^ \t] .* ) /x;
743 Which one you pick depends on which of these expressions better reflects
744 the above specification of comments.
746 =item C<(?(condition)yes-pattern|no-pattern)>
748 =item C<(?(condition)yes-pattern)>
750 B<WARNING>: This extended regular expression feature is considered
751 highly experimental, and may be changed or deleted without notice.
753 Conditional expression. C<(condition)> should be either an integer in
754 parentheses (which is valid if the corresponding pair of parentheses
755 matched), or look-ahead/look-behind/evaluate zero-width assertion.
764 matches a chunk of non-parentheses, possibly included in parentheses
771 NOTE: This section presents an abstract approximation of regular
772 expression behavior. For a more rigorous (and complicated) view of
773 the rules involved in selecting a match among possible alternatives,
774 see L<Combining pieces together>.
776 A fundamental feature of regular expression matching involves the
777 notion called I<backtracking>, which is currently used (when needed)
778 by all regular expression quantifiers, namely C<*>, C<*?>, C<+>,
779 C<+?>, C<{n,m}>, and C<{n,m}?>. Backtracking is often optimized
780 internally, but the general principle outlined here is valid.
782 For a regular expression to match, the I<entire> regular expression must
783 match, not just part of it. So if the beginning of a pattern containing a
784 quantifier succeeds in a way that causes later parts in the pattern to
785 fail, the matching engine backs up and recalculates the beginning
786 part--that's why it's called backtracking.
788 Here is an example of backtracking: Let's say you want to find the
789 word following "foo" in the string "Food is on the foo table.":
791 $_ = "Food is on the foo table.";
792 if ( /\b(foo)\s+(\w+)/i ) {
793 print "$2 follows $1.\n";
796 When the match runs, the first part of the regular expression (C<\b(foo)>)
797 finds a possible match right at the beginning of the string, and loads up
798 $1 with "Foo". However, as soon as the matching engine sees that there's
799 no whitespace following the "Foo" that it had saved in $1, it realizes its
800 mistake and starts over again one character after where it had the
801 tentative match. This time it goes all the way until the next occurrence
802 of "foo". The complete regular expression matches this time, and you get
803 the expected output of "table follows foo."
805 Sometimes minimal matching can help a lot. Imagine you'd like to match
806 everything between "foo" and "bar". Initially, you write something
809 $_ = "The food is under the bar in the barn.";
810 if ( /foo(.*)bar/ ) {
814 Which perhaps unexpectedly yields:
816 got <d is under the bar in the >
818 That's because C<.*> was greedy, so you get everything between the
819 I<first> "foo" and the I<last> "bar". Here it's more effective
820 to use minimal matching to make sure you get the text between a "foo"
821 and the first "bar" thereafter.
823 if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
824 got <d is under the >
826 Here's another example: let's say you'd like to match a number at the end
827 of a string, and you also want to keep the preceding part of the match.
830 $_ = "I have 2 numbers: 53147";
831 if ( /(.*)(\d*)/ ) { # Wrong!
832 print "Beginning is <$1>, number is <$2>.\n";
835 That won't work at all, because C<.*> was greedy and gobbled up the
836 whole string. As C<\d*> can match on an empty string the complete
837 regular expression matched successfully.
839 Beginning is <I have 2 numbers: 53147>, number is <>.
841 Here are some variants, most of which don't work:
843 $_ = "I have 2 numbers: 53147";
856 printf "%-12s ", $pat;
866 (.*)(\d*) <I have 2 numbers: 53147> <>
867 (.*)(\d+) <I have 2 numbers: 5314> <7>
869 (.*?)(\d+) <I have > <2>
870 (.*)(\d+)$ <I have 2 numbers: 5314> <7>
871 (.*?)(\d+)$ <I have 2 numbers: > <53147>
872 (.*)\b(\d+)$ <I have 2 numbers: > <53147>
873 (.*\D)(\d+)$ <I have 2 numbers: > <53147>
875 As you see, this can be a bit tricky. It's important to realize that a
876 regular expression is merely a set of assertions that gives a definition
877 of success. There may be 0, 1, or several different ways that the
878 definition might succeed against a particular string. And if there are
879 multiple ways it might succeed, you need to understand backtracking to
880 know which variety of success you will achieve.
882 When using look-ahead assertions and negations, this can all get even
883 trickier. Imagine you'd like to find a sequence of non-digits not
884 followed by "123". You might try to write that as
887 if ( /^\D*(?!123)/ ) { # Wrong!
888 print "Yup, no 123 in $_\n";
891 But that isn't going to match; at least, not the way you're hoping. It
892 claims that there is no 123 in the string. Here's a clearer picture of
893 why that pattern matches, contrary to popular expectations:
898 print "1: got $1\n" if $x =~ /^(ABC)(?!123)/ ;
899 print "2: got $1\n" if $y =~ /^(ABC)(?!123)/ ;
901 print "3: got $1\n" if $x =~ /^(\D*)(?!123)/ ;
902 print "4: got $1\n" if $y =~ /^(\D*)(?!123)/ ;
910 You might have expected test 3 to fail because it seems to a more
911 general purpose version of test 1. The important difference between
912 them is that test 3 contains a quantifier (C<\D*>) and so can use
913 backtracking, whereas test 1 will not. What's happening is
914 that you've asked "Is it true that at the start of $x, following 0 or more
915 non-digits, you have something that's not 123?" If the pattern matcher had
916 let C<\D*> expand to "ABC", this would have caused the whole pattern to
919 The search engine will initially match C<\D*> with "ABC". Then it will
920 try to match C<(?!123> with "123", which fails. But because
921 a quantifier (C<\D*>) has been used in the regular expression, the
922 search engine can backtrack and retry the match differently
923 in the hope of matching the complete regular expression.
925 The pattern really, I<really> wants to succeed, so it uses the
926 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
927 time. Now there's indeed something following "AB" that is not
928 "123". It's "C123", which suffices.
930 We can deal with this by using both an assertion and a negation.
931 We'll say that the first part in $1 must be followed both by a digit
932 and by something that's not "123". Remember that the look-aheads
933 are zero-width expressions--they only look, but don't consume any
934 of the string in their match. So rewriting this way produces what
935 you'd expect; that is, case 5 will fail, but case 6 succeeds:
937 print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/ ;
938 print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/ ;
942 In other words, the two zero-width assertions next to each other work as though
943 they're ANDed together, just as you'd use any built-in assertions: C</^$/>
944 matches only if you're at the beginning of the line AND the end of the
945 line simultaneously. The deeper underlying truth is that juxtaposition in
946 regular expressions always means AND, except when you write an explicit OR
947 using the vertical bar. C</ab/> means match "a" AND (then) match "b",
948 although the attempted matches are made at different positions because "a"
949 is not a zero-width assertion, but a one-width assertion.
951 B<WARNING>: particularly complicated regular expressions can take
952 exponential time to solve because of the immense number of possible
953 ways they can use backtracking to try match. For example, without
954 internal optimizations done by the regular expression engine, this will
955 take a painfully long time to run:
957 'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
959 And if you used C<*>'s in the internal groups instead of limiting them
960 to 0 through 5 matches, then it would take forever--or until you ran
961 out of stack space. Moreover, these internal optimizations are not
962 always applicable. For example, if you put C<{0,5}> instead of C<*>
963 on the external group, no current optimization is applicable, and the
964 match takes a long time to finish.
966 A powerful tool for optimizing such beasts is what is known as an
968 which does not backtrack (see L<C<< (?>pattern) >>>). Note also that
969 zero-length look-ahead/look-behind assertions will not backtrack to make
970 the tail match, since they are in "logical" context: only
971 whether they match is considered relevant. For an example
972 where side-effects of look-ahead I<might> have influenced the
973 following match, see L<C<< (?>pattern) >>>.
975 =head2 Version 8 Regular Expressions
977 In case you're not familiar with the "regular" Version 8 regex
978 routines, here are the pattern-matching rules not described above.
980 Any single character matches itself, unless it is a I<metacharacter>
981 with a special meaning described here or above. You can cause
982 characters that normally function as metacharacters to be interpreted
983 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
984 character; "\\" matches a "\"). A series of characters matches that
985 series of characters in the target string, so the pattern C<blurfl>
986 would match "blurfl" in the target string.
988 You can specify a character class, by enclosing a list of characters
989 in C<[]>, which will match any one character from the list. If the
990 first character after the "[" is "^", the class matches any character not
991 in the list. Within a list, the "-" character specifies a
992 range, so that C<a-z> represents all characters between "a" and "z",
993 inclusive. If you want either "-" or "]" itself to be a member of a
994 class, put it at the start of the list (possibly after a "^"), or
995 escape it with a backslash. "-" is also taken literally when it is
996 at the end of the list, just before the closing "]". (The
997 following all specify the same class of three characters: C<[-az]>,
998 C<[az-]>, and C<[a\-z]>. All are different from C<[a-z]>, which
999 specifies a class containing twenty-six characters, even on EBCDIC
1000 based coded character sets.) Also, if you try to use the character
1001 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
1002 a range, that's not a range, the "-" is understood literally.
1004 Note also that the whole range idea is rather unportable between
1005 character sets--and even within character sets they may cause results
1006 you probably didn't expect. A sound principle is to use only ranges
1007 that begin from and end at either alphabets of equal case ([a-e],
1008 [A-E]), or digits ([0-9]). Anything else is unsafe. If in doubt,
1009 spell out the character sets in full.
1011 Characters may be specified using a metacharacter syntax much like that
1012 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
1013 "\f" a form feed, etc. More generally, \I<nnn>, where I<nnn> is a string
1014 of octal digits, matches the character whose coded character set value
1015 is I<nnn>. Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
1016 matches the character whose numeric value is I<nn>. The expression \cI<x>
1017 matches the character control-I<x>. Finally, the "." metacharacter
1018 matches any character except "\n" (unless you use C</s>).
1020 You can specify a series of alternatives for a pattern using "|" to
1021 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
1022 or "foe" in the target string (as would C<f(e|i|o)e>). The
1023 first alternative includes everything from the last pattern delimiter
1024 ("(", "[", or the beginning of the pattern) up to the first "|", and
1025 the last alternative contains everything from the last "|" to the next
1026 pattern delimiter. That's why it's common practice to include
1027 alternatives in parentheses: to minimize confusion about where they
1030 Alternatives are tried from left to right, so the first
1031 alternative found for which the entire expression matches, is the one that
1032 is chosen. This means that alternatives are not necessarily greedy. For
1033 example: when matching C<foo|foot> against "barefoot", only the "foo"
1034 part will match, as that is the first alternative tried, and it successfully
1035 matches the target string. (This might not seem important, but it is
1036 important when you are capturing matched text using parentheses.)
1038 Also remember that "|" is interpreted as a literal within square brackets,
1039 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
1041 Within a pattern, you may designate subpatterns for later reference
1042 by enclosing them in parentheses, and you may refer back to the
1043 I<n>th subpattern later in the pattern using the metacharacter
1044 \I<n>. Subpatterns are numbered based on the left to right order
1045 of their opening parenthesis. A backreference matches whatever
1046 actually matched the subpattern in the string being examined, not
1047 the rules for that subpattern. Therefore, C<(0|0x)\d*\s\1\d*> will
1048 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
1049 1 matched "0x", even though the rule C<0|0x> could potentially match
1050 the leading 0 in the second number.
1052 =head2 Warning on \1 vs $1
1054 Some people get too used to writing things like:
1056 $pattern =~ s/(\W)/\\\1/g;
1058 This is grandfathered for the RHS of a substitute to avoid shocking the
1059 B<sed> addicts, but it's a dirty habit to get into. That's because in
1060 PerlThink, the righthand side of an C<s///> is a double-quoted string. C<\1> in
1061 the usual double-quoted string means a control-A. The customary Unix
1062 meaning of C<\1> is kludged in for C<s///>. However, if you get into the habit
1063 of doing that, you get yourself into trouble if you then add an C</e>
1066 s/(\d+)/ \1 + 1 /eg; # causes warning under -w
1072 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
1073 C<${1}000>. The operation of interpolation should not be confused
1074 with the operation of matching a backreference. Certainly they mean two
1075 different things on the I<left> side of the C<s///>.
1077 =head2 Repeated patterns matching zero-length substring
1079 B<WARNING>: Difficult material (and prose) ahead. This section needs a rewrite.
1081 Regular expressions provide a terse and powerful programming language. As
1082 with most other power tools, power comes together with the ability
1085 A common abuse of this power stems from the ability to make infinite
1086 loops using regular expressions, with something as innocuous as:
1088 'foo' =~ m{ ( o? )* }x;
1090 The C<o?> can match at the beginning of C<'foo'>, and since the position
1091 in the string is not moved by the match, C<o?> would match again and again
1092 because of the C<*> modifier. Another common way to create a similar cycle
1093 is with the looping modifier C<//g>:
1095 @matches = ( 'foo' =~ m{ o? }xg );
1099 print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
1101 or the loop implied by split().
1103 However, long experience has shown that many programming tasks may
1104 be significantly simplified by using repeated subexpressions that
1105 may match zero-length substrings. Here's a simple example being:
1107 @chars = split //, $string; # // is not magic in split
1108 ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
1110 Thus Perl allows such constructs, by I<forcefully breaking
1111 the infinite loop>. The rules for this are different for lower-level
1112 loops given by the greedy modifiers C<*+{}>, and for higher-level
1113 ones like the C</g> modifier or split() operator.
1115 The lower-level loops are I<interrupted> (that is, the loop is
1116 broken) when Perl detects that a repeated expression matched a
1117 zero-length substring. Thus
1119 m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
1121 is made equivalent to
1123 m{ (?: NON_ZERO_LENGTH )*
1128 The higher level-loops preserve an additional state between iterations:
1129 whether the last match was zero-length. To break the loop, the following
1130 match after a zero-length match is prohibited to have a length of zero.
1131 This prohibition interacts with backtracking (see L<"Backtracking">),
1132 and so the I<second best> match is chosen if the I<best> match is of
1140 results in C<< <><b><><a><><r><> >>. At each position of the string the best
1141 match given by non-greedy C<??> is the zero-length match, and the I<second
1142 best> match is what is matched by C<\w>. Thus zero-length matches
1143 alternate with one-character-long matches.
1145 Similarly, for repeated C<m/()/g> the second-best match is the match at the
1146 position one notch further in the string.
1148 The additional state of being I<matched with zero-length> is associated with
1149 the matched string, and is reset by each assignment to pos().
1150 Zero-length matches at the end of the previous match are ignored
1153 =head2 Combining pieces together
1155 Each of the elementary pieces of regular expressions which were described
1156 before (such as C<ab> or C<\Z>) could match at most one substring
1157 at the given position of the input string. However, in a typical regular
1158 expression these elementary pieces are combined into more complicated
1159 patterns using combining operators C<ST>, C<S|T>, C<S*> etc
1160 (in these examples C<S> and C<T> are regular subexpressions).
1162 Such combinations can include alternatives, leading to a problem of choice:
1163 if we match a regular expression C<a|ab> against C<"abc">, will it match
1164 substring C<"a"> or C<"ab">? One way to describe which substring is
1165 actually matched is the concept of backtracking (see L<"Backtracking">).
1166 However, this description is too low-level and makes you think
1167 in terms of a particular implementation.
1169 Another description starts with notions of "better"/"worse". All the
1170 substrings which may be matched by the given regular expression can be
1171 sorted from the "best" match to the "worst" match, and it is the "best"
1172 match which is chosen. This substitutes the question of "what is chosen?"
1173 by the question of "which matches are better, and which are worse?".
1175 Again, for elementary pieces there is no such question, since at most
1176 one match at a given position is possible. This section describes the
1177 notion of better/worse for combining operators. In the description
1178 below C<S> and C<T> are regular subexpressions.
1184 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
1185 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
1186 which can be matched by C<T>.
1188 If C<A> is better match for C<S> than C<A'>, C<AB> is a better
1191 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
1192 C<B> is better match for C<T> than C<B'>.
1196 When C<S> can match, it is a better match than when only C<T> can match.
1198 Ordering of two matches for C<S> is the same as for C<S>. Similar for
1199 two matches for C<T>.
1201 =item C<S{REPEAT_COUNT}>
1203 Matches as C<SSS...S> (repeated as many times as necessary).
1207 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
1209 =item C<S{min,max}?>
1211 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
1213 =item C<S?>, C<S*>, C<S+>
1215 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
1217 =item C<S??>, C<S*?>, C<S+?>
1219 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
1223 Matches the best match for C<S> and only that.
1225 =item C<(?=S)>, C<(?<=S)>
1227 Only the best match for C<S> is considered. (This is important only if
1228 C<S> has capturing parentheses, and backreferences are used somewhere
1229 else in the whole regular expression.)
1231 =item C<(?!S)>, C<(?<!S)>
1233 For this grouping operator there is no need to describe the ordering, since
1234 only whether or not C<S> can match is important.
1236 =item C<(??{ EXPR })>
1238 The ordering is the same as for the regular expression which is
1241 =item C<(?(condition)yes-pattern|no-pattern)>
1243 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
1244 already determined. The ordering of the matches is the same as for the
1245 chosen subexpression.
1249 The above recipes describe the ordering of matches I<at a given position>.
1250 One more rule is needed to understand how a match is determined for the
1251 whole regular expression: a match at an earlier position is always better
1252 than a match at a later position.
1254 =head2 Creating custom RE engines
1256 Overloaded constants (see L<overload>) provide a simple way to extend
1257 the functionality of the RE engine.
1259 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
1260 matches at boundary between white-space characters and non-whitespace
1261 characters. Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
1262 at these positions, so we want to have each C<\Y|> in the place of the
1263 more complicated version. We can create a module C<customre> to do
1271 die "No argument to customre::import allowed" if @_;
1272 overload::constant 'qr' => \&convert;
1275 sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
1277 my %rules = ( '\\' => '\\',
1278 'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
1284 { $rules{$1} or invalid($re,$1) }sgex;
1288 Now C<use customre> enables the new escape in constant regular
1289 expressions, i.e., those without any runtime variable interpolations.
1290 As documented in L<overload>, this conversion will work only over
1291 literal parts of regular expressions. For C<\Y|$re\Y|> the variable
1292 part of this regular expression needs to be converted explicitly
1293 (but only if the special meaning of C<\Y|> should be enabled inside $re):
1298 $re = customre::convert $re;
1303 This document varies from difficult to understand to completely
1304 and utterly opaque. The wandering prose riddled with jargon is
1305 hard to fathom in several places.
1307 This document needs a rewrite that separates the tutorial content
1308 from the reference content.
1316 L<perlop/"Regexp Quote-Like Operators">.
1318 L<perlop/"Gory details of parsing quoted constructs">.
1328 I<Mastering Regular Expressions> by Jeffrey Friedl, published
1329 by O'Reilly and Associates.