pod/perlre.pod

   1 =head1 NAME
   2 X<regular expression> X<regex> X<regexp>
   3
   4 perlre - Perl regular expressions
   5
   6 =head1 DESCRIPTION
   7
   8 This page describes the syntax of regular expressions in Perl.
   9
  10 If you haven't used regular expressions before, a quick-start
  11 introduction is available in L<perlrequick>, and a longer tutorial
  12 introduction is available in L<perlretut>.
  13
  14 For reference on how regular expressions are used in matching
  15 operations, plus various examples of the same, see discussions of
  16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
  17 Operators">.
  18
  19
  20 =head2 Modifiers
  21
  22 Matching operations can have various modifiers.  Modifiers
  23 that relate to the interpretation of the regular expression inside
  24 are listed below.  Modifiers that alter the way a regular expression
  25 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
  26 L<perlop/"Gory details of parsing quoted constructs">.
  27
  28 =over 4
  29
  30 =item m
  31 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
  32
  33 Treat string as multiple lines.  That is, change "^" and "$" from matching
  34 the start or end of the string to matching the start or end of any
  35 line anywhere within the string.
  36
  37 =item s
  38 X</s> X<regex, single-line> X<regexp, single-line>
  39 X<regular expression, single-line>
  40
  41 Treat string as single line.  That is, change "." to match any character
  42 whatsoever, even a newline, which normally it would not match.
  43
  44 Used together, as /ms, they let the "." match any character whatsoever,
  45 while still allowing "^" and "$" to match, respectively, just after
  46 and just before newlines within the string.
  47
  48 =item i
  49 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
  50 X<regular expression, case-insensitive>
  51
  52 Do case-insensitive pattern matching.
  53
  54 If C<use locale> is in effect, the case map is taken from the current
  55 locale.  See L<perllocale>.
  56
  57 =item x
  58 X</x>
  59
  60 Extend your pattern's legibility by permitting whitespace and comments.
  61
  62 =item p
  63 X</p> X<regex, preserve> X<regexp, preserve>
  64
  65 Preserve the string matched such that ${^PREMATCH}, {$^MATCH}, and
  66 ${^POSTMATCH} are available for use after matching.
  67
  68 =item g and c
  69 X</g> X</c>
  70
  71 Global matching, and keep the Current position after failed matching.
  72 Unlike i, m, s and x, these two flags affect the way the regex is used
  73 rather than the regex itself. See
  74 L<perlretut/"Using regular expressions in Perl"> for further explanation
  75 of the g and c modifiers.
  76
  77 =back
  78
  79 These are usually written as "the C</x> modifier", even though the delimiter
  80 in question might not really be a slash.  Any of these
  81 modifiers may also be embedded within the regular expression itself using
  82 the C<(?...)> construct.  See below.
  83
  84 The C</x> modifier itself needs a little more explanation.  It tells
  85 the regular expression parser to ignore whitespace that is neither
  86 backslashed nor within a character class.  You can use this to break up
  87 your regular expression into (slightly) more readable parts.  The C<#>
  88 character is also treated as a metacharacter introducing a comment,
  89 just as in ordinary Perl code.  This also means that if you want real
  90 whitespace or C<#> characters in the pattern (outside a character
  91 class, where they are unaffected by C</x>), then you'll either have to
  92 escape them (using backslashes or C<\Q...\E>) or encode them using octal
  93 or hex escapes.  Taken together, these features go a long way towards
  94 making Perl's regular expressions more readable.  Note that you have to
  95 be careful not to include the pattern delimiter in the comment--perl has
  96 no way of knowing you did not intend to close the pattern early.  See
  97 the C-comment deletion code in L<perlop>.  Also note that anything inside
  98 a C<\Q...\E> stays unaffected by C</x>.
  99 X</x>
 100
 101 =head2 Regular Expressions
 102
 103 =head3 Metacharacters
 104
 105 The patterns used in Perl pattern matching evolved from those supplied in
 106 the Version 8 regex routines.  (The routines are derived
 107 (distantly) from Henry Spencer's freely redistributable reimplementation
 108 of the V8 routines.)  See L<Version 8 Regular Expressions> for
 109 details.
 110
 111 In particular the following metacharacters have their standard I<egrep>-ish
 112 meanings:
 113 X<metacharacter>
 114 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
 115
 116
 117     \   Quote the next metacharacter
 118     ^   Match the beginning of the line
 119     .   Match any character (except newline)
 120     $   Match the end of the line (or before newline at the end)
 121     |   Alternation
 122     ()  Grouping
 123     []  Character class
 124
 125 By default, the "^" character is guaranteed to match only the
 126 beginning of the string, the "$" character only the end (or before the
 127 newline at the end), and Perl does certain optimizations with the
 128 assumption that the string contains only one line.  Embedded newlines
 129 will not be matched by "^" or "$".  You may, however, wish to treat a
 130 string as a multi-line buffer, such that the "^" will match after any
 131 newline within the string (except if the newline is the last character in
 132 the string), and "$" will match before any newline.  At the
 133 cost of a little more overhead, you can do this by using the /m modifier
 134 on the pattern match operator.  (Older programs did this by setting C<$*>,
 135 but this practice has been removed in perl 5.9.)
 136 X<^> X<$> X</m>
 137
 138 To simplify multi-line substitutions, the "." character never matches a
 139 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
 140 the string is a single line--even if it isn't.
 141 X<.> X</s>
 142
 143 =head3 Quantifiers
 144
 145 The following standard quantifiers are recognized:
 146 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
 147
 148     *      Match 0 or more times
 149     +      Match 1 or more times
 150     ?      Match 1 or 0 times
 151     {n}    Match exactly n times
 152     {n,}   Match at least n times
 153     {n,m}  Match at least n but not more than m times
 154
 155 (If a curly bracket occurs in any other context, it is treated
 156 as a regular character.  In particular, the lower bound
 157 is not optional.)  The "*" quantifier is equivalent to C<{0,}>, the "+"
 158 quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>.  n and m are limited
 159 to integral values less than a preset limit defined when perl is built.
 160 This is usually 32766 on the most common platforms.  The actual limit can
 161 be seen in the error message generated by code such as this:
 162
 163     $_ **= $_ , / {$_} / for 2 .. 42;
 164
 165 By default, a quantified subpattern is "greedy", that is, it will match as
 166 many times as possible (given a particular starting location) while still
 167 allowing the rest of the pattern to match.  If you want it to match the
 168 minimum number of times possible, follow the quantifier with a "?".  Note
 169 that the meanings don't change, just the "greediness":
 170 X<metacharacter> X<greedy> X<greediness>
 171 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
 172
 173     *?     Match 0 or more times, not greedily
 174     +?     Match 1 or more times, not greedily
 175     ??     Match 0 or 1 time, not greedily
 176     {n}?   Match exactly n times, not greedily
 177     {n,}?  Match at least n times, not greedily
 178     {n,m}? Match at least n but not more than m times, not greedily
 179
 180 By default, when a quantified subpattern does not allow the rest of the
 181 overall pattern to match, Perl will backtrack. However, this behaviour is
 182 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
 183 as well.
 184
 185     *+     Match 0 or more times and give nothing back
 186     ++     Match 1 or more times and give nothing back
 187     ?+     Match 0 or 1 time and give nothing back
 188     {n}+   Match exactly n times and give nothing back (redundant)
 189     {n,}+  Match at least n times and give nothing back
 190     {n,m}+ Match at least n but not more than m times and give nothing back
 191
 192 For instance,
 193
 194    'aaaa' =~ /a++a/
 195
 196 will never match, as the C<a++> will gobble up all the C<a>'s in the
 197 string and won't leave any for the remaining part of the pattern. This
 198 feature can be extremely useful to give perl hints about where it
 199 shouldn't backtrack. For instance, the typical "match a double-quoted
 200 string" problem can be most efficiently performed when written as:
 201
 202    /"(?:[^"\\]++|\\.)*+"/
 203
 204 as we know that if the final quote does not match, backtracking will not
 205 help. See the independent subexpression C<< (?>...) >> for more details;
 206 possessive quantifiers are just syntactic sugar for that construct. For
 207 instance the above example could also be written as follows:
 208
 209    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
 210
 211 =head3 Escape sequences
 212
 213 Because patterns are processed as double quoted strings, the following
 214 also work:
 215 X<\t> X<\n> X<\r> X<\f> X<\e> X<\a> X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q>
 216 X<\0> X<\c> X<\N> X<\x>
 217
 218     \t          tab                   (HT, TAB)
 219     \n          newline               (LF, NL)
 220     \r          return                (CR)
 221     \f          form feed             (FF)
 222     \a          alarm (bell)          (BEL)
 223     \e          escape (think troff)  (ESC)
 224     \033        octal char            (example: ESC)
 225     \x1B        hex char              (example: ESC)
 226     \x{263a}    long hex char         (example: Unicode SMILEY)
 227     \cK         control char          (example: VT)
 228     \N{name}    named Unicode character
 229     \l          lowercase next char (think vi)
 230     \u          uppercase next char (think vi)
 231     \L          lowercase till \E (think vi)
 232     \U          uppercase till \E (think vi)
 233     \E          end case modification (think vi)
 234     \Q          quote (disable) pattern metacharacters till \E
 235
 236 If C<use locale> is in effect, the case map used by C<\l>, C<\L>, C<\u>
 237 and C<\U> is taken from the current locale.  See L<perllocale>.  For
 238 documentation of C<\N{name}>, see L<charnames>.
 239
 240 You cannot include a literal C<$> or C<@> within a C<\Q> sequence.
 241 An unescaped C<$> or C<@> interpolates the corresponding variable,
 242 while escaping will cause the literal string C<\$> to be matched.
 243 You'll need to write something like C<m/\Quser\E\@\Qhost/>.
 244
 245 =head3 Character Classes and other Special Escapes
 246
 247 In addition, Perl defines the following:
 248 X<\w> X<\W> X<\s> X<\S> X<\d> X<\D> X<\X> X<\p> X<\P> X<\C>
 249 X<\g> X<\k> X<\N> X<\K> X<\v> X<\V> X<\h> X<\H>
 250 X<word> X<whitespace> X<character class> X<backreference>
 251
 252     \w       Match a "word" character (alphanumeric plus "_")
 253     \W       Match a non-"word" character
 254     \s       Match a whitespace character
 255     \S       Match a non-whitespace character
 256     \d       Match a digit character
 257     \D       Match a non-digit character
 258     \pP      Match P, named property.  Use \p{Prop} for longer names.
 259     \PP      Match non-P
 260     \X       Match eXtended Unicode "combining character sequence",
 261              equivalent to (?>\PM\pM*)
 262     \C       Match a single C char (octet) even under Unicode.
 263              NOTE: breaks up characters into their UTF-8 bytes,
 264              so you may end up with malformed pieces of UTF-8.
 265              Unsupported in lookbehind.
 266     \1       Backreference to a specific group.
 267              '1' may actually be any positive integer.
 268     \g1      Backreference to a specific or previous group,
 269     \g{-1}   number may be negative indicating a previous buffer and may
 270              optionally be wrapped in curly brackets for safer parsing.
 271     \g{name} Named backreference
 272     \k<name> Named backreference
 273     \K       Keep the stuff left of the \K, don't include it in $&
 274     \v       Vertical whitespace
 275     \V       Not vertical whitespace
 276     \h       Horizontal whitespace
 277     \H       Not horizontal whitespace
 278     \R       Linebreak
 279
 280 A C<\w> matches a single alphanumeric character (an alphabetic
 281 character, or a decimal digit) or C<_>, not a whole word.  Use C<\w+>
 282 to match a string of Perl-identifier characters (which isn't the same
 283 as matching an English word).  If C<use locale> is in effect, the list
 284 of alphabetic characters generated by C<\w> is taken from the current
 285 locale.  See L<perllocale>.  You may use C<\w>, C<\W>, C<\s>, C<\S>,
 286 C<\d>, and C<\D> within character classes, but they aren't usable
 287 as either end of a range. If any of them precedes or follows a "-",
 288 the "-" is understood literally. If Unicode is in effect, C<\s> matches
 289 also "\x{85}", "\x{2028}", and "\x{2029}". See L<perlunicode> for more
 290 details about C<\pP>, C<\PP>, C<\X> and the possibility of defining
 291 your own C<\p> and C<\P> properties, and L<perluniintro> about Unicode
 292 in general.
 293 X<\w> X<\W> X<word>
 294
 295 C<\R> will atomically match a linebreak, including the network line-ending
 296 "\x0D\x0A".  Specifically, X<\R> is exactly equivalent to
 297
 298   (?>\x0D\x0A?|[\x0A-\x0C\x85\x{2028}\x{2029}])
 299
 300 B<Note:> C<\R> has no special meaning inside of a character class;
 301 use C<\v> instead (vertical whitespace).
 302 X<\R>
 303
 304 The POSIX character class syntax
 305 X<character class>
 306
 307     [:class:]
 308
 309 is also available.  Note that the C<[> and C<]> brackets are I<literal>;
 310 they must always be used within a character class expression.
 311
 312     # this is correct:
 313     $string =~ /[[:alpha:]]/;
 314
 315     # this is not, and will generate a warning:
 316     $string =~ /[:alpha:]/;
 317
 318 The available classes and their backslash equivalents (if available) are
 319 as follows:
 320 X<character class>
 321 X<alpha> X<alnum> X<ascii> X<blank> X<cntrl> X<digit> X<graph>
 322 X<lower> X<print> X<punct> X<space> X<upper> X<word> X<xdigit>
 323
 324     alpha
 325     alnum
 326     ascii
 327     blank               [1]
 328     cntrl
 329     digit       \d
 330     graph
 331     lower
 332     print
 333     punct
 334     space       \s      [2]
 335     upper
 336     word        \w      [3]
 337     xdigit
 338
 339 =over
 340
 341 =item [1]
 342
 343 A GNU extension equivalent to C<[ \t]>, "all horizontal whitespace".
 344
 345 =item [2]
 346
 347 Not exactly equivalent to C<\s> since the C<[[:space:]]> includes
 348 also the (very rare) "vertical tabulator", "\cK" or chr(11) in ASCII.
 349
 350 =item [3]
 351
 352 A Perl extension, see above.
 353
 354 =back
 355
 356 For example use C<[:upper:]> to match all the uppercase characters.
 357 Note that the C<[]> are part of the C<[::]> construct, not part of the
 358 whole character class.  For example:
 359
 360     [01[:alpha:]%]
 361
 362 matches zero, one, any alphabetic character, and the percent sign.
 363
 364 The following equivalences to Unicode \p{} constructs and equivalent
 365 backslash character classes (if available), will hold:
 366 X<character class> X<\p> X<\p{}>
 367
 368     [[:...:]]   \p{...}         backslash
 369
 370     alpha       IsAlpha
 371     alnum       IsAlnum
 372     ascii       IsASCII
 373     blank
 374     cntrl       IsCntrl
 375     digit       IsDigit        \d
 376     graph       IsGraph
 377     lower       IsLower
 378     print       IsPrint         (but see [2] below)
 379     punct       IsPunct         (but see [3] below)
 380     space       IsSpace
 381                 IsSpacePerl    \s
 382     upper       IsUpper
 383     word        IsWord         \w
 384     xdigit      IsXDigit
 385
 386 For example C<[[:lower:]]> and C<\p{IsLower}> are equivalent.
 387
 388 However, the equivalence between C<[[:xxxxx:]]> and C<\p{IsXxxxx}>
 389 is not exact.
 390
 391 =over 4
 392
 393 =item [1]
 394
 395 If the C<utf8> pragma is not used but the C<locale> pragma is, the
 396 classes correlate with the usual isalpha(3) interface (except for
 397 "word" and "blank").
 398
 399 But if the C<locale> or C<encoding> pragmas are not used and
 400 the string is not C<utf8>, then C<[[:xxxxx:]]> (and C<\w>, etc.)
 401 will not match characters 0x80-0xff; whereas C<\p{IsXxxxx}> will
 402 force the string to C<utf8> and can match these characters
 403 (as Unicode).
 404
 405 =item [2]
 406
 407 C<\p{IsPrint}> matches characters 0x09-0x0d but C<[[:print:]]> does not.
 408
 409 =item [3]
 410
 411 C<[[:punct::]]> matches the following but C<\p{IsPunct}> does not,
 412 because they are classed as symbols (not punctuation) in Unicode.
 413
 414 =over 4
 415
 416 =item C<$>
 417
 418 Currency symbol
 419
 420 =item C<+> C<< < >> C<=> C<< > >> C<|> C<~>
 421
 422 Mathematical symbols
 423
 424 =item C<^> C<`>
 425
 426 Modifier symbols (accents)
 427
 428 =back
 429
 430 =back
 431
 432 The other named classes are:
 433
 434 =over 4
 435
 436 =item cntrl
 437 X<cntrl>
 438
 439 Any control character.  Usually characters that don't produce output as
 440 such but instead control the terminal somehow: for example newline and
 441 backspace are control characters.  All characters with ord() less than
 442 32 are usually classified as control characters (assuming ASCII,
 443 the ISO Latin character sets, and Unicode), as is the character with
 444 the ord() value of 127 (C<DEL>).
 445
 446 =item graph
 447 X<graph>
 448
 449 Any alphanumeric or punctuation (special) character.
 450
 451 =item print
 452 X<print>
 453
 454 Any alphanumeric or punctuation (special) character or the space character.
 455
 456 =item punct
 457 X<punct>
 458
 459 Any punctuation (special) character.
 460
 461 =item xdigit
 462 X<xdigit>
 463
 464 Any hexadecimal digit.  Though this may feel silly ([0-9A-Fa-f] would
 465 work just fine) it is included for completeness.
 466
 467 =back
 468
 469 You can negate the [::] character classes by prefixing the class name
 470 with a '^'. This is a Perl extension.  For example:
 471 X<character class, negation>
 472
 473     POSIX         traditional  Unicode
 474
 475     [[:^digit:]]    \D         \P{IsDigit}
 476     [[:^space:]]    \S         \P{IsSpace}
 477     [[:^word:]]     \W         \P{IsWord}
 478
 479 Perl respects the POSIX standard in that POSIX character classes are
 480 only supported within a character class.  The POSIX character classes
 481 [.cc.] and [=cc=] are recognized but B<not> supported and trying to
 482 use them will cause an error.
 483
 484 =head3 Assertions
 485
 486 Perl defines the following zero-width assertions:
 487 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
 488 X<regexp, zero-width assertion>
 489 X<regular expression, zero-width assertion>
 490 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
 491
 492     \b  Match a word boundary
 493     \B  Match except at a word boundary
 494     \A  Match only at beginning of string
 495     \Z  Match only at end of string, or before newline at the end
 496     \z  Match only at end of string
 497     \G  Match only at pos() (e.g. at the end-of-match position
 498         of prior m//g)
 499
 500 A word boundary (C<\b>) is a spot between two characters
 501 that has a C<\w> on one side of it and a C<\W> on the other side
 502 of it (in either order), counting the imaginary characters off the
 503 beginning and end of the string as matching a C<\W>.  (Within
 504 character classes C<\b> represents backspace rather than a word
 505 boundary, just as it normally does in any double-quoted string.)
 506 The C<\A> and C<\Z> are just like "^" and "$", except that they
 507 won't match multiple times when the C</m> modifier is used, while
 508 "^" and "$" will match at every internal line boundary.  To match
 509 the actual end of the string and not ignore an optional trailing
 510 newline, use C<\z>.
 511 X<\b> X<\A> X<\Z> X<\z> X</m>
 512
 513 The C<\G> assertion can be used to chain global matches (using
 514 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
 515 It is also useful when writing C<lex>-like scanners, when you have
 516 several patterns that you want to match against consequent substrings
 517 of your string, see the previous reference.  The actual location
 518 where C<\G> will match can also be influenced by using C<pos()> as
 519 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
 520 matches is modified somewhat, in that contents to the left of C<\G> is
 521 not counted when determining the length of the match. Thus the following
 522 will not match forever:
 523 X<\G>
 524
 525     $str = 'ABC';
 526     pos($str) = 1;
 527     while (/.\G/g) {
 528         print $&;
 529     }
 530
 531 It will print 'A' and then terminate, as it considers the match to
 532 be zero-width, and thus will not match at the same position twice in a
 533 row.
 534
 535 It is worth noting that C<\G> improperly used can result in an infinite
 536 loop. Take care when using patterns that include C<\G> in an alternation.
 537
 538 =head3 Capture buffers
 539
 540 The bracketing construct C<( ... )> creates capture buffers. To refer
 541 to the current contents of a buffer later on, within the same pattern,
 542 use \1 for the first, \2 for the second, and so on.
 543 Outside the match use "$" instead of "\".  (The
 544 \<digit> notation works in certain circumstances outside
 545 the match.  See the warning below about \1 vs $1 for details.)
 546 Referring back to another part of the match is called a
 547 I<backreference>.
 548 X<regex, capture buffer> X<regexp, capture buffer>
 549 X<regular expression, capture buffer> X<backreference>
 550
 551 There is no limit to the number of captured substrings that you may
 552 use.  However Perl also uses \10, \11, etc. as aliases for \010,
 553 \011, etc.  (Recall that 0 means octal, so \011 is the character at
 554 number 9 in your coded character set; which would be the 10th character,
 555 a horizontal tab under ASCII.)  Perl resolves this
 556 ambiguity by interpreting \10 as a backreference only if at least 10
 557 left parentheses have opened before it.  Likewise \11 is a
 558 backreference only if at least 11 left parentheses have opened
 559 before it.  And so on.  \1 through \9 are always interpreted as
 560 backreferences.
 561
 562 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
 563 In order to provide a safer and easier way to construct patterns using
 564 backreferences, Perl provides the C<\g{N}> notation (starting with perl
 565 5.10.0). The curly brackets are optional, however omitting them is less
 566 safe as the meaning of the pattern can be changed by text (such as digits)
 567 following it. When N is a positive integer the C<\g{N}> notation is
 568 exactly equivalent to using normal backreferences. When N is a negative
 569 integer then it is a relative backreference referring to the previous N'th
 570 capturing group. When the bracket form is used and N is not an integer, it
 571 is treated as a reference to a named buffer.
 572
 573 Thus C<\g{-1}> refers to the last buffer, C<\g{-2}> refers to the
 574 buffer before that. For example:
 575
 576         /
 577          (Y)            # buffer 1
 578          (              # buffer 2
 579             (X)         # buffer 3
 580             \g{-1}      # backref to buffer 3
 581             \g{-3}      # backref to buffer 1
 582          )
 583         /x
 584
 585 and would match the same as C</(Y) ( (X) \3 \1 )/x>.
 586
 587 Additionally, as of Perl 5.10.0 you may use named capture buffers and named
 588 backreferences. The notation is C<< (?<name>...) >> to declare and C<< \k<name> >>
 589 to reference. You may also use apostrophes instead of angle brackets to delimit the
 590 name; and you may use the bracketed C<< \g{name} >> backreference syntax.
 591 It's possible to refer to a named capture buffer by absolute and relative number as well.
 592 Outside the pattern, a named capture buffer is available via the C<%+> hash.
 593 When different buffers within the same pattern have the same name, C<$+{name}>
 594 and C<< \k<name> >> refer to the leftmost defined group. (Thus it's possible
 595 to do things with named capture buffers that would otherwise require C<(??{})>
 596 code to accomplish.)
 597 X<named capture buffer> X<regular expression, named capture buffer>
 598 X<%+> X<$+{name}> X<< \k<name> >>
 599
 600 Examples:
 601
 602     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
 603
 604     /(.)\1/                         # find first doubled char
 605          and print "'$1' is the first doubled character\n";
 606
 607     /(?<char>.)\k<char>/            # ... a different way
 608          and print "'$+{char}' is the first doubled character\n";
 609
 610     /(?'char'.)\1/                  # ... mix and match
 611          and print "'$1' is the first doubled character\n";
 612
 613     if (/Time: (..):(..):(..)/) {   # parse out values
 614         $hours = $1;
 615         $minutes = $2;
 616         $seconds = $3;
 617     }
 618
 619 Several special variables also refer back to portions of the previous
 620 match.  C<$+> returns whatever the last bracket match matched.
 621 C<$&> returns the entire matched string.  (At one point C<$0> did
 622 also, but now it returns the name of the program.)  C<$`> returns
 623 everything before the matched string.  C<$'> returns everything
 624 after the matched string. And C<$^N> contains whatever was matched by
 625 the most-recently closed group (submatch). C<$^N> can be used in
 626 extended patterns (see below), for example to assign a submatch to a
 627 variable.
 628 X<$+> X<$^N> X<$&> X<$`> X<$'>
 629
 630 The numbered match variables ($1, $2, $3, etc.) and the related punctuation
 631 set (C<$+>, C<$&>, C<$`>, C<$'>, and C<$^N>) are all dynamically scoped
 632 until the end of the enclosing block or until the next successful
 633 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
 634 X<$+> X<$^N> X<$&> X<$`> X<$'>
 635 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
 636
 637
 638 B<NOTE>: Failed matches in Perl do not reset the match variables,
 639 which makes it easier to write code that tests for a series of more
 640 specific cases and remembers the best match.
 641
 642 B<WARNING>: Once Perl sees that you need one of C<$&>, C<$`>, or
 643 C<$'> anywhere in the program, it has to provide them for every
 644 pattern match.  This may substantially slow your program.  Perl
 645 uses the same mechanism to produce $1, $2, etc, so you also pay a
 646 price for each pattern that contains capturing parentheses.  (To
 647 avoid this cost while retaining the grouping behaviour, use the
 648 extended regular expression C<(?: ... )> instead.)  But if you never
 649 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
 650 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
 651 if you can, but if you can't (and some algorithms really appreciate
 652 them), once you've used them once, use them at will, because you've
 653 already paid the price.  As of 5.005, C<$&> is not so costly as the
 654 other two.
 655 X<$&> X<$`> X<$'>
 656
 657 As a workaround for this problem, Perl 5.10.0 introduces C<${^PREMATCH}>,
 658 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
 659 and C<$'>, B<except> that they are only guaranteed to be defined after a
 660 successful match that was executed with the C</p> (preserve) modifier.
 661 The use of these variables incurs no global performance penalty, unlike
 662 their punctuation char equivalents, however at the trade-off that you
 663 have to tell perl when you want to use them.
 664 X</p> X<p modifier>
 665
 666 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
 667 C<\w>, C<\n>.  Unlike some other regular expression languages, there
 668 are no backslashed symbols that aren't alphanumeric.  So anything
 669 that looks like \\, \(, \), \<, \>, \{, or \} is always
 670 interpreted as a literal character, not a metacharacter.  This was
 671 once used in a common idiom to disable or quote the special meanings
 672 of regular expression metacharacters in a string that you want to
 673 use for a pattern. Simply quote all non-"word" characters:
 674
 675     $pattern =~ s/(\W)/\\$1/g;
 676
 677 (If C<use locale> is set, then this depends on the current locale.)
 678 Today it is more common to use the quotemeta() function or the C<\Q>
 679 metaquoting escape sequence to disable all metacharacters' special
 680 meanings like this:
 681
 682     /$unquoted\Q$quoted\E$unquoted/
 683
 684 Beware that if you put literal backslashes (those not inside
 685 interpolated variables) between C<\Q> and C<\E>, double-quotish
 686 backslash interpolation may lead to confusing results.  If you
 687 I<need> to use literal backslashes within C<\Q...\E>,
 688 consult L<perlop/"Gory details of parsing quoted constructs">.
 689
 690 =head2 Extended Patterns
 691
 692 Perl also defines a consistent extension syntax for features not
 693 found in standard tools like B<awk> and B<lex>.  The syntax is a
 694 pair of parentheses with a question mark as the first thing within
 695 the parentheses.  The character after the question mark indicates
 696 the extension.
 697
 698 The stability of these extensions varies widely.  Some have been
 699 part of the core language for many years.  Others are experimental
 700 and may change without warning or be completely removed.  Check
 701 the documentation on an individual feature to verify its current
 702 status.
 703
 704 A question mark was chosen for this and for the minimal-matching
 705 construct because 1) question marks are rare in older regular
 706 expressions, and 2) whenever you see one, you should stop and
 707 "question" exactly what is going on.  That's psychology...
 708
 709 =over 10
 710
 711 =item C<(?#text)>
 712 X<(?#)>
 713
 714 A comment.  The text is ignored.  If the C</x> modifier enables
 715 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
 716 the comment as soon as it sees a C<)>, so there is no way to put a literal
 717 C<)> in the comment.
 718
 719 =item C<(?pimsx-imsx)>
 720 X<(?)>
 721
 722 One or more embedded pattern-match modifiers, to be turned on (or
 723 turned off, if preceded by C<->) for the remainder of the pattern or
 724 the remainder of the enclosing pattern group (if any). This is
 725 particularly useful for dynamic patterns, such as those read in from a
 726 configuration file, taken from an argument, or specified in a table
 727 somewhere.  Consider the case where some patterns want to be case
 728 sensitive and some do not:  The case insensitive ones merely need to
 729 include C<(?i)> at the front of the pattern.  For example:
 730
 731     $pattern = "foobar";
 732     if ( /$pattern/i ) { }
 733
 734     # more flexible:
 735
 736     $pattern = "(?i)foobar";
 737     if ( /$pattern/ ) { }
 738
 739 These modifiers are restored at the end of the enclosing group. For example,
 740
 741     ( (?i) blah ) \s+ \1
 742
 743 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
 744 repetition of the previous word, assuming the C</x> modifier, and no C</i>
 745 modifier outside this group.
 746
 747 Note that the C<p> modifier is special in that it can only be enabled,
 748 not disabled, and that its presence anywhere in a pattern has a global
 749 effect. Thus C<(?-p)> and C<(?-p:...)> are meaningless and will warn
 750 when executed under C<use warnings>.
 751
 752 =item C<(?:pattern)>
 753 X<(?:)>
 754
 755 =item C<(?imsx-imsx:pattern)>
 756
 757 This is for clustering, not capturing; it groups subexpressions like
 758 "()", but doesn't make backreferences as "()" does.  So
 759
 760     @fields = split(/\b(?:a|b|c)\b/)
 761
 762 is like
 763
 764     @fields = split(/\b(a|b|c)\b/)
 765
 766 but doesn't spit out extra fields.  It's also cheaper not to capture
 767 characters if you don't need to.
 768
 769 Any letters between C<?> and C<:> act as flags modifiers as with
 770 C<(?imsx-imsx)>.  For example,
 771
 772     /(?s-i:more.*than).*million/i
 773
 774 is equivalent to the more verbose
 775
 776     /(?:(?s-i)more.*than).*million/i
 777
 778 =item C<(?|pattern)>
 779 X<(?|)> X<Branch reset>
 780
 781 This is the "branch reset" pattern, which has the special property
 782 that the capture buffers are numbered from the same starting point
 783 in each alternation branch. It is available starting from perl 5.10.0.
 784
 785 Capture buffers are numbered from left to right, but inside this
 786 construct the numbering is restarted for each branch.
 787
 788 The numbering within each branch will be as normal, and any buffers
 789 following this construct will be numbered as though the construct
 790 contained only one branch, that being the one with the most capture
 791 buffers in it.
 792
 793 This construct will be useful when you want to capture one of a
 794 number of alternative matches.
 795
 796 Consider the following pattern.  The numbers underneath show in
 797 which buffer the captured content will be stored.
 798
 799
 800     # before  ---------------branch-reset----------- after
 801     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
 802     # 1            2         2  3        2     3     4
 803
 804 Note: as of Perl 5.10.0, branch resets interfere with the contents of
 805 the C<%+> hash, that holds named captures. Consider using C<%-> instead.
 806
 807 =item Look-Around Assertions
 808 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
 809
 810 Look-around assertions are zero width patterns which match a specific
 811 pattern without including it in C<$&>. Positive assertions match when
 812 their subpattern matches, negative assertions match when their subpattern
 813 fails. Look-behind matches text up to the current match position,
 814 look-ahead matches text following the current match position.
 815
 816 =over 4
 817
 818 =item C<(?=pattern)>
 819 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
 820
 821 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
 822 matches a word followed by a tab, without including the tab in C<$&>.
 823
 824 =item C<(?!pattern)>
 825 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
 826
 827 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
 828 matches any occurrence of "foo" that isn't followed by "bar".  Note
 829 however that look-ahead and look-behind are NOT the same thing.  You cannot
 830 use this for look-behind.
 831
 832 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
 833 will not do what you want.  That's because the C<(?!foo)> is just saying that
 834 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
 835 match.  You would have to do something like C</(?!foo)...bar/> for that.   We
 836 say "like" because there's the case of your "bar" not having three characters
 837 before it.  You could cover that this way: C</(?:(?!foo)...|^.{0,2})bar/>.
 838 Sometimes it's still easier just to say:
 839
 840     if (/bar/ && $` !~ /foo$/)
 841
 842 For look-behind see below.
 843
 844 =item C<(?<=pattern)> C<\K>
 845 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
 846
 847 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
 848 matches a word that follows a tab, without including the tab in C<$&>.
 849 Works only for fixed-width look-behind.
 850
 851 There is a special form of this construct, called C<\K>, which causes the
 852 regex engine to "keep" everything it had matched prior to the C<\K> and
 853 not include it in C<$&>. This effectively provides variable length
 854 look-behind. The use of C<\K> inside of another look-around assertion
 855 is allowed, but the behaviour is currently not well defined.
 856
 857 For various reasons C<\K> may be significantly more efficient than the
 858 equivalent C<< (?<=...) >> construct, and it is especially useful in
 859 situations where you want to efficiently remove something following
 860 something else in a string. For instance
 861
 862   s/(foo)bar/$1/g;
 863
 864 can be rewritten as the much more efficient
 865
 866   s/foo\Kbar//g;
 867
 868 =item C<(?<!pattern)>
 869 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
 870
 871 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
 872 matches any occurrence of "foo" that does not follow "bar".  Works
 873 only for fixed-width look-behind.
 874
 875 =back
 876
 877 =item C<(?'NAME'pattern)>
 878
 879 =item C<< (?<NAME>pattern) >>
 880 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
 881
 882 A named capture buffer. Identical in every respect to normal capturing
 883 parentheses C<()> but for the additional fact that C<%+> or C<%-> may be
 884 used after a successful match to refer to a named buffer. See C<perlvar>
 885 for more details on the C<%+> and C<%-> hashes.
 886
 887 If multiple distinct capture buffers have the same name then the
 888 $+{NAME} will refer to the leftmost defined buffer in the match.
 889
 890 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
 891
 892 B<NOTE:> While the notation of this construct is the same as the similar
 893 function in .NET regexes, the behavior is not. In Perl the buffers are
 894 numbered sequentially regardless of being named or not. Thus in the
 895 pattern
 896
 897   /(x)(?<foo>y)(z)/
 898
 899 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
 900 the opposite which is what a .NET regex hacker might expect.
 901
 902 Currently NAME is restricted to simple identifiers only.
 903 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
 904 its Unicode extension (see L<utf8>),
 905 though it isn't extended by the locale (see L<perllocale>).
 906
 907 B<NOTE:> In order to make things easier for programmers with experience
 908 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
 909 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
 910 support the use of single quotes as a delimiter for the name.
 911
 912 =item C<< \k<NAME> >>
 913
 914 =item C<< \k'NAME' >>
 915
 916 Named backreference. Similar to numeric backreferences, except that
 917 the group is designated by name and not number. If multiple groups
 918 have the same name then it refers to the leftmost defined group in
 919 the current match.
 920
 921 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
 922 earlier in the pattern.
 923
 924 Both forms are equivalent.
 925
 926 B<NOTE:> In order to make things easier for programmers with experience
 927 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
 928 may be used instead of C<< \k<NAME> >>.
 929
 930 =item C<(?{ code })>
 931 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
 932
 933 B<WARNING>: This extended regular expression feature is considered
 934 experimental, and may be changed without notice. Code executed that
 935 has side effects may not perform identically from version to version
 936 due to the effect of future optimisations in the regex engine.
 937
 938 This zero-width assertion evaluates any embedded Perl code.  It
 939 always succeeds, and its C<code> is not interpolated.  Currently,
 940 the rules to determine where the C<code> ends are somewhat convoluted.
 941
 942 This feature can be used together with the special variable C<$^N> to
 943 capture the results of submatches in variables without having to keep
 944 track of the number of nested parentheses. For example:
 945
 946   $_ = "The brown fox jumps over the lazy dog";
 947   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
 948   print "color = $color, animal = $animal\n";
 949
 950 Inside the C<(?{...})> block, C<$_> refers to the string the regular
 951 expression is matching against. You can also use C<pos()> to know what is
 952 the current position of matching within this string.
 953
 954 The C<code> is properly scoped in the following sense: If the assertion
 955 is backtracked (compare L<"Backtracking">), all changes introduced after
 956 C<local>ization are undone, so that
 957
 958   $_ = 'a' x 8;
 959   m<
 960      (?{ $cnt = 0 })                    # Initialize $cnt.
 961      (
 962        a
 963        (?{
 964            local $cnt = $cnt + 1;       # Update $cnt, backtracking-safe.
 965        })
 966      )*
 967      aaaa
 968      (?{ $res = $cnt })                 # On success copy to non-localized
 969                                         # location.
 970    >x;
 971
 972 will set C<$res = 4>.  Note that after the match, C<$cnt> returns to the globally
 973 introduced value, because the scopes that restrict C<local> operators
 974 are unwound.
 975
 976 This assertion may be used as a C<(?(condition)yes-pattern|no-pattern)>
 977 switch.  If I<not> used in this way, the result of evaluation of
 978 C<code> is put into the special variable C<$^R>.  This happens
 979 immediately, so C<$^R> can be used from other C<(?{ code })> assertions
 980 inside the same regular expression.
 981
 982 The assignment to C<$^R> above is properly localized, so the old
 983 value of C<$^R> is restored if the assertion is backtracked; compare
 984 L<"Backtracking">.
 985
 986 Due to an unfortunate implementation issue, the Perl code contained in these
 987 blocks is treated as a compile time closure that can have seemingly bizarre
 988 consequences when used with lexically scoped variables inside of subroutines
 989 or loops.  There are various workarounds for this, including simply using
 990 global variables instead.  If you are using this construct and strange results
 991 occur then check for the use of lexically scoped variables.
 992
 993 For reasons of security, this construct is forbidden if the regular
 994 expression involves run-time interpolation of variables, unless the
 995 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
 996 variables contain results of C<qr//> operator (see
 997 L<perlop/"qr/STRING/imosx">).
 998
 999 This restriction is due to the wide-spread and remarkably convenient
