pod/perlop.pod

   1 =head1 NAME
   2 X<operator>
   3
   4 perlop - Perl operators and precedence
   5
   6 =head1 DESCRIPTION
   7
   8 =head2 Operator Precedence and Associativity
   9 X<operator, precedence> X<precedence> X<associativity>
  10
  11 Operator precedence and associativity work in Perl more or less like
  12 they do in mathematics.
  13
  14 I<Operator precedence> means some operators are evaluated before
  15 others.  For example, in C<2 + 4 * 5>, the multiplication has higher
  16 precedence so C<4 * 5> is evaluated first yielding C<2 + 20 ==
  17 22> and not C<6 * 5 == 30>.
  18
  19 I<Operator associativity> defines what happens if a sequence of the
  20 same operators is used one after another: whether the evaluator will
  21 evaluate the left operations first or the right.  For example, in C<8
  22 - 4 - 2>, subtraction is left associative so Perl evaluates the
  23 expression left to right.  C<8 - 4> is evaluated first making the
  24 expression C<4 - 2 == 2> and not C<8 - 2 == 6>.
  25
  26 Perl operators have the following associativity and precedence,
  27 listed from highest precedence to lowest.  Operators borrowed from
  28 C keep the same precedence relationship with each other, even where
  29 C's precedence is slightly screwy.  (This makes learning Perl easier
  30 for C folks.)  With very few exceptions, these all operate on scalar
  31 values only, not array values.
  32
  33     left        terms and list operators (leftward)
  34     left        ->
  35     nonassoc    ++ --
  36     right       **
  37     right       ! ~ \ and unary + and -
  38     left        =~ !~
  39     left        * / % x
  40     left        + - .
  41     left        << >>
  42     nonassoc    named unary operators
  43     nonassoc    < > <= >= lt gt le ge
  44     nonassoc    == != <=> eq ne cmp ~~
  45     left        &
  46     left        | ^
  47     left        &&
  48     left        || //
  49     nonassoc    ..  ...
  50     right       ?:
  51     right       = += -= *= etc.
  52     left        , =>
  53     nonassoc    list operators (rightward)
  54     right       not
  55     left        and
  56     left        or xor err
  57
  58 In the following sections, these operators are covered in precedence order.
  59
  60 Many operators can be overloaded for objects.  See L<overload>.
  61
  62 =head2 Terms and List Operators (Leftward)
  63 X<list operator> X<operator, list> X<term>
  64
  65 A TERM has the highest precedence in Perl.  They include variables,
  66 quote and quote-like operators, any expression in parentheses,
  67 and any function whose arguments are parenthesized.  Actually, there
  68 aren't really functions in this sense, just list operators and unary
  69 operators behaving as functions because you put parentheses around
  70 the arguments.  These are all documented in L<perlfunc>.
  71
  72 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
  73 is followed by a left parenthesis as the next token, the operator and
  74 arguments within parentheses are taken to be of highest precedence,
  75 just like a normal function call.
  76
  77 In the absence of parentheses, the precedence of list operators such as
  78 C<print>, C<sort>, or C<chmod> is either very high or very low depending on
  79 whether you are looking at the left side or the right side of the operator.
  80 For example, in
  81
  82     @ary = (1, 3, sort 4, 2);
  83     print @ary;         # prints 1324
  84
  85 the commas on the right of the sort are evaluated before the sort,
  86 but the commas on the left are evaluated after.  In other words,
  87 list operators tend to gobble up all arguments that follow, and
  88 then act like a simple TERM with regard to the preceding expression.
  89 Be careful with parentheses:
  90
  91     # These evaluate exit before doing the print:
  92     print($foo, exit);  # Obviously not what you want.
  93     print $foo, exit;   # Nor is this.
  94
  95     # These do the print before evaluating exit:
  96     (print $foo), exit; # This is what you want.
  97     print($foo), exit;  # Or this.
  98     print ($foo), exit; # Or even this.
  99
 100 Also note that
 101
 102     print ($foo & 255) + 1, "\n";
 103
 104 probably doesn't do what you expect at first glance.  The parentheses
 105 enclose the argument list for C<print> which is evaluated (printing
 106 the result of C<$foo & 255>).  Then one is added to the return value
 107 of C<print> (usually 1).  The result is something like this:
 108
 109     1 + 1, "\n";    # Obviously not what you meant.
 110
 111 To do what you meant properly, you must write:
 112
 113     print(($foo & 255) + 1, "\n");
 114
 115 See L<Named Unary Operators> for more discussion of this.
 116
 117 Also parsed as terms are the C<do {}> and C<eval {}> constructs, as
 118 well as subroutine and method calls, and the anonymous
 119 constructors C<[]> and C<{}>.
 120
 121 See also L<Quote and Quote-like Operators> toward the end of this section,
 122 as well as L</"I/O Operators">.
 123
 124 =head2 The Arrow Operator
 125 X<arrow> X<dereference> X<< -> >>
 126
 127 "C<< -> >>" is an infix dereference operator, just as it is in C
 128 and C++.  If the right side is either a C<[...]>, C<{...}>, or a
 129 C<(...)> subscript, then the left side must be either a hard or
 130 symbolic reference to an array, a hash, or a subroutine respectively.
 131 (Or technically speaking, a location capable of holding a hard
 132 reference, if it's an array or hash reference being used for
 133 assignment.)  See L<perlreftut> and L<perlref>.
 134
 135 Otherwise, the right side is a method name or a simple scalar
 136 variable containing either the method name or a subroutine reference,
 137 and the left side must be either an object (a blessed reference)
 138 or a class name (that is, a package name).  See L<perlobj>.
 139
 140 =head2 Auto-increment and Auto-decrement
 141 X<increment> X<auto-increment> X<++> X<decrement> X<auto-decrement> X<-->
 142
 143 "++" and "--" work as in C.  That is, if placed before a variable,
 144 they increment or decrement the variable by one before returning the
 145 value, and if placed after, increment or decrement after returning the
 146 value.
 147
 148     $i = 0;  $j = 0;
 149     print $i++;  # prints 0
 150     print ++$j;  # prints 1
 151
 152 Note that just as in C, Perl doesn't define B<when> the variable is
 153 incremented or decremented. You just know it will be done sometime
 154 before or after the value is returned. This also means that modifying
 155 a variable twice in the same statement will lead to undefined behaviour.
 156 Avoid statements like:
 157
 158     $i = $i ++;
 159     print ++ $i + $i ++;
 160
 161 Perl will not guarantee what the result of the above statements is.
 162
 163 The auto-increment operator has a little extra builtin magic to it.  If
 164 you increment a variable that is numeric, or that has ever been used in
 165 a numeric context, you get a normal increment.  If, however, the
 166 variable has been used in only string contexts since it was set, and
 167 has a value that is not the empty string and matches the pattern
 168 C</^[a-zA-Z]*[0-9]*\z/>, the increment is done as a string, preserving each
 169 character within its range, with carry:
 170
 171     print ++($foo = '99');      # prints '100'
 172     print ++($foo = 'a0');      # prints 'a1'
 173     print ++($foo = 'Az');      # prints 'Ba'
 174     print ++($foo = 'zz');      # prints 'aaa'
 175
 176 C<undef> is always treated as numeric, and in particular is changed
 177 to C<0> before incrementing (so that a post-increment of an undef value
 178 will return C<0> rather than C<undef>).
 179
 180 The auto-decrement operator is not magical.
 181
 182 =head2 Exponentiation
 183 X<**> X<exponentiation> X<power>
 184
 185 Binary "**" is the exponentiation operator.  It binds even more
 186 tightly than unary minus, so -2**4 is -(2**4), not (-2)**4. (This is
 187 implemented using C's pow(3) function, which actually works on doubles
 188 internally.)
 189
 190 =head2 Symbolic Unary Operators
 191 X<unary operator> X<operator, unary>
 192
 193 Unary "!" performs logical negation, i.e., "not".  See also C<not> for a lower
 194 precedence version of this.
 195 X<!>
 196
 197 Unary "-" performs arithmetic negation if the operand is numeric.  If
 198 the operand is an identifier, a string consisting of a minus sign
 199 concatenated with the identifier is returned.  Otherwise, if the string
 200 starts with a plus or minus, a string starting with the opposite sign
 201 is returned.  One effect of these rules is that -bareword is equivalent
 202 to the string "-bareword".  If, however, the string begins with a
 203 non-alphabetic character (exluding "+" or "-"), Perl will attempt to convert
 204 the string to a numeric and the arithmetic negation is performed. If the
 205 string cannot be cleanly converted to a numeric, Perl will give the warning
 206 B<Argument "the string" isn't numeric in negation (-) at ...>.
 207 X<-> X<negation, arithmetic>
 208
 209 Unary "~" performs bitwise negation, i.e., 1's complement.  For
 210 example, C<0666 & ~027> is 0640.  (See also L<Integer Arithmetic> and
 211 L<Bitwise String Operators>.)  Note that the width of the result is
 212 platform-dependent: ~0 is 32 bits wide on a 32-bit platform, but 64
 213 bits wide on a 64-bit platform, so if you are expecting a certain bit
 214 width, remember to use the & operator to mask off the excess bits.
 215 X<~> X<negation, binary>
 216
 217 Unary "+" has no effect whatsoever, even on strings.  It is useful
 218 syntactically for separating a function name from a parenthesized expression
 219 that would otherwise be interpreted as the complete list of function
 220 arguments.  (See examples above under L<Terms and List Operators (Leftward)>.)
 221 X<+>
 222
 223 Unary "\" creates a reference to whatever follows it.  See L<perlreftut>
 224 and L<perlref>.  Do not confuse this behavior with the behavior of
 225 backslash within a string, although both forms do convey the notion
 226 of protecting the next thing from interpolation.
 227 X<\> X<reference> X<backslash>
 228
 229 =head2 Binding Operators
 230 X<binding> X<operator, binding> X<=~> X<!~>
 231
 232 Binary "=~" binds a scalar expression to a pattern match.  Certain operations
 233 search or modify the string $_ by default.  This operator makes that kind
 234 of operation work on some other string.  The right argument is a search
 235 pattern, substitution, or transliteration.  The left argument is what is
 236 supposed to be searched, substituted, or transliterated instead of the default
 237 $_.  When used in scalar context, the return value generally indicates the
 238 success of the operation.  Behavior in list context depends on the particular
 239 operator.  See L</"Regexp Quote-Like Operators"> for details and
 240 L<perlretut> for examples using these operators.
 241
 242 If the right argument is an expression rather than a search pattern,
 243 substitution, or transliteration, it is interpreted as a search pattern at run
 244 time.
 245
 246 Binary "!~" is just like "=~" except the return value is negated in
 247 the logical sense.
 248
 249 =head2 Multiplicative Operators
 250 X<operator, multiplicative>
 251
 252 Binary "*" multiplies two numbers.
 253 X<*>
 254
 255 Binary "/" divides two numbers.
 256 X</> X<slash>
 257
 258 Binary "%" computes the modulus of two numbers.  Given integer
 259 operands C<$a> and C<$b>: If C<$b> is positive, then C<$a % $b> is
 260 C<$a> minus the largest multiple of C<$b> that is not greater than
 261 C<$a>.  If C<$b> is negative, then C<$a % $b> is C<$a> minus the
 262 smallest multiple of C<$b> that is not less than C<$a> (i.e. the
 263 result will be less than or equal to zero).  If the operands
 264 C<$a> and C<$b> are floting point values, only the integer portion
 265 of C<$a> and C<$b> will be used in the operation.
 266 Note that when C<use integer> is in scope, "%" gives you direct access
 267 to the modulus operator as implemented by your C compiler.  This
 268 operator is not as well defined for negative operands, but it will
 269 execute faster.
 270 X<%> X<remainder> X<modulus> X<mod>
 271
 272 Binary "x" is the repetition operator.  In scalar context or if the left
 273 operand is not enclosed in parentheses, it returns a string consisting
 274 of the left operand repeated the number of times specified by the right
 275 operand.  In list context, if the left operand is enclosed in
 276 parentheses or is a list formed by C<qw/STRING/>, it repeats the list.
 277 If the right operand is zero or negative, it returns an empty string
 278 or an empty list, depending on the context.
 279 X<x>
 280
 281     print '-' x 80;             # print row of dashes
 282
 283     print "\t" x ($tab/8), ' ' x ($tab%8);      # tab over
 284
 285     @ones = (1) x 80;           # a list of 80 1's
 286     @ones = (5) x @ones;        # set all elements to 5
 287
 288
 289 =head2 Additive Operators
 290 X<operator, additive>
 291
 292 Binary "+" returns the sum of two numbers.
 293 X<+>
 294
 295 Binary "-" returns the difference of two numbers.
 296 X<->
 297
 298 Binary "." concatenates two strings.
 299 X<string, concatenation> X<concatenation>
 300 X<cat> X<concat> X<concatenate> X<.>
 301
 302 =head2 Shift Operators
 303 X<shift operator> X<operator, shift> X<<< << >>>
 304 X<<< >> >>> X<right shift> X<left shift> X<bitwise shift>
 305 X<shl> X<shr> X<shift, right> X<shift, left>
 306
 307 Binary "<<" returns the value of its left argument shifted left by the
 308 number of bits specified by the right argument.  Arguments should be
 309 integers.  (See also L<Integer Arithmetic>.)
 310
 311 Binary ">>" returns the value of its left argument shifted right by
 312 the number of bits specified by the right argument.  Arguments should
 313 be integers.  (See also L<Integer Arithmetic>.)
 314
 315 Note that both "<<" and ">>" in Perl are implemented directly using
 316 "<<" and ">>" in C.  If C<use integer> (see L<Integer Arithmetic>) is
 317 in force then signed C integers are used, else unsigned C integers are
 318 used.  Either way, the implementation isn't going to generate results
 319 larger than the size of the integer type Perl was built with (32 bits
 320 or 64 bits).
 321
 322 The result of overflowing the range of the integers is undefined
 323 because it is undefined also in C.  In other words, using 32-bit
 324 integers, C<< 1 << 32 >> is undefined.  Shifting by a negative number
 325 of bits is also undefined.
 326
 327 =head2 Named Unary Operators
 328 X<operator, named unary>
 329
 330 The various named unary operators are treated as functions with one
 331 argument, with optional parentheses.
 332
 333 If any list operator (print(), etc.) or any unary operator (chdir(), etc.)
 334 is followed by a left parenthesis as the next token, the operator and
 335 arguments within parentheses are taken to be of highest precedence,
 336 just like a normal function call.  For example,
 337 because named unary operators are higher precedence than ||:
 338
 339     chdir $foo    || die;       # (chdir $foo) || die
 340     chdir($foo)   || die;       # (chdir $foo) || die
 341     chdir ($foo)  || die;       # (chdir $foo) || die
 342     chdir +($foo) || die;       # (chdir $foo) || die
 343
 344 but, because * is higher precedence than named operators:
 345
 346     chdir $foo * 20;    # chdir ($foo * 20)
 347     chdir($foo) * 20;   # (chdir $foo) * 20
 348     chdir ($foo) * 20;  # (chdir $foo) * 20
 349     chdir +($foo) * 20; # chdir ($foo * 20)
 350
 351     rand 10 * 20;       # rand (10 * 20)
 352     rand(10) * 20;      # (rand 10) * 20
 353     rand (10) * 20;     # (rand 10) * 20
 354     rand +(10) * 20;    # rand (10 * 20)
 355
 356 Regarding precedence, the filetest operators, like C<-f>, C<-M>, etc. are
 357 treated like named unary operators, but they don't follow this functional
 358 parenthesis rule.  That means, for example, that C<-f($file).".bak"> is
 359 equivalent to C<-f "$file.bak">.
 360 X<-X> X<filetest> X<operator, filetest>
 361
 362 See also L<"Terms and List Operators (Leftward)">.
 363
 364 =head2 Relational Operators
 365 X<relational operator> X<operator, relational>
 366
 367 Binary "<" returns true if the left argument is numerically less than
 368 the right argument.
 369 X<< < >>
 370
 371 Binary ">" returns true if the left argument is numerically greater
 372 than the right argument.
 373 X<< > >>
 374
 375 Binary "<=" returns true if the left argument is numerically less than
 376 or equal to the right argument.
 377 X<< <= >>
 378
 379 Binary ">=" returns true if the left argument is numerically greater
 380 than or equal to the right argument.
 381 X<< >= >>
 382
 383 Binary "lt" returns true if the left argument is stringwise less than
 384 the right argument.
 385 X<< lt >>
 386
 387 Binary "gt" returns true if the left argument is stringwise greater
 388 than the right argument.
 389 X<< gt >>
 390
 391 Binary "le" returns true if the left argument is stringwise less than
 392 or equal to the right argument.
 393 X<< le >>
 394
 395 Binary "ge" returns true if the left argument is stringwise greater
 396 than or equal to the right argument.
 397 X<< ge >>
 398
 399 =head2 Equality Operators
 400 X<equality> X<equal> X<equals> X<operator, equality>
 401
 402 Binary "==" returns true if the left argument is numerically equal to
 403 the right argument.
 404 X<==>
 405
 406 Binary "!=" returns true if the left argument is numerically not equal
 407 to the right argument.
 408 X<!=>
 409
 410 Binary "<=>" returns -1, 0, or 1 depending on whether the left
 411 argument is numerically less than, equal to, or greater than the right
 412 argument.  If your platform supports NaNs (not-a-numbers) as numeric
 413 values, using them with "<=>" returns undef.  NaN is not "<", "==", ">",
 414 "<=" or ">=" anything (even NaN), so those 5 return false. NaN != NaN
 415 returns true, as does NaN != anything else. If your platform doesn't
 416 support NaNs then NaN is just a string with numeric value 0.
 417 X<< <=> >> X<spaceship>
 418
 419     perl -le '$a = "NaN"; print "No NaN support here" if $a == $a'
 420     perl -le '$a = "NaN"; print "NaN support here" if $a != $a'
 421
 422 Binary "eq" returns true if the left argument is stringwise equal to
 423 the right argument.
 424 X<eq>
 425
 426 Binary "ne" returns true if the left argument is stringwise not equal
 427 to the right argument.
 428 X<ne>
 429
 430 Binary "cmp" returns -1, 0, or 1 depending on whether the left
 431 argument is stringwise less than, equal to, or greater than the right
 432 argument.
 433 X<cmp>
 434
 435 Binary "~~" does a smart match between its arguments. Smart matching
 436 is described in L<perlsyn/"Smart Matching in Detail">.
 437 This operator is only available if you enable the "~~" feature:
 438 see L<feature> for more information.
 439 X<~~>
 440
 441 "lt", "le", "ge", "gt" and "cmp" use the collation (sort) order specified
 442 by the current locale if C<use locale> is in effect.  See L<perllocale>.
 443
 444 =head2 Bitwise And
 445 X<operator, bitwise, and> X<bitwise and> X<&>
 446
 447 Binary "&" returns its operands ANDed together bit by bit.
 448 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
 449
 450 Note that "&" has lower priority than relational operators, so for example
 451 the brackets are essential in a test like
 452
 453         print "Even\n" if ($x & 1) == 0;
 454
 455 =head2 Bitwise Or and Exclusive Or
 456 X<operator, bitwise, or> X<bitwise or> X<|> X<operator, bitwise, xor>
 457 X<bitwise xor> X<^>
 458
 459 Binary "|" returns its operands ORed together bit by bit.
 460 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
 461
 462 Binary "^" returns its operands XORed together bit by bit.
 463 (See also L<Integer Arithmetic> and L<Bitwise String Operators>.)
 464
 465 Note that "|" and "^" have lower priority than relational operators, so
 466 for example the brackets are essential in a test like
 467
 468         print "false\n" if (8 | 2) != 10;
 469
 470 =head2 C-style Logical And
 471 X<&&> X<logical and> X<operator, logical, and>
 472
 473 Binary "&&" performs a short-circuit logical AND operation.  That is,
 474 if the left operand is false, the right operand is not even evaluated.
 475 Scalar or list context propagates down to the right operand if it
 476 is evaluated.
 477
 478 =head2 C-style Logical Or
 479 X<||> X<operator, logical, or>
 480
 481 Binary "||" performs a short-circuit logical OR operation.  That is,
 482 if the left operand is true, the right operand is not even evaluated.
 483 Scalar or list context propagates down to the right operand if it
 484 is evaluated.
 485
 486 =head2 C-style Logical Defined-Or
 487 X<//> X<operator, logical, defined-or>
 488
 489 Although it has no direct equivalent in C, Perl's C<//> operator is related
 490 to its C-style or.  In fact, it's exactly the same as C<||>, except that it
 491 tests the left hand side's definedness instead of its truth.  Thus, C<$a // $b>
 492 is similar to C<defined($a) || $b> (except that it returns the value of C<$a>
 493 rather than the value of C<defined($a)>) and is exactly equivalent to
 494 C<defined($a) ? $a : $b>.  This is very useful for providing default values
 495 for variables.  If you actually want to test if at least one of C<$a> and
 496 C<$b> is defined, use C<defined($a // $b)>.
 497
 498 The C<||>, C<//> and C<&&> operators return the last value evaluated
 499 (unlike C's C<||> and C<&&>, which return 0 or 1). Thus, a reasonably
 500 portable way to find out the home directory might be:
 501
 502     $home = $ENV{'HOME'} // $ENV{'LOGDIR'} //
 503         (getpwuid($<))[7] // die "You're homeless!\n";
 504
 505 In particular, this means that you shouldn't use this
 506 for selecting between two aggregates for assignment:
 507
 508     @a = @b || @c;              # this is wrong
 509     @a = scalar(@b) || @c;      # really meant this
 510     @a = @b ? @b : @c;          # this works fine, though
 511
 512 As more readable alternatives to C<&&>, C<//> and C<||> when used for
 513 control flow, Perl provides C<and>, C<err> and C<or> operators (see below).
 514 The short-circuit behavior is identical.  The precedence of "and", "err"
 515 and "or" is much lower, however, so that you can safely use them after a
 516 list operator without the need for parentheses:
 517
 518     unlink "alpha", "beta", "gamma"
 519             or gripe(), next LINE;
 520
 521 With the C-style operators that would have been written like this:
 522
 523     unlink("alpha", "beta", "gamma")
 524             || (gripe(), next LINE);
 525
 526 Using "or" for assignment is unlikely to do what you want; see below.
 527
 528 =head2 Range Operators
 529 X<operator, range> X<range> X<..> X<...>
 530
 531 Binary ".." is the range operator, which is really two different
 532 operators depending on the context.  In list context, it returns a
 533 list of values counting (up by ones) from the left value to the right
 534 value.  If the left value is greater than the right value then it
 535 returns the empty list.  The range operator is useful for writing
 536 C<foreach (1..10)> loops and for doing slice operations on arrays. In
 537 the current implementation, no temporary array is created when the
 538 range operator is used as the expression in C<foreach> loops, but older
 539 versions of Perl might burn a lot of memory when you write something
 540 like this:
 541
 542     for (1 .. 1_000_000) {
 543         # code
 544     }
 545
 546 The range operator also works on strings, using the magical auto-increment,
 547 see below.
 548
 549 In scalar context, ".." returns a boolean value.  The operator is
 550 bistable, like a flip-flop, and emulates the line-range (comma) operator
 551 of B<sed>, B<awk>, and various editors.  Each ".." operator maintains its
 552 own boolean state.  It is false as long as its left operand is false.
 553 Once the left operand is true, the range operator stays true until the
 554 right operand is true, I<AFTER> which the range operator becomes false
 555 again.  It doesn't become false till the next time the range operator is
 556 evaluated.  It can test the right operand and become false on the same
 557 evaluation it became true (as in B<awk>), but it still returns true once.
 558 If you don't want it to test the right operand till the next
 559 evaluation, as in B<sed>, just use three dots ("...") instead of
 560 two.  In all other regards, "..." behaves just like ".." does.
 561
 562 The right operand is not evaluated while the operator is in the
 563 "false" state, and the left operand is not evaluated while the
 564 operator is in the "true" state.  The precedence is a little lower
 565 than || and &&.  The value returned is either the empty string for
 566 false, or a sequence number (beginning with 1) for true.  The
 567 sequence number is reset for each range encountered.  The final
 568 sequence number in a range has the string "E0" appended to it, which
 569 doesn't affect its numeric value, but gives you something to search
 570 for if you want to exclude the endpoint.  You can exclude the
 571 beginning point by waiting for the sequence number to be greater
 572 than 1.
 573
 574 If either operand of scalar ".." is a constant expression,
 575 that operand is considered true if it is equal (C<==>) to the current
 576 input line number (the C<$.> variable).
 577
 578 To be pedantic, the comparison is actually C<int(EXPR) == int(EXPR)>,
 579 but that is only an issue if you use a floating point expression; when
 580 implicitly using C<$.> as described in the previous paragraph, the
 581 comparison is C<int(EXPR) == int($.)> which is only an issue when C<$.>
 582 is set to a floating point value and you are not reading from a file.
 583 Furthermore, C<"span" .. "spat"> or C<2.18 .. 3.14> will not do what
 584 you want in scalar context because each of the operands are evaluated
 585 using their integer representation.
 586
 587 Examples:
 588
 589 As a scalar operator:
 590
 591     if (101 .. 200) { print; } # print 2nd hundred lines, short for
 592                                #   if ($. == 101 .. $. == 200) ...
 593
 594     next LINE if (1 .. /^$/);  # skip header lines, short for
 595                                #   ... if ($. == 1 .. /^$/);
 596                                # (typically in a loop labeled LINE)
 597
 598     s/^/> / if (/^$/ .. eof());  # quote body
 599
 600     # parse mail messages
 601     while (<>) {
 602         $in_header =   1  .. /^$/;
 603         $in_body   = /^$/ .. eof;
 604         if ($in_header) {
 605             # ...
 606         } else { # in body
 607             # ...
 608         }
 609     } continue {
 610         close ARGV if eof;             # reset $. each file
 611     }
 612
 613 Here's a simple example to illustrate the difference between
 614 the two range operators:
 615
 616     @lines = ("   - Foo",
 617               "01 - Bar",
 618               "1  - Baz",
 619               "   - Quux");
 620
 621     foreach (@lines) {
 622         if (/0/ .. /1/) {
 623             print "$_\n";
 624         }
 625     }
 626
 627 This program will print only the line containing "Bar". If
 628 the range operator is changed to C<...>, it will also print the
 629 "Baz" line.
 630
 631 And now some examples as a list operator:
 632
 633     for (101 .. 200) { print; } # print $_ 100 times
 634     @foo = @foo[0 .. $#foo];    # an expensive no-op
 635     @foo = @foo[$#foo-4 .. $#foo];      # slice last 5 items
 636
 637 The range operator (in list context) makes use of the magical
 638 auto-increment algorithm if the operands are strings.  You
 639 can say
 640
 641     @alphabet = ('A' .. 'Z');
 642
 643 to get all normal letters of the English alphabet, or
 644
 645     $hexdigit = (0 .. 9, 'a' .. 'f')[$num & 15];
 646
 647 to get a hexadecimal digit, or
 648
 649     @z2 = ('01' .. '31');  print $z2[$mday];
 650
 651 to get dates with leading zeros.
 652
 653 If the final value specified is not in the sequence that the magical
 654 increment would produce, the sequence goes until the next value would
 655 be longer than the final value specified.
 656
 657 If the initial value specified isn't part of a magical increment
 658 sequence (that is, a non-empty string matching "/^[a-zA-Z]*[0-9]*\z/"),
 659 only the initial value will be returned.  So the following will only
 660 return an alpha:
 661
 662     use charnames 'greek';
 663     my @greek_small =  ("\N{alpha}" .. "\N{omega}");
 664
 665 To get lower-case greek letters, use this instead:
 666
 667     my @greek_small =  map { chr } ( ord("\N{alpha}") .. ord("\N{omega}") );
 668
 669 Because each operand is evaluated in integer form, C<2.18 .. 3.14> will
 670 return two elements in list context.
 671
 672     @list = (2.18 .. 3.14); # same as @list = (2 .. 3);
 673
 674 =head2 Conditional Operator
 675 X<operator, conditional> X<operator, ternary> X<ternary> X<?:>
 676
 677 Ternary "?:" is the conditional operator, just as in C.  It works much
 678 like an if-then-else.  If the argument before the ? is true, the
 679 argument before the : is returned, otherwise the argument after the :
 680 is returned.  For example:
 681
 682     printf "I have %d dog%s.\n", $n,
 683             ($n == 1) ? '' : "s";
 684
 685 Scalar or list context propagates downward into the 2nd
 686 or 3rd argument, whichever is selected.
 687
 688     $a = $ok ? $b : $c;  # get a scalar
 689     @a = $ok ? @b : @c;  # get an array
 690     $a = $ok ? @b : @c;  # oops, that's just a count!
 691
 692 The operator may be assigned to if both the 2nd and 3rd arguments are
 693 legal lvalues (meaning that you can assign to them):
 694
 695     ($a_or_b ? $a : $b) = $c;
 696
 697 Because this operator produces an assignable result, using assignments
 698 without parentheses will get you in trouble.  For example, this:
 699
 700     $a % 2 ? $a += 10 : $a += 2
 701
 702 Really means this:
 703
 704     (($a % 2) ? ($a += 10) : $a) += 2
 705
 706 Rather than this:
 707
 708     ($a % 2) ? ($a += 10) : ($a += 2)
 709
 710 That should probably be written more simply as:
 711
 712     $a += ($a % 2) ? 10 : 2;
 713
 714 =head2 Assignment Operators
 715 X<assignment> X<operator, assignment> X<=> X<**=> X<+=> X<*=> X<&=>
 716 X<<< <<= >>> X<&&=> X<-=> X</=> X<|=> X<<< >>= >>> X<||=> X<//=> X<.=>
 717 X<%=> X<^=> X<x=>
 718
 719 "=" is the ordinary assignment operator.
 720
 721 Assignment operators work as in C.  That is,
 722
 723     $a += 2;
 724
 725 is equivalent to
 726
 727     $a = $a + 2;
 728
 729 although without duplicating any side effects that dereferencing the lvalue
 730 might trigger, such as from tie().  Other assignment operators work similarly.
 731 The following are recognized:
 732
 733     **=    +=    *=    &=    <<=    &&=
 734            -=    /=    |=    >>=    ||=
 735            .=    %=    ^=           //=
 736                  x=
 737
 738 Although these are grouped by family, they all have the precedence
 739 of assignment.
 740
 741 Unlike in C, the scalar assignment operator produces a valid lvalue.
 742 Modifying an assignment is equivalent to doing the assignment and
 743 then modifying the variable that was assigned to.  This is useful
 744 for modifying a copy of something, like this:
 745
 746     ($tmp = $global) =~ tr [A-Z] [a-z];
 747
 748 Likewise,
 749
 750     ($a += 2) *= 3;
 751
 752 is equivalent to
 753
 754     $a += 2;
 755     $a *= 3;
 756
 757 Similarly, a list assignment in list context produces the list of
 758 lvalues assigned to, and a list assignment in scalar context returns
 759 the number of elements produced by the expression on the right hand
 760 side of the assignment.
 761
 762 =head2 Comma Operator
 763 X<comma> X<operator, comma> X<,>
 764
 765 Binary "," is the comma operator.  In scalar context it evaluates
 766 its left argument, throws that value away, then evaluates its right
 767 argument and returns that value.  This is just like C's comma operator.
 768
 769 In list context, it's just the list argument separator, and inserts
 770 both its arguments into the list.  These arguments are also evaluated
 771 from left to right.
 772
 773 The C<< => >> operator is a synonym for the comma, but forces any word
 774 (consisting entirely of word characters) to its left to be interpreted
 775 as a string (as of 5.001).  This includes words that might otherwise be
 776 considered a constant or function call.
 777
 778     use constant FOO => "something";
 779
 780     my %h = ( FOO => 23 );
 781
 782 is equivalent to:
 783
 784     my %h = ("FOO", 23);
 785
 786 It is I<NOT>:
 787
 788     my %h = ("something", 23);
 789
 790 If the argument on the left is not a word, it is first interpreted as
 791 an expression, and then the string value of that is used.
 792
 793 The C<< => >> operator is helpful in documenting the correspondence
 794 between keys and values in hashes, and other paired elements in lists.
 795
 796         %hash = ( $key => $value );
 797         login( $username => $password );
 798
 799 =head2 List Operators (Rightward)
 800 X<operator, list, rightward> X<list operator>
 801
 802 On the right side of a list operator, it has very low precedence,
 803 such that it controls all comma-separated expressions found there.
 804 The only operators with lower precedence are the logical operators
 805 "and", "or", and "not", which may be used to evaluate calls to list
 806 operators without the need for extra parentheses:
 807
 808     open HANDLE, "filename"
 809         or die "Can't open: $!\n";
 810
 811 See also discussion of list operators in L<Terms and List Operators (Leftward)>.
 812
 813 =head2 Logical Not
 814 X<operator, logical, not> X<not>
 815
 816 Unary "not" returns the logical negation of the expression to its right.
 817 It's the equivalent of "!" except for the very low precedence.
 818
 819 =head2 Logical And
 820 X<operator, logical, and> X<and>
 821
 822 Binary "and" returns the logical conjunction of the two surrounding
 823 expressions.  It's equivalent to && except for the very low
 824 precedence.  This means that it short-circuits: i.e., the right
 825 expression is evaluated only if the left expression is true.
 826
 827 =head2 Logical or, Defined or, and Exclusive Or
 828 X<operator, logical, or> X<operator, logical, xor> X<operator, logical, err>
 829 X<operator, logical, defined or> X<operator, logical, exclusive or>
 830 X<or> X<xor> X<err>
 831
 832 Binary "or" returns the logical disjunction of the two surrounding
 833 expressions.  It's equivalent to || except for the very low precedence.
 834 This makes it useful for control flow
 835
 836     print FH $data              or die "Can't write to FH: $!";
 837
 838 This means that it short-circuits: i.e., the right expression is evaluated
 839 only if the left expression is false.  Due to its precedence, you should
 840 probably avoid using this for assignment, only for control flow.
 841
 842     $a = $b or $c;              # bug: this is wrong
 843     ($a = $b) or $c;            # really means this
 844     $a = $b || $c;              # better written this way
 845
 846 However, when it's a list-context assignment and you're trying to use
 847 "||" for control flow, you probably need "or" so that the assignment
 848 takes higher precedence.
 849
 850     @info = stat($file) || die;     # oops, scalar sense of stat!
 851     @info = stat($file) or die;     # better, now @info gets its due
 852
 853 Then again, you could always use parentheses.
 854
 855 Binary "err" is equivalent to C<//>--it's just like binary "or", except it
 856 tests its left argument's definedness instead of its truth.  There are two
 857 ways to remember "err":  either because many functions return C<undef> on
 858 an B<err>or, or as a sort of correction:  C<$a = ($b err 'default')>. This
 859 keyword is only available when the 'err' feature is enabled: see
 860 L<feature> for more information.
 861
 862 Binary "xor" returns the exclusive-OR of the two surrounding expressions.
 863 It cannot short circuit, of course.
 864
 865 =head2 C Operators Missing From Perl
 866 X<operator, missing from perl> X<&> X<*>
 867 X<typecasting> X<(TYPE)>
 868
 869 Here is what C has that Perl doesn't:
 870
 871 =over 8
 872
 873 =item unary &
 874
 875 Address-of operator.  (But see the "\" operator for taking a reference.)
 876
 877 =item unary *
 878
 879 Dereference-address operator. (Perl's prefix dereferencing
 880 operators are typed: $, @, %, and &.)
 881
 882 =item (TYPE)
 883
 884 Type-casting operator.
 885
 886 =back
 887
 888 =head2 Quote and Quote-like Operators
 889 X<operator, quote> X<operator, quote-like> X<q> X<qq> X<qx> X<qw> X<m>
 890 X<qr> X<s> X<tr> X<'> X<''> X<"> X<""> X<//> X<`> X<``> X<<< << >>>
 891 X<escape sequence> X<escape>
 892
 893
 894 While we usually think of quotes as literal values, in Perl they
 895 function as operators, providing various kinds of interpolating and
 896 pattern matching capabilities.  Perl provides customary quote characters
 897 for these behaviors, but also provides a way for you to choose your
 898 quote character for any of them.  In the following table, a C<{}> represents
 899 any pair of delimiters you choose.
 900
 901     Customary  Generic        Meaning        Interpolates
 902         ''       q{}          Literal             no
 903         ""      qq{}          Literal             yes
 904         ``      qx{}          Command             yes*
 905                 qw{}         Word list            no
 906         //       m{}       Pattern match          yes*
 907                 qr{}          Pattern             yes*
 908                  s{}{}      Substitution          yes*
 909                 tr{}{}    Transliteration         no (but see below)
 910         <<EOF                 here-doc            yes*
 911
 912         * unless the delimiter is ''.
 913
 914 Non-bracketing delimiters use the same character fore and aft, but the four
 915 sorts of brackets (round, angle, square, curly) will all nest, which means
 916 that
 917
 918         q{foo{bar}baz}
 919
 920 is the same as
 921
 922         'foo{bar}baz'
 923
 924 Note, however, that this does not always work for quoting Perl code:
 925
 926         $s = q{ if($a eq "}") ... }; # WRONG
 927
 928 is a syntax error. The C<Text::Balanced> module (from CPAN, and
 929 starting from Perl 5.8 part of the standard distribution) is able
 930 to do this properly.
 931
 932 There can be whitespace between the operator and the quoting
 933 characters, except when C<#> is being used as the quoting character.
 934 C<q#foo#> is parsed as the string C<foo>, while C<q #foo#> is the
 935 operator C<q> followed by a comment.  Its argument will be taken
 936 from the next line.  This allows you to write:
 937
 938     s {foo}  # Replace foo
 939       {bar}  # with bar.
 940
 941 The following escape sequences are available in constructs that interpolate
 942 and in transliterations.
 943 X<\t> X<\n> X<\r> X<\f> X<\b> X<\a> X<\e> X<\x> X<\0> X<\c> X<\N>
 944
 945     \t          tab             (HT, TAB)
 946     \n          newline         (NL)
 947     \r          return          (CR)
 948     \f          form feed       (FF)
 949     \b          backspace       (BS)
 950     \a          alarm (bell)    (BEL)
 951     \e          escape          (ESC)
 952     \033        octal char      (ESC)
 953     \x1b        hex char        (ESC)
 954     \x{263a}    wide hex char   (SMILEY)
 955     \c[         control char    (ESC)
 956     \N{name}    named Unicode character
 957
 958 B<NOTE>: Unlike C and other languages, Perl has no \v escape sequence for
 959 the vertical tab (VT - ASCII 11).
 960
 961 The following escape sequences are available in constructs that interpolate
 962 but not in transliterations.
 963 X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q>
 964
 965     \l          lowercase next char
 966     \u          uppercase next char
 967     \L          lowercase till \E
 968     \U          uppercase till \E
 969     \E          end case modification
 970     \Q          quote non-word characters till \E
 971
 972 If C<use locale> is in effect, the case map used by C<\l>, C<\L>,
 973 C<\u> and C<\U> is taken from the current locale.  See L<perllocale>.
 974 If Unicode (for example, C<\N{}> or wide hex characters of 0x100 or
 975 beyond) is being used, the case map used by C<\l>, C<\L>, C<\u> and
 976 C<\U> is as defined by Unicode.  For documentation of C<\N{name}>,
 977 see L<charnames>.
 978
 979 All systems use the virtual C<"\n"> to represent a line terminator,
 980 called a "newline".  There is no such thing as an unvarying, physical
 981 newline character.  It is only an illusion that the operating system,
 982 device drivers, C libraries, and Perl all conspire to preserve.  Not all
 983 systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF.  For example,
 984 on a Mac, these are reversed, and on systems without line terminator,
 985 printing C<"\n"> may emit no actual data.  In general, use C<"\n"> when
 986 you mean a "newline" for your system, but use the literal ASCII when you
 987 need an exact character.  For example, most networking protocols expect
 988 and prefer a CR+LF (C<"\015\012"> or C<"\cM\cJ">) for line terminators,
 989 and although they often accept just C<"\012">, they seldom tolerate just
 990 C<"\015">.  If you get in the habit of using C<"\n"> for networking,
 991 you may be burned some day.
 992 X<newline> X<line terminator> X<eol> X<end of line>
 993 X<\n> X<\r> X<\r\n>
 994
 995 For constructs that do interpolate, variables beginning with "C<$>"
 996 or "C<@>" are interpolated.  Subscripted variables such as C<$a[3]> or
 997 C<< $href->{key}[0] >> are also interpolated, as are array and hash slices.
 998 But method calls such as C<< $obj->meth >> are not.
 999
1000 Interpolating an array or slice interpolates the elements in order,
1001 separated by the value of C<$">, so is equivalent to interpolating
1002 C<join $", @array>.    "Punctuation" arrays such as C<@+> are only
1003 interpolated if the name is enclosed in braces C<@{+}>.
1004
1005 You cannot include a literal C<$> or C<@> within a C<\Q> sequence.
1006 An unescaped C<$> or C<@> interpolates the corresponding variable,
1007 while escaping will cause the literal string C<\$> to be inserted.
1008 You'll need to write something like C<m/\Quser\E\@\Qhost/>.
1009
1010 Patterns are subject to an additional level of interpretation as a
1011 regular expression.  This is done as a second pass, after variables are
1012 interpolated, so that regular expressions may be incorporated into the
1013 pattern from the variables.  If this is not what you want, use C<\Q> to
1014 interpolate a variable literally.
1015
1016 Apart from the behavior described above, Perl does not expand
1017 multiple levels of interpolation.  In particular, contrary to the
1018 expectations of shell programmers, back-quotes do I<NOT> interpolate
1019 within double quotes, nor do single quotes impede evaluation of
1020 variables when used within double quotes.
1021
1022 =head2 Regexp Quote-Like Operators
1023 X<operator, regexp>
1024
1025 Here are the quote-like operators that apply to pattern
1026 matching and related activities.
1027
1028 =over 8
1029
1030 =item ?PATTERN?
1031 X<?>
1032
1033 This is just like the C</pattern/> search, except that it matches only
1034 once between calls to the reset() operator.  This is a useful
1035 optimization when you want to see only the first occurrence of
1036 something in each file of a set of files, for instance.  Only C<??>
1037 patterns local to the current package are reset.
1038
1039     while (<>) {
1040         if (?^$?) {
1041                             # blank line between header and body
1042         }
1043     } continue {
1044         reset if eof;       # clear ?? status for next file
1045     }
1046
1047 This usage is vaguely deprecated, which means it just might possibly
1048 be removed in some distant future version of Perl, perhaps somewhere
1049 around the year 2168.
1050
1051 =item m/PATTERN/cgimosx
1052 X<m> X<operator, match>
1053 X<regexp, options> X<regexp> X<regex, options> X<regex>
1054 X</c> X</i> X</m> X</o> X</s> X</x>
1055
1056 =item /PATTERN/cgimosx
1057
1058 Searches a string for a pattern match, and in scalar context returns
1059 true if it succeeds, false if it fails.  If no string is specified
1060 via the C<=~> or C<!~> operator, the $_ string is searched.  (The
1061 string specified with C<=~> need not be an lvalue--it may be the
1062 result of an expression evaluation, but remember the C<=~> binds
1063 rather tightly.)  See also L<perlre>.  See L<perllocale> for
1064 discussion of additional considerations that apply when C<use locale>
1065 is in effect.
1066
1067 Options are:
1068
1069     c   Do not reset search position on a failed match when /g is in effect.
1070     g   Match globally, i.e., find all occurrences.
1071     i   Do case-insensitive pattern matching.
1072     m   Treat string as multiple lines.
1073     o   Compile pattern only once.
1074     s   Treat string as single line.
1075     x   Use extended regular expressions.
1076
1077 If "/" is the delimiter then the initial C<m> is optional.  With the C<m>
1078 you can use any pair of non-alphanumeric, non-whitespace characters
1079 as delimiters.  This is particularly useful for matching path names
1080 that contain "/", to avoid LTS (leaning toothpick syndrome).  If "?" is
1081 the delimiter, then the match-only-once rule of C<?PATTERN?> applies.
1082 If "'" is the delimiter, no interpolation is performed on the PATTERN.
1083
1084 PATTERN may contain variables, which will be interpolated (and the
1085 pattern recompiled) every time the pattern search is evaluated, except
1086 for when the delimiter is a single quote.  (Note that C<$(>, C<$)>, and
1087 C<$|> are not interpolated because they look like end-of-string tests.)
1088 If you want such a pattern to be compiled only once, add a C</o> after
1089 the trailing delimiter.  This avoids expensive run-time recompilations,
1090 and is useful when the value you are interpolating won't change over
1091 the life of the script.  However, mentioning C</o> constitutes a promise
1092 that you won't change the variables in the pattern.  If you change them,
1093 Perl won't even notice.  See also L<"qr/STRING/imosx">.
1094
1095 If the PATTERN evaluates to the empty string, the last
1096 I<successfully> matched regular expression is used instead. In this
1097 case, only the C<g> and C<c> flags on the empty pattern is honoured -
1098 the other flags are taken from the original pattern. If no match has
1099 previously succeeded, this will (silently) act instead as a genuine
1100 empty pattern (which will always match).
1101
1102 Note that it's possible to confuse Perl into thinking C<//> (the empty
1103 regex) is really C<//> (the defined-or operator).  Perl is usually pretty
1104 good about this, but some pathological cases might trigger this, such as
1105 C<$a///> (is that C<($a) / (//)> or C<$a // />?) and C<print $fh //>
1106 (C<print $fh(//> or C<print($fh //>?).  In all of these examples, Perl
1107 will assume you meant defined-or.  If you meant the empty regex, just
1108 use parentheses or spaces to disambiguate, or even prefix the empty
1109 regex with an C<m> (so C<//> becomes C<m//>).
1110
1111 If the C</g> option is not used, C<m//> in list context returns a
1112 list consisting of the subexpressions matched by the parentheses in the
1113 pattern, i.e., (C<$1>, C<$2>, C<$3>...).  (Note that here C<$1> etc. are
1114 also set, and that this differs from Perl 4's behavior.)  When there are
1115 no parentheses in the pattern, the return value is the list C<(1)> for
1116 success.  With or without parentheses, an empty list is returned upon
1117 failure.
1118
1119 Examples:
1120
1121     open(TTY, '/dev/tty');
1122     <TTY> =~ /^y/i && foo();    # do foo if desired
1123
1124     if (/Version: *([0-9.]*)/) { $version = $1; }
1125
1126     next if m#^/usr/spool/uucp#;
1127
1128     # poor man's grep
1129     $arg = shift;
1130     while (<>) {
1131         print if /$arg/o;       # compile only once
1132     }
1133
1134     if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))
1135
1136 This last example splits $foo into the first two words and the
1137 remainder of the line, and assigns those three fields to $F1, $F2, and
1138 $Etc.  The conditional is true if any variables were assigned, i.e., if
1139 the pattern matched.
1140
1141 The C</g> modifier specifies global pattern matching--that is,
1142 matching as many times as possible within the string.  How it behaves
1143 depends on the context.  In list context, it returns a list of the
1144 substrings matched by any capturing parentheses in the regular
1145 expression.  If there are no parentheses, it returns a list of all
1146 the matched strings, as if there were parentheses around the whole
1147 pattern.
1148
1149 In scalar context, each execution of C<m//g> finds the next match,
1150 returning true if it matches, and false if there is no further match.
1151 The position after the last match can be read or set using the pos()
1152 function; see L<perlfunc/pos>.   A failed match normally resets the
1153 search position to the beginning of the string, but you can avoid that
1154 by adding the C</c> modifier (e.g. C<m//gc>).  Modifying the target
1155 string also resets the search position.
1156
1157 You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a
1158 zero-width assertion that matches the exact position where the previous
1159 C<m//g>, if any, left off.  Without the C</g> modifier, the C<\G> assertion
1160 still anchors at pos(), but the match is of course only attempted once.
1161 Using C<\G> without C</g> on a target string that has not previously had a
1162 C</g> match applied to it is the same as using the C<\A> assertion to match
1163 the beginning of the string.  Note also that, currently, C<\G> is only
1164 properly supported when anchored at the very beginning of the pattern.
1165
1166 Examples:
1167
1168     # list context
1169     ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g);
1170
1171     # scalar context
1172     $/ = "";
1173     while (defined($paragraph = <>)) {
1174         while ($paragraph =~ /[a-z]['")]*[.!?]+['")]*\s/g) {
1175             $sentences++;
1176         }
1177     }
1178     print "$sentences\n";
1179
1180     # using m//gc with \G
1181     $_ = "ppooqppqq";
1182     while ($i++ < 2) {
1183         print "1: '";
1184         print $1 while /(o)/gc; print "', pos=", pos, "\n";
1185         print "2: '";
1186         print $1 if /\G(q)/gc;  print "', pos=", pos, "\n";
1187         print "3: '";
1188         print $1 while /(p)/gc; print "', pos=", pos, "\n";
1189     }
1190     print "Final: '$1', pos=",pos,"\n" if /\G(.)/;
1191
1192 The last example should print:
1193
1194     1: 'oo', pos=4
1195     2: 'q', pos=5
1196     3: 'pp', pos=7
1197     1: '', pos=7
1198     2: 'q', pos=8
1199     3: '', pos=8
1200     Final: 'q', pos=8
1201
1202 Notice that the final match matched C<q> instead of C<p>, which a match
1203 without the C<\G> anchor would have done. Also note that the final match
1204 did not update C<pos> -- C<pos> is only updated on a C</g> match. If the
1205 final match did indeed match C<p>, it's a good bet that you're running an
1206 older (pre-5.6.0) Perl.
1207
1208 A useful idiom for C<lex>-like scanners is C</\G.../gc>.  You can
1209 combine several regexps like this to process a string part-by-part,
1210 doing different actions depending on which regexp matched.  Each
1211 regexp tries to match where the previous one leaves off.
1212
1213  $_ = <<'EOL';
1214       $url = new URI::URL "http://www/";   die if $url eq "xXx";
1215  EOL
1216  LOOP:
1217     {
1218       print(" digits"),         redo LOOP if /\G\d+\b[,.;]?\s*/gc;
1219       print(" lowercase"),      redo LOOP if /\G[a-z]+\b[,.;]?\s*/gc;
1220       print(" UPPERCASE"),      redo LOOP if /\G[A-Z]+\b[,.;]?\s*/gc;
1221       print(" Capitalized"),    redo LOOP if /\G[A-Z][a-z]+\b[,.;]?\s*/gc;
1222       print(" MiXeD"),          redo LOOP if /\G[A-Za-z]+\b[,.;]?\s*/gc;
1223       print(" alphanumeric"),   redo LOOP if /\G[A-Za-z0-9]+\b[,.;]?\s*/gc;
1224       print(" line-noise"),     redo LOOP if /\G[^A-Za-z0-9]+/gc;
1225       print ". That's all!\n";
1226     }
1227
1228 Here is the output (split into several lines):
1229
1230  line-noise lowercase line-noise lowercase UPPERCASE line-noise
1231  UPPERCASE line-noise lowercase line-noise lowercase line-noise
1232  lowercase lowercase line-noise lowercase lowercase line-noise
1233  MiXeD line-noise. That's all!
1234
1235 =item q/STRING/
1236 X<q> X<quote, single> X<'> X<''>
1237
1238 =item 'STRING'
1239
1240 A single-quoted, literal string.  A backslash represents a backslash
1241 unless followed by the delimiter or another backslash, in which case
1242 the delimiter or backslash is interpolated.
1243
1244     $foo = q!I said, "You said, 'She said it.'"!;
1245     $bar = q('This is it.');
1246     $baz = '\n';                # a two-character string
1247
1248 =item qq/STRING/
1249 X<qq> X<quote, double> X<"> X<"">
1250
1251 =item "STRING"
1252
1253 A double-quoted, interpolated string.
1254
1255     $_ .= qq
1256      (*** The previous line contains the naughty word "$1".\n)
1257                 if /\b(tcl|java|python)\b/i;      # :-)
1258     $baz = "\n";                # a one-character string
1259
1260 =item qr/STRING/imosx
1261 X<qr> X</i> X</m> X</o> X</s> X</x>
1262
1263 This operator quotes (and possibly compiles) its I<STRING> as a regular
1264 expression.  I<STRING> is interpolated the same way as I<PATTERN>
1265 in C<m/PATTERN/>.  If "'" is used as the delimiter, no interpolation
1266 is done.  Returns a Perl value which may be used instead of the
1267 corresponding C</STRING/imosx> expression.
1268
1269 For example,
1270
1271     $rex = qr/my.STRING/is;
1272     s/$rex/foo/;
1273
1274 is equivalent to
1275
1276     s/my.STRING/foo/is;
1277
1278 The result may be used as a subpattern in a match:
1279
1280     $re = qr/$pattern/;
1281     $string =~ /foo${re}bar/;   # can be interpolated in other patterns
1282     $string =~ $re;             # or used standalone
1283     $string =~ /$re/;           # or this way
1284
1285 Since Perl may compile the pattern at the moment of execution of qr()
1286 operator, using qr() may have speed advantages in some situations,
1287 notably if the result of qr() is used standalone:
1288
1289     sub match {
1290         my $patterns = shift;
1291         my @compiled = map qr/$_/i, @$patterns;
1292         grep {
1293             my $success = 0;
1294             foreach my $pat (@compiled) {
1295                 $success = 1, last if /$pat/;
1296             }
1297             $success;
1298         } @_;
1299     }
1300
1301 Precompilation of the pattern into an internal representation at
1302 the moment of qr() avoids a need to recompile the pattern every
1303 time a match C</$pat/> is attempted.  (Perl has many other internal
1304 optimizations, but none would be triggered in the above example if
1305 we did not use qr() operator.)
1306
1307 Options are:
1308
1309     i   Do case-insensitive pattern matching.
1310     m   Treat string as multiple lines.
1311     o   Compile pattern only once.
1312     s   Treat string as single line.
1313     x   Use extended regular expressions.
1314
1315 See L<perlre> for additional information on valid syntax for STRING, and
1316 for a detailed look at the semantics of regular expressions.
1317
1318 =item qx/STRING/
1319 X<qx> X<`> X<``> X<backtick>
1320
1321 =item `STRING`
1322
1323 A string which is (possibly) interpolated and then executed as a
1324 system command with C</bin/sh> or its equivalent.  Shell wildcards,
1325 pipes, and redirections will be honored.  The collected standard
1326 output of the command is returned; standard error is unaffected.  In
1327 scalar context, it comes back as a single (potentially multi-line)
1328 string, or undef if the command failed.  In list context, returns a
1329 list of lines (however you've defined lines with $/ or
1330 $INPUT_RECORD_SEPARATOR), or an empty list if the command failed.
1331
1332 Because backticks do not affect standard error, use shell file descriptor
1333 syntax (assuming the shell supports this) if you care to address this.
1334 To capture a command's STDERR and STDOUT together:
1335
1336     $output = `cmd 2>&1`;
1337
1338 To capture a command's STDOUT but discard its STDERR:
1339
1340     $output = `cmd 2>/dev/null`;
1341
1342 To capture a command's STDERR but discard its STDOUT (ordering is
1343 important here):
1344
1345     $output = `cmd 2>&1 1>/dev/null`;
1346
1347 To exchange a command's STDOUT and STDERR in order to capture the STDERR
1348 but leave its STDOUT to come out the old STDERR:
1349
1350     $output = `cmd 3>&1 1>&2 2>&3 3>&-`;
1351
1352 To read both a command's STDOUT and its STDERR separately, it's easiest
1353 to redirect them separately to files, and then read from those files
1354 when the program is done:
1355
1356     system("program args 1>program.stdout 2>program.stderr");
1357
1358 The STDIN filehandle used by the command is inherited from Perl's STDIN.
1359 For example:
1360
1361     open BLAM, "blam" || die "Can't open: $!";
1362     open STDIN, "<&BLAM";
1363     print `sort`;
1364
1365 will print the sorted contents of the file "blam".
1366
1367 Using single-quote as a delimiter protects the command from Perl's
1368 double-quote interpolation, passing it on to the shell instead:
1369
1370     $perl_info  = qx(ps $$);            # that's Perl's $$
1371     $shell_info = qx'ps $$';            # that's the new shell's $$
1372
1373 How that string gets evaluated is entirely subject to the command
1374 interpreter on your system.  On most platforms, you will have to protect
1375 shell metacharacters if you want them treated literally.  This is in
1376 practice difficult to do, as it's unclear how to escape which characters.
1377 See L<perlsec> for a clean and safe example of a manual fork() and exec()
1378 to emulate backticks safely.
1379
1380 On some platforms (notably DOS-like ones), the shell may not be
1381 capable of dealing with multiline commands, so putting newlines in
1382 the string may not get you what you want.  You may be able to evaluate
1383 multiple commands in a single line by separating them with the command
1384 separator character, if your shell supports that (e.g. C<;> on many Unix
1385 shells; C<&> on the Windows NT C<cmd> shell).
1386
1387 Beginning with v5.6.0, Perl will attempt to flush all files opened for
1388 output before starting the child process, but this may not be supported
1389 on some platforms (see L<perlport>).  To be safe, you may need to set
1390 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
1391 C<IO::Handle> on any open handles.
1392
1393 Beware that some command shells may place restrictions on the length
1394 of the command line.  You must ensure your strings don't exceed this
1395 limit after any necessary interpolations.  See the platform-specific
1396 release notes for more details about your particular environment.
1397
1398 Using this operator can lead to programs that are difficult to port,
1399 because the shell commands called vary between systems, and may in
1400 fact not be present at all.  As one example, the C<type> command under
1401 the POSIX shell is very different from the C<type> command under DOS.
1402 That doesn't mean you should go out of your way to avoid backticks
1403 when they're the right way to get something done.  Perl was made to be
1404 a glue language, and one of the things it glues together is commands.
1405 Just understand what you're getting yourself into.
1406
1407 See L</"I/O Operators"> for more discussion.
1408
1409 =item qw/STRING/
1410 X<qw> X<quote, list> X<quote, words>
1411
1412 Evaluates to a list of the words extracted out of STRING, using embedded
1413 whitespace as the word delimiters.  It can be understood as being roughly
1414 equivalent to:
1415
1416     split(' ', q/STRING/);
1417
1418 the differences being that it generates a real list at compile time, and
1419 in scalar context it returns the last element in the list.  So
1420 this expression:
1421
1422     qw(foo bar baz)
1423
1424 is semantically equivalent to the list:
1425
1426     'foo', 'bar', 'baz'
1427
1428 Some frequently seen examples:
1429
1430     use POSIX qw( setlocale localeconv )
1431     @EXPORT = qw( foo bar baz );
1432
1433 A common mistake is to try to separate the words with comma or to
1434 put comments into a multi-line C<qw>-string.  For this reason, the
1435 C<use warnings> pragma and the B<-w> switch (that is, the C<$^W> variable)
1436 produces warnings if the STRING contains the "," or the "#" character.
1437
1438 =item s/PATTERN/REPLACEMENT/egimosx
1439 X<substitute> X<substitution> X<replace> X<regexp, replace>
1440 X<regexp, substitute> X</e> X</g> X</i> X</m> X</o> X</s> X</x>
1441
1442 Searches a string for a pattern, and if found, replaces that pattern
1443 with the replacement text and returns the number of substitutions
1444 made.  Otherwise it returns false (specifically, the empty string).
1445
1446 If no string is specified via the C<=~> or C<!~> operator, the C<$_>
1447 variable is searched and modified.  (The string specified with C<=~> must
1448 be scalar variable, an array element, a hash element, or an assignment
1449 to one of those, i.e., an lvalue.)
1450
1451 If the delimiter chosen is a single quote, no interpolation is
1452 done on either the PATTERN or the REPLACEMENT.  Otherwise, if the
1453 PATTERN contains a $ that looks like a variable rather than an
1454 end-of-string test, the variable will be interpolated into the pattern
1455 at run-time.  If you want the pattern compiled only once the first time
1456 the variable is interpolated, use the C</o> option.  If the pattern
1457 evaluates to the empty string, the last successfully executed regular
1458 expression is used instead.  See L<perlre> for further explanation on these.
1459 See L<perllocale> for discussion of additional considerations that apply
1460 when C<use locale> is in effect.
1461
1462 Options are:
1463
1464     e   Evaluate the right side as an expression.
1465     g   Replace globally, i.e., all occurrences.
1466     i   Do case-insensitive pattern matching.
1467     m   Treat string as multiple lines.
1468     o   Compile pattern only once.
1469     s   Treat string as single line.
1470     x   Use extended regular expressions.
1471
1472 Any non-alphanumeric, non-whitespace delimiter may replace the
1473 slashes.  If single quotes are used, no interpretation is done on the
1474 replacement string (the C</e> modifier overrides this, however).  Unlike
1475 Perl 4, Perl 5 treats backticks as normal delimiters; the replacement
1476 text is not evaluated as a command.  If the
1477 PATTERN is delimited by bracketing quotes, the REPLACEMENT has its own
1478 pair of quotes, which may or may not be bracketing quotes, e.g.,
1479 C<s(foo)(bar)> or C<< s<foo>/bar/ >>.  A C</e> will cause the
1480 replacement portion to be treated as a full-fledged Perl expression
1481 and evaluated right then and there.  It is, however, syntax checked at
1482 compile-time. A second C<e> modifier will cause the replacement portion
1483 to be C<eval>ed before being run as a Perl expression.
1484
1485 Examples:
1486
1487     s/\bgreen\b/mauve/g;                # don't change wintergreen
1488
1489     $path =~ s|/usr/bin|/usr/local/bin|;
1490
1491     s/Login: $foo/Login: $bar/; # run-time pattern
1492
1493     ($foo = $bar) =~ s/this/that/;      # copy first, then change
1494
1495     $count = ($paragraph =~ s/Mister\b/Mr./g);  # get change-count
1496
1497     $_ = 'abc123xyz';
1498     s/\d+/$&*2/e;               # yields 'abc246xyz'
1499     s/\d+/sprintf("%5d",$&)/e;  # yields 'abc  246xyz'
1500     s/\w/$& x 2/eg;             # yields 'aabbcc  224466xxyyzz'
1501
1502     s/%(.)/$percent{$1}/g;      # change percent escapes; no /e
1503     s/%(.)/$percent{$1} || $&/ge;       # expr now, so /e
1504     s/^=(\w+)/&pod($1)/ge;      # use function call
1505
1506     # expand variables in $_, but dynamics only, using
1507     # symbolic dereferencing
1508     s/\$(\w+)/${$1}/g;
1509
1510     # Add one to the value of any numbers in the string
1511     s/(\d+)/1 + $1/eg;
1512
1513     # This will expand any embedded scalar variable
1514     # (including lexicals) in $_ : First $1 is interpolated
1515     # to the variable name, and then evaluated
1516     s/(\$\w+)/$1/eeg;
1517
1518     # Delete (most) C comments.
1519     $program =~ s {
1520         /\*     # Match the opening delimiter.
1521         .*?     # Match a minimal number of characters.
1522         \*/     # Match the closing delimiter.
1523     } []gsx;
1524
1525     s/^\s*(.*?)\s*$/$1/;        # trim whitespace in $_, expensively
1526
1527     for ($variable) {           # trim whitespace in $variable, cheap
1528         s/^\s+//;
1529         s/\s+$//;
1530     }
1531
1532     s/([^ ]*) *([^ ]*)/$2 $1/;  # reverse 1st two fields
1533
1534 Note the use of $ instead of \ in the last example.  Unlike
1535 B<sed>, we use the \<I<digit>> form in only the left hand side.
1536 Anywhere else it's $<I<digit>>.
1537
1538 Occasionally, you can't use just a C</g> to get all the changes
1539 to occur that you might want.  Here are two common cases:
1540
1541     # put commas in the right places in an integer
1542     1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g;
1543
1544     # expand tabs to 8-column spacing
1545     1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
1546
1547 =item tr/SEARCHLIST/REPLACEMENTLIST/cds
1548 X<tr> X<y> X<transliterate> X</c> X</d> X</s>
1549
1550 =item y/SEARCHLIST/REPLACEMENTLIST/cds
1551
1552 Transliterates all occurrences of the characters found in the search list
1553 with the corresponding character in the replacement list.  It returns
1554 the number of characters replaced or deleted.  If no string is
1555 specified via the =~ or !~ operator, the $_ string is transliterated.  (The
1556 string specified with =~ must be a scalar variable, an array element, a
1557 hash element, or an assignment to one of those, i.e., an lvalue.)
1558
1559 A character range may be specified with a hyphen, so C<tr/A-J/0-9/>
1560 does the same replacement as C<tr/ACEGIBDFHJ/0246813579/>.
1561 For B<sed> devotees, C<y> is provided as a synonym for C<tr>.  If the
1562 SEARCHLIST is delimited by bracketing quotes, the REPLACEMENTLIST has
1563 its own pair of quotes, which may or may not be bracketing quotes,
1564 e.g., C<tr[A-Z][a-z]> or C<tr(+\-*/)/ABCD/>.
1565
1566 Note that C<tr> does B<not> do regular expression character classes
1567 such as C<\d> or C<[:lower:]>.  The <tr> operator is not equivalent to
1568 the tr(1) utility.  If you want to map strings between lower/upper
1569 cases, see L<perlfunc/lc> and L<perlfunc/uc>, and in general consider
1570 using the C<s> operator if you need regular expressions.
1571
1572 Note also that the whole range idea is rather unportable between
1573 character sets--and even within character sets they may cause results
1574 you probably didn't expect.  A sound principle is to use only ranges
1575 that begin from and end at either alphabets of equal case (a-e, A-E),
1576 or digits (0-4).  Anything else is unsafe.  If in doubt, spell out the
1577 character sets in full.
1578
1579 Options:
1580
1581     c   Complement the SEARCHLIST.
1582     d   Delete found but unreplaced characters.
1583     s   Squash duplicate replaced characters.
1584
1585 If the C</c> modifier is specified, the SEARCHLIST character set
1586 is complemented.  If the C</d> modifier is specified, any characters
1587 specified by SEARCHLIST not found in REPLACEMENTLIST are deleted.
1588 (Note that this is slightly more flexible than the behavior of some
1589 B<tr> programs, which delete anything they find in the SEARCHLIST,
1590 period.) If the C</s> modifier is specified, sequences of characters
1591 that were transliterated to the same character are squashed down
1592 to a single instance of the character.
1593
1594 If the C</d> modifier is used, the REPLACEMENTLIST is always interpreted
1595 exactly as specified.  Otherwise, if the REPLACEMENTLIST is shorter
1596 than the SEARCHLIST, the final character is replicated till it is long
1597 enough.  If the REPLACEMENTLIST is empty, the SEARCHLIST is replicated.
1598 This latter is useful for counting characters in a class or for
1599 squashing character sequences in a class.
1600
1601 Examples:
1602
1603     $ARGV[1] =~ tr/A-Z/a-z/;    # canonicalize to lower case
1604
1605     $cnt = tr/*/*/;             # count the stars in $_
1606
1607     $cnt = $sky =~ tr/*/*/;     # count the stars in $sky
1608
1609     $cnt = tr/0-9//;            # count the digits in $_
1610
1611     tr/a-zA-Z//s;               # bookkeeper -> bokeper
1612
1613     ($HOST = $host) =~ tr/a-z/A-Z/;
1614
1615     tr/a-zA-Z/ /cs;             # change non-alphas to single space
1616
1617     tr [\200-\377]
1618        [\000-\177];             # delete 8th bit
1619
1620 If multiple transliterations are given for a character, only the
1621 first one is used:
1622
1623     tr/AAA/XYZ/
1624
1625 will transliterate any A to X.
1626
1627 Because the transliteration table is built at compile time, neither
1628 the SEARCHLIST nor the REPLACEMENTLIST are subjected to double quote
1629 interpolation.  That means that if you want to use variables, you
1630 must use an eval():
1631
1632     eval "tr/$oldlist/$newlist/";
1633     die $@ if $@;
1634
1635     eval "tr/$oldlist/$newlist/, 1" or die $@;
1636
1637 =item <<EOF
1638 X<here-doc> X<heredoc> X<here-document> X<<< << >>>
1639
1640 A line-oriented form of quoting is based on the shell "here-document"
1641 syntax.  Following a C<< << >> you specify a string to terminate
1642 the quoted material, and all lines following the current line down to
1643 the terminating string are the value of the item.  The terminating
1644 string may be either an identifier (a word), or some quoted text.  If
1645 quoted, the type of quotes you use determines the treatment of the
1646 text, just as in regular quoting.  An unquoted identifier works like
1647 double quotes.  There must be no space between the C<< << >> and
1648 the identifier, unless the identifier is quoted.  (If you put a space it
1649 will be treated as a null identifier, which is valid, and matches the first
1650 empty line.)  The terminating string must appear by itself (unquoted and
1651 with no surrounding whitespace) on the terminating line.
1652
1653        print <<EOF;
1654     The price is $Price.
1655     EOF
1656
1657        print << "EOF"; # same as above
1658     The price is $Price.
1659     EOF
1660
1661        print << `EOC`; # execute commands
1662     echo hi there
1663     echo lo there
1664     EOC
1665
1666        print <<"foo", <<"bar"; # you can stack them
1667     I said foo.
1668     foo
1669     I said bar.
1670     bar
1671
1672        myfunc(<< "THIS", 23, <<'THAT');
1673     Here's a line
1674     or two.
1675     THIS
1676     and here's another.
1677     THAT
1678
1679 Just don't forget that you have to put a semicolon on the end
1680 to finish the statement, as Perl doesn't know you're not going to
1681 try to do this:
1682
1683        print <<ABC
1684     179231
1685     ABC
1686        + 20;
1687
1688 If you want your here-docs to be indented with the
1689 rest of the code, you'll need to remove leading whitespace
1690 from each line manually:
1691
1692     ($quote = <<'FINIS') =~ s/^\s+//gm;
1693        The Road goes ever on and on,
1694        down from the door where it began.
1695     FINIS
1696
1697 If you use a here-doc within a delimited construct, such as in C<s///eg>,
1698 the quoted material must come on the lines following the final delimiter.
1699 So instead of
1700
1701     s/this/<<E . 'that'
1702     the other
1703     E
1704      . 'more '/eg;
1705
1706 you have to write
1707
1708     s/this/<<E . 'that'
1709      . 'more '/eg;
1710     the other
1711     E
1712
1713 If the terminating identifier is on the last line of the program, you
1714 must be sure there is a newline after it; otherwise, Perl will give the
1715 warning B<Can't find string terminator "END" anywhere before EOF...>.
1716
1717 Additionally, the quoting rules for the identifier are not related to
1718 Perl's quoting rules -- C<q()>, C<qq()>, and the like are not supported
1719 in place of C<''> and C<"">, and the only interpolation is for backslashing
1720 the quoting character:
1721
1722     print << "abc\"def";
1723     testing...
1724     abc"def
1725
1726 Finally, quoted strings cannot span multiple lines.  The general rule is
1727 that the identifier must be a string literal.  Stick with that, and you
1728 should be safe.
1729
1730 =back
1731
1732 =head2 Gory details of parsing quoted constructs
1733 X<quote, gory details>
1734
1735 When presented with something that might have several different
1736 interpretations, Perl uses the B<DWIM> (that's "Do What I Mean")
1737 principle to pick the most probable interpretation.  This strategy
1738 is so successful that Perl programmers often do not suspect the
1739 ambivalence of what they write.  But from time to time, Perl's
1740 notions differ substantially from what the author honestly meant.
1741
1742 This section hopes to clarify how Perl handles quoted constructs.
1743 Although the most common reason to learn this is to unravel labyrinthine
1744 regular expressions, because the initial steps of parsing are the
1745 same for all quoting operators, they are all discussed together.
1746
1747 The most important Perl parsing rule is the first one discussed
1748 below: when processing a quoted construct, Perl first finds the end
1749 of that construct, then interprets its contents.  If you understand
1750 this rule, you may skip the rest of this section on the first
1751 reading.  The other rules are likely to contradict the user's
1752 expectations much less frequently than this first one.
1753
1754 Some passes discussed below are performed concurrently, but because
1755 their results are the same, we consider them individually.  For different
1756 quoting constructs, Perl performs different numbers of passes, from
1757 one to five, but these passes are always performed in the same order.
1758
1759 =over 4
1760
1761 =item Finding the end
1762
1763 The first pass is finding the end of the quoted construct, whether
1764 it be a multicharacter delimiter C<"\nEOF\n"> in the C<<<EOF>
1765 construct, a C</> that terminates a C<qq//> construct, a C<]> which
1766 terminates C<qq[]> construct, or a C<< > >> which terminates a
1767 fileglob started with C<< < >>.
1768
1769 When searching for single-character non-pairing delimiters, such
1770 as C</>, combinations of C<\\> and C<\/> are skipped.  However,
1771 when searching for single-character pairing delimiter like C<[>,
1772 combinations of C<\\>, C<\]>, and C<\[> are all skipped, and nested
1773 C<[>, C<]> are skipped as well.  When searching for multicharacter
1774 delimiters, nothing is skipped.
1775
1776 For constructs with three-part delimiters (C<s///>, C<y///>, and
1777 C<tr///>), the search is repeated once more.
1778
1779 During this search no attention is paid to the semantics of the construct.
1780 Thus:
1781
1782     "$hash{"$foo/$bar"}"
1783
1784 or:
1785
1786     m/
1787       bar       # NOT a comment, this slash / terminated m//!
1788      /x
1789
1790 do not form legal quoted expressions.   The quoted part ends on the
1791 first C<"> and C</>, and the rest happens to be a syntax error.
1792 Because the slash that terminated C<m//> was followed by a C<SPACE>,
1793 the example above is not C<m//x>, but rather C<m//> with no C</x>
1794 modifier.  So the embedded C<#> is interpreted as a literal C<#>.
1795
1796 Also no attention is paid to C<\c\> during this search.
1797 Thus the second C<\> in C<qq/\c\/> is interpreted as a part of C<\/>,
1798 and the following C</> is not recognized as a delimiter.
1799 Instead, use C<\034> or C<\x1c> at the end of quoted constructs.
1800
1801 =item Removal of backslashes before delimiters
1802
1803 During the second pass, text between the starting and ending
1804 delimiters is copied to a safe location, and the C<\> is removed
1805 from combinations consisting of C<\> and delimiter--or delimiters,
1806 meaning both starting and ending delimiters will should these differ.
1807 This removal does not happen for multi-character delimiters.
1808 Note that the combination C<\\> is left intact, just as it was.
1809
1810 Starting from this step no information about the delimiters is
1811 used in parsing.
1812
1813 =item Interpolation
1814 X<interpolation>
1815
1816 The next step is interpolation in the text obtained, which is now
1817 delimiter-independent.  There are four different cases.
1818
1819 =over 4
1820
1821 =item C<<<'EOF'>, C<m''>, C<s'''>, C<tr///>, C<y///>
1822
1823 No interpolation is performed.
1824
1825 =item C<''>, C<q//>
1826
1827 The only interpolation is removal of C<\> from pairs C<\\>.
1828
1829 =item C<"">, C<``>, C<qq//>, C<qx//>, C<< <file*glob> >>
1830
1831 C<\Q>, C<\U>, C<\u>, C<\L>, C<\l> (possibly paired with C<\E>) are
1832 converted to corresponding Perl constructs.  Thus, C<"$foo\Qbaz$bar">
1833 is converted to C<$foo . (quotemeta("baz" . $bar))> internally.
1834 The other combinations are replaced with appropriate expansions.
1835
1836 Let it be stressed that I<whatever falls between C<\Q> and C<\E>>
1837 is interpolated in the usual way.  Something like C<"\Q\\E"> has
1838 no C<\E> inside.  instead, it has C<\Q>, C<\\>, and C<E>, so the
1839 result is the same as for C<"\\\\E">.  As a general rule, backslashes
1840 between C<\Q> and C<\E> may lead to counterintuitive results.  So,
1841 C<"\Q\t\E"> is converted to C<quotemeta("\t")>, which is the same
1842 as C<"\\\t"> (since TAB is not alphanumeric).  Note also that:
1843
1844   $str = '\t';
1845   return "\Q$str";
1846
1847 may be closer to the conjectural I<intention> of the writer of C<"\Q\t\E">.
1848
1849 Interpolated scalars and arrays are converted internally to the C<join> and
1850 C<.> catenation operations.  Thus, C<"$foo XXX '@arr'"> becomes:
1851
1852   $foo . " XXX '" . (join $", @arr) . "'";
1853
1854 All operations above are performed simultaneously, left to right.
1855
1856 Because the result of C<"\Q STRING \E"> has all metacharacters
1857 quoted, there is no way to insert a literal C<$> or C<@> inside a
1858 C<\Q\E> pair.  If protected by C<\>, C<$> will be quoted to became
1859 C<"\\\$">; if not, it is interpreted as the start of an interpolated
1860 scalar.
1861
1862 Note also that the interpolation code needs to make a decision on
1863 where the interpolated scalar ends.  For instance, whether
1864 C<< "a $b -> {c}" >> really means:
1865
1866   "a " . $b . " -> {c}";
1867
1868 or:
1869
1870   "a " . $b -> {c};
1871
1872 Most of the time, the longest possible text that does not include
1873 spaces between components and which contains matching braces or
1874 brackets.  because the outcome may be determined by voting based
1875 on heuristic estimators, the result is not strictly predictable.
1876 Fortunately, it's usually correct for ambiguous cases.
1877
1878 =item C<?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>,
1879
1880 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, and interpolation
1881 happens (almost) as with C<qq//> constructs, but the substitution
1882 of C<\> followed by RE-special chars (including C<\>) is not
1883 performed.  Moreover, inside C<(?{BLOCK})>, C<(?# comment )>, and
1884 a C<#>-comment in a C<//x>-regular expression, no processing is
1885 performed whatsoever.  This is the first step at which the presence
1886 of the C<//x> modifier is relevant.
1887
1888 Interpolation has several quirks: C<$|>, C<$(>, and C<$)> are not
1889 interpolated, and constructs C<$var[SOMETHING]> are voted (by several
1890 different estimators) to be either an array element or C<$var>
1891 followed by an RE alternative.  This is where the notation
1892 C<${arr[$bar]}> comes handy: C</${arr[0-9]}/> is interpreted as
1893 array element C<-9>, not as a regular expression from the variable
1894 C<$arr> followed by a digit, which would be the interpretation of
1895 C</$arr[0-9]/>.  Since voting among different estimators may occur,
1896 the result is not predictable.
1897
1898 It is at this step that C<\1> is begrudgingly converted to C<$1> in
1899 the replacement text of C<s///> to correct the incorrigible
1900 I<sed> hackers who haven't picked up the saner idiom yet.  A warning
1901 is emitted if the C<use warnings> pragma or the B<-w> command-line flag
1902 (that is, the C<$^W> variable) was set.
1903
1904 The lack of processing of C<\\> creates specific restrictions on
1905 the post-processed text.  If the delimiter is C</>, one cannot get
1906 the combination C<\/> into the result of this step.  C</> will
1907 finish the regular expression, C<\/> will be stripped to C</> on
1908 the previous step, and C<\\/> will be left as is.  Because C</> is
1909 equivalent to C<\/> inside a regular expression, this does not
1910 matter unless the delimiter happens to be character special to the
1911 RE engine, such as in C<s*foo*bar*>, C<m[foo]>, or C<?foo?>; or an
1912 alphanumeric char, as in:
1913
1914   m m ^ a \s* b mmx;
1915
1916 In the RE above, which is intentionally obfuscated for illustration, the
1917 delimiter is C<m>, the modifier is C<mx>, and after backslash-removal the
1918 RE is the same as for C<m/ ^ a \s* b /mx>.  There's more than one
1919 reason you're encouraged to restrict your delimiters to non-alphanumeric,
1920 non-whitespace choices.
1921
1922 =back
1923
1924 This step is the last one for all constructs except regular expressions,
1925 which are processed further.
1926
1927 =item Interpolation of regular expressions
1928 X<regexp, interpolation>
1929
1930 Previous steps were performed during the compilation of Perl code,
1931 but this one happens at run time--although it may be optimized to
1932 be calculated at compile time if appropriate.  After preprocessing
1933 described above, and possibly after evaluation if catenation,
1934 joining, casing translation, or metaquoting are involved, the
1935 resulting I<string> is passed to the RE engine for compilation.
1936
1937 Whatever happens in the RE engine might be better discussed in L<perlre>,
1938 but for the sake of continuity, we shall do so here.
1939
1940 This is another step where the presence of the C<//x> modifier is
1941 relevant.  The RE engine scans the string from left to right and
1942 converts it to a finite automaton.
1943
1944 Backslashed characters are either replaced with corresponding
1945 literal strings (as with C<\{>), or else they generate special nodes
1946 in the finite automaton (as with C<\b>).  Characters special to the
1947 RE engine (such as C<|>) generate corresponding nodes or groups of
1948 nodes.  C<(?#...)> comments are ignored.  All the rest is either
1949 converted to literal strings to match, or else is ignored (as is
1950 whitespace and C<#>-style comments if C<//x> is present).
1951
1952 Parsing of the bracketed character class construct, C<[...]>, is
1953 rather different than the rule used for the rest of the pattern.
1954 The terminator of this construct is found using the same rules as
1955 for finding the terminator of a C<{}>-delimited construct, the only
1956 exception being that C<]> immediately following C<[> is treated as
1957 though preceded by a backslash.  Similarly, the terminator of
1958 C<(?{...})> is found using the same rules as for finding the
1959 terminator of a C<{}>-delimited construct.
1960
1961 It is possible to inspect both the string given to RE engine and the
1962 resulting finite automaton.  See the arguments C<debug>/C<debugcolor>
1963 in the C<use L<re>> pragma, as well as Perl's B<-Dr> command-line
1964 switch documented in L<perlrun/"Command Switches">.
1965
1966 =item Optimization of regular expressions
1967 X<regexp, optimization>
1968
1969 This step is listed for completeness only.  Since it does not change
1970 semantics, details of this step are not documented and are subject
1971 to change without notice.  This step is performed over the finite
1972 automaton that was generated during the previous pass.
1973
1974 It is at this stage that C<split()> silently optimizes C</^/> to
1975 mean C</^/m>.
1976
1977 =back
1978
1979 =head2 I/O Operators
1980 X<operator, i/o> X<operator, io> X<io> X<while> X<filehandle>
1981 X<< <> >> X<@ARGV>
1982
1983 There are several I/O operators you should know about.
1984
1985 A string enclosed by backticks (grave accents) first undergoes
1986 double-quote interpolation.  It is then interpreted as an external
1987 command, and the output of that command is the value of the
1988 backtick string, like in a shell.  In scalar context, a single string
1989 consisting of all output is returned.  In list context, a list of
1990 values is returned, one per line of output.  (You can set C<$/> to use
1991 a different line terminator.)  The command is executed each time the
1992 pseudo-literal is evaluated.  The status value of the command is
1993 returned in C<$?> (see L<perlvar> for the interpretation of C<$?>).
1994 Unlike in B<csh>, no translation is done on the return data--newlines
1995 remain newlines.  Unlike in any of the shells, single quotes do not
1996 hide variable names in the command from interpretation.  To pass a
1997 literal dollar-sign through to the shell you need to hide it with a
1998 backslash.  The generalized form of backticks is C<qx//>.  (Because
1999 backticks always undergo shell expansion as well, see L<perlsec> for
2000 security concerns.)
2001 X<qx> X<`> X<``> X<backtick> X<glob>
2002
2003 In scalar context, evaluating a filehandle in angle brackets yields
2004 the next line from that file (the newline, if any, included), or
2005 C<undef> at end-of-file or on error.  When C<$/> is set to C<undef>
2006 (sometimes known as file-slurp mode) and the file is empty, it
2007 returns C<''> the first time, followed by C<undef> subsequently.
2008
2009 Ordinarily you must assign the returned value to a variable, but
2010 there is one situation where an automatic assignment happens.  If
2011 and only if the input symbol is the only thing inside the conditional
2012 of a C<while> statement (even if disguised as a C<for(;;)> loop),
2013 the value is automatically assigned to the global variable $_,
2014 destroying whatever was there previously.  (This may seem like an
2015 odd thing to you, but you'll use the construct in almost every Perl
2016 script you write.)  The $_ variable is not implicitly localized.
2017 You'll have to put a C<local $_;> before the loop if you want that
2018 to happen.
2019
2020 The following lines are equivalent:
2021
2022     while (defined($_ = <STDIN>)) { print; }
2023     while ($_ = <STDIN>) { print; }
2024     while (<STDIN>) { print; }
2025     for (;<STDIN>;) { print; }
2026     print while defined($_ = <STDIN>);
2027     print while ($_ = <STDIN>);
2028     print while <STDIN>;
2029
2030 This also behaves similarly, but avoids $_ :
2031
2032     while (my $line = <STDIN>) { print $line }
2033
2034 In these loop constructs, the assigned value (whether assignment
2035 is automatic or explicit) is then tested to see whether it is
2036 defined.  The defined test avoids problems where line has a string
2037 value that would be treated as false by Perl, for example a "" or
2038 a "0" with no trailing newline.  If you really mean for such values
2039 to terminate the loop, they should be tested for explicitly:
2040
2041     while (($_ = <STDIN>) ne '0') { ... }
2042     while (<STDIN>) { last unless $_; ... }
2043
2044 In other boolean contexts, C<< <I<filehandle>> >> without an
2045 explicit C<defined> test or comparison elicit a warning if the
2046 C<use warnings> pragma or the B<-w>
2047 command-line switch (the C<$^W> variable) is in effect.
2048
2049 The filehandles STDIN, STDOUT, and STDERR are predefined.  (The
2050 filehandles C<stdin>, C<stdout>, and C<stderr> will also work except
2051 in packages, where they would be interpreted as local identifiers
2052 rather than global.)  Additional filehandles may be created with
2053 the open() function, amongst others.  See L<perlopentut> and
2054 L<perlfunc/open> for details on this.
2055 X<stdin> X<stdout> X<sterr>
2056
2057 If a <FILEHANDLE> is used in a context that is looking for
2058 a list, a list comprising all input lines is returned, one line per
2059 list element.  It's easy to grow to a rather large data space this
2060 way, so use with care.
2061
2062 <FILEHANDLE> may also be spelled C<readline(*FILEHANDLE)>.
2063 See L<perlfunc/readline>.
2064
2065 The null filehandle <> is special: it can be used to emulate the
2066 behavior of B<sed> and B<awk>.  Input from <> comes either from
2067 standard input, or from each file listed on the command line.  Here's
2068 how it works: the first time <> is evaluated, the @ARGV array is
2069 checked, and if it is empty, C<$ARGV[0]> is set to "-", which when opened
2070 gives you standard input.  The @ARGV array is then processed as a list
2071 of filenames.  The loop
2072
2073     while (<>) {
2074         ...                     # code for each line
2075     }
2076
2077 is equivalent to the following Perl-like pseudo code:
2078
2079     unshift(@ARGV, '-') unless @ARGV;
2080     while ($ARGV = shift) {
2081         open(ARGV, $ARGV);
2082         while (<ARGV>) {
2083             ...         # code for each line
2084         }
2085     }
2086
2087 except that it isn't so cumbersome to say, and will actually work.
2088 It really does shift the @ARGV array and put the current filename
2089 into the $ARGV variable.  It also uses filehandle I<ARGV>
2090 internally--<> is just a synonym for <ARGV>, which
2091 is magical.  (The pseudo code above doesn't work because it treats
2092 <ARGV> as non-magical.)
2093
2094 You can modify @ARGV before the first <> as long as the array ends up
2095 containing the list of filenames you really want.  Line numbers (C<$.>)
2096 continue as though the input were one big happy file.  See the example
2097 in L<perlfunc/eof> for how to reset line numbers on each file.
2098
2099 If you want to set @ARGV to your own list of files, go right ahead.
2100 This sets @ARGV to all plain text files if no @ARGV was given:
2101
2102     @ARGV = grep { -f && -T } glob('*') unless @ARGV;
2103
2104 You can even set them to pipe commands.  For example, this automatically
2105 filters compressed arguments through B<gzip>:
2106
2107     @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV;
2108
2109 If you want to pass switches into your script, you can use one of the
2110 Getopts modules or put a loop on the front like this:
2111
2112     while ($_ = $ARGV[0], /^-/) {
2113         shift;
2114         last if /^--$/;
2115         if (/^-D(.*)/) { $debug = $1 }
2116         if (/^-v/)     { $verbose++  }
2117         # ...           # other switches
2118     }
2119
2120     while (<>) {
2121         # ...           # code for each line
2122     }
2123
2124 The <> symbol will return C<undef> for end-of-file only once.
2125 If you call it again after this, it will assume you are processing another
2126 @ARGV list, and if you haven't set @ARGV, will read input from STDIN.
2127
2128 If what the angle brackets contain is a simple scalar variable (e.g.,
2129 <$foo>), then that variable contains the name of the
2130 filehandle to input from, or its typeglob, or a reference to the
2131 same.  For example:
2132
2133     $fh = \*STDIN;
2134     $line = <$fh>;
2135
2136 If what's within the angle brackets is neither a filehandle nor a simple
2137 scalar variable containing a filehandle name, typeglob, or typeglob
2138 reference, it is interpreted as a filename pattern to be globbed, and
2139 either a list of filenames or the next filename in the list is returned,
2140 depending on context.  This distinction is determined on syntactic
2141 grounds alone.  That means C<< <$x> >> is always a readline() from
2142 an indirect handle, but C<< <$hash{key}> >> is always a glob().
2143 That's because $x is a simple scalar variable, but C<$hash{key}> is
2144 not--it's a hash element.  Even C<< <$x > >> (note the extra space)
2145 is treated as C<glob("$x ")>, not C<readline($x)>.
2146
2147 One level of double-quote interpretation is done first, but you can't
2148 say C<< <$foo> >> because that's an indirect filehandle as explained
2149 in the previous paragraph.  (In older versions of Perl, programmers
2150 would insert curly brackets to force interpretation as a filename glob:
2151 C<< <${foo}> >>.  These days, it's considered cleaner to call the
2152 internal function directly as C<glob($foo)>, which is probably the right
2153 way to have done it in the first place.)  For example:
2154
2155     while (<*.c>) {
2156         chmod 0644, $_;
2157     }
2158
2159 is roughly equivalent to:
2160
2161     open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
2162     while (<FOO>) {
2163         chomp;
2164         chmod 0644, $_;
2165     }
2166
2167 except that the globbing is actually done internally using the standard
2168 C<File::Glob> extension.  Of course, the shortest way to do the above is:
2169
2170     chmod 0644, <*.c>;
2171
2172 A (file)glob evaluates its (embedded) argument only when it is
2173 starting a new list.  All values must be read before it will start
2174 over.  In list context, this isn't important because you automatically
2175 get them all anyway.  However, in scalar context the operator returns
2176 the next value each time it's called, or C<undef> when the list has
2177 run out.  As with filehandle reads, an automatic C<defined> is
2178 generated when the glob occurs in the test part of a C<while>,
2179 because legal glob returns (e.g. a file called F<0>) would otherwise
2180 terminate the loop.  Again, C<undef> is returned only once.  So if
2181 you're expecting a single value from a glob, it is much better to
2182 say
2183
2184     ($file) = <blurch*>;
2185
2186 than
2187
2188     $file = <blurch*>;
2189
2190 because the latter will alternate between returning a filename and
2191 returning false.
2192
2193 If you're trying to do variable interpolation, it's definitely better
2194 to use the glob() function, because the older notation can cause people
2195 to become confused with the indirect filehandle notation.
2196
2197     @files = glob("$dir/*.[ch]");
2198     @files = glob($files[$i]);
2199
2200 =head2 Constant Folding
2201 X<constant folding> X<folding>
2202
2203 Like C, Perl does a certain amount of expression evaluation at
2204 compile time whenever it determines that all arguments to an
2205 operator are static and have no side effects.  In particular, string
2206 concatenation happens at compile time between literals that don't do
2207 variable substitution.  Backslash interpolation also happens at
2208 compile time.  You can say
2209
2210     'Now is the time for all' . "\n" .
2211         'good men to come to.'
2212
2213 and this all reduces to one string internally.  Likewise, if
2214 you say
2215
2216     foreach $file (@filenames) {
2217         if (-s $file > 5 + 100 * 2**16) {  }
2218     }
2219
2220 the compiler will precompute the number which that expression
2221 represents so that the interpreter won't have to.
2222
2223 =head2 No-ops
2224 X<no-op> X<nop>
2225
2226 Perl doesn't officially have a no-op operator, but the bare constants
2227 C<0> and C<1> are special-cased to not produce a warning in a void
2228 context, so you can for example safely do
2229
2230     1 while foo();
2231
2232 =head2 Bitwise String Operators
2233 X<operator, bitwise, string>
2234
2235 Bitstrings of any size may be manipulated by the bitwise operators
2236 (C<~ | & ^>).
2237
2238 If the operands to a binary bitwise op are strings of different
2239 sizes, B<|> and B<^> ops act as though the shorter operand had
2240 additional zero bits on the right, while the B<&> op acts as though
2241 the longer operand were truncated to the length of the shorter.
2242 The granularity for such extension or truncation is one or more
2243 bytes.
2244
2245     # ASCII-based examples
2246     print "j p \n" ^ " a h";            # prints "JAPH\n"
2247     print "JA" | "  ph\n";              # prints "japh\n"
2248     print "japh\nJunk" & '_____';       # prints "JAPH\n";
2249     print 'p N$' ^ " E<H\n";            # prints "Perl\n";
2250
2251 If you are intending to manipulate bitstrings, be certain that
2252 you're supplying bitstrings: If an operand is a number, that will imply
2253 a B<numeric> bitwise operation.  You may explicitly show which type of
2254 operation you intend by using C<""> or C<0+>, as in the examples below.
2255
2256     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
2257     $foo = '150' |  105;        # yields 255
2258     $foo =  150  | '105';       # yields 255
2259     $foo = '150' | '105';       # yields string '155' (under ASCII)
2260
2261     $baz = 0+$foo & 0+$bar;     # both ops explicitly numeric
2262     $biz = "$foo" ^ "$bar";     # both ops explicitly stringy
2263
2264 See L<perlfunc/vec> for information on how to manipulate individual bits
2265 in a bit vector.
2266
2267 =head2 Integer Arithmetic
2268 X<integer>
2269
2270 By default, Perl assumes that it must do most of its arithmetic in
2271 floating point.  But by saying
2272
2273     use integer;
2274
2275 you may tell the compiler that it's okay to use integer operations
2276 (if it feels like it) from here to the end of the enclosing BLOCK.
2277 An inner BLOCK may countermand this by saying
2278
2279     no integer;
2280
2281 which lasts until the end of that BLOCK.  Note that this doesn't
2282 mean everything is only an integer, merely that Perl may use integer
2283 operations if it is so inclined.  For example, even under C<use
2284 integer>, if you take the C<sqrt(2)>, you'll still get C<1.4142135623731>
2285 or so.
2286
2287 Used on numbers, the bitwise operators ("&", "|", "^", "~", "<<",
2288 and ">>") always produce integral results.  (But see also
2289 L<Bitwise String Operators>.)  However, C<use integer> still has meaning for
2290 them.  By default, their results are interpreted as unsigned integers, but
2291 if C<use integer> is in effect, their results are interpreted
2292 as signed integers.  For example, C<~0> usually evaluates to a large
2293 integral value.  However, C<use integer; ~0> is C<-1> on two's-complement
2294 machines.
2295
2296 =head2 Floating-point Arithmetic
2297 X<floating-point> X<floating point> X<float> X<real>
2298
2299 While C<use integer> provides integer-only arithmetic, there is no
2300 analogous mechanism to provide automatic rounding or truncation to a
2301 certain number of decimal places.  For rounding to a certain number
2302 of digits, sprintf() or printf() is usually the easiest route.
2303 See L<perlfaq4>.
2304
2305 Floating-point numbers are only approximations to what a mathematician
2306 would call real numbers.  There are infinitely more reals than floats,
2307 so some corners must be cut.  For example:
2308
2309     printf "%.20g\n", 123456789123456789;
2310     #        produces 123456789123456784
2311
2312 Testing for exact equality of floating-point equality or inequality is
2313 not a good idea.  Here's a (relatively expensive) work-around to compare
2314 whether two floating-point numbers are equal to a particular number of
2315 decimal places.  See Knuth, volume II, for a more robust treatment of
2316 this topic.
2317
2318     sub fp_equal {
2319         my ($X, $Y, $POINTS) = @_;
2320         my ($tX, $tY);
2321         $tX = sprintf("%.${POINTS}g", $X);
2322         $tY = sprintf("%.${POINTS}g", $Y);
2323         return $tX eq $tY;
2324     }
2325
2326 The POSIX module (part of the standard perl distribution) implements
2327 ceil(), floor(), and other mathematical and trigonometric functions.
2328 The Math::Complex module (part of the standard perl distribution)
2329 defines mathematical functions that work on both the reals and the
2330 imaginary numbers.  Math::Complex not as efficient as POSIX, but
2331 POSIX can't work with complex numbers.
2332
2333 Rounding in financial applications can have serious implications, and
2334 the rounding method used should be specified precisely.  In these
2335 cases, it probably pays not to trust whichever system rounding is
2336 being used by Perl, but to instead implement the rounding function you
2337 need yourself.
2338
2339 =head2 Bigger Numbers
2340 X<number, arbitrary precision>
2341
2342 The standard Math::BigInt and Math::BigFloat modules provide
2343 variable-precision arithmetic and overloaded operators, although
2344 they're currently pretty slow. At the cost of some space and
2345 considerable speed, they avoid the normal pitfalls associated with
2346 limited-precision representations.
2347
2348     use Math::BigInt;
2349     $x = Math::BigInt->new('123456789123456789');
2350     print $x * $x;
2351
2352     # prints +15241578780673678515622620750190521
2353
2354 There are several modules that let you calculate with (bound only by
2355 memory and cpu-time) unlimited or fixed precision. There are also
2356 some non-standard modules that provide faster implementations via
2357 external C libraries.
2358
2359 Here is a short, but incomplete summary:
2360
2361         Math::Fraction          big, unlimited fractions like 9973 / 12967
2362         Math::String            treat string sequences like numbers
2363         Math::FixedPrecision    calculate with a fixed precision
2364         Math::Currency          for currency calculations
2365         Bit::Vector             manipulate bit vectors fast (uses C)
2366         Math::BigIntFast        Bit::Vector wrapper for big numbers
2367         Math::Pari              provides access to the Pari C library
2368         Math::BigInteger        uses an external C library
2369         Math::Cephes            uses external Cephes C library (no big numbers)
2370         Math::Cephes::Fraction  fractions via the Cephes library
2371         Math::GMP               another one using an external C library
2372
2373 Choose wisely.
2374
2375 =cut