1000 custom of using run-time determined strings as patterns.  For example:
1001
1002     $re = <>;
1003     chomp $re;
1004     $string =~ /$re/;
1005
1006 Before Perl knew how to execute interpolated code within a pattern,
1007 this operation was completely safe from a security point of view,
1008 although it could raise an exception from an illegal pattern.  If
1009 you turn on the C<use re 'eval'>, though, it is no longer secure,
1010 so you should only do so if you are also using taint checking.
1011 Better yet, use the carefully constrained evaluation within a Safe
1012 compartment.  See L<perlsec> for details about both these mechanisms.
1013
1014 Because Perl's regex engine is currently not re-entrant, interpolated
1015 code may not invoke the regex engine either directly with C<m//> or C<s///>),
1016 or indirectly with functions such as C<split>.
1017
1018 =item C<(??{ code })>
1019 X<(??{})>
1020 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
1021
1022 B<WARNING>: This extended regular expression feature is considered
1023 experimental, and may be changed without notice. Code executed that
1024 has side effects may not perform identically from version to version
1025 due to the effect of future optimisations in the regex engine.
1026
1027 This is a "postponed" regular subexpression.  The C<code> is evaluated
1028 at run time, at the moment this subexpression may match.  The result
1029 of evaluation is considered as a regular expression and matched as
1030 if it were inserted instead of this construct.  Note that this means
1031 that the contents of capture buffers defined inside an eval'ed pattern
1032 are not available outside of the pattern, and vice versa, there is no
1033 way for the inner pattern to refer to a capture buffer defined outside.
1034 Thus,
1035
1036     ('a' x 100)=~/(??{'(.)' x 100})/
1037
1038 B<will> match, it will B<not> set $1.
1039
1040 The C<code> is not interpolated.  As before, the rules to determine
1041 where the C<code> ends are currently somewhat convoluted.
1042
1043 The following pattern matches a parenthesized group:
1044
1045   $re = qr{
1046              \(
1047              (?:
1048                 (?> [^()]+ )    # Non-parens without backtracking
1049               |
1050                 (??{ $re })     # Group with matching parens
1051              )*
1052              \)
1053           }x;
1054
1055 See also C<(?PARNO)> for a different, more efficient way to accomplish
1056 the same task.
1057
1058 Because perl's regex engine is not currently re-entrant, delayed
1059 code may not invoke the regex engine either directly with C<m//> or C<s///>),
1060 or indirectly with functions such as C<split>.
1061
1062 Recursing deeper than 50 times without consuming any input string will
1063 result in a fatal error.  The maximum depth is compiled into perl, so
1064 changing it requires a custom build.
1065
1066 =item C<(?PARNO)> C<(?-PARNO)> C<(?+PARNO)> C<(?R)> C<(?0)>
1067 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1068 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1069 X<regex, relative recursion>
1070
1071 Similar to C<(??{ code })> except it does not involve compiling any code,
1072 instead it treats the contents of a capture buffer as an independent
1073 pattern that must match at the current position.  Capture buffers
1074 contained by the pattern will have the value as determined by the
1075 outermost recursion.
1076
1077 PARNO is a sequence of digits (not starting with 0) whose value reflects
1078 the paren-number of the capture buffer to recurse to. C<(?R)> recurses to
1079 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1080 C<(?R)>. If PARNO is preceded by a plus or minus sign then it is assumed
1081 to be relative, with negative numbers indicating preceding capture buffers
1082 and positive ones following. Thus C<(?-1)> refers to the most recently
1083 declared buffer, and C<(?+1)> indicates the next buffer to be declared.
1084 Note that the counting for relative recursion differs from that of
1085 relative backreferences, in that with recursion unclosed buffers B<are>
1086 included.
1087
1088 The following pattern matches a function foo() which may contain
1089 balanced parentheses as the argument.
1090
1091   $re = qr{ (                    # paren group 1 (full function)
1092               foo
1093               (                  # paren group 2 (parens)
1094                 \(
1095                   (              # paren group 3 (contents of parens)
1096                   (?:
1097                    (?> [^()]+ )  # Non-parens without backtracking
1098                   |
1099                    (?2)          # Recurse to start of paren group 2
1100                   )*
1101                   )
1102                 \)
1103               )
1104             )
1105           }x;
1106
1107 If the pattern was used as follows
1108
1109     'foo(bar(baz)+baz(bop))'=~/$re/
1110         and print "\$1 = $1\n",
1111                   "\$2 = $2\n",
1112                   "\$3 = $3\n";
1113
1114 the output produced should be the following:
1115
1116     $1 = foo(bar(baz)+baz(bop))
1117     $2 = (bar(baz)+baz(bop))
1118     $3 = bar(baz)+baz(bop)
1119
1120 If there is no corresponding capture buffer defined, then it is a
1121 fatal error.  Recursing deeper than 50 times without consuming any input
1122 string will also result in a fatal error.  The maximum depth is compiled
1123 into perl, so changing it requires a custom build.
1124
1125 The following shows how using negative indexing can make it
1126 easier to embed recursive patterns inside of a C<qr//> construct
1127 for later use:
1128
1129     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1130     if (/foo $parens \s+ + \s+ bar $parens/x) {
1131        # do something here...
1132     }
1133
1134 B<Note> that this pattern does not behave the same way as the equivalent
1135 PCRE or Python construct of the same form. In Perl you can backtrack into
1136 a recursed group, in PCRE and Python the recursed into group is treated
1137 as atomic. Also, modifiers are resolved at compile time, so constructs
1138 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1139 be processed.
1140
1141 =item C<(?&NAME)>
1142 X<(?&NAME)>
1143
1144 Recurse to a named subpattern. Identical to C<(?PARNO)> except that the
1145 parenthesis to recurse to is determined by name. If multiple parentheses have
1146 the same name, then it recurses to the leftmost.
1147
1148 It is an error to refer to a name that is not declared somewhere in the
1149 pattern.
1150
1151 B<NOTE:> In order to make things easier for programmers with experience
1152 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1153 may be used instead of C<< (?&NAME) >>.
1154
1155 =item C<(?(condition)yes-pattern|no-pattern)>
1156 X<(?()>
1157
1158 =item C<(?(condition)yes-pattern)>
1159
1160 Conditional expression.  C<(condition)> should be either an integer in
1161 parentheses (which is valid if the corresponding pair of parentheses
1162 matched), a look-ahead/look-behind/evaluate zero-width assertion, a
1163 name in angle brackets or single quotes (which is valid if a buffer
1164 with the given name matched), or the special symbol (R) (true when
1165 evaluated inside of recursion or eval). Additionally the R may be
1166 followed by a number, (which will be true when evaluated when recursing
1167 inside of the appropriate group), or by C<&NAME>, in which case it will
1168 be true only when evaluated during recursion in the named group.
1169
1170 Here's a summary of the possible predicates:
1171
1172 =over 4
1173
1174 =item (1) (2) ...
1175
1176 Checks if the numbered capturing buffer has matched something.
1177
1178 =item (<NAME>) ('NAME')
1179
1180 Checks if a buffer with the given name has matched something.
1181
1182 =item (?{ CODE })
1183
1184 Treats the code block as the condition.
1185
1186 =item (R)
1187
1188 Checks if the expression has been evaluated inside of recursion.
1189
1190 =item (R1) (R2) ...
1191
1192 Checks if the expression has been evaluated while executing directly
1193 inside of the n-th capture group. This check is the regex equivalent of
1194
1195   if ((caller(0))[3] eq 'subname') { ... }
1196
1197 In other words, it does not check the full recursion stack.
1198
1199 =item (R&NAME)
1200
1201 Similar to C<(R1)>, this predicate checks to see if we're executing
1202 directly inside of the leftmost group with a given name (this is the same
1203 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1204 stack, but only the name of the innermost active recursion.
1205
1206 =item (DEFINE)
1207
1208 In this case, the yes-pattern is never directly executed, and no
1209 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1210 See below for details.
1211
1212 =back
1213
1214 For example:
1215
1216     m{ ( \( )?
1217        [^()]+
1218        (?(1) \) )
1219      }x
1220
1221 matches a chunk of non-parentheses, possibly included in parentheses
1222 themselves.
1223
1224 A special form is the C<(DEFINE)> predicate, which never executes directly
1225 its yes-pattern, and does not allow a no-pattern. This allows to define
1226 subpatterns which will be executed only by using the recursion mechanism.
1227 This way, you can define a set of regular expression rules that can be
1228 bundled into any pattern you choose.
1229
1230 It is recommended that for this usage you put the DEFINE block at the
1231 end of the pattern, and that you name any subpatterns defined within it.
1232
1233 Also, it's worth noting that patterns defined this way probably will
1234 not be as efficient, as the optimiser is not very clever about
1235 handling them.
1236
1237 An example of how this might be used is as follows:
1238
1239   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1240    (?(DEFINE)
1241      (?<NAME_PAT>....)
1242      (?<ADRESS_PAT>....)
1243    )/x
1244
1245 Note that capture buffers matched inside of recursion are not accessible
1246 after the recursion returns, so the extra layer of capturing buffers is
1247 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1248 C<$+{NAME}> would be.
1249
1250 =item C<< (?>pattern) >>
1251 X<backtrack> X<backtracking> X<atomic> X<possessive>
1252
1253 An "independent" subexpression, one which matches the substring
1254 that a I<standalone> C<pattern> would match if anchored at the given
1255 position, and it matches I<nothing other than this substring>.  This
1256 construct is useful for optimizations of what would otherwise be
1257 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1258 It may also be useful in places where the "grab all you can, and do not
1259 give anything back" semantic is desirable.
1260
1261 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1262 (anchored at the beginning of string, as above) will match I<all>
1263 characters C<a> at the beginning of string, leaving no C<a> for
1264 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1265 since the match of the subgroup C<a*> is influenced by the following
1266 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1267 C<a*ab> will match fewer characters than a standalone C<a*>, since
1268 this makes the tail match.
1269
1270 An effect similar to C<< (?>pattern) >> may be achieved by writing
1271 C<(?=(pattern))\1>.  This matches the same substring as a standalone
1272 C<a+>, and the following C<\1> eats the matched string; it therefore
1273 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1274 (The difference between these two constructs is that the second one
1275 uses a capturing group, thus shifting ordinals of backreferences
1276 in the rest of a regular expression.)
1277
1278 Consider this pattern:
1279
1280     m{ \(
1281           (
1282             [^()]+              # x+
1283           |
1284             \( [^()]* \)
1285           )+
1286        \)
1287      }x
1288
1289 That will efficiently match a nonempty group with matching parentheses
1290 two levels deep or less.  However, if there is no such group, it
1291 will take virtually forever on a long string.  That's because there
1292 are so many different ways to split a long string into several
1293 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1294 to a subpattern of the above pattern.  Consider how the pattern
1295 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1296 seconds, but that each extra letter doubles this time.  This
1297 exponential performance will make it appear that your program has
1298 hung.  However, a tiny change to this pattern
1299
1300     m{ \(
1301           (
1302             (?> [^()]+ )        # change x+ above to (?> x+ )
1303           |
1304             \( [^()]* \)
1305           )+
1306        \)
1307      }x
1308
1309 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1310 this yourself would be a productive exercise), but finishes in a fourth
1311 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1312 however, that this pattern currently triggers a warning message under
1313 the C<use warnings> pragma or B<-w> switch saying it
1314 C<"matches null string many times in regex">.
1315
1316 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1317 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1318 This was only 4 times slower on a string with 1000000 C<a>s.
1319
1320 The "grab all you can, and do not give anything back" semantic is desirable
1321 in many situations where on the first sight a simple C<()*> looks like
1322 the correct solution.  Suppose we parse text with comments being delimited
1323 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1324 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1325 the comment delimiter, because it may "give up" some whitespace if
1326 the remainder of the pattern can be made to match that way.  The correct
1327 answer is either one of these:
1328
1329     (?>#[ \t]*)
1330     #[ \t]*(?![ \t])
1331
1332 For example, to grab non-empty comments into $1, one should use either
1333 one of these:
1334
1335     / (?> \# [ \t]* ) (        .+ ) /x;
1336     /     \# [ \t]*   ( [^ \t] .* ) /x;
1337
1338 Which one you pick depends on which of these expressions better reflects
1339 the above specification of comments.
1340
1341 In some literature this construct is called "atomic matching" or
1342 "possessive matching".
1343
1344 Possessive quantifiers are equivalent to putting the item they are applied
1345 to inside of one of these constructs. The following equivalences apply:
1346
1347     Quantifier Form     Bracketing Form
1348     ---------------     ---------------
1349     PAT*+               (?>PAT*)
1350     PAT++               (?>PAT+)
1351     PAT?+               (?>PAT?)
1352     PAT{min,max}+       (?>PAT{min,max})
1353
1354 =back
1355
1356 =head2 Special Backtracking Control Verbs
1357
1358 B<WARNING:> These patterns are experimental and subject to change or
1359 removal in a future version of Perl. Their usage in production code should
1360 be noted to avoid problems during upgrades.
1361
1362 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1363 otherwise stated the ARG argument is optional; in some cases, it is
1364 forbidden.
1365
1366 Any pattern containing a special backtracking verb that allows an argument
1367 has the special behaviour that when executed it sets the current packages'
1368 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1369 rules apply:
1370
1371 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1372 verb pattern, if the verb was involved in the failure of the match. If the
1373 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1374 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1375 none. Also, the C<$REGMARK> variable will be set to FALSE.
1376
1377 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1378 the C<$REGMARK> variable will be set to the name of the last
1379 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1380 C<(*MARK:NAME)> verb below for more details.
1381
1382 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1383 and most other regex related variables. They are not local to a scope, nor
1384 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1385 Use C<local> to localize changes to them to a specific scope if necessary.
1386
1387 If a pattern does not contain a special backtracking verb that allows an
1388 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1389
1390 =over 4
1391
1392 =item Verbs that take an argument
1393
1394 =over 4
1395
1396 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1397 X<(*PRUNE)> X<(*PRUNE:NAME)>
1398
1399 This zero-width pattern prunes the backtracking tree at the current point
1400 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1401 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1402 A may backtrack as necessary to match. Once it is reached, matching
1403 continues in B, which may also backtrack as necessary; however, should B
1404 not match, then no further backtracking will take place, and the pattern
1405 will fail outright at the current starting position.
1406
1407 The following example counts all the possible matching strings in a
1408 pattern (without actually matching any of them).
1409
1410     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1411     print "Count=$count\n";
1412
1413 which produces:
1414
1415     aaab
1416     aaa
1417     aa
1418     a
1419     aab
1420     aa
1421     a
1422     ab
1423     a
1424     Count=9
1425
1426 If we add a C<(*PRUNE)> before the count like the following
1427
1428     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1429     print "Count=$count\n";
1430
1431 we prevent backtracking and find the count of the longest matching
1432 at each matching starting point like so:
1433
1434     aaab
1435     aab
1436     ab
1437     Count=3
1438
1439 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1440
1441 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1442 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1443 replaced with a C<< (?>pattern) >> with no functional difference; however,
1444 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1445 C<< (?>pattern) >> alone.
1446
1447
1448 =item C<(*SKIP)> C<(*SKIP:NAME)>
1449 X<(*SKIP)>
1450
1451 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1452 failure it also signifies that whatever text that was matched leading up
1453 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1454 of this pattern. This effectively means that the regex engine "skips" forward
1455 to this position on failure and tries to match again, (assuming that
1456 there is sufficient room to match).
1457
1458 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1459 C<(*MARK:NAME)> was encountered while matching, then it is that position
1460 which is used as the "skip point". If no C<(*MARK)> of that name was
1461 encountered, then the C<(*SKIP)> operator has no effect. When used
1462 without a name the "skip point" is where the match point was when
1463 executing the (*SKIP) pattern.
1464
1465 Compare the following to the examples in C<(*PRUNE)>, note the string
1466 is twice as long:
1467
1468     'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1469     print "Count=$count\n";
1470
1471 outputs
1472
1473     aaab
1474     aaab
1475     Count=2
1476
1477 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1478 executed, the next starting point will be where the cursor was when the
1479 C<(*SKIP)> was executed.
1480
1481 =item C<(*MARK:NAME)> C<(*:NAME)>
1482 X<(*MARK)> C<(*MARK:NAME)> C<(*:NAME)>
1483
1484 This zero-width pattern can be used to mark the point reached in a string
1485 when a certain part of the pattern has been successfully matched. This
1486 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1487 forward to that point if backtracked into on failure. Any number of
1488 C<(*MARK)> patterns are allowed, and the NAME portion is optional and may
1489 be duplicated.
1490
1491 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1492 can be used to "label" a pattern branch, so that after matching, the
1493 program can determine which branches of the pattern were involved in the
1494 match.
1495
1496 When a match is successful, the C<$REGMARK> variable will be set to the
1497 name of the most recently executed C<(*MARK:NAME)> that was involved
1498 in the match.
1499
1500 This can be used to determine which branch of a pattern was matched
1501 without using a separate capture buffer for each branch, which in turn
1502 can result in a performance improvement, as perl cannot optimize
1503 C</(?:(x)|(y)|(z))/> as efficiently as something like
1504 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1505
1506 When a match has failed, and unless another verb has been involved in
1507 failing the match and has provided its own name to use, the C<$REGERROR>
1508 variable will be set to the name of the most recently executed
1509 C<(*MARK:NAME)>.
1510
1511 See C<(*SKIP)> for more details.
1512
1513 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1514
1515 =item C<(*THEN)> C<(*THEN:NAME)>
1516
1517 This is similar to the "cut group" operator C<::> from Perl 6. Like
1518 C<(*PRUNE)>, this verb always matches, and when backtracked into on
1519 failure, it causes the regex engine to try the next alternation in the
1520 innermost enclosing group (capturing or otherwise).
1521
1522 Its name comes from the observation that this operation combined with the
1523 alternation operator (C<|>) can be used to create what is essentially a
1524 pattern-based if/then/else block:
1525
1526   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1527
1528 Note that if this operator is used and NOT inside of an alternation then
1529 it acts exactly like the C<(*PRUNE)> operator.
1530
1531   / A (*PRUNE) B /
1532
1533 is the same as
1534
1535   / A (*THEN) B /
1536
1537 but
1538
1539   / ( A (*THEN) B | C (*THEN) D ) /
1540
1541 is not the same as
1542
1543   / ( A (*PRUNE) B | C (*PRUNE) D ) /
1544
1545 as after matching the A but failing on the B the C<(*THEN)> verb will
1546 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
1547
1548 =item C<(*COMMIT)>
1549 X<(*COMMIT)>
1550
1551 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
1552 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
1553 into on failure it causes the match to fail outright. No further attempts
1554 to find a valid match by advancing the start pointer will occur again.
1555 For example,
1556
1557     'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
1558     print "Count=$count\n";
1559
1560 outputs
1561
1562     aaab
1563     Count=1
1564
1565 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
1566 does not match, the regex engine will not try any further matching on the
1567 rest of the string.
1568
1569 =back
1570
1571 =item Verbs without an argument
1572
1573 =over 4
1574
1575 =item C<(*FAIL)> C<(*F)>
1576 X<(*FAIL)> X<(*F)>
1577
1578 This pattern matches nothing and always fails. It can be used to force the
1579 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
1580 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
1581
1582 It is probably useful only when combined with C<(?{})> or C<(??{})>.
1583
1584 =item C<(*ACCEPT)>
1585 X<(*ACCEPT)>
1586
1587 B<WARNING:> This feature is highly experimental. It is not recommended
1588 for production code.
1589
1590 This pattern matches nothing and causes the end of successful matching at
1591 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
1592 whether there is actually more to match in the string. When inside of a
1593 nested pattern, such as recursion, or in a subpattern dynamically generated
1594 via C<(??{})>, only the innermost pattern is ended immediately.
1595
1596 If the C<(*ACCEPT)> is inside of capturing buffers then the buffers are
1597 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
1598 For instance:
1599
1600   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
1601
1602 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
1603 be set. If another branch in the inner parentheses were matched, such as in the
1604 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
1605
1606 =back
1607
1608 =back
1609
1610 =head2 Backtracking
1611 X<backtrack> X<backtracking>
1612
1613 NOTE: This section presents an abstract approximation of regular
1614 expression behavior.  For a more rigorous (and complicated) view of
1615 the rules involved in selecting a match among possible alternatives,
1616 see L<Combining RE Pieces>.
1617
1618 A fundamental feature of regular expression matching involves the
1619 notion called I<backtracking>, which is currently used (when needed)
1620 by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
1621 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
1622 internally, but the general principle outlined here is valid.
1623
1624 For a regular expression to match, the I<entire> regular expression must
1625 match, not just part of it.  So if the beginning of a pattern containing a
1626 quantifier succeeds in a way that causes later parts in the pattern to
1627 fail, the matching engine backs up and recalculates the beginning
1628 part--that's why it's called backtracking.
1629
1630 Here is an example of backtracking:  Let's say you want to find the
1631 word following "foo" in the string "Food is on the foo table.":
1632
1633     $_ = "Food is on the foo table.";
1634     if ( /\b(foo)\s+(\w+)/i ) {
1635         print "$2 follows $1.\n";
1636     }
1637
1638 When the match runs, the first part of the regular expression (C<\b(foo)>)
1639 finds a possible match right at the beginning of the string, and loads up
1640 $1 with "Foo".  However, as soon as the matching engine sees that there's
1641 no whitespace following the "Foo" that it had saved in $1, it realizes its
1642 mistake and starts over again one character after where it had the
1643 tentative match.  This time it goes all the way until the next occurrence
1644 of "foo". The complete regular expression matches this time, and you get
1645 the expected output of "table follows foo."
1646
1647 Sometimes minimal matching can help a lot.  Imagine you'd like to match
1648 everything between "foo" and "bar".  Initially, you write something
1649 like this:
1650
1651     $_ =  "The food is under the bar in the barn.";
1652     if ( /foo(.*)bar/ ) {
1653         print "got <$1>\n";
1654     }
1655
1656 Which perhaps unexpectedly yields:
1657
1658   got <d is under the bar in the >
1659
1660 That's because C<.*> was greedy, so you get everything between the
1661 I<first> "foo" and the I<last> "bar".  Here it's more effective
1662 to use minimal matching to make sure you get the text between a "foo"
1663 and the first "bar" thereafter.
1664
1665     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
1666   got <d is under the >
1667
1668 Here's another example. Let's say you'd like to match a number at the end
1669 of a string, and you also want to keep the preceding part of the match.
1670 So you write this:
1671
1672     $_ = "I have 2 numbers: 53147";
1673     if ( /(.*)(\d*)/ ) {                                # Wrong!
1674         print "Beginning is <$1>, number is <$2>.\n";
1675     }
1676
1677 That won't work at all, because C<.*> was greedy and gobbled up the
1678 whole string. As C<\d*> can match on an empty string the complete
1679 regular expression matched successfully.
1680
1681     Beginning is <I have 2 numbers: 53147>, number is <>.
1682
1683 Here are some variants, most of which don't work:
1684
1685     $_ = "I have 2 numbers: 53147";
1686     @pats = qw{
1687         (.*)(\d*)
1688         (.*)(\d+)
1689         (.*?)(\d*)
1690         (.*?)(\d+)
1691         (.*)(\d+)$
1692         (.*?)(\d+)$
1693         (.*)\b(\d+)$
1694         (.*\D)(\d+)$
1695     };
1696
1697     for $pat (@pats) {
1698         printf "%-12s ", $pat;
1699         if ( /$pat/ ) {
1700             print "<$1> <$2>\n";
1701         } else {
1702             print "FAIL\n";
1703         }
1704     }
1705
1706 That will print out:
1707
1708     (.*)(\d*)    <I have 2 numbers: 53147> <>
1709     (.*)(\d+)    <I have 2 numbers: 5314> <7>
1710     (.*?)(\d*)   <> <>
1711     (.*?)(\d+)   <I have > <2>
1712     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
1713     (.*?)(\d+)$  <I have 2 numbers: > <53147>
1714     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
1715     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
1716
1717 As you see, this can be a bit tricky.  It's important to realize that a
1718 regular expression is merely a set of assertions that gives a definition
1719 of success.  There may be 0, 1, or several different ways that the
1720 definition might succeed against a particular string.  And if there are
1721 multiple ways it might succeed, you need to understand backtracking to
1722 know which variety of success you will achieve.
1723
1724 When using look-ahead assertions and negations, this can all get even
1725 trickier.  Imagine you'd like to find a sequence of non-digits not
1726 followed by "123".  You might try to write that as
1727
1728     $_ = "ABC123";
1729     if ( /^\D*(?!123)/ ) {              # Wrong!
1730         print "Yup, no 123 in $_\n";
1731     }
1732
1733 But that isn't going to match; at least, not the way you're hoping.  It
1734 claims that there is no 123 in the string.  Here's a clearer picture of
1735 why that pattern matches, contrary to popular expectations:
1736
1737     $x = 'ABC123';
1738     $y = 'ABC445';
1739
1740     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
1741     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
1742
1743     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
1744     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
1745
1746 This prints
1747
1748     2: got ABC
1749     3: got AB
1750     4: got ABC
1751
1752 You might have expected test 3 to fail because it seems to a more
1753 general purpose version of test 1.  The important difference between
1754 them is that test 3 contains a quantifier (C<\D*>) and so can use
1755 backtracking, whereas test 1 will not.  What's happening is
1756 that you've asked "Is it true that at the start of $x, following 0 or more
1757 non-digits, you have something that's not 123?"  If the pattern matcher had
1758 let C<\D*> expand to "ABC", this would have caused the whole pattern to
1759 fail.
1760
1761 The search engine will initially match C<\D*> with "ABC".  Then it will
1762 try to match C<(?!123> with "123", which fails.  But because
1763 a quantifier (C<\D*>) has been used in the regular expression, the
1764 search engine can backtrack and retry the match differently
1765 in the hope of matching the complete regular expression.
1766
1767 The pattern really, I<really> wants to succeed, so it uses the
1768 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
1769 time.  Now there's indeed something following "AB" that is not
1770 "123".  It's "C123", which suffices.
1771
1772 We can deal with this by using both an assertion and a negation.
1773 We'll say that the first part in $1 must be followed both by a digit
1774 and by something that's not "123".  Remember that the look-aheads
1775 are zero-width expressions--they only look, but don't consume any
1776 of the string in their match.  So rewriting this way produces what
1777 you'd expect; that is, case 5 will fail, but case 6 succeeds:
1778
1779     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
1780     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
1781
1782     6: got ABC
1783
1784 In other words, the two zero-width assertions next to each other work as though
1785 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
1786 matches only if you're at the beginning of the line AND the end of the
1787 line simultaneously.  The deeper underlying truth is that juxtaposition in
1788 regular expressions always means AND, except when you write an explicit OR
1789 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
1790 although the attempted matches are made at different positions because "a"
1791 is not a zero-width assertion, but a one-width assertion.
1792
1793 B<WARNING>: Particularly complicated regular expressions can take
1794 exponential time to solve because of the immense number of possible
1795 ways they can use backtracking to try for a match.  For example, without
1796 internal optimizations done by the regular expression engine, this will
1797 take a painfully long time to run:
1798
1799     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
1800
1801 And if you used C<*>'s in the internal groups instead of limiting them
1802 to 0 through 5 matches, then it would take forever--or until you ran
1803 out of stack space.  Moreover, these internal optimizations are not
1804 always applicable.  For example, if you put C<{0,5}> instead of C<*>
1805 on the external group, no current optimization is applicable, and the
1806 match takes a long time to finish.
1807
1808 A powerful tool for optimizing such beasts is what is known as an
1809 "independent group",
1810 which does not backtrack (see L<C<< (?>pattern) >>>).  Note also that
1811 zero-length look-ahead/look-behind assertions will not backtrack to make
1812 the tail match, since they are in "logical" context: only
1813 whether they match is considered relevant.  For an example
1814 where side-effects of look-ahead I<might> have influenced the
1815 following match, see L<C<< (?>pattern) >>>.
1816
1817 =head2 Version 8 Regular Expressions
1818 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
1819
1820 In case you're not familiar with the "regular" Version 8 regex
1821 routines, here are the pattern-matching rules not described above.
1822
1823 Any single character matches itself, unless it is a I<metacharacter>
1824 with a special meaning described here or above.  You can cause
1825 characters that normally function as metacharacters to be interpreted
1826 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
1827 character; "\\" matches a "\"). This escape mechanism is also required
1828 for the character used as the pattern delimiter.
1829
1830 A series of characters matches that series of characters in the target
1831 string, so the pattern  C<blurfl> would match "blurfl" in the target
1832 string.
1833
1834 You can specify a character class, by enclosing a list of characters
1835 in C<[]>, which will match any character from the list.  If the
1836 first character after the "[" is "^", the class matches any character not
1837 in the list.  Within a list, the "-" character specifies a
1838 range, so that C<a-z> represents all characters between "a" and "z",
1839 inclusive.  If you want either "-" or "]" itself to be a member of a
1840 class, put it at the start of the list (possibly after a "^"), or
1841 escape it with a backslash.  "-" is also taken literally when it is
1842 at the end of the list, just before the closing "]".  (The
1843 following all specify the same class of three characters: C<[-az]>,
1844 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
1845 specifies a class containing twenty-six characters, even on EBCDIC-based
1846 character sets.)  Also, if you try to use the character
1847 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
1848 a range, the "-" is understood literally.
1849
1850 Note also that the whole range idea is rather unportable between
1851 character sets--and even within character sets they may cause results
1852 you probably didn't expect.  A sound principle is to use only ranges
1853 that begin from and end at either alphabetics of equal case ([a-e],
1854 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
1855 spell out the character sets in full.
1856
1857 Characters may be specified using a metacharacter syntax much like that
1858 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
1859 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
1860 of octal digits, matches the character whose coded character set value
1861 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
1862 matches the character whose numeric value is I<nn>. The expression \cI<x>
1863 matches the character control-I<x>.  Finally, the "." metacharacter
1864 matches any character except "\n" (unless you use C</s>).
1865
1866 You can specify a series of alternatives for a pattern using "|" to
1867 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
1868 or "foe" in the target string (as would C<f(e|i|o)e>).  The
1869 first alternative includes everything from the last pattern delimiter
1870 ("(", "[", or the beginning of the pattern) up to the first "|", and
1871 the last alternative contains everything from the last "|" to the next
1872 pattern delimiter.  That's why it's common practice to include
1873 alternatives in parentheses: to minimize confusion about where they
1874 start and end.
1875
1876 Alternatives are tried from left to right, so the first
1877 alternative found for which the entire expression matches, is the one that
1878 is chosen. This means that alternatives are not necessarily greedy. For
1879 example: when matching C<foo|foot> against "barefoot", only the "foo"
1880 part will match, as that is the first alternative tried, and it successfully
1881 matches the target string. (This might not seem important, but it is
1882 important when you are capturing matched text using parentheses.)
1883
1884 Also remember that "|" is interpreted as a literal within square brackets,
1885 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
1886
1887 Within a pattern, you may designate subpatterns for later reference
1888 by enclosing them in parentheses, and you may refer back to the
1889 I<n>th subpattern later in the pattern using the metacharacter
1890 \I<n>.  Subpatterns are numbered based on the left to right order
1891 of their opening parenthesis.  A backreference matches whatever
1892 actually matched the subpattern in the string being examined, not
1893 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\1\d*> will
1894 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
1895 1 matched "0x", even though the rule C<0|0x> could potentially match
1896 the leading 0 in the second number.
1897
1898 =head2 Warning on \1 Instead of $1
1899
1900 Some people get too used to writing things like:
1901
1902     $pattern =~ s/(\W)/\\\1/g;
1903
1904 This is grandfathered for the RHS of a substitute to avoid shocking the
1905 B<sed> addicts, but it's a dirty habit to get into.  That's because in
1906 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
1907 the usual double-quoted string means a control-A.  The customary Unix
1908 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
1909 of doing that, you get yourself into trouble if you then add an C</e>
1910 modifier.
1911
1912     s/(\d+)/ \1 + 1 /eg;        # causes warning under -w
1913
1914 Or if you try to do
1915
1916     s/(\d+)/\1000/;
1917
1918 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
1919 C<${1}000>.  The operation of interpolation should not be confused
1920 with the operation of matching a backreference.  Certainly they mean two
1921 different things on the I<left> side of the C<s///>.
1922
1923 =head2 Repeated Patterns Matching a Zero-length Substring
1924
1925 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
1926
1927 Regular expressions provide a terse and powerful programming language.  As
1928 with most other power tools, power comes together with the ability
1929 to wreak havoc.
1930
1931 A common abuse of this power stems from the ability to make infinite
1932 loops using regular expressions, with something as innocuous as:
1933
1934     'foo' =~ m{ ( o? )* }x;
1935
1936 The C<o?> matches at the beginning of C<'foo'>, and since the position
1937 in the string is not moved by the match, C<o?> would match again and again
1938 because of the C<*> quantifier.  Another common way to create a similar cycle
1939 is with the looping modifier C<//g>:
1940
1941     @matches = ( 'foo' =~ m{ o? }xg );
1942
1943 or
1944
1945     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
1946
1947 or the loop implied by split().
1948
1949 However, long experience has shown that many programming tasks may
1950 be significantly simplified by using repeated subexpressions that
1951 may match zero-length substrings.  Here's a simple example being:
1952
1953     @chars = split //, $string;           # // is not magic in split
1954     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
1955
1956 Thus Perl allows such constructs, by I<forcefully breaking
1957 the infinite loop>.  The rules for this are different for lower-level
1958 loops given by the greedy quantifiers C<*+{}>, and for higher-level
1959 ones like the C</g> modifier or split() operator.
1960
1961 The lower-level loops are I<interrupted> (that is, the loop is
1962 broken) when Perl detects that a repeated expression matched a
1963 zero-length substring.   Thus
1964
1965    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
1966
1967 is made equivalent to
1968
1969    m{   (?: NON_ZERO_LENGTH )*
1970       |
1971         (?: ZERO_LENGTH )?
1972     }x;
1973
1974 The higher level-loops preserve an additional state between iterations:
1975 whether the last match was zero-length.  To break the loop, the following
1976 match after a zero-length match is prohibited to have a length of zero.
1977 This prohibition interacts with backtracking (see L<"Backtracking">),
1978 and so the I<second best> match is chosen if the I<best> match is of
1979 zero length.
1980
1981 For example:
1982
1983     $_ = 'bar';
1984     s/\w??/<$&>/g;
1985
1986 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
1987 match given by non-greedy C<??> is the zero-length match, and the I<second
1988 best> match is what is matched by C<\w>.  Thus zero-length matches
1989 alternate with one-character-long matches.
1990
1991 Similarly, for repeated C<m/()/g> the second-best match is the match at the
1992 position one notch further in the string.
1993
1994 The additional state of being I<matched with zero-length> is associated with
1995 the matched string, and is reset by each assignment to pos().
1996 Zero-length matches at the end of the previous match are ignored
1997 during C<split>.
1998
1999 =head2 Combining RE Pieces
2000
2001 Each of the elementary pieces of regular expressions which were described
2002 before (such as C<ab> or C<\Z>) could match at most one substring
2003 at the given position of the input string.  However, in a typical regular
2004 expression these elementary pieces are combined into more complicated
2005 patterns using combining operators C<ST>, C<S|T>, C<S*> etc
2006 (in these examples C<S> and C<T> are regular subexpressions).
2007
2008 Such combinations can include alternatives, leading to a problem of choice:
2009 if we match a regular expression C<a|ab> against C<"abc">, will it match
2010 substring C<"a"> or C<"ab">?  One way to describe which substring is
2011 actually matched is the concept of backtracking (see L<"Backtracking">).
2012 However, this description is too low-level and makes you think
2013 in terms of a particular implementation.
2014
2015 Another description starts with notions of "better"/"worse".  All the
2016 substrings which may be matched by the given regular expression can be
2017 sorted from the "best" match to the "worst" match, and it is the "best"
2018 match which is chosen.  This substitutes the question of "what is chosen?"
2019 by the question of "which matches are better, and which are worse?".
2020
2021 Again, for elementary pieces there is no such question, since at most
2022 one match at a given position is possible.  This section describes the
2023 notion of better/worse for combining operators.  In the description
2024 below C<S> and C<T> are regular subexpressions.
2025
2026 =over 4
2027
2028 =item C<ST>
2029
2030 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
2031 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
2032 which can be matched by C<T>.
2033
2034 If C<A> is better match for C<S> than C<A'>, C<AB> is a better
2035 match than C<A'B'>.
2036
2037 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
2038 C<B> is better match for C<T> than C<B'>.
2039
2040 =item C<S|T>
2041
2042 When C<S> can match, it is a better match than when only C<T> can match.
2043
2044 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
2045 two matches for C<T>.
2046
2047 =item C<S{REPEAT_COUNT}>
2048
2049 Matches as C<SSS...S> (repeated as many times as necessary).
2050
2051 =item C<S{min,max}>
2052
2053 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
2054
2055 =item C<S{min,max}?>
2056
2057 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
2058
2059 =item C<S?>, C<S*>, C<S+>
2060
2061 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
2062
2063 =item C<S??>, C<S*?>, C<S+?>
2064
2065 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
2066
2067 =item C<< (?>S) >>
2068
2069 Matches the best match for C<S> and only that.
2070
2071 =item C<(?=S)>, C<(?<=S)>
2072
2073 Only the best match for C<S> is considered.  (This is important only if
2074 C<S> has capturing parentheses, and backreferences are used somewhere
2075 else in the whole regular expression.)
2076
2077 =item C<(?!S)>, C<(?<!S)>
2078
2079 For this grouping operator there is no need to describe the ordering, since
2080 only whether or not C<S> can match is important.
2081
2082 =item C<(??{ EXPR })>, C<(?PARNO)>
2083
2084 The ordering is the same as for the regular expression which is
2085 the result of EXPR, or the pattern contained by capture buffer PARNO.
2086
2087 =item C<(?(condition)yes-pattern|no-pattern)>
2088
2089 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
2090 already determined.  The ordering of the matches is the same as for the
2091 chosen subexpression.
2092
2093 =back
2094
2095 The above recipes describe the ordering of matches I<at a given position>.
2096 One more rule is needed to understand how a match is determined for the
2097 whole regular expression: a match at an earlier position is always better
2098 than a match at a later position.
2099
2100 =head2 Creating Custom RE Engines
2101
2102 Overloaded constants (see L<overload>) provide a simple way to extend
2103 the functionality of the RE engine.
2104
2105 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2106 matches at a boundary between whitespace characters and non-whitespace
2107 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
2108 at these positions, so we want to have each C<\Y|> in the place of the
2109 more complicated version.  We can create a module C<customre> to do
2110 this:
2111
2112     package customre;
2113     use overload;
2114
2115     sub import {
2116       shift;
2117       die "No argument to customre::import allowed" if @_;
2118       overload::constant 'qr' => \&convert;
2119     }
2120
2121     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2122
2123     # We must also take care of not escaping the legitimate \\Y|
2124     # sequence, hence the presence of '\\' in the conversion rules.
2125     my %rules = ( '\\' => '\\\\',
2126                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2127     sub convert {
2128       my $re = shift;
2129       $re =~ s{
2130                 \\ ( \\ | Y . )
2131               }
2132               { $rules{$1} or invalid($re,$1) }sgex;
2133       return $re;
2134     }
2135
2136 Now C<use customre> enables the new escape in constant regular
2137 expressions, i.e., those without any runtime variable interpolations.
2138 As documented in L<overload>, this conversion will work only over
2139 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2140 part of this regular expression needs to be converted explicitly
2141 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2142
2143     use customre;
2144     $re = <>;
2145     chomp $re;
2146     $re = customre::convert $re;
2147     /\Y|$re\Y|/;
2148
2149 =head1 PCRE/Python Support
2150
2151 As of Perl 5.10.0, Perl supports several Python/PCRE specific extensions
2152 to the regex syntax. While Perl programmers are encouraged to use the
2153 Perl specific syntax, the following are also accepted:
2154
2155 =over 4
2156
2157 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2158
2159 Define a named capture buffer. Equivalent to C<< (?<NAME>pattern) >>.
2160
2161 =item C<< (?P=NAME) >>
2162
2163 Backreference to a named capture buffer. Equivalent to C<< \g{NAME} >>.
2164
2165 =item C<< (?P>NAME) >>
2166
2167 Subroutine call to a named capture buffer. Equivalent to C<< (?&NAME) >>.
2168
2169 =back
2170
2171 =head1 BUGS
2172
2173 This document varies from difficult to understand to completely
2174 and utterly opaque.  The wandering prose riddled with jargon is
2175 hard to fathom in several places.
2176
2177 This document needs a rewrite that separates the tutorial content
2178 from the reference content.
2179
2180 =head1 SEE ALSO
2181
2182 L<perlrequick>.
2183
2184 L<perlretut>.
2185
2186 L<perlop/"Regexp Quote-Like Operators">.
2187
2188 L<perlop/"Gory details of parsing quoted constructs">.
2189
2190 L<perlfaq6>.
2191
2192 L<perlfunc/pos>.
2193
2194 L<perllocale>.
2195
2196 L<perlebcdic>.
2197
2198 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2199 by O'Reilly and Associates.